CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8)
   2
   3 project(Gromacs)
   4 include(Dart)
   5 mark_as_advanced(DART_ROOT)
   6
   7 # PROJECT_VERSION should have the following structure:
   8 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
   9 #
  10 # The "-dev" suffix is important to keep because it makes possible to distinguish
  11 # between a build from official release and a build from git release branch on a
  12 # machine with no git.
  13 #
  14 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  15 set(PROJECT_VERSION "4.6-dev")
  16 set(CUSTOM_VERSION_STRING ""
  17     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  18 mark_as_advanced(CUSTOM_VERSION_STRING)
  19 if (CUSTOM_VERSION_STRING)
  20     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  21 endif (CUSTOM_VERSION_STRING)
  22 set(SOVERSION 6)
  23 # It is a bit irritating, but this has to be set separately for now!
  24 SET(CPACK_PACKAGE_VERSION_MAJOR "4")
  25 SET(CPACK_PACKAGE_VERSION_MINOR "6")
  26 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  27
  28
  29 # Cmake modules/macros are in a subdirectory to keep this file cleaner
  30 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  31
  32 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  33 set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  34 endif()
  35
  36 if(NOT CMAKE_BUILD_TYPE)
  37     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
  38 endif(NOT CMAKE_BUILD_TYPE)
  39
  40 enable_language(C)
  41
  42 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
  43 set(CPACK_PACKAGE_VENDOR "gromacs.org")
  44 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
  45 set(CPACK_SET_DESTDIR "ON")
  46 set(CPACK_INCLUDE_TOPLEVEL_DIRECTORY 0)
  47 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
  48 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
  49 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/admin/InstallLicense.txt")
  50 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
  51
  52 #must come after all cpack settings!
  53 include(CPack)
  54
  55 ########################################################################
  56 # Check and warn if cache generated on a different host is being reused
  57 ########################################################################
  58 if(CMAKE_HOST_UNIX)
  59     execute_process(COMMAND hostname
  60                     OUTPUT_VARIABLE TMP_HOSTNAME
  61                     OUTPUT_STRIP_TRAILING_WHITESPACE)
  62     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
  63         message(WARNING "
  64             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
  65             is being reused! This could lead to inconsitencies; therefore, it is
  66             recommended to regenerate the cache!")
  67     endif()
  68     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
  69             "Hostname of the machine where the cache was generated.")
  70 endif()
  71
  72 ########################################################################
  73 # Fix stupid flags on MSVC
  74 ########################################################################
  75 SET(SHARED_LIBS_DEFAULT ON)
  76 IF(CMAKE_GENERATOR MATCHES "Visual Studio")
  77     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
  78     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
  79     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
  80     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
  81     SET(SHARED_LIBS_DEFAULT OFF)
  82 ENDIF(CMAKE_GENERATOR MATCHES "Visual Studio")
  83
  84 set(GMX_EXTRA_LIBRARIES)
  85
  86
  87
  88 ######################################################################
  89 # compiler tests
  90 # these need ot be done early (before further tests).
  91 #####################################################################
  92
  93 include(CheckCCompilerFlag)
  94 include(CheckCXXCompilerFlag)
  95
  96 include(gmxCFlags)
  97 gmx_c_flags()
  98
  99 ########################################################################
 100 # User input options                                                   #
 101 ########################################################################
 102 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 103 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 104 option(GMX_THREADS    "Build a parallel (thread-based) version of GROMACS (cannot be combined with MPI yet)" ON)
 105 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 106 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 107 option(GMX_POWERPC_INVSQRT "Use PowerPC hardware 1/sqrt" OFF)
 108 mark_as_advanced(GMX_POWERPC_INVSQRT)
 109 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 110 mark_as_advanced(GMX_FAHCORE)
 111 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library (rerun cmake after changing to see relevant options)" OFF)
 112 set(GMX_ACCELERATION "auto"
 113     CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran")
 114
 115 set(GMX_FFT_LIBRARY "fftw3"
 116     CACHE STRING "FFT library choices: fftw3,fftw2,mkl,fftpack[built-in]")
 117 option(GMX_DISABLE_FFTW_MEASURE
 118        "Do not optimize FFTW setups (not needed with SSE)" OFF)
 119 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 120 set(GMX_QMMM_PROGRAM "none"
 121     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
 122 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 123 mark_as_advanced(GMX_BROKEN_CALLOC)
 124 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI, Windows)" ${SHARED_LIBS_DEFAULT})
 125 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
 126 mark_as_advanced(GMX_MPI_IN_PLACE)
 127 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 128 mark_as_advanced(GMX_LOAD_PLUGINS)
 129
 130
 131 option(GMX_IA32_ASM "Add SSE assembly files for IA32" OFF)
 132 mark_as_advanced(GMX_IA32_ASM)
 133 option(GMX_X86_64_ASM "Add SSE assembly files for X86_64" OFF)
 134 mark_as_advanced(GMX_X86_64_ASM)
 135
 136 option(GMX_OPENMP "Enable OpenMP-based mutithreading. " ON)
 137
 138 option(USE_VERSION_H "Generate development version string/information" ON)
 139 mark_as_advanced(USE_VERSION_H)
 140
 141 option(GMX_DEFAULT_SUFFIX "Use default suffixes for GROMACS binaries and libs (_d for double, _mpi for MPI; rerun cmake after changing to see relevant options)" ON)
 142
 143 if(UNIX AND NOT APPLE)
 144     option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer \".a\" static archives (NOTE: this is enabled only for UNIX (excluding APPLE) platforms but it might not always work!" OFF)
 145     mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 146 endif()
 147
 148 ########################################################################
 149 # Set up binary and library suffixing
 150 ########################################################################
 151 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 152 set(GMX_LIBS_SUFFIX ""
 153   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 154 if (GMX_DEFAULT_SUFFIX)
 155   set(GMX_BINARY_SUFFIX "")
 156   set(GMX_LIBS_SUFFIX "")
 157   if (GMX_MPI)
 158     set(GMX_BINARY_SUFFIX "_mpi")
 159     set(GMX_LIBS_SUFFIX "_mpi")
 160   endif(GMX_MPI)
 161   if (GMX_DOUBLE)
 162     set (GMX_BINARY_SUFFIX "${GMX_BINARY_SUFFIX}_d")
 163     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
 164   endif(GMX_DOUBLE)
 165   if (GMX_OPENMM)
 166     set (GMX_BINARY_SUFFIX "-gpu")
 167     set (GMX_LIBS_SUFFIX "_gpu")
 168   endif(GMX_OPENMM)
 169   mark_as_advanced(FORCE GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 170   if (NOT SUFFIX_QUIETLY)
 171     message(STATUS "Using default binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 172     message(STATUS "Using default library suffix: \"${GMX_LIBS_SUFFIX}\"")
 173   endif (NOT SUFFIX_QUIETLY)
 174 else(GMX_DEFAULT_SUFFIX)
 175   mark_as_advanced(CLEAR GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 176   if (NOT SUFFIX_QUIETLY)
 177     message(STATUS "Using manually set binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 178     message(STATUS "Using manually set library suffix: \"${GMX_LIBS_SUFFIX}\"")
 179   endif (NOT SUFFIX_QUIETLY)
 180 endif(GMX_DEFAULT_SUFFIX)
 181 set(SUFFIX_QUIETLY TRUE CACHE INTERNAL "")
 182
 183 set(PKG_CFLAGS "")
 184 if(GMX_DOUBLE)
 185     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 186 endif(GMX_DOUBLE)
 187 if(GMX_SOFTWARE_INVSQRT)
 188   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 189 endif(GMX_SOFTWARE_INVSQRT)
 190 if(GMX_POWERPC_INVSQRT)
 191   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_POWERPC_INVSQRT")
 192 endif(GMX_POWERPC_INVSQRT)
 193
 194 ########################################################################
 195 #Process MPI settings
 196 ########################################################################
 197 include(gmxManageMPI)
 198
 199 #######################################################################
 200 # Check for options incompatible with OpenMM build                    #
 201 #######################################################################
 202 if(GMX_OPENMM)
 203     cmake_minimum_required(VERSION 2.6.4)
 204     # we'll use the built-in fft to avoid unnecessary dependencies
 205     string(TOUPPER ${GMX_FFT_LIBRARY} GMX_FFT_LIBRARY)
 206     if(NOT ${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 207         message(STATUS "No external FFT libraries needed for the OpenMM build, switching to fftpack!")
 208         set(GMX_FFT_LIBRARY "fftpack" CACHE STRING
 209                 "No external FFT libraries needed for the OpenMM build, switching to  fftpack!" FORCE)
 210     endif()
 211     if(GMX_MPI)
 212         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
 213     endif(GMX_MPI)
 214     if(GMX_THREADS)
 215         message(STATUS "Threads are  not compatible with OpenMM build, disabled!")
 216         set(GMX_THREADS OFF CACHE BOOL
 217                 "Threads are not compatible with OpenMM build, disabled!" FORCE)
 218     endif(GMX_THREADS)
 219     if(GMX_OPENMP)
 220         message(STATUS "OpenMP multithreading is not compatible with OpenMM, disabled")
 221         set(GMX_OPENMP OFF CACHE BOOL
 222             "OpenMP multithreading is not compatible with OpenMM, disabled!" FORCE)
 223     endif()
 224     if(GMX_SOFTWARE_INVSQRT)
 225         set(GMX_SOFTWARE_INVSQRT OFF CACHE STRING
 226                 "The OpenMM build does not need GROMACS software 1/sqrt!" FORCE)
 227     endif(GMX_SOFTWARE_INVSQRT)
 228     string(TOUPPER ${GMX_ACCELERATION} GMX_ACCELERATION)
 229     if(NOT GMX_ACCELERATION STREQUAL "NONE")
 230         message(STATUS "Switching off CPU-based acceleration, the OpenMM build does not support/need any!")
 231         set(GMX_ACCELERATION "none" CACHE STRING
 232                 "Switching off CPU-based acceleration, the OpenMM build does not support/need any!" FORCE)
 233     endif()
 234     if(GMX_FAHCORE)
 235         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
 236     endif(GMX_FAHCORE)
 237     if(GMX_DOUBLE)
 238         message(FATAL_ERROR  "The OpenMM-build does not support double precision calculations!")
 239     endif()
 240     # mark as advanced the unused variables
 241     mark_as_advanced(FORCE GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 242         GMX_QMMM_PROGRAM GMX_THREADS GMX_DOUBLE)
 243 else(GMX_OPENMM)
 244      mark_as_advanced(CLEAR GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 245         GMX_QMMM_PROGRAM GMX_THREADS GMX_DOUBLE)
 246 endif(GMX_OPENMM)
 247
 248
 249 ########################################################################
 250 # Basic system tests (standard libraries, headers, functions, types)   #
 251 ########################################################################
 252 include(CheckIncludeFiles)
 253 check_include_files(string.h     HAVE_STRING_H)
 254 check_include_files(math.h       HAVE_MATH_H)
 255 check_include_files(limits.h     HAVE_LIMITS_H)
 256 check_include_files(memory.h     HAVE_MEMORY_H)
 257 check_include_files(unistd.h     HAVE_UNISTD_H)
 258 check_include_files(direct.h     HAVE_DIRECT_H)
 259 check_include_files(pwd.h        HAVE_PWD_H)
 260 check_include_files(stdint.h     HAVE_STDINT_H)
 261 check_include_files(stdlib.h     HAVE_STDLIB_H)
 262 check_include_files(pthread.h    HAVE_PTHREAD_H)
 263 check_include_files(dirent.h     HAVE_DIRENT_H)
 264 check_include_files(inttypes.h   HAVE_INTTYPES_H)
 265 check_include_files(regex.h      HAVE_REGEX_H)
 266 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 267 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
 268 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 269 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
 270 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
 271 # SSE support
 272 check_include_files(xmmintrin.h  HAVE_XMMINTRIN_H)
 273 check_include_files(emmintrin.h  HAVE_EMMINTRIN_H)
 274 check_include_files(pmmintrin.h  HAVE_PMMINTRIN_H)
 275 check_include_files(smmintrin.h  HAVE_SMMINTRIN_H)
 276 check_include_files(io.h                 HAVE_IO_H)
 277
 278
 279 include(CheckFunctionExists)
 280 check_function_exists(strcasecmp        HAVE_STRCASECMP)
 281 check_function_exists(strdup            HAVE_STRDUP)
 282 check_function_exists(vprintf           HAVE_VPRINTF)
 283 check_function_exists(memcmp            HAVE_MEMCMP)
 284 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 285 check_function_exists(memalign          HAVE_MEMALIGN)
 286 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 287 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 288 check_function_exists(isnan             HAVE_ISNAN)
 289 check_function_exists(_isnan            HAVE__ISNAN)
 290 check_function_exists(fsync             HAVE_FSYNC)
 291 check_function_exists(_fileno           HAVE__FILENO)
 292 check_function_exists(fileno            HAVE_FILENO)
 293 check_function_exists(_commit           HAVE__COMMIT)
 294
 295 include(CheckLibraryExists)
 296 check_library_exists(m sqrt "" HAVE_LIBM)
 297 check_library_exists(m cbrt "" HAVE_CBRT)
 298
 299
 300 include(CheckTypeSize)
 301
 302 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 303 check_type_size("int"           SIZEOF_INT)
 304 check_type_size("long int"      SIZEOF_LONG_INT)
 305 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 306 check_type_size("off_t"         SIZEOF_OFF_T)
 307 check_type_size("void *"        SIZEOF_VOIDP)
 308
 309 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 310     set(GMX_64_BIT TRUE)
 311 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 312     set(GMX_64_BIT FALSE)
 313 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 314
 315 # Check for some basic types that we *need*, so set these to int if they are not present
 316 check_type_size(uid_t uid_t)
 317 if(NOT uid_t)
 318   set(uid_t int)
 319 else(NOT uid_t)
 320   set(uid_t 0)
 321 endif(NOT uid_t)
 322
 323 check_type_size(gid_t gid_t)
 324 if(NOT gid_t)
 325   set(gid_t 1)
 326 else(NOT gid_t)
 327   set(gid_t 0)
 328 endif(NOT gid_t)
 329
 330 check_type_size(size_t size_t)
 331 if(NOT size_t)
 332   set(size_t int)
 333 else(NOT size_t)
 334   set(size_t 0)
 335 endif(NOT size_t)
 336
 337 check_type_size(off_t off_t)
 338 if(NOT off_t)
 339   set(off_t int)
 340 else(NOT off_t)
 341   set(off_t 0)
 342 endif(NOT off_t)
 343
 344 include(TestBigEndian)
 345 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 346
 347
 348
 349
 350 ########################################################################
 351 # Find external packages                                               #
 352 ########################################################################
 353 if(UNIX AND NOT APPLE)
 354     if(GMX_PREFER_STATIC_LIBS)
 355         SET(CMAKE_FIND_LIBRARY_SUFFIXES .a ${CMAKE_FIND_LIBRARY_SUFFIXES})
 356         if(BUILD_SHARED_LIBS)
 357             message(WARNING "Static libraries requested, the GROMACS libraries will also be build static (BUILD_SHARED_LIBS=OFF)")
 358             set(BUILD_SHARED_LIBS OFF CACHE BOOL "Enable shared libraries (can be problematic with MPI, Windows)" FORCE)
 359         endif()
 360     endif()
 361 endif()
 362
 363 option(GMX_XML "Use libxml2 to parse xml files" ON)
 364 if (GMX_XML)
 365   find_package(LibXml2)
 366   set(PKG_XML "")
 367   if(LIBXML2_FOUND)
 368     include_directories(${LIBXML2_INCLUDE_DIR})
 369     set(PKG_XML libxml-2.0)
 370     set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 371     set(HAVE_LIBXML2 1)
 372   endif(LIBXML2_FOUND)
 373 endif(GMX_XML)
 374
 375 option(GMX_GSL "Add support for gsl" OFF)
 376 if (GMX_GSL)
 377   find_package(gsl)
 378   set(PKG_GSL "")
 379   if(GSL_FOUND)
 380     include_directories(${GSL_INCLUDE_DIR})
 381     set(PKG_GSL gsl)
 382     set(HAVE_LIBGSL 1)
 383   endif(GSL_FOUND)
 384 endif (GMX_GSL)
 385
 386 option(GMX_X11 "Use X window system" OFF)
 387 if (GMX_X11)
 388         find_package(X11)
 389         # X11 includes/libraries are only set in the ngmx subdirectory!
 390         if(X11_FOUND)
 391         set(HAVE_X11 1)
 392         endif(X11_FOUND)
 393 endif(GMX_X11)
 394
 395 if(GMX_THREADS)
 396     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREADS")
 397     include(ThreadMPI)
 398     set(THREAD_MPI_LIB thread_mpi)
 399     set(GMX_MPI 1)
 400     string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 401     if(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 402         message(FATAL_ERROR "FFTW2 can't be used with threads. Try fftw3 or mkl.")
 403     endif()
 404 endif(GMX_THREADS)
 405
 406 if(GMX_OPENMM)
 407     set(CUDA_BUILD_EMULATION OFF)
 408     find_package(CUDA 3.1 REQUIRED)
 409     add_definitions(-DGMX_OPENMM)
 410     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 411         set(CUDA_VERBOSE_BUILD ON)
 412     endif()
 413     find_package(OpenMM)
 414 endif(GMX_OPENMM)
 415
 416 if(GMX_OPENMP)
 417     find_package(OpenMP REQUIRED)
 418     list(APPEND GROMACS_C_FLAGS ${OpenMP_C_FLAGS})
 419     list(APPEND GROMACS_CXX_FLAGS ${OpenMP_CXX_FLAGS})
 420     add_definitions(-DGMX_OPENMP)
 421 endif()
 422
 423 if(APPLE)
 424    find_library(ACCELERATE_FRAMEWORK Accelerate)
 425    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 426 endif(APPLE)
 427
 428 if(CYGWIN)
 429     set(GMX_CYGWIN 1)
 430 endif(CYGWIN)
 431
 432 # only bother with finding git and using version.h if the source is a git repo
 433 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 434     if(USE_VERSION_H)
 435         # We need at least git v1.5.1 be able to parse git's date output. If not
 436         # found or the version is too small, we can't generate version information.
 437         find_package(Git)
 438
 439         # Find out the git version
 440         if(GIT_FOUND AND NOT GIT_VERSION)
 441           execute_process(COMMAND ${GIT_EXECUTABLE} "--version"
 442             OUTPUT_VARIABLE _exec_out
 443             OUTPUT_STRIP_TRAILING_WHITESPACE)
 444           string(REGEX REPLACE "git version (.*)" "\\1" GIT_VERSION ${_exec_out})
 445           set(GIT_VERSION ${GIT_VERSION} CACHE STRING "Git version")
 446           mark_as_advanced(GIT_VERSION)
 447         endif()
 448
 449         if(NOT GIT_FOUND OR GIT_VERSION VERSION_LESS "1.5.1")
 450           message("No compatible git version found, won't be able to generate proper development version information.")
 451           set(USE_VERSION_H OFF)
 452         endif()
 453     endif()
 454 else()
 455     set(USE_VERSION_H OFF)
 456 endif()
 457
 458 ########################################################################
 459 # Generate development version info for cache
 460 ########################################################################
 461 # set(GEN_VERSION_INFO_INTERNAL "ON")
 462 # include(gmxGenerateVersionString)
 463
 464 ########################################################################
 465 # Our own GROMACS tests
 466 ########################################################################
 467
 468 add_definitions( -DHAVE_CONFIG_H )
 469 include_directories(${CMAKE_BINARY_DIR}/src)
 470 include_directories(${CMAKE_SOURCE_DIR}/include)
 471
 472 include(gmxCheckBuildUserTime)
 473 gmx_check_build_user_time(BUILD_TIME BUILD_USER BUILD_MACHINE)
 474
 475 include(gmxTestFloatFormat)
 476 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 477                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 478                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 479
 480 include(gmxTestLargeFiles)
 481 gmx_test_large_files(GMX_LARGEFILES)
 482 check_function_exists(fseeko     HAVE_FSEEKO)
 483
 484 include(gmxTestSignal)
 485 gmx_test_sigusr1(HAVE_SIGUSR1)
 486
 487 include(gmxTestInline)
 488 gmx_test_inline(INLINE_KEYWORD)
 489
 490 include(gmxTestRestrict)
 491 gmx_test_inline(RESTRICT_KEYWORD)
 492
 493 include(gmxTestPipes)
 494 gmx_test_pipes(HAVE_PIPES)
 495
 496 include(gmxTestIsfinite)
 497 gmx_test_isfinite(HAVE_ISFINITE)
 498 gmx_test__isfinite(HAVE__ISFINITE)
 499 gmx_test__finite(HAVE__FINITE)
 500
 501 include(gmxTestInlineASM)
 502 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 503 gmx_test_inline_asm_msvc_x86(GMX_X86_MSVC_INLINE_ASM)
 504
 505 # turn on SSE if supported with reasonable defaults.
 506 if (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 507   if(CMAKE_SYSTEM_PROCESSOR MATCHES "^(i.86|x86|x64|x86_64|AMD64|amd64)" OR CYGWIN)
 508
 509     set(GMX_ACCELERATION "SSE" CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran" FORCE)
 510
 511     # Determine the assembler/compiler to use
 512   else()
 513     set(GMX_ACCELERATION "none" CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran" FORCE)
 514   endif()
 515 endif (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 516
 517 include(gmxTestXDR)
 518 gmx_test_xdr(GMX_SYSTEM_XDR)
 519 if(NOT GMX_SYSTEM_XDR)
 520     set(GMX_INTERNAL_XDR 1)
 521     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 522 endif(NOT GMX_SYSTEM_XDR)
 523
 524 # Process nonbonded accelerated kernels settings
 525 string(TOUPPER ${GMX_ACCELERATION} ${GMX_ACCELERATION})
 526 if(${GMX_ACCELERATION} STREQUAL "NONE")
 527   # nothing to do
 528 elseif(${GMX_ACCELERATION} STREQUAL "SSE")
 529
 530     if (GMX_64_BIT)
 531       set(GMX_X86_64_ASM ON CACHE BOOL "Add SSE assembly files for x86_64" FORCE)
 532     else (GMX_64_BIT)
 533       set(GMX_IA32_ASM ON CACHE BOOL "Add SSE assembly files for i386" FORCE)
 534     endif (GMX_64_BIT)
 535
 536     if(CMAKE_GENERATOR MATCHES "Visual Studio")
 537       option(GMX_ASM_USEASM-NASM "Use Nasm for assembly instead of compiler (necessary on windows)" ON)
 538     else()
 539       option(GMX_ASM_USEASM-NASM "Use Nasm for assembly instead of compiler (necessary on windows)" OFF)
 540     endif()
 541         mark_as_advanced(GMX_ASM_USEASM-NASM)
 542
 543     if (NOT GMX_64_BIT)
 544         # for 32-bit compiles, we might need to turn on sse
 545         CHECK_C_COMPILER_FLAG("-msse2" XFLAGS_SSE)
 546         if (XFLAGS_SSE)
 547             set(GROMACS_C_FLAGS "-msse2 ${GROMACS_C_FLAGS}")
 548         endif (XFLAGS_SSE)
 549         CHECK_CXX_COMPILER_FLAG("-msse2" XXFLAGS_SSE)
 550         if (XXFLAGS_SSE)
 551             set(GROMACS_CXX_FLAGS "-msse2 ${GROMACS_CXX_FLAGS}")
 552         endif (XXFLAGS_SSE)
 553     endif (NOT GMX_64_BIT)
 554
 555     if(GMX_IA32_ASM)
 556       if(GMX_DOUBLE)
 557         set(GMX_IA32_SSE2 1)
 558       else()
 559        set(GMX_IA32_SSE 1)
 560       endif()
 561     elseif(GMX_X86_64_ASM)
 562       if(GMX_DOUBLE)
 563        set(GMX_X86_64_SSE2 1)
 564       else()
 565         set(GMX_X86_64_SSE 1)
 566       endif()
 567     endif()
 568
 569 #    if(HAVE_PMMINTRIN_H)
 570 #        set(GMX_SSE3 1)
 571 #    endif(HAVE_PMMINTRIN_H)
 572 #    if(HAVE_SMMINTRIN_H)
 573 #        set(GMX_SSE4_1 1)
 574 #    endif(HAVE_SMMINTRIN_H)
 575
 576 elseif(${GMX_ACCELERATION} STREQUAL "FORTRAN")
 577     set(GMX_FORTRAN 1)
 578     #these are switch on by default sometimes
 579     set(GMX_IA32_ASM 0)
 580     set(GMX_GMX_X86_64_ASM 0)
 581 elseif(${GMX_ACCELERATION} STREQUAL "BLUEGENE")
 582 # GMX_ACCELERATION=BlueGene should be set in the Toolchain-BlueGene?-???.cmake file
 583     message(STATUS "Configuring for BlueGene")
 584     set(GMX_BLUEGENE 1)
 585     if (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 586         set(SHARED_LIBS_DEFAULT OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 587         set(BUILD_SHARED_LIBS OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 588     endif (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 589     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on BlueGene" FORCE)
 590     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on BlueGene" FORCE)
 591     set(GMX_X11 OFF CACHE BOOL "X11 not compatible with BlueGene, disabled!" FORCE)
 592     set(GMX_THREADS OFF CACHE BOOL "Threads not compatible with BlueGene, disabled!" FORCE)
 593     set(GMX_MPI ON CACHE BOOL "Use MPI on BlueGene" FORCE)
 594 elseif(${GMX_ACCELERATION} STREQUAL "POWER6")
 595     set(GMX_POWER6 1)
 596     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on Power6" FORCE)
 597     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on Power6" FORCE)
 598 elseif(${GMX_ACCELERATION} STREQUAL "IA64")
 599     set(GMX_IA64_ASM 1)
 600     set(DISABLE_WATERWATER_NLIST 1)
 601     set(DISABLE_WATER_NLIST 1)
 602 elseif(${GMX_ACCELERATION} STREQUAL "ALTIVEC")
 603     check_include_files(altivec.h HAVE_ALTIVEC_H)
 604     if(HAVE_ALTIVEC_H)
 605         set(GMX_PPC_ALTIVEC 1)
 606     endif(HAVE_ALTIVEC_H)
 607 else(${GMX_ACCELERATION} STREQUAL "NONE")
 608     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_ACCELERATION}. Pick one of auto, none, SSE, Fortran, BlueGene, Power6, ia64, altivec")
 609 endif(${GMX_ACCELERATION} STREQUAL "NONE")
 610
 611 if(GMX_FORTRAN OR GMX_POWER6)
 612     if (GMX_THREADS)
 613         message(FATAL_ERROR "FORTRAN/POWER6 is incompatible with threads and only provides a speed-up on certain IBM compilers. Disable FORTRAN (or threads if you really want to use FORTRAN kernels).")
 614     endif(GMX_THREADS)
 615     enable_language(Fortran)
 616     include(FortranCInterface)
 617     discover_fortran_mangling(prefix isupper suffix extra_under_score found)
 618     if(extra_under_score)
 619         set(extrasuffix "_")
 620     endif(extra_under_score)
 621     if(prefix)
 622       set(prefix "${prefix} ##")
 623     endif(prefix)
 624     if(suffix)
 625       set(suffix "## ${suffix}")
 626       if(extrasuffix)
 627         set(extrasuffix "${suffix}${extrasuffix}")
 628       endif(extrasuffix)
 629     else(suffix)
 630       if(extrasuffix)
 631         # Don't know if this is needed, but it can't hurt
 632         set(extrasuffix "## ${extrasuffix}")
 633       endif(extrasuffix)
 634     endif(suffix)
 635
 636     if(isupper)
 637         set(F77_FUNCDEF   "${prefix} NAME ${suffix}")
 638         set(F77_FUNCDEF_  "${prefix} NAME ${extrasuffix}")
 639     else(isupper)
 640         set(F77_FUNCDEF   "${prefix} name ${suffix}")
 641         set(F77_FUNCDEF_  "${prefix} name ${extrasuffix}")
 642     endif(isupper)
 643 else(GMX_FORTRAN OR GMX_POWER6)
 644         set(F77_FUNCDEF   "name ## _")
 645         set(F77_FUNCDEF_  "name ## _")
 646 endif(GMX_FORTRAN OR GMX_POWER6)
 647
 648 # Process QM/MM Settings
 649 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 650 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 651     set(GMX_QMMM_GAUSSIAN 1)
 652 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 653     set(GMX_QMMM_MOPAC 1)
 654 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 655     set(GMX_QMMM_GAMESS 1)
 656 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 657     set(GMX_QMMM_ORCA 1)
 658 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 659     # nothing to do
 660 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 661     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 662 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 663
 664 # Process FFT library settings - if not OpenMM build
 665 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 666 set(PKG_FFT "")
 667 set(PKG_FFT_LIBS "")
 668 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 669 #    MESSAGE(STATUS "Using external FFT library - fftw3")
 670     if(GMX_DOUBLE)
 671         find_package(FFTW3 REQUIRED)
 672                 include_directories(${FFTW3_INCLUDE_DIR})
 673         set(FFT_LIBRARIES ${FFTW3_LIBRARIES})
 674         set(PKG_FFT "fftw3")
 675     else(GMX_DOUBLE)
 676         find_package(FFTW3F REQUIRED)
 677         include_directories(${FFTW3F_INCLUDE_DIR})
 678         set(FFT_LIBRARIES ${FFTW3F_LIBRARIES})
 679         set(PKG_FFT "fftw3f")
 680     endif(GMX_DOUBLE)
 681
 682     if(NOT FFTW3_FOUND AND NOT FFTW3F_FOUND)
 683         MESSAGE(FATAL_ERROR "Cannot find fftw3 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 684     endif(NOT FFTW3_FOUND AND NOT FFTW3F_FOUND)
 685
 686     set(GMX_FFT_FFTW3 1)
 687
 688 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 689 #    MESSAGE(STATUS "Using external FFT library - fftw2")
 690     if(GMX_DOUBLE)
 691         find_package(FFTW2 REQUIRED)
 692     else(GMX_DOUBLE)
 693         find_package(FFTW2F REQUIRED)
 694     endif(GMX_DOUBLE)
 695
 696     if(NOT FFTW2_FOUND)
 697            MESSAGE(FATAL_ERROR "Cannot find fftw2 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 698     endif(NOT FFTW2_FOUND)
 699     include_directories(${FFTW2_INCLUDE_DIR})
 700     set(FFT_LIBRARIES ${FFTW2_LIBRARIES})
 701     set(PKG_FFT_LIBS ${FFTW2_LIBRARIES})
 702
 703     if("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 704         set(FFTW2_NAME_DFFTW 1)
 705     elseif("${FFTW2_LIBRARIES}" MATCHES "sfftw")
 706         set(FFTW2_NAME_SFFTW 1)
 707     else("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 708         set(FFTW2_NAME_FFTW 1)
 709     endif("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 710
 711     set(GMX_FFT_FFTW2 1)
 712 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 713 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 714     find_package(MKL REQUIRED)
 715     include_directories(${MKL_INCLUDE_DIR})
 716     set(FFT_LIBRARIES ${MKL_LIBRARIES})
 717     set(PKG_FFT_LIBS ${MKL_LIBRARIES})
 718
 719     set(GMX_FFT_MKL 1)
 720     set(HAVE_MKL 1)
 721
 722 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 723 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 724 #    set(GMX_FFT_ACML 1)
 725 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 726     MESSAGE(STATUS "Using internal FFT library - fftpack")
 727     set(GMX_FFT_FFTPACK 1)
 728 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 729     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, fftw2, mkl, acml, fftpack")
 730 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 731
 732 # MKL has BLAS/LAPACK routines
 733 if(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 734   set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 735   set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 736 else(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 737   set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external BLAS instead of built-in")
 738   set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 739   if(GMX_EXTERNAL_BLAS)
 740     #FindBLAS needs Fortran
 741     enable_language(Fortran)
 742     if (GMX_BLAS_USER)
 743         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_BLAS_USER})
 744     else(GMX_BLAS_USER)
 745         find_package(BLAS REQUIRED)
 746         list(APPEND GMX_EXTRA_LIBRARIES ${BLAS_LIBRARIES})
 747     endif(GMX_BLAS_USER)
 748   endif(GMX_EXTERNAL_BLAS)
 749   if(GMX_EXTERNAL_LAPACK)
 750     #FindLAPACK needs Fortran
 751     enable_language(Fortran)
 752         if (GMX_LAPACK_USER)
 753         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_LAPACK_USER})
 754         else(GMX_LAPACK_USER)
 755         find_package(LAPACK REQUIRED)
 756         list(APPEND GMX_EXTRA_LIBRARIES ${LAPACK_LIBRARIES})
 757     endif(GMX_LAPACK_USER)
 758   endif(GMX_EXTERNAL_LAPACK)
 759 endif(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 760 mark_as_advanced(GMX_EXTERNAL_LAPACK)
 761 mark_as_advanced(GMX_EXTERNAL_BLAS)
 762
 763 set(GMX_USE_PLUGINS OFF CACHE INTERNAL "Whether GROMACS will really try to compile support for VMD plugins")
 764 set(GMX_VMD_PLUGIN_PATH)
 765 mark_as_advanced(GMX_VMD_PLUGIN_PATH)
 766
 767 if(GMX_LOAD_PLUGINS)
 768   if(CYGWIN OR NOT WIN32)
 769     # Native Windows does not have, nor need dlopen
 770     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 771     include(gmxTestdlopen)
 772     gmx_test_dlopen(HAVE_DLOPEN)
 773   endif()
 774
 775   find_package(VMD)
 776
 777   # Test for unsuitable versions of VMD
 778
 779   if(VMD_FOUND AND NOT GMX_VMD_PLUGIN_PATH)
 780     message(STATUS "Checking for suitable VMD version")
 781     exec_program(${VMD_EXECUTABLE}
 782       ARGS --help
 783       OUTPUT_VARIABLE VMD_HELP
 784       RETURN_VALUE VMD_EXEC_RETURN)
 785
 786     if(VMD_EXEC_RETURN EQUAL 0)
 787       # This is the accepted idiom for subexpression matching, unfortunately
 788       string(REGEX REPLACE ".*VMD for .*, version ([0-9]+\\.[0-9]*\\.?[0-9]*).*" "\\1" VMD_VERSION ${VMD_HELP})
 789       string(REGEX REPLACE ".*VMD for (.*), version .*" "\\1" VMD_ARCH ${VMD_HELP})
 790
 791       if(VMD_VERSION VERSION_LESS "1.8")
 792         MESSAGE(WARNING "Found VMD version ${VMD_VERSION}, but GROMACS needs at least 1.8")
 793         unset(VMD_EXECUTABLE)
 794         set(VMD_FOUND FALSE)
 795       else()
 796         message(STATUS "VMD version ${VMD_VERSION} is suitable")
 797         if(DEFINED ENV{VMDDIR})
 798           # This permits GROMACS to avoid hard-coding a fall-back
 799           # path that it can tell right now would be useless.
 800           set(GMX_VMD_PLUGIN_PATH "$ENV{VMDDIR}/plugins/${VMD_ARCH}/molfile" CACHE PATH "Path to VMD plugins for molfile I/O")
 801         else()
 802           set(GMX_VMD_PLUGIN_PATH "/usr/local/lib/vmd/plugins/*/molfile" CACHE PATH "Path to VMD plugins for molfile I/O")
 803         endif()
 804       endif()
 805
 806       # clean up
 807       unset(VMD_HELP)
 808       unset(VMD_VERSION)
 809       unset(VMD_ARCH)
 810     endif()
 811   endif()
 812
 813   # so, should we use plug-ins?
 814   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 815     if (NOT VMD_QUIETLY)
 816       MESSAGE(STATUS "Found the ability to use plug-ins when building shared libaries, so will compile to use plug-ins (e.g. to read VMD-supported file formats).")
 817     endif(NOT VMD_QUIETLY)
 818     set(GMX_USE_PLUGINS ON)
 819     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 820     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 821   else()
 822     set(PKG_DL_LIBS)
 823   endif()
 824 endif(GMX_LOAD_PLUGINS)
 825 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 826
 827 # Math and thread libraries must often come after all others when linking...
 828 if(HAVE_LIBM)
 829     list(APPEND GMX_EXTRA_LIBRARIES m)
 830 endif(HAVE_LIBM)
 831
 832 if(GMX_FAHCORE)
 833   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 834       "Path to swindirect.h")
 835   include_directories(${COREWRAP_INCLUDE_DIR})
 836 endif(GMX_FAHCORE)
 837
 838 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 839 # these are set after everything else
 840 if (NOT DEFINED GROMACS_C_FLAGS_SET)
 841     set(GROMACS_C_FLAGS_SET true CACHE INTERNAL "Whether to reset the C flags"
 842         FORCE)
 843     set(CMAKE_C_FLAGS "${GROMACS_C_FLAGS} ${CMAKE_C_FLAGS}" CACHE STRING
 844         "Flags used by the compiler during all build types" FORCE)
 845     set(CMAKE_CXX_FLAGS "${GROMACS_CXX_FLAGS} ${CMAKE_CXX_FLAGS}" CACHE STRING
 846         "Flags used by the compiler during all build types" FORCE)
 847     set(CMAKE_EXE_LINKER_FLAGS
 848         "${GROMACS_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}"
 849         CACHE STRING "Linker flags" FORCE)
 850 endif (NOT DEFINED GROMACS_C_FLAGS_SET)
 851
 852 ########################################################################
 853 # Specify install locations and which subdirectories to process        #
 854 ########################################################################
 855 if ( DEFINED GMXLIB )
 856     set(LIB_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/${GMXLIB}")
 857 else()
 858     set(LIB_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/lib)
 859 endif()
 860 set(BIN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/bin)
 861 set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/gromacs)
 862 set(MAN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/share/man)
 863 set(INCL_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/include)
 864
 865 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
 866
 867 ##################################################################
 868 # Shared library settings - Darwin uses INSTALL_NAME_DIR instead!
 869 ##################################################################
 870 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 871     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
 872     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
 873     set(CMAKE_INSTALL_RPATH "${LIB_INSTALL_DIR}")
 874     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 875 endif()
 876
 877 add_subdirectory(share)
 878 add_subdirectory(include)
 879 add_subdirectory(man)
 880 add_subdirectory(src)
 881 add_subdirectory(scripts)
 882
 883 #######################
 884 ## uninstall target
 885 #######################
 886     CONFIGURE_FILE(
 887                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 888                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 889                    IMMEDIATE @ONLY)
 890 ###########################
 891 ADD_CUSTOM_TARGET(uninstall
 892                   "${CMAKE_COMMAND}" -P
 893                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 894 ###########################
 895
 896
 897 ########################################################################
 898 # Tests                                                                #
 899 ########################################################################
 900
 901 include(CTest)
 902 mark_as_advanced(BUILD_TESTING)
 903 IF(BUILD_TESTING)
 904         enable_testing()
 905         add_subdirectory(tests)
 906 ENDIF()
 907