CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.6)
   2
   3 project(Gromacs)
   4 include(Dart)
   5 # PROJECT_VERSION should have the following structure:
   6 # VERSION[-dev-SUFFIX] where the VERSION can have any form and the suffix
   7 set(PROJECT_VERSION "4.5-beta4"
   8     CACHE STRING "Gromacs version string")
   9 set(SOVERSION 6)
  10
  11 # Cmake modules/macros are in a subdirectory to keep this file cleaner
  12 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  13
  14 if(NOT CMAKE_INSTALL_PREFIX)
  15     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "" FORCE)
  16 endif()
  17
  18 if(NOT CMAKE_BUILD_TYPE)
  19     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
  20 endif(NOT CMAKE_BUILD_TYPE)
  21
  22 enable_language(C)
  23
  24 ########################################################################
  25 # Fix stupid flags on MSVC
  26 ########################################################################
  27 IF(CMAKE_GENERATOR MATCHES "Visual Studio")
  28     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
  29     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
  30     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
  31     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
  32 ENDIF(CMAKE_GENERATOR MATCHES "Visual Studio")
  33
  34 set(GMX_EXTRA_LIBRARIES)
  35
  36 ######################################################################
  37 # compiler tests
  38 # these need ot be done early (before further tests).
  39 #####################################################################
  40
  41 include(CheckCCompilerFlag)
  42 include(CheckCXXCompilerFlag)
  43
  44 include(gmxCFlags)
  45 gmx_c_flags()
  46
  47 ########################################################################
  48 # User input options                                                   #
  49 ########################################################################
  50 option(GMX_DOUBLE "Use double precision" OFF)
  51 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
  52 option(GMX_THREADS    "Build a parallel (thread-based) version of GROMACS)" ON)
  53 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
  54 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
  55 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library" OFF)
  56 set(GMX_ACCELERATION "auto"
  57     CACHE STRING "Accelerated kernels. Pick one of: none, SSE, BlueGene, Power6, ia64, altivec")
  58
  59 set(GMX_FFT_LIBRARY "fftw3"
  60     CACHE STRING "FFT library choices: fftw3,fftw2,mkl,fftpack[built-in]")
  61 option(GMX_DISABLE_FFTW_MEASURE
  62        "Do not optimize FFTW setups (not needed with SSE)" OFF)
  63 set(GMX_QMMM_PROGRAM "none"
  64     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
  65 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
  66 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI)" OFF)
  67 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
  68 option(GMX_DLOPEN "Compile with dlopen, needed to read VMD supported file formats" ON)
  69 mark_as_advanced(GMX_MPI_IN_PLACE)
  70
  71
  72 option(GMX_IA32_ASM "Add SSE assembly files for IA32" OFF)
  73 option(GMX_X86_64_ASM "Add SSE assembly files for X86_64" OFF)
  74
  75 option(USE_VERSION_H "Generate development version string/information" ON)
  76
  77 option(GMX_DEFAULT_SUFFIX "Use default GROMACS suffixes" ON)
  78 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for doubule).")
  79 set(GMX_LIBS_SUFFIX ""
  80   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for mpi, _mpi_d for mpi and double).")
  81 if (GMX_DEFAULT_SUFFIX)
  82   if (GMX_MPI)
  83     set(GMX_LIBS_SUFFIX "_mpi")
  84   endif(GMX_MPI)
  85   if (GMX_DOUBLE)
  86     set (GMX_BINARY_SUFFIX "_d")
  87     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
  88   endif(GMX_DOUBLE)
  89 endif(GMX_DEFAULT_SUFFIX)
  90
  91 set(PKG_CFLAGS "")
  92 if(GMX_DOUBLE)
  93   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
  94 endif(GMX_DOUBLE)
  95 if(GMX_SOFTWARE_INVSQRT)
  96   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
  97 endif(GMX_SOFTWARE_INVSQRT)
  98
  99 ########################################################################
 100 #Process MPI settings
 101 ########################################################################
 102 if(GMX_MPI)
 103         MESSAGE(WARNING "
 104             There are known problems with some MPI implementations:
 105                      OpenMPI version < 1.4.1
 106                      MVAPICH2 version <= 1.4.1                               *")
 107     if(GMX_THREADS)
 108         #message(FATAL_ERROR "Thread-based parallelization conflicts with MPI.")
 109         set(GMX_THREADS OFF CACHE BOOL
 110             "Thread-based parallelization conflicts with MPI." FORCE)
 111     endif(GMX_THREADS)
 112     find_package(MPI)
 113     if(MPI_FOUND)
 114         set(GROMACS_C_FLAGS ${GROMACS_FLAGS} ${MPI_COMPILE_FLAGS})
 115         set(GROMACS_LINKER_FLAGS ${GROMACS_LINKER_FLAGS} ${MPI_LINK_FLAGS})
 116
 117         include_directories(${MPI_INCLUDE_PATH})
 118         list(APPEND GMX_EXTRA_LIBRARIES ${MPI_LIBRARIES})
 119         add_definitions( -DMPI ) #for FAHCORE
 120         include(gmxTestMPI_IN_PLACE)
 121         if (GMX_MPI_IN_PLACE)
 122             gmx_test_mpi_in_place(MPI_IN_PLACE_EXISTS)
 123         endif (GMX_MPI_IN_PLACE)
 124     else(MPI_FOUND)
 125         message(FATAL_ERROR "MPI support requested, but no MPI compiler found.")
 126     endif(MPI_FOUND)
 127     include(gmxTestCatamount)
 128     gmx_test_catamount(GMX_CRAY_XT3)
 129     if(GMX_CRAY_XT3)
 130         set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_CRAY_XT3")
 131         set(GMX_NO_SYSTEM 1)
 132         set(GMX_NO_NICE 1)
 133     endif(GMX_CRAY_XT3)
 134     set(GMX_LIB_MPI 1)
 135     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_LIB_MPI")
 136 endif(GMX_MPI)
 137
 138
 139 #######################################################################
 140 # Check for options incompatible with OpenMM build                    #
 141 #######################################################################
 142 if(GMX_OPENMM)
 143     cmake_minimum_required(VERSION 2.6.4)
 144     # we'll use the built-in fft to avoid unnecessary dependencies
 145     message(STATUS "No external FFT libraries needed for the OpenMM build, using fftpack!")
 146     set (GMX_FFT_LIBRARY "fftpack" CACHE STRING
 147                 "No external FFT libraries needed for the OpenMM build, using fftpack!" FORCE)
 148     if(GMX_MPI)
 149         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
 150     endif(GMX_MPI)
 151     if(GMX_THREADS)
 152         message(STATUS "Threads not compatible with OpenMM build, disabled!")
 153         set(GMX_THREADS OFF CACHE BOOL
 154                 "Threads not compatible with OpenMM build, disabled!" FORCE)
 155     endif(GMX_THREADS)
 156     if(GMX_SOFTWARE_INVSQRT)
 157         set(GMX_SOFTWARE_INVSQRT OFF FORCE)
 158     endif(GMX_SOFTWARE_INVSQRT)
 159     if(NOT GMX_ACCELERATION MATCHES "^(none|None|NONE)")
 160         message(WARNING "CPU-based acceleration turned off, OpenMM does not support/need any!")
 161         unset(GMX_ACCELERATION CACHE)
 162         set(GMX_ACCELERATION "none" CACHE STRING
 163                 "CPU-based acceleration turned off, OpenMM does not support/need any!" FORCE)
 164     endif()
 165     if(GMX_FAHCORE)
 166         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
 167     endif(GMX_FAHCORE)
 168 endif(GMX_OPENMM)
 169
 170
 171 ########################################################################
 172 # Basic system tests (standard libraries, headers, functions, types)   #
 173 ########################################################################
 174 include(CheckIncludeFiles)
 175 check_include_files(string.h     HAVE_STRING_H)
 176 check_include_files(math.h       HAVE_MATH_H)
 177 check_include_files(limits.h     HAVE_LIMITS_H)
 178 check_include_files(memory.h     HAVE_MEMORY_H)
 179 check_include_files(unistd.h     HAVE_UNISTD_H)
 180 check_include_files(pwd.h        HAVE_PWD_H)
 181 check_include_files(stdint.h     HAVE_STDINT_H)
 182 check_include_files(stdlib.h     HAVE_STDLIB_H)
 183 check_include_files(pthread.h    HAVE_PTHREAD_H)
 184 check_include_files(dirent.h     HAVE_DIRENT_H)
 185 check_include_files(inttypes.h   HAVE_INTTYPES_H)
 186 check_include_files(regex.h      HAVE_REGEX_H)
 187 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 188 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
 189 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 190 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
 191 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
 192 # SSE support
 193 check_include_files(xmmintrin.h  HAVE_XMMINTRIN_H)
 194 check_include_files(emmintrin.h  HAVE_EMMINTRIN_H)
 195 check_include_files(pmmintrin.h  HAVE_PMMINTRIN_H)
 196 check_include_files(smmintrin.h  HAVE_SMMINTRIN_H)
 197 check_include_files(io.h                 HAVE_IO_H)
 198
 199
 200 include(CheckFunctionExists)
 201 check_function_exists(strcasecmp        HAVE_STRCASECMP)
 202 check_function_exists(strdup            HAVE_STRDUP)
 203 check_function_exists(vprintf           HAVE_VPRINTF)
 204 check_function_exists(memcmp            HAVE_MEMCMP)
 205 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 206 check_function_exists(memalign          HAVE_MEMALIGN)
 207 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 208 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 209 check_function_exists(isnan             HAVE_ISNAN)
 210 check_function_exists(_isnan            HAVE__ISNAN)
 211 check_function_exists(isfinite          HAVE_ISFINITE)
 212 check_function_exists(_isfinite         HAVE__ISFINITE)
 213 check_function_exists(fsync             HAVE_FSYNC)
 214 check_function_exists(_fileno           HAVE__FILENO)
 215 check_function_exists(fileno            HAVE_FILENO)
 216 check_function_exists(_commit           HAVE__COMMIT)
 217
 218 include(CheckLibraryExists)
 219 check_library_exists(m sqrt "" HAVE_LIBM)
 220 check_library_exists(m cbrt "" HAVE_CBRT)
 221
 222
 223 include(CheckTypeSize)
 224
 225 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 226 check_type_size("int"           SIZEOF_INT)
 227 check_type_size("long int"      SIZEOF_LONG_INT)
 228 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 229 check_type_size("off_t"         SIZEOF_OFF_T)
 230 check_type_size("void *"        SIZEOF_VOIDP)
 231
 232 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 233     set(GMX_64_BIT TRUE)
 234 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 235     set(GMX_64_BIT FALSE)
 236 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 237
 238 # Check for some basic types that we *need*, so set these to int if they are not present
 239 check_type_size(uid_t uid_t)
 240 if(NOT uid_t)
 241   set(uid_t int)
 242 else(NOT uid_t)
 243   set(uid_t 0)
 244 endif(NOT uid_t)
 245
 246 check_type_size(gid_t gid_t)
 247 if(NOT gid_t)
 248   set(gid_t 1)
 249 else(NOT gid_t)
 250   set(gid_t 0)
 251 endif(NOT gid_t)
 252
 253 check_type_size(size_t size_t)
 254 if(NOT size_t)
 255   set(size_t int)
 256 else(NOT size_t)
 257   set(size_t 0)
 258 endif(NOT size_t)
 259
 260 check_type_size(off_t off_t)
 261 if(NOT off_t)
 262   set(off_t int)
 263 else(NOT off_t)
 264   set(off_t 0)
 265 endif(NOT off_t)
 266
 267 include(TestBigEndian)
 268 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 269
 270
 271
 272
 273 ########################################################################
 274 # Find external packages                                               #
 275 ########################################################################
 276
 277 find_package(LibXml2)
 278 set(PKG_XML "")
 279 if(LIBXML2_FOUND)
 280     include_directories(${LIBXML2_INCLUDE_DIR})
 281     set(PKG_XML libxml-2.0)
 282     set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 283     set(HAVE_LIBXML2 1)
 284 endif(LIBXML2_FOUND)
 285
 286 find_package(X11)
 287 # X11 includes/libraries are only set in the ngmx subdirectory!
 288 if(X11_FOUND)
 289     set(HAVE_X11 1)
 290 endif(X11_FOUND)
 291
 292 if(GMX_THREADS)
 293     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREADS")
 294     include(ThreadMPI)
 295     set(THREAD_MPI_LIB thread_mpi)
 296     set(GMX_MPI 1)
 297     string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 298     if(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 299         message(FATAL_ERROR "FFTW2 can't be used with threads. Try fftw3 or mkl.")
 300     endif()
 301 endif(GMX_THREADS)
 302
 303 if(GMX_OPENMM)
 304     set(CUDA_BUILD_EMULATION OFF)
 305     find_package(CUDA 3.1 REQUIRED)
 306     add_definitions(-DGMX_OPENMM)
 307     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 308         set(CUDA_VERBOSE_BUILD ON)
 309     endif()
 310     find_package(OpenMM)
 311 endif(GMX_OPENMM)
 312
 313 if(APPLE)
 314    find_library(ACCELERATE_FRAMEWORK Accelerate)
 315    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 316 endif(APPLE)
 317
 318 # only bother with finding git and using version.h if the source is a git repo
 319 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 320     if(USE_VERSION_H)
 321         # We need at least git v1.5.1 be able to parse git's date output. If not
 322         # fund or the version is too small, we can't generate version information.
 323         find_package(Git 1.5.1)
 324         # this should at some point become VERSION_LESS
 325         if(NOT Git_FOUND OR Git_VERSION STRLESS "1.5.1")
 326             message("No compatible git version found, won't be able to generate proper development version information.")
 327         endif()
 328     endif()
 329 else()
 330     set(USE_VERSION_H OFF)
 331 endif()
 332
 333 if (GMX_DLOPEN)
 334     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS})
 335 endif (GMX_DLOPEN)
 336
 337 ########################################################################
 338 # Generate development version info for cache
 339 ########################################################################
 340 # set(GEN_VERSION_INFO_INTERNAL "ON")
 341 # include(gmxGenerateVersionString)
 342
 343 ########################################################################
 344 # Our own GROMACS tests
 345 ########################################################################
 346
 347 add_definitions( -DHAVE_CONFIG_H )
 348 include_directories(${CMAKE_BINARY_DIR}/src)
 349 include_directories(${CMAKE_SOURCE_DIR}/include)
 350
 351 include(gmxCheckBuildUserTime)
 352 gmx_check_build_user_time(BUILD_TIME BUILD_USER BUILD_MACHINE)
 353
 354 include(gmxTestFloatFormat)
 355 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 356                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 357                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 358
 359 include(gmxTestLargeFiles)
 360 gmx_test_large_files(GMX_LARGEFILES)
 361 check_function_exists(fseeko     HAVE_FSEEKO)
 362
 363 include(gmxTestSignal)
 364 gmx_test_retsigtype(RETSIGTYPE)
 365 gmx_test_sigusr1(HAVE_SIGUSR1)
 366
 367 include(gmxTestInline)
 368 gmx_test_inline(INLINE_KEYWORD)
 369
 370 include(gmxTestRestrict)
 371 gmx_test_inline(RESTRICT_KEYWORD)
 372
 373 include(gmxTestPipes)
 374 gmx_test_pipes(HAVE_PIPES)
 375
 376 include(gmxTestInlineASM)
 377 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 378 gmx_test_inline_asm_msvc_x86(GMX_X86_MSVC_INLINE_ASM)
 379
 380 # turn on SSE if supported with reasonable defaults.
 381 if (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 382   if(CMAKE_SYSTEM_PROCESSOR MATCHES "^(i.86|x86|x64|x86_64|AMD64|amd64)")
 383
 384     set(GMX_ACCELERATION "SSE" CACHE STRING "Accelerated kernels. Pick one of: none, SSE, BlueGene, Power6, ia64, altivec" FORCE)
 385
 386     if (GMX_64_BIT)
 387       set(GMX_X86_64_ASM ON CACHE BOOL "Add SSE assembly files for x86_64" FORCE)
 388     else (GMX_64_BIT)
 389       set(GMX_IA32_ASM ON CACHE BOOL "Add SSE assembly files for i386" FORCE)
 390     endif (GMX_64_BIT)
 391
 392     # Determine the assembler/compiler to use
 393   else()
 394     set(GMX_ACCELERATION "none" CACHE STRING "Accelerated kernels. Pick one of: none, SSE, BlueGene, Power6, ia64, altivec" FORCE)
 395   endif()
 396 endif (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 397
 398
 399 include(gmxTestXDR)
 400 gmx_test_xdr(GMX_SYSTEM_XDR)
 401 if(NOT GMX_SYSTEM_XDR)
 402     set(GMX_INTERNAL_XDR 1)
 403     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 404 endif(NOT GMX_SYSTEM_XDR)
 405
 406 if(GMX_FORTRAN OR GMX_POWER6)
 407     enable_language(Fortran)
 408     include(FortranCInterface)
 409     discover_fortran_mangling(prefix isupper suffix extra_under_score found)
 410     if(extra_under_score)
 411         set(extrasuffix "_")
 412     endif(extra_under_score)
 413
 414     if(isupper)
 415         set(F77_FUNCDEF   "${prefix} ## NAME ## ${suffix}")
 416         set(F77_FUNCDEF_  "${prefix} ## NAME ## ${suffix}${extrasuffix}")
 417     else(isupper)
 418         set(F77_FUNCDEF   "${prefix} ## name ## ${suffix}")
 419         set(F77_FUNCDEF_  "${prefix} ## name ## ${suffix}${extrasuffix}")
 420     endif(isupper)
 421 else(GMX_FORTRAN OR GMX_POWER6)
 422         set(F77_FUNCDEF   "name ## _")
 423         set(F77_FUNCDEF_  "name ## _")
 424 endif(GMX_FORTRAN OR GMX_POWER6)
 425
 426
 427 # Process nonbonded accelerated kernels settings
 428 string(TOUPPER ${GMX_ACCELERATION} ${GMX_ACCELERATION})
 429 if(${GMX_ACCELERATION} STREQUAL "NONE")
 430   # nothing to do
 431 elseif(${GMX_ACCELERATION} STREQUAL "SSE")
 432
 433     if(CMAKE_GENERATOR MATCHES "Visual Studio")
 434       option(GMX_ASM_USEASM-NASM "Use Nasm for assembly instead of compiler (necessary on windows)" ON)
 435     else(CMAKE_GENERATOR MATCHES "Visual Studio")
 436       option(GMX_ASM_USEASM-NASM "Use Nasm for assembly instead of compiler (necessary on windows)" OFF)
 437     endif(CMAKE_GENERATOR MATCHES "Visual Studio")
 438     if (NOT GMX_64_BIT)
 439         # for 32-bit compiles, we might need to turn on sse
 440         CHECK_C_COMPILER_FLAG("-msse2" XFLAGS_SSE)
 441         if (XFLAGS_SSE)
 442             set(GROMACS_C_FLAGS "-msse2 ${GROMACS_C_FLAGS}")
 443         endif (XFLAGS_SSE)
 444         CHECK_CXX_COMPILER_FLAG("-msse2" XXFLAGS_SSE)
 445         if (XXFLAGS_SSE)
 446             set(GROMACS_CXX_FLAGS "-msse2 ${GROMACS_CXX_FLAGS}")
 447         endif (XXFLAGS_SSE)
 448     endif (NOT GMX_64_BIT)
 449
 450     if(GMX_IA32_ASM)
 451       if(GMX_DOUBLE)
 452         set(GMX_IA32_SSE2 1)
 453       else()
 454         set(GMX_IA32_SSE 1)
 455       endif()
 456     elseif(GMX_X86_64_ASM)
 457       if(GMX_DOUBLE)
 458         set(GMX_X86_64_SSE2 1)
 459       else()
 460         set(GMX_X86_64_SSE 1)
 461       endif()
 462     endif()
 463
 464 #    if(HAVE_PMMINTRIN_H)
 465 #        set(GMX_SSE3 1)
 466 #    endif(HAVE_PMMINTRIN_H)
 467 #    if(HAVE_SMMINTRIN_H)
 468 #        set(GMX_SSE4_1 1)
 469 #    endif(HAVE_SMMINTRIN_H)
 470
 471 elseif(${GMX_ACCELERATION} STREQUAL "FORTRAN")
 472     set(GMX_FORTRAN 1)
 473 elseif(${GMX_ACCELERATION} STREQUAL "BLUEGENE")
 474     set(GMX_BLUEGENE 1)
 475 elseif(${GMX_ACCELERATION} STREQUAL "POWER6")
 476     set(GMX_POWER6 1)
 477 elseif(${GMX_ACCELERATION} STREQUAL "IA64")
 478     set(GMX_IA64_ASM 1)
 479     set(DISABLE_WATERWATER_NLIST 1)
 480     set(DISABLE_WATER_NLIST 1)
 481 elseif(${GMX_ACCELERATION} STREQUAL "ALTIVEC")
 482     check_include_files(altivec.h HAVE_ALTIVEC_H)
 483     if(HAVE_ALTIVEC_H)
 484         set(GMX_PPC_ALTIVEC 1)
 485     endif(HAVE_ALTIVEC_H)
 486 else(${GMX_ACCELERATION} STREQUAL "NONE")
 487     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_ACCELERATION}. Pick one of none, SSE, Fortran, BlueGene, Power6, ia64, altivec")
 488 endif(${GMX_ACCELERATION} STREQUAL "NONE")
 489
 490
 491
 492
 493
 494
 495
 496 # Process QM/MM Settings
 497 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 498 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 499     set(GMX_QMMM_GAUSSIAN 1)
 500 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 501     set(GMX_QMMM_MOPAC 1)
 502 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 503     set(GMX_QMMM_GAMESS 1)
 504 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 505     set(GMX_QMMM_ORCA 1)
 506 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 507     # nothing to do
 508 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 509     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 510 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 511
 512 # Process FFT library settings - if not OpenMM build
 513 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 514 set(PKG_FFT "")
 515 set(PKG_FFT_LIBS "")
 516 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 517 #    MESSAGE(STATUS "Using external FFT library - fftw3")
 518     if(GMX_DOUBLE)
 519         find_package(FFTW3 REQUIRED)
 520                 include_directories(${FFTW3_INCLUDE_DIR})
 521         set(FFT_LIBRARIES ${FFTW3_LIBRARIES})
 522         set(PKG_FFT "fftw3")
 523     else(GMX_DOUBLE)
 524         find_package(FFTW3F REQUIRED)
 525         include_directories(${FFTW3F_INCLUDE_DIR})
 526         set(FFT_LIBRARIES ${FFTW3F_LIBRARIES})
 527         set(PKG_FFT "fftw3f")
 528     endif(GMX_DOUBLE)
 529
 530     if(NOT FFTW3_FOUND AND NOT FFTW3F_FOUND)
 531         MESSAGE(FATAL_ERROR "Cannot find fftw3 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 532     endif(NOT FFTW3_FOUND AND NOT FFTW3F_FOUND)
 533
 534     set(GMX_FFT_FFTW3 1)
 535
 536 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 537 #    MESSAGE(STATUS "Using external FFT library - fftw2")
 538     if(GMX_DOUBLE)
 539         find_package(FFTW2 REQUIRED)
 540     else(GMX_DOUBLE)
 541         find_package(FFTW2F REQUIRED)
 542     endif(GMX_DOUBLE)
 543
 544     if(NOT FFTW2_FOUND)
 545            MESSAGE(FATAL_ERROR "Cannot find fftw2 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 546     endif(NOT FFTW2_FOUND)
 547     include_directories(${FFTW2_INCLUDE_DIR})
 548     set(FFT_LIBRARIES ${FFTW2_LIBRARIES})
 549     set(PKG_FFT_LIBS ${FFTW2_LIBRARIES})
 550
 551     if("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 552         set(FFTW2_NAME_DFFTW 1)
 553     elseif("${FFTW2_LIBRARIES}" MATCHES "sfftw")
 554         set(FFTW2_NAME_SFFTW 1)
 555     else("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 556         set(FFTW2_NAME_FFTW 1)
 557     endif("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 558
 559     set(GMX_FFT_FFTW2 1)
 560 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 561 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 562     find_package(MKL REQUIRED)
 563     include_directories(${MKL_INCLUDE_DIR})
 564     set(FFT_LIBRARIES ${MKL_LIBRARIES})
 565     set(PKG_FFT_LIBS ${MKL_LIBRARIES})
 566
 567     set(GMX_FFT_MKL 1)
 568     set(HAVE_MKL 1)
 569
 570 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 571 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 572 #    set(GMX_FFT_ACML 1)
 573 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 574     MESSAGE(STATUS "Using internal FFT library - fftpack")
 575     set(GMX_FFT_FFTPACK 1)
 576 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 577     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, fftw2, mkl, acml, fftpack")
 578 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 579
 580 # MKL has BLAS/LAPACK routines
 581 if(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 582   set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 583   set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 584 else(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 585   set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 586   set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 587 endif(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 588
 589 # Math and thread libraries must often come after all others when linking...
 590 if(HAVE_LIBM)
 591     list(APPEND GMX_EXTRA_LIBRARIES m)
 592 endif(HAVE_LIBM)
 593
 594
 595
 596 if(GMX_FAHCORE)
 597   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 598       "Path to swindirect.h")
 599   include_directories(${COREWRAP_INCLUDE_DIR})
 600 endif(GMX_FAHCORE)
 601
 602 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 603 # these are set after everything else
 604 if (NOT DEFINED GROMACS_C_FLAGS_SET)
 605     set(GROMACS_C_FLAGS_SET true CACHE INTERNAL "Whether to reset the C flags"
 606         FORCE)
 607     set(CMAKE_C_FLAGS "${GROMACS_C_FLAGS} ${CMAKE_C_FLAGS}" CACHE STRING
 608         "Flags used by the compiler during all build types" FORCE)
 609     set(CMAKE_CXX_FLAGS "${GROMACS_CXX_FLAGS} ${CMAKE_CXX_FLAGS}" CACHE STRING
 610         "Flags used by the compiler during all build types" FORCE)
 611     set(CMAKE_EXE_LINKER_FLAGS
 612         "${GROMACS_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}"
 613         CACHE STRING "Linker flags" FORCE)
 614 endif (NOT DEFINED GROMACS_C_FLAGS_SET)
 615
 616 ########################################################################
 617 # Specify install locations and which subdirectories to process        #
 618 ########################################################################
 619 set(LIB_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/lib)
 620 set(BIN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/bin)
 621 set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/gromacs)
 622 set(MAN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/share/man)
 623 set(INCL_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/include)
 624
 625 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
 626
 627
 628 add_subdirectory(share)
 629 add_subdirectory(include)
 630 add_subdirectory(man)
 631 add_subdirectory(src)
 632 add_subdirectory(scripts)
 633
 634 #######################
 635 ## uninstall target
 636 #######################
 637     CONFIGURE_FILE(
 638                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 639                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 640                    IMMEDIATE @ONLY)
 641 ###########################
 642 ADD_CUSTOM_TARGET(uninstall
 643                   "${CMAKE_COMMAND}" -P
 644                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 645 ###########################
 646
 647
 648 ########################################################################
 649 # Tests                                                                #
 650 ########################################################################
 651
 652 enable_testing()
 653 add_test(TestBuildAll make)
 654
 655 add_subdirectory(tests)