CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014,2015, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 2.8.8)
  36 # When we require cmake >= 2.8.12, it will provide
  37 # CMAKE_MINIMUM_REQUIRED_VERSION automatically, but in the meantime we
  38 # need to set a variable, and it must have a different name.
  39 set(GMX_CMAKE_MINIMUM_REQUIRED_VERSION "2.8.8")
  40
  41 # CMake modules/macros are in a subdirectory to keep this file cleaner
  42 # This needs to be set before project() in order to pick up toolchain files
  43 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  44
  45 project(Gromacs)
  46
  47 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  48 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  49 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  50
  51 # Set up common version variables, as well as general information about
  52 # the build tree (whether the build is from a source package or from a git
  53 # repository).  Also declares a few functions that will be used for generating
  54 # version info files later.
  55 include(gmxVersionInfo)
  56
  57 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  58     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  59 endif()
  60 if("${CMAKE_INSTALL_PREFIX}" STREQUAL "${CMAKE_BINARY_DIR}")
  61     message(FATAL_ERROR "GROMACS cannot be installed into the build tree, choose a different location for CMAKE_INSTALL_PREFIX")
  62 endif()
  63
  64 include(gmxBuildTypeReference)
  65 include(gmxBuildTypeProfile)
  66 include(gmxBuildTypeTSAN)
  67 include(gmxBuildTypeASAN)
  68 include(gmxBuildTypeMSAN)
  69 include(gmxBuildTypeReleaseWithAssert)
  70
  71 if(NOT CMAKE_BUILD_TYPE)
  72     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert Profile." FORCE)
  73     # There's no need to offer a user the choice of ThreadSanitizer
  74     # Set the possible values of build type for cmake-gui
  75     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
  76         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert" "Profile")
  77 endif()
  78 if(CMAKE_CONFIGURATION_TYPES)
  79     # Add appropriate GROMACS-specific build types for the Visual
  80     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
  81     # are already present by default).
  82     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
  83     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
  84     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
  85         "List of configuration types"
  86         FORCE)
  87 endif()
  88 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
  89
  90 set_property(GLOBAL PROPERTY FIND_LIBRARY_USE_LIB64_PATHS ON)
  91
  92 # Set a default valgrind suppression file.
  93 # This unfortunately needs to duplicate information from CTest to work as
  94 # expected...
  95 set(MEMORYCHECK_SUPPRESSIONS_FILE
  96     "${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp"
  97     CACHE FILEPATH
  98     "File that contains suppressions for the memory checker")
  99 include(CTest)
 100
 101 include(gmxCPackUtilities)
 102 gmx_cpack_init()
 103
 104 # Variables that accumulate stuff influencing the installed headers
 105 set(INSTALLED_HEADER_INCLUDE_DIRS "")
 106 set(INSTALLED_HEADER_DEFINITIONS "")
 107
 108 ########################################################################
 109 # Check and warn if cache generated on a different host is being reused
 110 ########################################################################
 111 if(CMAKE_HOST_UNIX)
 112     execute_process(COMMAND hostname
 113                     OUTPUT_VARIABLE TMP_HOSTNAME
 114                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 115     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 116         message(WARNING "
 117             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 118             is being reused! This could lead to inconsistencies; therefore, it is
 119             recommended to regenerate the cache!")
 120     endif()
 121     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 122             "Hostname of the machine where the cache was generated.")
 123 endif()
 124
 125 ########################################################################
 126 # Detect architecture before setting options so we can alter defaults
 127 ########################################################################
 128 # Detect the architecture the compiler is targetting, detect
 129 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 130 # to use if none is specified, and populate the cache option for CPU
 131 # SIMD.
 132 include(gmxDetectTargetArchitecture)
 133 gmx_detect_target_architecture()
 134
 135
 136 ########################################################################
 137 # Detect CXX11 support and flags
 138 ########################################################################
 139 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 140 # are used with permission from CMake v3.0.0 so that GROMACS can detect
 141 # invalid options with the Intel Compilers, and we have added a line
 142 # to detect warnings with the Fujitsu compilers on K computer and ICC.
 143 # CMake-3.0 also has a bug where the FAIL_REGEX pattern for AIX contains
 144 # a semicolon. Since this is also used as a separator in lists inside CMake,
 145 # that string ends up being split into two separate patterns, and the last
 146 # part is just a single word that also matches other messages. We solved this
 147 # by replacing the semicolon with a period that matches any character.
 148 #
 149 # These files should be removed from the source tree when a CMake version that
 150 # includes the features in question becomes required for building GROMACS.
 151 include(CheckCCompilerFlag)
 152 include(CheckCXXCompilerFlag)
 153
 154 # This must come early, since some of our configuration flag tests
 155 # depend on being able to compile C++11 source files
 156 include(gmxTestCXX11)
 157 gmx_test_cxx11(GMX_CXX11_SUPPORTED GMX_CXX11_FLAGS)
 158 if(NOT GMX_CXX11_SUPPORTED)
 159 message(FATAL_ERROR "This version of GROMACS requires C++11. Please use a newer compiler or use the GROMACS 5.1.x release. Note it might be sufficient to instruct the compiler to use a newer STL version. See the installation guide for details.")
 160 endif()
 161
 162 # Make sure all tests are run in C++11 mode
 163 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${GMX_CXX11_FLAGS}")
 164
 165 ########################################################################
 166 # User input options                                                   #
 167 ########################################################################
 168 include(gmxOptionUtilities)
 169
 170 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 171
 172 # Fujitsu only has SIMD in double precision, so this will be faster
 173 gmx_set_boolean(GMX_DOUBLE_DEFAULT GMX_TARGET_FUJITSU_SPARC64)
 174 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" ${GMX_DOUBLE_DEFAULT})
 175 option(GMX_RELAXED_DOUBLE_PRECISION "Accept single precision 1/sqrt(x) when using Fujitsu HPC-ACE SIMD" OFF)
 176 mark_as_advanced(GMX_RELAXED_DOUBLE_PRECISION)
 177
 178 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 179 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 180 gmx_dependent_option(
 181     GMX_MPI_IN_PLACE
 182     "Enable MPI_IN_PLACE for MPIs that have it defined"
 183     ON
 184     GMX_MPI)
 185 mark_as_advanced(GMX_MPI_IN_PLACE)
 186 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 187 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 188 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 189 mark_as_advanced(GMX_FAHCORE)
 190
 191 option(GMX_COOL_QUOTES "Enable GROMACS cool quotes" ON)
 192 mark_as_advanced(GMX_COOL_QUOTES)
 193 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 194
 195 option(GMX_USE_OPENCL "Enable OpenCL acceleration" OFF)
 196
 197 # Decide on GPU settings based on user-settings and GPU/CUDA detection.
 198 # GCC 4.6 requires CUDA 5.0 and VS2013 requires CUDA 6.5
 199 if(MSVC)
 200     set(REQUIRED_CUDA_VERSION 6.5)
 201 else()
 202     set(REQUIRED_CUDA_VERSION 5.0)
 203 endif()
 204 set(REQUIRED_CUDA_COMPUTE_CAPABILITY 2.0)
 205
 206 # OpenCL required version: 1.1 or newer
 207 set(REQUIRED_OPENCL_MIN_VERSION 1.1)
 208
 209 if(NOT GMX_USE_OPENCL)
 210     # CUDA detection is done only if GMX_USE_OPENCL is OFF
 211     include(gmxManageGPU)
 212 else()
 213     #Now the OpenCL path
 214     if(GMX_GPU)
 215         include(gmxManageOpenCL)
 216     else(GMX_GPU)
 217         message(FATAL_ERROR "OpenCL requested but GPU option is not enabled (try -DGMX_GPU=on) ")
 218     endif(GMX_GPU)
 219 endif()
 220
 221 include(gmxDetectSimd)
 222 gmx_detect_simd(GMX_SUGGESTED_SIMD)
 223
 224 gmx_option_multichoice(
 225     GMX_SIMD
 226     "SIMD instruction set for CPU kernels and compiler optimization"
 227     "${GMX_SUGGESTED_SIMD}"
 228     None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 AVX_512F AVX_512ER MIC ARM_NEON ARM_NEON_ASIMD IBM_QPX IBM_VMX IBM_VSX Sparc64_HPC_ACE Reference)
 229
 230 if(GMX_TARGET_MIC)
 231     set(GMX_FFT_LIBRARY_DEFAULT "mkl")
 232 else()
 233     set(GMX_FFT_LIBRARY_DEFAULT "fftw3")
 234 endif()
 235
 236 gmx_option_multichoice(
 237     GMX_FFT_LIBRARY
 238     "FFT library"
 239     "${GMX_FFT_LIBRARY_DEFAULT}"
 240     fftw3 mkl "fftpack[built-in]")
 241 gmx_dependent_option(
 242     GMX_BUILD_OWN_FFTW
 243     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 244     OFF
 245     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 246 gmx_dependent_option(
 247     GMX_DISABLE_FFTW_MEASURE
 248     "Do not optimize FFTW setups (not needed with SSE)"
 249     OFF
 250     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 251 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 252 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 253
 254 gmx_option_multichoice(
 255     GMX_QMMM_PROGRAM
 256     "QM package for QM/MM"
 257     None
 258     none gaussian mopac gamess orca)
 259
 260 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 261 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 262
 263 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 264
 265 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 266 mark_as_advanced(GMX_BROKEN_CALLOC)
 267 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 268 mark_as_advanced(GMX_LOAD_PLUGINS)
 269
 270 option(GMX_GPU  "Enable GPU acceleration" ON)
 271 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 272
 273 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 274
 275 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 276
 277 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 278 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 279
 280 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 281 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 282
 283 option(GMX_BUILD_FOR_COVERAGE
 284        "Tune build for better code coverage metrics (e.g., disable asserts)"
 285        OFF)
 286 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 287
 288 option(GMX_DEVELOPER_BUILD
 289     "Enable Developer convenience features: always build unit-tests"
 290     OFF)
 291 mark_as_advanced(GMX_DEVELOPER_BUILD)
 292
 293 gmx_set_boolean(GMX_COMPILER_WARNINGS_DEFAULT "NOT SOURCE_IS_SOURCE_DISTRIBUTION")
 294 option(GMX_COMPILER_WARNINGS
 295     "Enable a default set of compiler warnings"
 296     ${GMX_COMPILER_WARNINGS_DEFAULT})
 297 mark_as_advanced(GMX_COMPILER_WARNINGS)
 298 # Always turn on compiler warnings with a developer build.
 299 gmx_add_cache_dependency(GMX_COMPILER_WARNINGS BOOL "NOT GMX_DEVELOPER_BUILD" ON)
 300
 301 option(GMX_BUILD_SHARED_EXE
 302     "Build exectuables as shared binaries. If not set, this disables rpath and dynamic linker flags in an attempt to build a static binary, but this may require setting up the toolchain properly and making appropriate libraries available."
 303     ON)
 304 mark_as_advanced(GMX_BUILD_SHARED_EXE)
 305
 306 ######################################################################
 307 # Detect OpenMP support
 308 ######################################################################
 309 # The OpenMP detection _must_ come before tests for other CFLAGS.
 310 include(gmxManageOpenMP)
 311
 312
 313
 314 ######################################################################
 315 # Compiler tests
 316 # These need to be done early (before further tests).
 317 #####################################################################
 318
 319 include(gmxCFlags)
 320 gmx_c_flags()
 321
 322 # This variable should be used for additional compiler flags which are not
 323 # generated in gmxCFlags nor are SIMD or MPI related.
 324 set(EXTRA_C_FLAGS "")
 325 set(EXTRA_CXX_FLAGS "")
 326
 327 # Run through a number of tests for buggy compilers and other issues
 328 include(gmxTestCompilerProblems)
 329 gmx_test_compiler_problems()
 330 # GMX_SIMD will not be set automatically until the second
 331 # pass (which is not strictly guaranteed to occur), so putting this
 332 # check here among logically-related tests is inefficient, but the
 333 # potential loss is likely zero.
 334 if(GMX_SIMD STREQUAL "AVX_256"
 335         AND CMAKE_COMPILER_IS_GNUCC
 336         AND (C_COMPILER_VERSION VERSION_EQUAL "4.6.1"
 337             OR CXX_COMPILER_VERSION VERSION_EQUAL "4.6.1"))
 338     message(FATAL_ERROR "gcc 4.6.1 has buggy support for AVX, and GROMACS mdrun will not work. If you want simulation performance, use a more recent compiler. Otherwise, use GMX_SIMD=SSE4.1")
 339     # See http://gcc.gnu.org/bugzilla/show_bug.cgi?id=49002
 340 endif()
 341
 342
 343 if(GMX_DOUBLE)
 344     add_definitions(-DGMX_DOUBLE)
 345     list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_DOUBLE")
 346     if(GMX_RELAXED_DOUBLE_PRECISION)
 347         add_definitions(-DGMX_RELAXED_DOUBLE_PRECISION)
 348     endif()
 349 endif()
 350 if(GMX_SOFTWARE_INVSQRT)
 351     list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_SOFTWARE_INVSQRT")
 352 endif()
 353
 354 if(WIN32)
 355     list(APPEND GMX_EXTRA_LIBRARIES "wsock32")
 356     add_definitions(-DGMX_HAVE_WINSOCK)
 357 endif()
 358
 359
 360
 361 ########################################################################
 362 # Basic system tests (standard libraries, headers, functions, types)   #
 363 ########################################################################
 364 include(CheckIncludeFiles)
 365 include(CheckIncludeFileCXX)
 366 check_include_files(unistd.h     HAVE_UNISTD_H)
 367 check_include_files(pwd.h        HAVE_PWD_H)
 368 check_include_files(dirent.h     HAVE_DIRENT_H)
 369 check_include_files(time.h       HAVE_TIME_H)
 370 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 371 check_include_files(io.h         HAVE_IO_H)
 372 check_include_files(sched.h      HAVE_SCHED_H)
 373
 374 check_include_files(regex.h      HAVE_POSIX_REGEX)
 375 # TODO: It could be nice to inform the user if no regex support is found,
 376 # as selections won't be fully functional.
 377
 378 include(CheckCXXSymbolExists)
 379 check_cxx_symbol_exists(gettimeofday      sys/time.h   HAVE_GETTIMEOFDAY)
 380 check_cxx_symbol_exists(sysconf           unistd.h     HAVE_SYSCONF)
 381 check_cxx_symbol_exists(nice              unistd.h     HAVE_NICE)
 382 check_cxx_symbol_exists(fsync             unistd.h     HAVE_FSYNC)
 383 check_cxx_symbol_exists(_fileno           stdio.h      HAVE__FILENO)
 384 check_cxx_symbol_exists(fileno            stdio.h      HAVE_FILENO)
 385 check_cxx_symbol_exists(_commit           io.h         HAVE__COMMIT)
 386 check_cxx_symbol_exists(sigaction         signal.h     HAVE_SIGACTION)
 387 check_cxx_symbol_exists(rsqrt             math.h       HAVE_RSQRT)
 388 check_cxx_symbol_exists(rsqrtf            math.h       HAVE_RSQRTF)
 389 check_cxx_symbol_exists(sqrtf             math.h       HAVE_SQRTF)
 390
 391 include(CheckLibraryExists)
 392 find_library(HAVE_LIBM m)
 393 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 394 check_library_exists(m feenableexcept "" HAVE_FEENABLEEXCEPT)
 395
 396 include(TestSchedAffinity)
 397 test_sched_affinity(HAVE_SCHED_AFFINITY)
 398
 399 # Aligned memory allocation. We need to check for both mm_malloc(),
 400 # posix_memalign(), memalign(), and on windows also _aligned_malloc()
 401 include(gmxTestMMMalloc)
 402 gmx_test_mm_malloc(HAVE__MM_MALLOC)
 403 check_cxx_symbol_exists(posix_memalign    stdlib.h     HAVE_POSIX_MEMALIGN)
 404 check_cxx_symbol_exists(memalign          stdlib.h     HAVE_MEMALIGN)
 405 if(MSVC)
 406     # No need to waste time on this test on platforms where it will never be true
 407     check_cxx_symbol_exists(_aligned_malloc   stdlib.h     HAVE__ALIGNED_MALLOC)
 408 endif()
 409
 410 include(TestBigEndian)
 411 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 412
 413 gmx_set_boolean(GMX_USE_NICE "HAVE_UNISTD_H AND HAVE_NICE")
 414
 415 # Management of GROMACS options for specific toolchains should go
 416 # here. Because the initial settings for some of the main options have
 417 # already happened, but things like library detection and MPI compiler
 418 # feature detection have not, the docstrings for any over-rides of
 419 # GROMACS defaults or user settings will make sense. Also, any
 420 # toolchain-related reasons for choosing whether to detect various
 421 # things can be sorted out now, before the detection takes place.
 422 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 423     include(gmxManageBlueGene)
 424 endif()
 425
 426 if(GMX_TARGET_FUJITSU_SPARC64)
 427     include(gmxManageFujitsuSparc64)
 428 endif()
 429
 430 ########################################################################
 431 #Process MPI settings
 432 ########################################################################
 433 include(gmxManageMPI)
 434
 435
 436 ########################################################################
 437 #Process shared/static library settings
 438 ########################################################################
 439 include(gmxManageSharedLibraries)
 440
 441
 442 ########################################################################
 443 # Find external packages                                               #
 444 ########################################################################
 445
 446 # TNG wants zlib if it is available. And static libxml2 might have a dependency
 447 find_package(ZLIB QUIET)
 448 include(gmxTestZLib)
 449 gmx_test_zlib(HAVE_ZLIB)
 450
 451 # Unconditionally find the package, as it is also required for unit
 452 # tests. This exports LIBXML2_FOUND, which we should not use because
 453 # it does not tell us that linking will succeed. Instead, we test that
 454 # next.
 455 if(DEFINED LIBXML2_LIBRARIES)
 456   set(LibXml2_FIND_QUIETLY TRUE)
 457 endif()
 458 find_package(LibXml2)
 459 include(gmxTestLibXml2)
 460 gmx_test_libxml2(HAVE_LIBXML2)
 461 option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 462 set(PKG_XML "")
 463 mark_as_advanced(GMX_XML)
 464 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 465 #if(GMX_XML AND NOT HAVE_LIBXML2)
 466 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 467 #endif()
 468 #if(GMX_XML)
 469 #    include_directories(${LIBXML2_INCLUDE_DIR})
 470 #    set(PKG_XML libxml-2.0)
 471 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 472 #endif()
 473
 474 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 475 mark_as_advanced(GMX_EXTRAE)
 476
 477 if (GMX_EXTRAE)
 478   find_package(EXTRAE)
 479   if(EXTRAE_FOUND)
 480     include_directories(SYSTEM ${EXTRAE_INCLUDE_DIR})
 481     set(HAVE_EXTRAE 1)
 482   else()
 483     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 484   endif()
 485 endif()
 486
 487 option(GMX_X11 "Use X window system" OFF)
 488 if (GMX_X11)
 489     find_package(X11)
 490     # X11 includes/libraries are only set in the ngmx subdirectory!
 491     if(NOT X11_FOUND)
 492         message(FATAL_ERROR
 493                 "X11 include files and/or libraries were not found. "
 494                 "Set GMX_X11=OFF to compile without X11 support. "
 495                 "gmx view will not be available.")
 496     endif()
 497     include_directories(SYSTEM ${X11_INCLUDE_DIR})
 498 endif()
 499
 500 include(ThreadMPI)
 501 # Enable core threading facilities
 502 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 503 # Enable tMPI C++ support
 504 tmpi_enable_cxx()
 505 if(GMX_THREAD_MPI)
 506     # enable MPI functions
 507     tmpi_enable()
 508     set(MPI_IN_PLACE_EXISTS 1)
 509 endif()
 510 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 511 if (TMPI_ATOMICS_DISABLED)
 512    add_definitions(-DTMPI_ATOMICS_DISABLED)
 513 endif()
 514
 515 if(GMX_GPU)
 516     # now that we have detected the dependencies, do the second configure pass
 517     gmx_gpu_setup()
 518 endif()
 519
 520 if(CYGWIN)
 521     set(GMX_CYGWIN 1)
 522 endif()
 523
 524 if(WIN32)
 525     set(GMX_NATIVE_WINDOWS 1)
 526     # This makes windows.h not declare min/max as macros that would break
 527     # C++ code using std::min/std::max.
 528     add_definitions(-DNOMINMAX)
 529 endif()
 530
 531 if(CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Work-around for cmake bug #10837
 532     if (CMAKE_COMPILER_IS_GNUCC OR CMAKE_C_COMPILER_ID MATCHES "Intel" OR CMAKE_C_COMPILER_ID MATCHES "Clang")
 533         set(CMAKE_INCLUDE_SYSTEM_FLAG_C "-isystem ")
 534     endif()
 535     if (CMAKE_COMPILER_IS_GNUCXX OR CMAKE_CXX_COMPILER_ID MATCHES "Intel" OR CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 536         set(CMAKE_INCLUDE_SYSTEM_FLAG_CXX "-isystem ")
 537     endif()
 538 endif()
 539
 540 if(NOT DEFINED GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 541     message(WARNING "libxml2 not found. Will build GROMACS without unit-tests. This is not recommended, because the unit-tests help to verify that GROMACS functions correctly. Most likely you are missing the libxml2-dev(el) package. After you installed it, set GMX_BUILD_UNITTESTS=ON.")
 542 endif()
 543 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ${HAVE_LIBXML2})
 544 mark_as_advanced(GMX_BUILD_UNITTESTS)
 545 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 546 if (GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 547     message(FATAL_ERROR
 548         "Cannot build unit tests without libxml2. "
 549         "Either set GMX_BUILD_UNITTESTS=OFF or tell CMake how to find a working version of libxml2.")
 550 endif()
 551
 552 ########################################################################
 553 # Our own GROMACS tests
 554 ########################################################################
 555
 556 add_definitions( -DHAVE_CONFIG_H )
 557 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src)
 558 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include)
 559 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 560 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src)
 561
 562 include(gmxTestInlineASM)
 563 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 564
 565 include(gmxSetBuildInformation)
 566 gmx_set_build_information()
 567 # Turn on RDTSCP if:
 568 # - the build system's CPU supports it
 569 # - the acceleration is set to AVX as all AVX-capable CPUs support AVX (which
 570 #   at this point means that the user set it).
 571 # Note: it's better to not use the later set value of GMX_SIMD because
 572 # it reflects the system's capability of both compiling and running AVX code.
 573 # TODO: After merge with 5.0 one could implement a cache variable dependency
 574 # such that GMX_USE_RDTSCP can change if GMX_SIMD is changed to AVX
 575 # after the first cmake pass.
 576 if (BUILD_CPU_FEATURES MATCHES "rdtscp" OR GMX_SIMD MATCHES "AVX")
 577     set(GMX_USE_RDTSCP_DEFAULT_VALUE ON)
 578 else()
 579     set(GMX_USE_RDTSCP_DEFAULT_VALUE OFF)
 580 endif()
 581 option(GMX_USE_RDTSCP "Use RDTSCP for better CPU-based timers (available on recent x86 CPUs; might need to be off when compiling for heterogeneous environments)" ${GMX_USE_RDTSCP_DEFAULT_VALUE})
 582 mark_as_advanced(GMX_USE_RDTSCP)
 583 if(GMX_USE_RDTSCP)
 584     set(HAVE_RDTSCP 1)
 585 endif()
 586
 587 include(gmxTestLargeFiles)
 588 gmx_test_large_files(GMX_LARGEFILES)
 589
 590 include(gmxTestSignal)
 591 gmx_test_sigusr1(HAVE_SIGUSR1)
 592
 593 include(gmxTestPipes)
 594 gmx_test_pipes(HAVE_PIPES)
 595
 596 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 597
 598 include(gmxTestXDR)
 599 gmx_test_xdr(GMX_SYSTEM_XDR)
 600 if(NOT GMX_SYSTEM_XDR)
 601     set(GMX_INTERNAL_XDR 1)
 602 endif()
 603
 604
 605 ##################################################
 606 # Process SIMD instruction settings
 607 ##################################################
 608 # This checks what flags to add in order to
 609 # support the SIMD instructions we need, it sets
 610 # correct defines for the SIMD instructions supported,
 611 # and adds advanced options to control accuracy
 612 # for SIMD math operations.
 613 include(gmxManageSimd)
 614 gmx_manage_simd()
 615
 616 # Process QM/MM Settings
 617 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 618     set(GMX_QMMM_GAUSSIAN 1)
 619 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 620     set(GMX_QMMM_MOPAC 1)
 621 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 622     set(GMX_QMMM_GAMESS 1)
 623 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 624     set(GMX_QMMM_ORCA 1)
 625 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 626     # nothing to do
 627 else()
 628     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 629 endif()
 630
 631
 632 ##################################################
 633 # Process FFT library settings
 634 ##################################################
 635 include(gmxManageFFTLibraries)
 636
 637
 638 include(gmxManageLinearAlgebraLibraries)
 639
 640 # Whether GROMACS will really try to compile support for VMD plugins
 641 set(GMX_USE_PLUGINS OFF)
 642
 643 if(GMX_LOAD_PLUGINS)
 644   if(NOT WIN32)
 645     # Native Windows does not have, nor need dlopen
 646     include(gmxTestdlopen)
 647     gmx_test_dlopen(HAVE_DLOPEN)
 648   endif()
 649
 650   # so, should we use plug-ins?
 651   if(WIN32 OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 652     if(NOT VMD_QUIETLY)
 653       MESSAGE(STATUS "Using dynamic plugins (e.g VMD-supported file formats)")
 654     endif()
 655     if(NOT GMX_VMD_PLUGIN_PATH)
 656       find_package(VMD)
 657     endif()
 658     set(GMX_USE_PLUGINS ON)
 659     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 660     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 661   else()
 662     set(PKG_DL_LIBS)
 663   endif()
 664 endif()
 665 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 666
 667 # Link real-time library for POSIX timers. The check for clock_gettime
 668 # confirms the linkability of rt.
 669 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 670     list(APPEND GMX_EXTRA_LIBRARIES rt)
 671 endif()
 672
 673 # Math and thread libraries must often come after all others when linking...
 674 if(HAVE_LIBM)
 675     list(APPEND GMX_EXTRA_LIBRARIES m)
 676 endif()
 677
 678 option(GMX_NACL "Configure for Native Client builds" OFF)
 679 if (GMX_NACL)
 680   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 681   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 682   # TODO: Is this still necessary with the check for its presence?
 683   set(GMX_USE_NICE 0)
 684   set(GMX_NO_RENAME 1)
 685 endif()
 686 mark_as_advanced(GMX_NACL)
 687
 688 if(GMX_FAHCORE)
 689   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 690       "Path to swindirect.h")
 691   include_directories(${COREWRAP_INCLUDE_DIR})
 692 endif()
 693
 694 # Value of GMX_BUILD_HELP=AUTO tries to generate things, but will only
 695 # produce warnings if that fails.
 696 set(build_help_default AUTO)
 697 if (SOURCE_IS_SOURCE_DISTRIBUTION OR CMAKE_CROSSCOMPILING)
 698     set(build_help_default OFF)
 699 endif()
 700 gmx_option_trivalue(GMX_BUILD_HELP "Build completions automatically (requires that compiled binaries can be executed on the build host) and install man pages if built (requires building the 'man' target manually)" ${build_help_default})
 701 mark_as_advanced(GMX_BUILD_HELP)
 702 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND BUILD_IS_INSOURCE)
 703     message(FATAL_ERROR
 704         "Rebuilding shell completions or man pages is not supported for "
 705         "in-source builds from a source distribution. "
 706         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 707 endif()
 708
 709 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 710 # these are set after everything else
 711 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 712     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 713     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 714     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 715     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 716 else()
 717     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 718     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 719     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 720     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 721     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 722     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 723     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 724     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 725     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
 726 endif()
 727
 728 if(NOT GMX_OPENMP)
 729     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 730     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 731     unset(OpenMP_C_FLAGS CACHE)
 732     unset(OpenMP_CXX_FLAGS CACHE)
 733 else()
 734     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 735     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 736 endif()
 737
 738 ########################################################################
 739 # Specify install locations
 740 ########################################################################
 741 # Use GNUInstallDirs to set paths on multiarch systems.
 742 include(GNUInstallDirs)
 743
 744 # Customization for the installation tree paths.
 745 set(GMX_LIB_INSTALL_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING
 746     "Library installation directory (default: ${CMAKE_INSTALL_LIBDIR})")
 747 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 748     "Data installation directory under share/ (default: gromacs)")
 749 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 750
 751 # These variables are used internally to provide a central location for
 752 # customizing the install locations.
 753 set(LIB_INSTALL_DIR       ${GMX_LIB_INSTALL_DIR})
 754 set(BIN_INSTALL_DIR       bin)
 755 # This variable also gets written into config.h for use in finding the data
 756 # directories.
 757 set(DATA_INSTALL_DIR      share/${GMX_DATA_INSTALL_DIR})
 758 set(MAN_INSTALL_DIR       share/man)
 759 # If the nesting level wrt. the installation root is changed,
 760 # gromacs-config.cmake.cmakein needs to be adapted.
 761 set(CMAKE_INSTALL_DIR     share/cmake)
 762 # TODO: Make GMXRC adapt if this is changed
 763 set(PKGCONFIG_INSTALL_DIR ${LIB_INSTALL_DIR}/pkgconfig)
 764 set(OCL_INSTALL_DIR       ${DATA_INSTALL_DIR}/opencl)
 765 set(INCL_INSTALL_DIR      include)
 766
 767 list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${INCL_INSTALL_DIR})
 768
 769 # Binary and library suffix options
 770 include(gmxManageSuffixes)
 771
 772 ################################################################
 773 # Shared library load path settings
 774 ################################################################
 775 # CMake supports RPATH on OS X only from 2.8.12 upwards.
 776 # CMAKE_SYSTEM_VERSION > 8.0 matches OS X 10.5 and above, where RPATH support
 777 # was added.
 778
 779 if(NOT GMX_BUILD_SHARED_EXE)
 780     # No rpath
 781     set(CMAKE_SKIP_RPATH TRUE)
 782     set(CMAKE_EXE_LINK_DYNAMIC_C_FLAGS) # remove -Wl,-Bdynamic
 783     set(CMAKE_EXE_LINK_DYNAMIC_CXX_FLAGS)
 784 elseif((NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin") OR
 785    ((CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) AND (NOT CMAKE_VERSION VERSION_LESS 2.8.12)))
 786     # The build folder always has bin/ and lib/; if we are also going to
 787     # install to lib/, then the installation RPATH works also in the build
 788     # tree.  This makes installation slightly faster (no need to rewrite the
 789     # RPATHs), and makes the binaries in the build tree relocatable.
 790     if(GMX_LIB_INSTALL_DIR STREQUAL "lib")
 791         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 792     endif()
 793     # Set the RPATH as relative to the executable location to make the
 794     # binaries relocatable.
 795     if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 796         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${GMX_LIB_INSTALL_DIR}")
 797     else()
 798         set(CMAKE_INSTALL_RPATH "@executable_path/../${GMX_LIB_INSTALL_DIR}")
 799     endif()
 800     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 801     set(CMAKE_MACOSX_RPATH 1)
 802 else()
 803     # We are on Darwin/OSX, and CMake cannot handle RPATHs automatically.
 804     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0)
 805         # Set the RPATH options manually.
 806         set(CMAKE_INSTALL_NAME_DIR "@rpath")
 807         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../${GMX_LIB_INSTALL_DIR}")
 808     else()
 809         # Use the old INSTALL_NAME_DIR mechanism if RPATH is not supported.
 810         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
 811     endif()
 812 endif()
 813
 814 #COPYING file: Only necessary for binary distributions.
 815 #Simpler to always install.
 816 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 817
 818 if (GMX_BUILD_FOR_COVERAGE)
 819     # Code heavy with asserts makes conditional coverage close to useless metric,
 820     # as by design most of the false branches are impossible to trigger in
 821     # correctly functioning code.  And the benefit of testing those that could
 822     # be triggered by using an API against its specification isn't usually
 823     # worth the effort.
 824     add_definitions(-DNDEBUG -DGMX_DISABLE_ASSERTS)
 825 endif()
 826
 827 if (BUILD_TESTING)
 828     # "tests" target builds all the separate test binaries.
 829     add_custom_target(tests)
 830     # "run-ctest" is an internal target that actually runs the tests.
 831     # This is necessary to be able to add separate targets that execute as part
 832     # of 'make check', but are ensured to be executed after the actual tests.
 833     add_custom_target(run-ctest
 834                       COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure
 835                       COMMENT "Running all tests"
 836                       VERBATIM)
 837     add_dependencies(run-ctest tests)
 838     # "check" target builds and runs all tests.
 839     add_custom_target(check DEPENDS run-ctest)
 840 endif()
 841
 842 if (NOT GMX_BUILD_MDRUN_ONLY)
 843     add_subdirectory(docs)
 844     add_subdirectory(share)
 845     add_subdirectory(scripts)
 846 endif()
 847 add_subdirectory(src)
 848
 849 if (BUILD_TESTING)
 850     add_subdirectory(tests)
 851 endif()
 852
 853 gmx_cpack_write_config()
 854
 855 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 856 # Don't bother the user after the first configure pass.
 857 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 858     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 859 endif()
 860 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 861
 862 #######################
 863 ## uninstall target
 864 #######################
 865 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 866                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 867                   IMMEDIATE @ONLY)
 868 ###########################
 869 ADD_CUSTOM_TARGET(uninstall
 870                   "${CMAKE_COMMAND}" -P
 871                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 872 ###########################
 873 set_directory_properties(PROPERTIES
 874             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")