CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8)
   2 # Keep CMake suitably quiet on Cygwin
   3 set(CMAKE_LEGACY_CYGWIN_WIN32 0) # Remove when CMake >= 2.8.4 is required
   4
   5 project(Gromacs)
   6 include(Dart)
   7 mark_as_advanced(DART_ROOT)
   8
   9 # PROJECT_VERSION should have the following structure:
  10 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  11 #
  12 # The "-dev" suffix is important to keep because it makes possible to distinguish
  13 # between a build from official release and a build from git release branch on a
  14 # machine with no git.
  15 #
  16 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  17 set(PROJECT_VERSION "4.6-dev")
  18 set(CUSTOM_VERSION_STRING ""
  19     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  20 mark_as_advanced(CUSTOM_VERSION_STRING)
  21 if (CUSTOM_VERSION_STRING)
  22     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  23 endif (CUSTOM_VERSION_STRING)
  24 set(SOVERSION 6)
  25 # It is a bit irritating, but this has to be set separately for now!
  26 SET(CPACK_PACKAGE_VERSION_MAJOR "4")
  27 SET(CPACK_PACKAGE_VERSION_MINOR "6")
  28 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  29
  30
  31 # Cmake modules/macros are in a subdirectory to keep this file cleaner
  32 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  33
  34 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  35 set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  36 endif()
  37
  38 if(NOT CMAKE_BUILD_TYPE)
  39     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
  40 endif(NOT CMAKE_BUILD_TYPE)
  41
  42 enable_language(C)
  43 enable_language(CXX)
  44
  45 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
  46 set(CPACK_PACKAGE_VENDOR "gromacs.org")
  47 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
  48 set(CPACK_SET_DESTDIR "ON")
  49 set(CPACK_INCLUDE_TOPLEVEL_DIRECTORY 0)
  50 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
  51 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
  52 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/admin/InstallLicense.txt")
  53 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
  54
  55 #must come after all cpack settings!
  56 include(CPack)
  57
  58 ########################################################################
  59 # Check and warn if cache generated on a different host is being reused
  60 ########################################################################
  61 if(CMAKE_HOST_UNIX)
  62     execute_process(COMMAND hostname
  63                     OUTPUT_VARIABLE TMP_HOSTNAME
  64                     OUTPUT_STRIP_TRAILING_WHITESPACE)
  65     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
  66         message(WARNING "
  67             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
  68             is being reused! This could lead to inconsitencies; therefore, it is
  69             recommended to regenerate the cache!")
  70     endif()
  71     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
  72             "Hostname of the machine where the cache was generated.")
  73 endif()
  74
  75 ########################################################################
  76 # Fix stupid flags on Windows
  77 ########################################################################
  78 SET(SHARED_LIBS_DEFAULT ON)
  79 IF( WIN32 AND NOT CYGWIN)
  80   option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static system libraries (MT instead of MD)!" ON)
  81   mark_as_advanced(GMX_PREFER_STATIC_LIBS)
  82   SET(SHARED_LIBS_DEFAULT OFF)  #is currently not working on Windows
  83
  84   IF (GMX_PREFER_STATIC_LIBS)
  85     #Only setting Debug and Release flags. Others configurations current not used.
  86     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
  87     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
  88     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
  89     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
  90     STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE})
  91     SET(CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE} CACHE STRING "" FORCE)
  92     STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
  93     SET(CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG} CACHE STRING "" FORCE)
  94   ENDIF()
  95
  96   #Workaround for cmake bug 13174. Replace deprecated options.
  97   IF( CMAKE_C_COMPILER_ID MATCHES "Intel" )
  98     STRING(REPLACE /GZ /RTC1 CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
  99     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
 100   ENDIF()
 101   IF( CMAKE_CXX_COMPILER_ID MATCHES "Intel" )
 102     STRING(REPLACE /GZ /RTC1 CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 103     STRING(REPLACE /GX /EHsc CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 104     SET(CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG} CACHE STRING "" FORCE)
 105
 106     STRING(REPLACE /GX /EHsc CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE})
 107     SET(CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE} CACHE STRING "" FORCE)
 108   ENDIF()
 109 ENDIF()
 110
 111 ########################################################################
 112 # User input options                                                   #
 113 ########################################################################
 114 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 115 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 116 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 117 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 118 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 119 option(GMX_POWERPC_INVSQRT "Use PowerPC hardware 1/sqrt" OFF)
 120 mark_as_advanced(GMX_POWERPC_INVSQRT)
 121 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 122 mark_as_advanced(GMX_FAHCORE)
 123 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library (rerun cmake after changing to see relevant options)" OFF)
 124 set(GMX_ACCELERATION "auto"
 125     CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran")
 126
 127 set(GMX_FFT_LIBRARY "fftw3"
 128     CACHE STRING "FFT library choices: fftw3,mkl,fftpack[built-in]")
 129 option(GMX_DISABLE_FFTW_MEASURE
 130        "Do not optimize FFTW setups (not needed with SSE)" OFF)
 131 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 132 set(GMX_QMMM_PROGRAM "none"
 133     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
 134 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 135 mark_as_advanced(GMX_BROKEN_CALLOC)
 136 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI, Windows)" ${SHARED_LIBS_DEFAULT})
 137 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
 138 mark_as_advanced(GMX_MPI_IN_PLACE)
 139 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 140 mark_as_advanced(GMX_LOAD_PLUGINS)
 141
 142
 143 option(GMX_IA32_ASM "Add SSE assembly files for IA32" OFF)
 144 mark_as_advanced(GMX_IA32_ASM)
 145 option(GMX_X86_64_ASM "Add SSE assembly files for X86_64" OFF)
 146 mark_as_advanced(GMX_X86_64_ASM)
 147
 148 option(GMX_OPENMP "Enable OpenMP-based mutithreading. " ON)
 149
 150 option(USE_VERSION_H "Generate development version string/information" ON)
 151 mark_as_advanced(USE_VERSION_H)
 152
 153 option(GMX_DEFAULT_SUFFIX "Use default suffixes for GROMACS binaries and libs (_d for double, _mpi for MPI; rerun cmake after changing to see relevant options)" ON)
 154
 155 if(UNIX AND NOT APPLE)
 156     option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer \".a\" static archives (NOTE: this is enabled only for UNIX (excluding APPLE) platforms but it might not always work!" OFF)
 157     mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 158 endif()
 159
 160
 161 ######################################################################
 162 # compiler tests
 163 # these need ot be done early (before further tests).
 164 #####################################################################
 165
 166 # cmake/Check{C,CXX}CompilerFlag.cmake are lifted from CMake git next
 167 # branch (proposed for v2.8.9) to be able to detect invalid options
 168 # with the Intel Compilers.
 169 # Remove these files from the source tree when a CMake version that
 170 # includes the features in question becomes required.
 171 include(CheckCCompilerFlag)
 172 include(CheckCXXCompilerFlag)
 173
 174 include(gmxCFlags)
 175 gmx_c_flags()
 176
 177
 178 ########################################################################
 179 # Set up binary and library suffixing
 180 ########################################################################
 181 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 182 set(GMX_LIBS_SUFFIX ""
 183   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 184 if (GMX_DEFAULT_SUFFIX)
 185   set(GMX_BINARY_SUFFIX "")
 186   set(GMX_LIBS_SUFFIX "")
 187   if (GMX_MPI)
 188     set(GMX_BINARY_SUFFIX "_mpi")
 189     set(GMX_LIBS_SUFFIX "_mpi")
 190   endif(GMX_MPI)
 191   if (GMX_DOUBLE)
 192     set (GMX_BINARY_SUFFIX "${GMX_BINARY_SUFFIX}_d")
 193     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
 194   endif(GMX_DOUBLE)
 195   if (GMX_OPENMM)
 196     set (GMX_BINARY_SUFFIX "-gpu")
 197     set (GMX_LIBS_SUFFIX "_gpu")
 198   endif(GMX_OPENMM)
 199   mark_as_advanced(FORCE GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 200   if (NOT SUFFIX_QUIETLY)
 201     message(STATUS "Using default binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 202     message(STATUS "Using default library suffix: \"${GMX_LIBS_SUFFIX}\"")
 203   endif (NOT SUFFIX_QUIETLY)
 204 else(GMX_DEFAULT_SUFFIX)
 205   mark_as_advanced(CLEAR GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 206   if (NOT SUFFIX_QUIETLY)
 207     message(STATUS "Using manually set binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 208     message(STATUS "Using manually set library suffix: \"${GMX_LIBS_SUFFIX}\"")
 209   endif (NOT SUFFIX_QUIETLY)
 210 endif(GMX_DEFAULT_SUFFIX)
 211 set(SUFFIX_QUIETLY TRUE CACHE INTERNAL "")
 212
 213 set(PKG_CFLAGS "")
 214 if(GMX_DOUBLE)
 215     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 216 endif(GMX_DOUBLE)
 217 if(GMX_SOFTWARE_INVSQRT)
 218   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 219 endif(GMX_SOFTWARE_INVSQRT)
 220 if(GMX_POWERPC_INVSQRT)
 221   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_POWERPC_INVSQRT")
 222 endif(GMX_POWERPC_INVSQRT)
 223
 224 ########################################################################
 225 #Process MPI settings
 226 ########################################################################
 227 include(gmxManageMPI)
 228
 229 #######################################################################
 230 # Check for options incompatible with OpenMM build                    #
 231 #######################################################################
 232 if(GMX_OPENMM)
 233     # we'll use the built-in fft to avoid unnecessary dependencies
 234     string(TOUPPER ${GMX_FFT_LIBRARY} GMX_FFT_LIBRARY)
 235     if(NOT ${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 236         message(STATUS "No external FFT libraries needed for the OpenMM build, switching to fftpack!")
 237         set(GMX_FFT_LIBRARY "fftpack" CACHE STRING
 238                 "No external FFT libraries needed for the OpenMM build, switching to  fftpack!" FORCE)
 239     endif()
 240     if(GMX_MPI)
 241         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
 242     endif(GMX_MPI)
 243     if(GMX_THREAD_MPI)
 244         message(STATUS "Thread-MPI not compatible with OpenMM, disabled!")
 245         set(GMX_THREAD_MPI OFF CACHE BOOL
 246                 "Thread-MPI not compatible with OpenMM build, disabled!" FORCE)
 247     endif(GMX_THREAD_MPI)
 248     if(GMX_OPENMP)
 249         message(STATUS "OpenMP multithreading not compatible with OpenMM, disabled")
 250         set(GMX_OPENMP OFF CACHE BOOL
 251             "OpenMP multithreading not compatible with OpenMM, disabled!" FORCE)
 252     endif()
 253     if(GMX_SOFTWARE_INVSQRT)
 254         set(GMX_SOFTWARE_INVSQRT OFF CACHE STRING
 255                 "The OpenMM build does not need GROMACS software 1/sqrt!" FORCE)
 256     endif(GMX_SOFTWARE_INVSQRT)
 257     string(TOUPPER ${GMX_ACCELERATION} GMX_ACCELERATION)
 258     if(NOT GMX_ACCELERATION STREQUAL "NONE")
 259         message(STATUS "Switching off CPU-based acceleration, the OpenMM build does not support/need any!")
 260         set(GMX_ACCELERATION "none" CACHE STRING
 261                 "Switching off CPU-based acceleration, the OpenMM build does not support/need any!" FORCE)
 262     endif()
 263     if(GMX_FAHCORE)
 264         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
 265     endif(GMX_FAHCORE)
 266     if(GMX_DOUBLE)
 267         message(FATAL_ERROR  "The OpenMM-build does not support double precision calculations!")
 268     endif()
 269     # mark as advanced the unused variables
 270     mark_as_advanced(FORCE GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 271         GMX_QMMM_PROGRAM GMX_THREAD_MPI GMX_DOUBLE)
 272 else(GMX_OPENMM)
 273      mark_as_advanced(CLEAR GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 274         GMX_QMMM_PROGRAM GMX_THREAD_MPI GMX_DOUBLE)
 275 endif(GMX_OPENMM)
 276
 277
 278 ########################################################################
 279 # Basic system tests (standard libraries, headers, functions, types)   #
 280 ########################################################################
 281 include(CheckIncludeFiles)
 282 check_include_files(string.h     HAVE_STRING_H)
 283 check_include_files(math.h       HAVE_MATH_H)
 284 check_include_files(limits.h     HAVE_LIMITS_H)
 285 check_include_files(memory.h     HAVE_MEMORY_H)
 286 check_include_files(unistd.h     HAVE_UNISTD_H)
 287 check_include_files(direct.h     HAVE_DIRECT_H)
 288 check_include_files(pwd.h        HAVE_PWD_H)
 289 check_include_files(stdint.h     HAVE_STDINT_H)
 290 check_include_files(stdlib.h     HAVE_STDLIB_H)
 291 check_include_files(pthread.h    HAVE_PTHREAD_H)
 292 check_include_files(dirent.h     HAVE_DIRENT_H)
 293 check_include_files(inttypes.h   HAVE_INTTYPES_H)
 294 check_include_files(regex.h      HAVE_REGEX_H)
 295 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 296 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
 297 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 298 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
 299 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
 300 # SSE support
 301 check_include_files(xmmintrin.h  HAVE_XMMINTRIN_H)
 302 check_include_files(emmintrin.h  HAVE_EMMINTRIN_H)
 303 check_include_files(pmmintrin.h  HAVE_PMMINTRIN_H)
 304 check_include_files(smmintrin.h  HAVE_SMMINTRIN_H)
 305 check_include_files(io.h                 HAVE_IO_H)
 306
 307
 308 include(CheckFunctionExists)
 309 check_function_exists(strcasecmp        HAVE_STRCASECMP)
 310 check_function_exists(strdup            HAVE_STRDUP)
 311 check_function_exists(vprintf           HAVE_VPRINTF)
 312 check_function_exists(memcmp            HAVE_MEMCMP)
 313 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 314 check_function_exists(memalign          HAVE_MEMALIGN)
 315 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 316 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 317 check_function_exists(isnan             HAVE_ISNAN)
 318 check_function_exists(_isnan            HAVE__ISNAN)
 319 check_function_exists(fsync             HAVE_FSYNC)
 320 check_function_exists(_fileno           HAVE__FILENO)
 321 check_function_exists(fileno            HAVE_FILENO)
 322 check_function_exists(_commit           HAVE__COMMIT)
 323 check_function_exists(lstat             HAVE_LSTAT)
 324 check_function_exists(sigaction         HAVE_SIGACTION)
 325
 326 include(CheckLibraryExists)
 327 check_library_exists(m sqrt "" HAVE_LIBM)
 328 check_library_exists(m cbrt "" HAVE_CBRT)
 329
 330
 331 include(CheckTypeSize)
 332
 333 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 334 check_type_size("int"           SIZEOF_INT)
 335 check_type_size("long int"      SIZEOF_LONG_INT)
 336 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 337 check_type_size("off_t"         SIZEOF_OFF_T)
 338 check_type_size("void *"        SIZEOF_VOIDP)
 339
 340 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 341     set(GMX_64_BIT TRUE)
 342 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 343     set(GMX_64_BIT FALSE)
 344 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 345
 346 # Check for some basic types that we *need*, so set these to int if they are not present
 347 check_type_size(uid_t uid_t)
 348 if(NOT uid_t)
 349   set(uid_t int)
 350 else(NOT uid_t)
 351   set(uid_t 0)
 352 endif(NOT uid_t)
 353
 354 check_type_size(gid_t gid_t)
 355 if(NOT gid_t)
 356   set(gid_t 1)
 357 else(NOT gid_t)
 358   set(gid_t 0)
 359 endif(NOT gid_t)
 360
 361 check_type_size(size_t size_t)
 362 if(NOT size_t)
 363   set(size_t int)
 364 else(NOT size_t)
 365   set(size_t 0)
 366 endif(NOT size_t)
 367
 368 check_type_size(off_t off_t)
 369 if(NOT off_t)
 370   set(off_t int)
 371 else(NOT off_t)
 372   set(off_t 0)
 373 endif(NOT off_t)
 374
 375 include(TestBigEndian)
 376 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 377
 378
 379
 380
 381 ########################################################################
 382 # Find external packages                                               #
 383 ########################################################################
 384 if(UNIX AND NOT APPLE)
 385     if(GMX_PREFER_STATIC_LIBS)
 386         SET(CMAKE_FIND_LIBRARY_SUFFIXES .a ${CMAKE_FIND_LIBRARY_SUFFIXES})
 387         if(BUILD_SHARED_LIBS)
 388             message(WARNING "Static libraries requested, the GROMACS libraries will also be build static (BUILD_SHARED_LIBS=OFF)")
 389             set(BUILD_SHARED_LIBS OFF CACHE BOOL "Enable shared libraries (can be problematic with MPI, Windows)" FORCE)
 390         endif()
 391     endif()
 392 endif()
 393
 394 option(GMX_XML "Use libxml2 to parse xml files" ON)
 395 if (GMX_XML)
 396   find_package(LibXml2)
 397   set(PKG_XML "")
 398   if(LIBXML2_FOUND)
 399     include_directories(${LIBXML2_INCLUDE_DIR})
 400     set(PKG_XML libxml-2.0)
 401     set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 402     set(HAVE_LIBXML2 1)
 403   endif(LIBXML2_FOUND)
 404 endif(GMX_XML)
 405
 406 option(GMX_GSL "Add support for gsl" OFF)
 407 if (GMX_GSL)
 408   find_package(gsl)
 409   set(PKG_GSL "")
 410   if(GSL_FOUND)
 411     include_directories(${GSL_INCLUDE_DIR})
 412     set(PKG_GSL gsl)
 413     set(HAVE_LIBGSL 1)
 414   endif(GSL_FOUND)
 415 endif (GMX_GSL)
 416
 417 option(GMX_X11 "Use X window system" OFF)
 418 if (GMX_X11)
 419         find_package(X11)
 420         # X11 includes/libraries are only set in the ngmx subdirectory!
 421         if(X11_FOUND)
 422         set(HAVE_X11 1)
 423         endif(X11_FOUND)
 424 endif(GMX_X11)
 425
 426 if(GMX_THREAD_MPI)
 427     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREAD_MPI")
 428     include(ThreadMPI)
 429     set(THREAD_MPI_LIB thread_mpi)
 430     set(GMX_MPI 1)
 431     string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 432 endif(GMX_THREAD_MPI)
 433
 434 if(GMX_OPENMM)
 435     set(CUDA_BUILD_EMULATION OFF)
 436     find_package(CUDA 3.1 REQUIRED)
 437     add_definitions(-DGMX_OPENMM)
 438     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 439         set(CUDA_VERBOSE_BUILD ON)
 440     endif()
 441     find_package(OpenMM)
 442 endif(GMX_OPENMM)
 443
 444 if(GMX_OPENMP)
 445     find_package(OpenMP REQUIRED)
 446     set(GROMACS_C_FLAGS "${OpenMP_C_FLAGS} ${GROMACS_C_FLAGS}")
 447     set(GROMACS_CXX_FLAGS "${OpenMP_CXX_FLAGS} ${GROMACS_CXX_FLAGS}")
 448     add_definitions(-DGMX_OPENMP)
 449 endif()
 450
 451 if(APPLE)
 452    find_library(ACCELERATE_FRAMEWORK Accelerate)
 453    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 454 endif(APPLE)
 455
 456 if(CYGWIN)
 457     set(GMX_CYGWIN 1)
 458 endif(CYGWIN)
 459
 460 if(WIN32 AND NOT CYGWIN)
 461     set(GMX_NATIVE_WINDOWS 1)
 462 endif()
 463
 464 # only bother with finding git and using version.h if the source is a git repo
 465 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 466     if(USE_VERSION_H)
 467         # We need at least git v1.5.1 be able to parse git's date output. If not
 468         # found or the version is too small, we can't generate version information.
 469         find_package(Git)
 470
 471         # Find out the git version
 472         if(GIT_FOUND AND NOT GIT_VERSION)
 473           execute_process(COMMAND ${GIT_EXECUTABLE} "--version"
 474             OUTPUT_VARIABLE _exec_out
 475             OUTPUT_STRIP_TRAILING_WHITESPACE)
 476           string(REGEX REPLACE "git version (.*)" "\\1" GIT_VERSION ${_exec_out})
 477           set(GIT_VERSION ${GIT_VERSION} CACHE STRING "Git version")
 478           mark_as_advanced(GIT_VERSION)
 479         endif()
 480
 481         if(NOT GIT_FOUND OR GIT_VERSION VERSION_LESS "1.5.1")
 482           message("No compatible git version found, won't be able to generate proper development version information.")
 483           set(USE_VERSION_H OFF)
 484         endif()
 485     endif()
 486 else()
 487     set(USE_VERSION_H OFF)
 488 endif()
 489
 490 option(GMX_INTERNAL_BOOST "Use minimal internal version of boost" OFF)
 491 if ( NOT GMX_INTERNAL_BOOST )
 492   find_package( Boost 1.36.0 )
 493 else ( NOT GMX_INTERNAL_BOOST )
 494   set (Boost_FOUND FALSE)
 495 endif( NOT GMX_INTERNAL_BOOST )
 496
 497 if(Boost_FOUND)
 498   include_directories(${Boost_INCLUDE_DIRS})
 499 else()
 500   message("Boost >= 1.36 not found. Using minimal internal version. Not recommended if GROMACS is used as library!")
 501   include_directories(${CMAKE_SOURCE_DIR}/src/external/boost)
 502   add_definitions( -DBOOST_NO_TYPEID )  #TYPEID not supported for minimal internal version (would add significant more code)
 503   # TODO: Propagate the above settings to the installed CMakeFiles.txt template
 504   # (from share/template/)
 505   # TODO: Reorder stuff such that INCL_INSTALL_DIR could be used here
 506   set(PKG_CFLAGS "${PKG_CFLAGS} -DBOOST_NO_TYPEID -I${CMAKE_INSTALL_PREFIX}/include/gromacs/external/boost")
 507   install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
 508           DESTINATION ${CMAKE_INSTALL_PREFIX}/include/gromacs/external/boost
 509           COMPONENT development)
 510 endif()
 511
 512 option(GMX_USE_GTEST "Build tests that require Google C++ Testing Framework" ON)
 513 option(GMX_USE_GMOCK "Build tests that require Google C++ Mocking Framework" ON)
 514 mark_as_advanced(GMX_USE_GTEST)
 515 mark_as_advanced(GMX_USE_GMOCK)
 516 if (BUILD_TESTING)
 517     add_subdirectory(src/external/gmock-1.6.0)
 518     add_custom_target(tests)
 519 endif (BUILD_TESTING)
 520 set(MEMORYCHECK_SUPPRESSIONS_FILE ${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp)
 521
 522 find_package(Doxygen)
 523
 524 ########################################################################
 525 # Generate development version info for cache
 526 ########################################################################
 527 # set(GEN_VERSION_INFO_INTERNAL "ON")
 528 # include(gmxGenerateVersionString)
 529
 530 ########################################################################
 531 # Our own GROMACS tests
 532 ########################################################################
 533
 534 add_definitions( -DHAVE_CONFIG_H )
 535 include_directories(${CMAKE_SOURCE_DIR}/src)
 536 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 537 include_directories(${CMAKE_BINARY_DIR}/src)
 538 # Required for now to make old code compile
 539 include_directories(${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders)
 540
 541 include(gmxCheckBuildUserTime)
 542 gmx_check_build_user_time(BUILD_TIME BUILD_USER BUILD_MACHINE)
 543
 544 include(gmxTestFloatFormat)
 545 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 546                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 547                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 548
 549 include(gmxTestLargeFiles)
 550 gmx_test_large_files(GMX_LARGEFILES)
 551 check_function_exists(fseeko     HAVE_FSEEKO)
 552
 553 include(gmxTestSignal)
 554 gmx_test_sigusr1(HAVE_SIGUSR1)
 555
 556 include(gmxTestInline)
 557 gmx_test_inline(INLINE_KEYWORD)
 558
 559 include(gmxTestRestrict)
 560 gmx_test_inline(RESTRICT_KEYWORD)
 561
 562 include(gmxTestPipes)
 563 gmx_test_pipes(HAVE_PIPES)
 564
 565 include(gmxTestIsfinite)
 566 gmx_test_isfinite(HAVE_ISFINITE)
 567 gmx_test__isfinite(HAVE__ISFINITE)
 568 gmx_test__finite(HAVE__FINITE)
 569
 570 include(gmxTestInlineASM)
 571 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 572 gmx_test_inline_asm_msvc_x86(GMX_X86_MSVC_INLINE_ASM)
 573
 574 include(gmxTestCXX11)
 575 gmx_test_cxx11(GMX_CXX11 CXX11_FLAG)
 576 set(GROMACS_CXX_FLAGS "${CXX11_FLAG} ${GROMACS_CXX_FLAGS}")
 577
 578 # turn on SSE if supported with reasonable defaults.
 579 if (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 580   if(CMAKE_SYSTEM_PROCESSOR MATCHES "^(i.86|x86|x64|x86_64|AMD64|amd64)" OR CYGWIN)
 581
 582     set(GMX_ACCELERATION "SSE" CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran" FORCE)
 583
 584     # Determine the assembler/compiler to use
 585   else()
 586     set(GMX_ACCELERATION "none" CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran" FORCE)
 587   endif()
 588 endif (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 589
 590 include(gmxTestXDR)
 591 gmx_test_xdr(GMX_SYSTEM_XDR)
 592 if(NOT GMX_SYSTEM_XDR)
 593     set(GMX_INTERNAL_XDR 1)
 594     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 595 endif(NOT GMX_SYSTEM_XDR)
 596
 597 # Process nonbonded accelerated kernels settings
 598 string(TOUPPER ${GMX_ACCELERATION} ${GMX_ACCELERATION})
 599 if(${GMX_ACCELERATION} STREQUAL "NONE")
 600   # nothing to do
 601 elseif(${GMX_ACCELERATION} STREQUAL "SSE")
 602
 603     if (GMX_64_BIT)
 604       set(GMX_X86_64_ASM ON CACHE BOOL "Add SSE assembly files for x86_64" FORCE)
 605     else (GMX_64_BIT)
 606       set(GMX_IA32_ASM ON CACHE BOOL "Add SSE assembly files for i386" FORCE)
 607     endif (GMX_64_BIT)
 608
 609     if( WIN32 AND NOT CYGWIN )
 610       option(GMX_ASM_USEASM_NASM "Use Nasm for assembly instead of compiler (necessary on windows)" ON)
 611     else()
 612       option(GMX_ASM_USEASM_NASM "Use Nasm for assembly instead of compiler (necessary on windows)" OFF)
 613     endif()
 614         mark_as_advanced(GMX_ASM_USEASM_NASM)
 615
 616     if (NOT GMX_64_BIT)
 617         # for 32-bit compiles, we might need to turn on sse
 618         CHECK_C_COMPILER_FLAG("-msse2" XFLAGS_SSE)
 619         if (XFLAGS_SSE)
 620             set(GROMACS_C_FLAGS "-msse2 ${GROMACS_C_FLAGS}")
 621         endif (XFLAGS_SSE)
 622         CHECK_CXX_COMPILER_FLAG("-msse2" XXFLAGS_SSE)
 623         if (XXFLAGS_SSE)
 624             set(GROMACS_CXX_FLAGS "-msse2 ${GROMACS_CXX_FLAGS}")
 625         endif (XXFLAGS_SSE)
 626     endif (NOT GMX_64_BIT)
 627
 628     if(GMX_IA32_ASM)
 629       if(GMX_DOUBLE)
 630         set(GMX_IA32_SSE2 1)
 631       else()
 632        set(GMX_IA32_SSE 1)
 633       endif()
 634     elseif(GMX_X86_64_ASM)
 635       if(GMX_DOUBLE)
 636        set(GMX_X86_64_SSE2 1)
 637       else()
 638         set(GMX_X86_64_SSE 1)
 639       endif()
 640     endif()
 641
 642 #    if(HAVE_PMMINTRIN_H)
 643 #        set(GMX_SSE3 1)
 644 #    endif(HAVE_PMMINTRIN_H)
 645 #    if(HAVE_SMMINTRIN_H)
 646 #        set(GMX_SSE4_1 1)
 647 #    endif(HAVE_SMMINTRIN_H)
 648
 649 elseif(${GMX_ACCELERATION} STREQUAL "FORTRAN")
 650     set(GMX_FORTRAN 1)
 651     #these are switch on by default sometimes
 652     set(GMX_IA32_ASM 0)
 653     set(GMX_GMX_X86_64_ASM 0)
 654 elseif(${GMX_ACCELERATION} STREQUAL "BLUEGENE")
 655 # GMX_ACCELERATION=BlueGene should be set in the Toolchain-BlueGene?-???.cmake file
 656     message(STATUS "Configuring for BlueGene")
 657     set(GMX_BLUEGENE 1)
 658     if (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 659         set(SHARED_LIBS_DEFAULT OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 660         set(BUILD_SHARED_LIBS OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 661     endif (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 662     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on BlueGene" FORCE)
 663     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on BlueGene" FORCE)
 664     set(GMX_X11 OFF CACHE BOOL "X11 not compatible with BlueGene, disabled!" FORCE)
 665     set(GMX_THREAD_MPI OFF CACHE BOOL "Thread-MPI not compatible with BlueGene, disabled!" FORCE)
 666     set(GMX_MPI ON CACHE BOOL "Use MPI on BlueGene" FORCE)
 667 elseif(${GMX_ACCELERATION} STREQUAL "POWER6")
 668     set(GMX_POWER6 1)
 669     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on Power6" FORCE)
 670     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on Power6" FORCE)
 671 elseif(${GMX_ACCELERATION} STREQUAL "IA64")
 672     set(GMX_IA64_ASM 1)
 673     set(DISABLE_WATERWATER_NLIST 1)
 674     set(DISABLE_WATER_NLIST 1)
 675 elseif(${GMX_ACCELERATION} STREQUAL "ALTIVEC")
 676     check_include_files(altivec.h HAVE_ALTIVEC_H)
 677     if(HAVE_ALTIVEC_H)
 678         set(GMX_PPC_ALTIVEC 1)
 679     endif(HAVE_ALTIVEC_H)
 680 else(${GMX_ACCELERATION} STREQUAL "NONE")
 681     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_ACCELERATION}. Pick one of auto, none, SSE, Fortran, BlueGene, Power6, ia64, altivec")
 682 endif(${GMX_ACCELERATION} STREQUAL "NONE")
 683
 684 if(GMX_FORTRAN OR GMX_POWER6)
 685     if (GMX_THREAD_MPI)
 686         message(FATAL_ERROR "FORTRAN/POWER6 is incompatible with thread-MPI and only provides a speed-up on certain IBM compilers. Disable FORTRAN (or threads if you really want to use FORTRAN kernels).")
 687     endif(GMX_THREAD_MPI)
 688     enable_language(Fortran)
 689     include(FortranCInterface)
 690     discover_fortran_mangling(prefix isupper suffix extra_under_score found)
 691     if(extra_under_score)
 692         set(extrasuffix "_")
 693     endif(extra_under_score)
 694     if(prefix)
 695       set(prefix "${prefix} ##")
 696     endif(prefix)
 697     if(suffix)
 698       set(suffix "## ${suffix}")
 699       if(extrasuffix)
 700         set(extrasuffix "${suffix}${extrasuffix}")
 701       endif(extrasuffix)
 702     else(suffix)
 703       if(extrasuffix)
 704         # Don't know if this is needed, but it can't hurt
 705         set(extrasuffix "## ${extrasuffix}")
 706       endif(extrasuffix)
 707     endif(suffix)
 708
 709     if(isupper)
 710         set(F77_FUNCDEF   "${prefix} NAME ${suffix}")
 711         set(F77_FUNCDEF_  "${prefix} NAME ${extrasuffix}")
 712     else(isupper)
 713         set(F77_FUNCDEF   "${prefix} name ${suffix}")
 714         set(F77_FUNCDEF_  "${prefix} name ${extrasuffix}")
 715     endif(isupper)
 716 else(GMX_FORTRAN OR GMX_POWER6)
 717         set(F77_FUNCDEF   "name ## _")
 718         set(F77_FUNCDEF_  "name ## _")
 719 endif(GMX_FORTRAN OR GMX_POWER6)
 720
 721 # Process QM/MM Settings
 722 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 723 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 724     set(GMX_QMMM_GAUSSIAN 1)
 725 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 726     set(GMX_QMMM_MOPAC 1)
 727 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 728     set(GMX_QMMM_GAMESS 1)
 729 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 730     set(GMX_QMMM_ORCA 1)
 731 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 732     # nothing to do
 733 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 734     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 735 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 736
 737 # Process FFT library settings - if not OpenMM build
 738 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 739 set(PKG_FFT "")
 740 set(PKG_FFT_LIBS "")
 741 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 742     if(GMX_DOUBLE)
 743         find_package(FFTW 3 COMPONENTS fftw)
 744     else(GMX_DOUBLE)
 745         find_package(FFTW 3 COMPONENTS fftwf)
 746     endif(GMX_DOUBLE)
 747     if(NOT FFTW_FOUND)
 748       MESSAGE(FATAL_ERROR "Cannot find FFTW3 (with correct precision - libfftw3f for single precision GROMACS or libfftw3 for double precision GROMACS). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 749     endif(NOT FFTW_FOUND)
 750     include_directories(${FFTW_INCLUDE_DIRS})
 751     set(FFT_LIBRARIES ${FFTW_LIBRARIES})
 752     set(PKG_FFT "${FFTW_PKG}")
 753
 754     set(GMX_FFT_FFTW3 1)
 755
 756     if (${GMX_ACCELERATION} STREQUAL "SSE" AND NOT FFTW_HAVE_SSE)
 757       message(WARNING "The fftw library found is compiled without SSE support, which makes it slow. Consider recompiling it or contact your admin")
 758     endif (${GMX_ACCELERATION} STREQUAL "SSE" AND NOT FFTW_HAVE_SSE)
 759
 760 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 761 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 762     find_package(MKL REQUIRED)
 763     include_directories(${MKL_INCLUDE_DIR})
 764     set(FFT_LIBRARIES ${MKL_LIBRARIES})
 765     set(PKG_FFT_LIBS ${MKL_LIBRARIES})
 766
 767     set(GMX_FFT_MKL 1)
 768     set(HAVE_MKL 1)
 769
 770 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 771 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 772 #    set(GMX_FFT_ACML 1)
 773 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 774     MESSAGE(STATUS "Using internal FFT library - fftpack")
 775     set(GMX_FFT_FFTPACK 1)
 776 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 777     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, mkl, fftpack")
 778 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 779
 780 # MKL has BLAS/LAPACK routines
 781 if(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 782   set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 783   set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 784 else(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 785   set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external BLAS instead of built-in")
 786   set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 787   if(GMX_EXTERNAL_BLAS)
 788     #FindBLAS needs Fortran
 789     enable_language(Fortran)
 790     if (GMX_BLAS_USER)
 791         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_BLAS_USER})
 792     else(GMX_BLAS_USER)
 793         find_package(BLAS REQUIRED)
 794         list(APPEND GMX_EXTRA_LIBRARIES ${BLAS_LIBRARIES})
 795     endif(GMX_BLAS_USER)
 796   endif(GMX_EXTERNAL_BLAS)
 797   if(GMX_EXTERNAL_LAPACK)
 798     #FindLAPACK needs Fortran
 799     enable_language(Fortran)
 800         if (GMX_LAPACK_USER)
 801         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_LAPACK_USER})
 802         else(GMX_LAPACK_USER)
 803         find_package(LAPACK REQUIRED)
 804         list(APPEND GMX_EXTRA_LIBRARIES ${LAPACK_LIBRARIES})
 805     endif(GMX_LAPACK_USER)
 806   endif(GMX_EXTERNAL_LAPACK)
 807 endif(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 808 mark_as_advanced(GMX_EXTERNAL_LAPACK)
 809 mark_as_advanced(GMX_EXTERNAL_BLAS)
 810
 811 set(GMX_USE_PLUGINS OFF CACHE INTERNAL "Whether GROMACS will really try to compile support for VMD plugins")
 812 set(GMX_VMD_PLUGIN_PATH)
 813 mark_as_advanced(GMX_VMD_PLUGIN_PATH)
 814
 815 if(GMX_LOAD_PLUGINS)
 816   if(CYGWIN OR NOT WIN32)
 817     # Native Windows does not have, nor need dlopen
 818     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 819     include(gmxTestdlopen)
 820     gmx_test_dlopen(HAVE_DLOPEN)
 821   endif()
 822
 823   find_package(VMD)
 824
 825   # Test for unsuitable versions of VMD
 826
 827   if(VMD_FOUND AND NOT GMX_VMD_PLUGIN_PATH)
 828     message(STATUS "Checking for suitable VMD version")
 829     exec_program(${VMD_EXECUTABLE}
 830       ARGS --help
 831       OUTPUT_VARIABLE VMD_HELP
 832       RETURN_VALUE VMD_EXEC_RETURN)
 833
 834     if(VMD_EXEC_RETURN EQUAL 0)
 835       # This is the accepted idiom for subexpression matching, unfortunately
 836       string(REGEX REPLACE ".*VMD for .*, version ([0-9]+\\.[0-9]*\\.?[0-9]*).*" "\\1" VMD_VERSION ${VMD_HELP})
 837       string(REGEX REPLACE ".*VMD for (.*), version .*" "\\1" VMD_ARCH ${VMD_HELP})
 838
 839       if(VMD_VERSION VERSION_LESS "1.8")
 840         MESSAGE(WARNING "Found VMD version ${VMD_VERSION}, but GROMACS needs at least 1.8")
 841         unset(VMD_EXECUTABLE)
 842         set(VMD_FOUND FALSE)
 843       else()
 844         message(STATUS "VMD version ${VMD_VERSION} is suitable")
 845         if(DEFINED ENV{VMDDIR})
 846           # This permits GROMACS to avoid hard-coding a fall-back
 847           # path that it can tell right now would be useless.
 848           set(GMX_VMD_PLUGIN_PATH "$ENV{VMDDIR}/plugins/${VMD_ARCH}/molfile" CACHE PATH "Path to VMD plugins for molfile I/O")
 849         else()
 850           set(GMX_VMD_PLUGIN_PATH "/usr/local/lib/vmd/plugins/*/molfile" CACHE PATH "Path to VMD plugins for molfile I/O")
 851         endif()
 852       endif()
 853
 854       # clean up
 855       unset(VMD_HELP)
 856       unset(VMD_VERSION)
 857       unset(VMD_ARCH)
 858     endif()
 859   endif()
 860
 861   # so, should we use plug-ins?
 862   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 863     if (NOT VMD_QUIETLY)
 864       MESSAGE(STATUS "Found the ability to use plug-ins when building shared libaries, so will compile to use plug-ins (e.g. to read VMD-supported file formats).")
 865     endif(NOT VMD_QUIETLY)
 866     set(GMX_USE_PLUGINS ON)
 867     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 868     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 869   else()
 870     set(PKG_DL_LIBS)
 871   endif()
 872 endif(GMX_LOAD_PLUGINS)
 873 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 874
 875 # Math and thread libraries must often come after all others when linking...
 876 if(HAVE_LIBM)
 877     list(APPEND GMX_EXTRA_LIBRARIES m)
 878 endif(HAVE_LIBM)
 879
 880 if(GMX_FAHCORE)
 881   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 882       "Path to swindirect.h")
 883   include_directories(${COREWRAP_INCLUDE_DIR})
 884 endif(GMX_FAHCORE)
 885
 886 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 887 # these are set after everything else
 888 if (NOT DEFINED GROMACS_C_FLAGS_SET)
 889     set(GROMACS_C_FLAGS_SET true CACHE INTERNAL "Whether to reset the C flags"
 890         FORCE)
 891     set(CMAKE_C_FLAGS "${GROMACS_C_FLAGS} ${CMAKE_C_FLAGS}" CACHE STRING
 892         "Flags used by the compiler during all build types" FORCE)
 893     set(CMAKE_CXX_FLAGS "${GROMACS_CXX_FLAGS} ${CMAKE_CXX_FLAGS}" CACHE STRING
 894         "Flags used by the compiler during all build types" FORCE)
 895     set(CMAKE_EXE_LINKER_FLAGS
 896         "${GROMACS_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}"
 897         CACHE STRING "Linker flags" FORCE)
 898 endif (NOT DEFINED GROMACS_C_FLAGS_SET)
 899
 900 ########################################################################
 901 # Specify install locations and which subdirectories to process        #
 902 ########################################################################
 903 if ( DEFINED GMXLIB )
 904     set(LIB_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/${GMXLIB}")
 905 else()
 906     set(LIB_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/lib)
 907 endif()
 908 set(BIN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/bin)
 909 set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/gromacs)
 910 set(MAN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/share/man)
 911 set(INCL_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/include)
 912
 913 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
 914
 915 ##################################################################
 916 # Shared library settings - Darwin uses INSTALL_NAME_DIR instead!
 917 ##################################################################
 918 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 919     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
 920     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
 921     set(CMAKE_INSTALL_RPATH "${LIB_INSTALL_DIR}")
 922     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 923 endif()
 924
 925 add_subdirectory(share)
 926 add_subdirectory(man)
 927 add_subdirectory(src)
 928 add_subdirectory(scripts)
 929
 930 #######################
 931 ## uninstall target
 932 #######################
 933     CONFIGURE_FILE(
 934                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 935                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 936                    IMMEDIATE @ONLY)
 937 ###########################
 938 ADD_CUSTOM_TARGET(uninstall
 939                   "${CMAKE_COMMAND}" -P
 940                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 941 ###########################
 942
 943 ########################################################################
 944 # Doxygen configuration
 945 ########################################################################
 946 if (DOXYGEN_FOUND)
 947     FILE(GLOB NB_KERNEL_DIRS src/gromacs/gmxlib/nonbonded/nb_kernel_*/)
 948     LIST(REMOVE_ITEM NB_KERNEL_DIRS
 949          ${CMAKE_SOURCE_DIR}/src/gromacs/gmxlib/nonbonded/nb_kernel_c)
 950     FOREACH(NB_KERNEL_DIR ${NB_KERNEL_DIRS})
 951         SET(NB_KERNEL_DIRS_TO_IGNORE_IN_DOXYGEN
 952             "${NB_KERNEL_DIRS_TO_IGNORE_IN_DOXYGEN} \\\n                         ${NB_KERNEL_DIR}")
 953     ENDFOREACH(NB_KERNEL_DIR)
 954     CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/Doxyfile.cmakein
 955                    ${CMAKE_BINARY_DIR}/Doxyfile)
 956     CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/Doxyfile-lib.cmakein
 957                    ${CMAKE_BINARY_DIR}/Doxyfile-lib)
 958     CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/Doxyfile-user.cmakein
 959                    ${CMAKE_BINARY_DIR}/Doxyfile-user)
 960     add_custom_target(doc
 961       ${DOXYGEN_EXECUTABLE} ${CMAKE_CURRENT_BINARY_DIR}/Doxyfile
 962       WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
 963       COMMENT "Generating full documentation with Doxygen" VERBATIM)
 964     add_custom_target(doc-user
 965       ${DOXYGEN_EXECUTABLE} ${CMAKE_CURRENT_BINARY_DIR}/Doxyfile-user
 966       WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
 967       COMMENT "Generating user documentation with Doxygen" VERBATIM)
 968     add_custom_target(doc-lib
 969       ${DOXYGEN_EXECUTABLE} ${CMAKE_CURRENT_BINARY_DIR}/Doxyfile-lib
 970       WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
 971       COMMENT "Generating libary documentation with Doxygen" VERBATIM)
 972 endif (DOXYGEN_FOUND)
 973
 974
 975 ########################################################################
 976 # Tests                                                                #
 977 ########################################################################
 978
 979 include(CTest)
 980 mark_as_advanced(BUILD_TESTING)
 981 IF(BUILD_TESTING)
 982     enable_testing()
 983     add_subdirectory(tests)
 984 ENDIF()
 985