CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8)
   2
   3 project(Gromacs)
   4 include(Dart)
   5 mark_as_advanced(DART_ROOT)
   6
   7 # PROJECT_VERSION should have the following structure:
   8 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
   9 #
  10 # The "-dev" suffix is important to keep because it makes possible to distinguish
  11 # between a build from official release and a build from git release branch on a
  12 # machine with no git.
  13 #
  14 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  15 set(PROJECT_VERSION "4.6-dev")
  16 set(CUSTOM_VERSION_STRING ""
  17     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  18 mark_as_advanced(CUSTOM_VERSION_STRING)
  19 if (CUSTOM_VERSION_STRING)
  20     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  21 endif (CUSTOM_VERSION_STRING)
  22 set(SOVERSION 6)
  23 # It is a bit irritating, but this has to be set separately for now!
  24 SET(CPACK_PACKAGE_VERSION_MAJOR "4")
  25 SET(CPACK_PACKAGE_VERSION_MINOR "6")
  26 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  27
  28
  29 # Cmake modules/macros are in a subdirectory to keep this file cleaner
  30 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  31
  32 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  33 set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  34 endif()
  35
  36 if(NOT CMAKE_BUILD_TYPE)
  37     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
  38 endif(NOT CMAKE_BUILD_TYPE)
  39
  40 enable_language(C)
  41
  42 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
  43 set(CPACK_PACKAGE_VENDOR "gromacs.org")
  44 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
  45 set(CPACK_SET_DESTDIR "ON")
  46 set(CPACK_INCLUDE_TOPLEVEL_DIRECTORY 0)
  47 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
  48 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
  49 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/admin/InstallLicense.txt")
  50 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
  51
  52 #must come after all cpack settings!
  53 include(CPack)
  54
  55 ########################################################################
  56 # Check and warn if cache generated on a different host is being reused
  57 ########################################################################
  58 if(CMAKE_HOST_UNIX)
  59     execute_process(COMMAND hostname
  60                     OUTPUT_VARIABLE TMP_HOSTNAME
  61                     OUTPUT_STRIP_TRAILING_WHITESPACE)
  62     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
  63         message(WARNING "
  64             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
  65             is being reused! This could lead to inconsitencies; therefore, it is
  66             recommended to regenerate the cache!")
  67     endif()
  68     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
  69             "Hostname of the machine where the cache was generated.")
  70 endif()
  71
  72 ########################################################################
  73 # Fix stupid flags on Windows
  74 ########################################################################
  75 SET(SHARED_LIBS_DEFAULT ON)
  76 IF( (CMAKE_GENERATOR MATCHES "Visual Studio" OR CMAKE_GENERATOR MATCHES "NMake") AND MSVC )
  77     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
  78     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
  79     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
  80     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
  81     SET(SHARED_LIBS_DEFAULT OFF)
  82 ENDIF()
  83
  84 IF(CMAKE_GENERATOR MATCHES "NMake" AND CMAKE_C_COMPILER_ID MATCHES "Intel")
  85     STRING(REPLACE /GZ /RTC1 CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
  86     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
  87     STRING(REPLACE /GZ /RTC1 CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
  88     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
  89     SET(SHARED_LIBS_DEFAULT OFF)
  90 ENDIF()
  91
  92 set(GMX_EXTRA_LIBRARIES)
  93
  94
  95
  96 ######################################################################
  97 # compiler tests
  98 # these need ot be done early (before further tests).
  99 #####################################################################
 100
 101 include(CheckCCompilerFlag)
 102 include(CheckCXXCompilerFlag)
 103
 104 include(gmxCFlags)
 105 gmx_c_flags()
 106
 107 ########################################################################
 108 # User input options                                                   #
 109 ########################################################################
 110 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 111 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 112 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 113 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 114 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 115 option(GMX_POWERPC_INVSQRT "Use PowerPC hardware 1/sqrt" OFF)
 116 mark_as_advanced(GMX_POWERPC_INVSQRT)
 117 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 118 mark_as_advanced(GMX_FAHCORE)
 119 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library (rerun cmake after changing to see relevant options)" OFF)
 120 set(GMX_ACCELERATION "auto"
 121     CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran")
 122
 123 set(GMX_FFT_LIBRARY "fftw3"
 124     CACHE STRING "FFT library choices: fftw3,fftw2,mkl,fftpack[built-in]")
 125 option(GMX_DISABLE_FFTW_MEASURE
 126        "Do not optimize FFTW setups (not needed with SSE)" OFF)
 127 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 128 set(GMX_QMMM_PROGRAM "none"
 129     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
 130 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 131 mark_as_advanced(GMX_BROKEN_CALLOC)
 132 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI, Windows)" ${SHARED_LIBS_DEFAULT})
 133 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
 134 mark_as_advanced(GMX_MPI_IN_PLACE)
 135 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 136 mark_as_advanced(GMX_LOAD_PLUGINS)
 137
 138
 139 option(GMX_IA32_ASM "Add SSE assembly files for IA32" OFF)
 140 mark_as_advanced(GMX_IA32_ASM)
 141 option(GMX_X86_64_ASM "Add SSE assembly files for X86_64" OFF)
 142 mark_as_advanced(GMX_X86_64_ASM)
 143
 144 option(GMX_OPENMP "Enable OpenMP-based mutithreading. " ON)
 145
 146 option(USE_VERSION_H "Generate development version string/information" ON)
 147 mark_as_advanced(USE_VERSION_H)
 148
 149 option(GMX_DEFAULT_SUFFIX "Use default suffixes for GROMACS binaries and libs (_d for double, _mpi for MPI; rerun cmake after changing to see relevant options)" ON)
 150
 151 if(UNIX AND NOT APPLE)
 152     option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer \".a\" static archives (NOTE: this is enabled only for UNIX (excluding APPLE) platforms but it might not always work!" OFF)
 153     mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 154 endif()
 155
 156 ########################################################################
 157 # Set up binary and library suffixing
 158 ########################################################################
 159 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 160 set(GMX_LIBS_SUFFIX ""
 161   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 162 if (GMX_DEFAULT_SUFFIX)
 163   set(GMX_BINARY_SUFFIX "")
 164   set(GMX_LIBS_SUFFIX "")
 165   if (GMX_MPI)
 166     set(GMX_BINARY_SUFFIX "_mpi")
 167     set(GMX_LIBS_SUFFIX "_mpi")
 168   endif(GMX_MPI)
 169   if (GMX_DOUBLE)
 170     set (GMX_BINARY_SUFFIX "${GMX_BINARY_SUFFIX}_d")
 171     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
 172   endif(GMX_DOUBLE)
 173   if (GMX_OPENMM)
 174     set (GMX_BINARY_SUFFIX "-gpu")
 175     set (GMX_LIBS_SUFFIX "_gpu")
 176   endif(GMX_OPENMM)
 177   mark_as_advanced(FORCE GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 178   if (NOT SUFFIX_QUIETLY)
 179     message(STATUS "Using default binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 180     message(STATUS "Using default library suffix: \"${GMX_LIBS_SUFFIX}\"")
 181   endif (NOT SUFFIX_QUIETLY)
 182 else(GMX_DEFAULT_SUFFIX)
 183   mark_as_advanced(CLEAR GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 184   if (NOT SUFFIX_QUIETLY)
 185     message(STATUS "Using manually set binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 186     message(STATUS "Using manually set library suffix: \"${GMX_LIBS_SUFFIX}\"")
 187   endif (NOT SUFFIX_QUIETLY)
 188 endif(GMX_DEFAULT_SUFFIX)
 189 set(SUFFIX_QUIETLY TRUE CACHE INTERNAL "")
 190
 191 set(PKG_CFLAGS "")
 192 if(GMX_DOUBLE)
 193     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 194 endif(GMX_DOUBLE)
 195 if(GMX_SOFTWARE_INVSQRT)
 196   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 197 endif(GMX_SOFTWARE_INVSQRT)
 198 if(GMX_POWERPC_INVSQRT)
 199   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_POWERPC_INVSQRT")
 200 endif(GMX_POWERPC_INVSQRT)
 201
 202 ########################################################################
 203 #Process MPI settings
 204 ########################################################################
 205 include(gmxManageMPI)
 206
 207 #######################################################################
 208 # Check for options incompatible with OpenMM build                    #
 209 #######################################################################
 210 if(GMX_OPENMM)
 211     cmake_minimum_required(VERSION 2.6.4)
 212     # we'll use the built-in fft to avoid unnecessary dependencies
 213     string(TOUPPER ${GMX_FFT_LIBRARY} GMX_FFT_LIBRARY)
 214     if(NOT ${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 215         message(STATUS "No external FFT libraries needed for the OpenMM build, switching to fftpack!")
 216         set(GMX_FFT_LIBRARY "fftpack" CACHE STRING
 217                 "No external FFT libraries needed for the OpenMM build, switching to  fftpack!" FORCE)
 218     endif()
 219     if(GMX_MPI)
 220         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
 221     endif(GMX_MPI)
 222     if(GMX_THREAD_MPI)
 223         message(STATUS "Thread-MPI not compatible with OpenMM, disabled!")
 224         set(GMX_THREAD_MPI OFF CACHE BOOL
 225                 "Thread-MPI not compatible with OpenMM build, disabled!" FORCE)
 226     endif(GMX_THREAD_MPI)
 227     if(GMX_OPENMP)
 228         message(STATUS "OpenMP multithreading not compatible with OpenMM, disabled")
 229         set(GMX_OPENMP OFF CACHE BOOL
 230             "OpenMP multithreading not compatible with OpenMM, disabled!" FORCE)
 231     endif()
 232     if(GMX_SOFTWARE_INVSQRT)
 233         set(GMX_SOFTWARE_INVSQRT OFF CACHE STRING
 234                 "The OpenMM build does not need GROMACS software 1/sqrt!" FORCE)
 235     endif(GMX_SOFTWARE_INVSQRT)
 236     string(TOUPPER ${GMX_ACCELERATION} GMX_ACCELERATION)
 237     if(NOT GMX_ACCELERATION STREQUAL "NONE")
 238         message(STATUS "Switching off CPU-based acceleration, the OpenMM build does not support/need any!")
 239         set(GMX_ACCELERATION "none" CACHE STRING
 240                 "Switching off CPU-based acceleration, the OpenMM build does not support/need any!" FORCE)
 241     endif()
 242     if(GMX_FAHCORE)
 243         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
 244     endif(GMX_FAHCORE)
 245     if(GMX_DOUBLE)
 246         message(FATAL_ERROR  "The OpenMM-build does not support double precision calculations!")
 247     endif()
 248     # mark as advanced the unused variables
 249     mark_as_advanced(FORCE GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 250         GMX_QMMM_PROGRAM GMX_THREAD_MPI GMX_DOUBLE)
 251 else(GMX_OPENMM)
 252      mark_as_advanced(CLEAR GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 253         GMX_QMMM_PROGRAM GMX_THREAD_MPI GMX_DOUBLE)
 254 endif(GMX_OPENMM)
 255
 256
 257 ########################################################################
 258 # Basic system tests (standard libraries, headers, functions, types)   #
 259 ########################################################################
 260 include(CheckIncludeFiles)
 261 check_include_files(string.h     HAVE_STRING_H)
 262 check_include_files(math.h       HAVE_MATH_H)
 263 check_include_files(limits.h     HAVE_LIMITS_H)
 264 check_include_files(memory.h     HAVE_MEMORY_H)
 265 check_include_files(unistd.h     HAVE_UNISTD_H)
 266 check_include_files(direct.h     HAVE_DIRECT_H)
 267 check_include_files(pwd.h        HAVE_PWD_H)
 268 check_include_files(stdint.h     HAVE_STDINT_H)
 269 check_include_files(stdlib.h     HAVE_STDLIB_H)
 270 check_include_files(pthread.h    HAVE_PTHREAD_H)
 271 check_include_files(dirent.h     HAVE_DIRENT_H)
 272 check_include_files(inttypes.h   HAVE_INTTYPES_H)
 273 check_include_files(regex.h      HAVE_REGEX_H)
 274 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 275 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
 276 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 277 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
 278 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
 279 # SSE support
 280 check_include_files(xmmintrin.h  HAVE_XMMINTRIN_H)
 281 check_include_files(emmintrin.h  HAVE_EMMINTRIN_H)
 282 check_include_files(pmmintrin.h  HAVE_PMMINTRIN_H)
 283 check_include_files(smmintrin.h  HAVE_SMMINTRIN_H)
 284 check_include_files(io.h                 HAVE_IO_H)
 285
 286
 287 include(CheckFunctionExists)
 288 check_function_exists(strcasecmp        HAVE_STRCASECMP)
 289 check_function_exists(strdup            HAVE_STRDUP)
 290 check_function_exists(vprintf           HAVE_VPRINTF)
 291 check_function_exists(memcmp            HAVE_MEMCMP)
 292 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 293 check_function_exists(memalign          HAVE_MEMALIGN)
 294 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 295 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 296 check_function_exists(isnan             HAVE_ISNAN)
 297 check_function_exists(_isnan            HAVE__ISNAN)
 298 check_function_exists(fsync             HAVE_FSYNC)
 299 check_function_exists(_fileno           HAVE__FILENO)
 300 check_function_exists(fileno            HAVE_FILENO)
 301 check_function_exists(_commit           HAVE__COMMIT)
 302
 303 include(CheckLibraryExists)
 304 check_library_exists(m sqrt "" HAVE_LIBM)
 305 check_library_exists(m cbrt "" HAVE_CBRT)
 306
 307
 308 include(CheckTypeSize)
 309
 310 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 311 check_type_size("int"           SIZEOF_INT)
 312 check_type_size("long int"      SIZEOF_LONG_INT)
 313 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 314 check_type_size("off_t"         SIZEOF_OFF_T)
 315 check_type_size("void *"        SIZEOF_VOIDP)
 316
 317 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 318     set(GMX_64_BIT TRUE)
 319 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 320     set(GMX_64_BIT FALSE)
 321 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 322
 323 # Check for some basic types that we *need*, so set these to int if they are not present
 324 check_type_size(uid_t uid_t)
 325 if(NOT uid_t)
 326   set(uid_t int)
 327 else(NOT uid_t)
 328   set(uid_t 0)
 329 endif(NOT uid_t)
 330
 331 check_type_size(gid_t gid_t)
 332 if(NOT gid_t)
 333   set(gid_t 1)
 334 else(NOT gid_t)
 335   set(gid_t 0)
 336 endif(NOT gid_t)
 337
 338 check_type_size(size_t size_t)
 339 if(NOT size_t)
 340   set(size_t int)
 341 else(NOT size_t)
 342   set(size_t 0)
 343 endif(NOT size_t)
 344
 345 check_type_size(off_t off_t)
 346 if(NOT off_t)
 347   set(off_t int)
 348 else(NOT off_t)
 349   set(off_t 0)
 350 endif(NOT off_t)
 351
 352 include(TestBigEndian)
 353 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 354
 355
 356
 357
 358 ########################################################################
 359 # Find external packages                                               #
 360 ########################################################################
 361 if(UNIX AND NOT APPLE)
 362     if(GMX_PREFER_STATIC_LIBS)
 363         SET(CMAKE_FIND_LIBRARY_SUFFIXES .a ${CMAKE_FIND_LIBRARY_SUFFIXES})
 364         if(BUILD_SHARED_LIBS)
 365             message(WARNING "Static libraries requested, the GROMACS libraries will also be build static (BUILD_SHARED_LIBS=OFF)")
 366             set(BUILD_SHARED_LIBS OFF CACHE BOOL "Enable shared libraries (can be problematic with MPI, Windows)" FORCE)
 367         endif()
 368     endif()
 369 endif()
 370
 371 option(GMX_XML "Use libxml2 to parse xml files" ON)
 372 if (GMX_XML)
 373   find_package(LibXml2)
 374   set(PKG_XML "")
 375   if(LIBXML2_FOUND)
 376     include_directories(${LIBXML2_INCLUDE_DIR})
 377     set(PKG_XML libxml-2.0)
 378     set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 379     set(HAVE_LIBXML2 1)
 380   endif(LIBXML2_FOUND)
 381 endif(GMX_XML)
 382
 383 option(GMX_GSL "Add support for gsl" OFF)
 384 if (GMX_GSL)
 385   find_package(gsl)
 386   set(PKG_GSL "")
 387   if(GSL_FOUND)
 388     include_directories(${GSL_INCLUDE_DIR})
 389     set(PKG_GSL gsl)
 390     set(HAVE_LIBGSL 1)
 391   endif(GSL_FOUND)
 392 endif (GMX_GSL)
 393
 394 option(GMX_X11 "Use X window system" OFF)
 395 if (GMX_X11)
 396         find_package(X11)
 397         # X11 includes/libraries are only set in the ngmx subdirectory!
 398         if(X11_FOUND)
 399         set(HAVE_X11 1)
 400         endif(X11_FOUND)
 401 endif(GMX_X11)
 402
 403 if(GMX_THREAD_MPI)
 404     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREAD_MPI")
 405     include(ThreadMPI)
 406     set(THREAD_MPI_LIB thread_mpi)
 407     set(GMX_MPI 1)
 408     string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 409     if(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 410         message(FATAL_ERROR "FFTW2 can't be used with thread-MPI. Try fftw3 or mkl.")
 411     endif()
 412 endif(GMX_THREAD_MPI)
 413
 414 if(GMX_OPENMM)
 415     set(CUDA_BUILD_EMULATION OFF)
 416     find_package(CUDA 3.1 REQUIRED)
 417     add_definitions(-DGMX_OPENMM)
 418     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 419         set(CUDA_VERBOSE_BUILD ON)
 420     endif()
 421     find_package(OpenMM)
 422 endif(GMX_OPENMM)
 423
 424 if(GMX_OPENMP)
 425     find_package(OpenMP REQUIRED)
 426     list(APPEND GROMACS_C_FLAGS ${OpenMP_C_FLAGS})
 427     list(APPEND GROMACS_CXX_FLAGS ${OpenMP_CXX_FLAGS})
 428     add_definitions(-DGMX_OPENMP)
 429 endif()
 430
 431 if(APPLE)
 432    find_library(ACCELERATE_FRAMEWORK Accelerate)
 433    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 434 endif(APPLE)
 435
 436 if(CYGWIN)
 437     set(GMX_CYGWIN 1)
 438 endif(CYGWIN)
 439
 440 # only bother with finding git and using version.h if the source is a git repo
 441 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 442     if(USE_VERSION_H)
 443         # We need at least git v1.5.1 be able to parse git's date output. If not
 444         # found or the version is too small, we can't generate version information.
 445         find_package(Git)
 446
 447         # Find out the git version
 448         if(GIT_FOUND AND NOT GIT_VERSION)
 449           execute_process(COMMAND ${GIT_EXECUTABLE} "--version"
 450             OUTPUT_VARIABLE _exec_out
 451             OUTPUT_STRIP_TRAILING_WHITESPACE)
 452           string(REGEX REPLACE "git version (.*)" "\\1" GIT_VERSION ${_exec_out})
 453           set(GIT_VERSION ${GIT_VERSION} CACHE STRING "Git version")
 454           mark_as_advanced(GIT_VERSION)
 455         endif()
 456
 457         if(NOT GIT_FOUND OR GIT_VERSION VERSION_LESS "1.5.1")
 458           message("No compatible git version found, won't be able to generate proper development version information.")
 459           set(USE_VERSION_H OFF)
 460         endif()
 461     endif()
 462 else()
 463     set(USE_VERSION_H OFF)
 464 endif()
 465
 466 ########################################################################
 467 # Generate development version info for cache
 468 ########################################################################
 469 # set(GEN_VERSION_INFO_INTERNAL "ON")
 470 # include(gmxGenerateVersionString)
 471
 472 ########################################################################
 473 # Our own GROMACS tests
 474 ########################################################################
 475
 476 add_definitions( -DHAVE_CONFIG_H )
 477 include_directories(${CMAKE_BINARY_DIR}/src)
 478 include_directories(${CMAKE_SOURCE_DIR}/include)
 479
 480 include(gmxCheckBuildUserTime)
 481 gmx_check_build_user_time(BUILD_TIME BUILD_USER BUILD_MACHINE)
 482
 483 include(gmxTestFloatFormat)
 484 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 485                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 486                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 487
 488 include(gmxTestLargeFiles)
 489 gmx_test_large_files(GMX_LARGEFILES)
 490 check_function_exists(fseeko     HAVE_FSEEKO)
 491
 492 include(gmxTestSignal)
 493 gmx_test_sigusr1(HAVE_SIGUSR1)
 494
 495 include(gmxTestInline)
 496 gmx_test_inline(INLINE_KEYWORD)
 497
 498 include(gmxTestRestrict)
 499 gmx_test_inline(RESTRICT_KEYWORD)
 500
 501 include(gmxTestPipes)
 502 gmx_test_pipes(HAVE_PIPES)
 503
 504 include(gmxTestIsfinite)
 505 gmx_test_isfinite(HAVE_ISFINITE)
 506 gmx_test__isfinite(HAVE__ISFINITE)
 507 gmx_test__finite(HAVE__FINITE)
 508
 509 include(gmxTestInlineASM)
 510 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 511 gmx_test_inline_asm_msvc_x86(GMX_X86_MSVC_INLINE_ASM)
 512
 513 # turn on SSE if supported with reasonable defaults.
 514 if (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 515   if(CMAKE_SYSTEM_PROCESSOR MATCHES "^(i.86|x86|x64|x86_64|AMD64|amd64)" OR CYGWIN)
 516
 517     set(GMX_ACCELERATION "SSE" CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran" FORCE)
 518
 519     # Determine the assembler/compiler to use
 520   else()
 521     set(GMX_ACCELERATION "none" CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran" FORCE)
 522   endif()
 523 endif (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 524
 525 include(gmxTestXDR)
 526 gmx_test_xdr(GMX_SYSTEM_XDR)
 527 if(NOT GMX_SYSTEM_XDR)
 528     set(GMX_INTERNAL_XDR 1)
 529     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 530 endif(NOT GMX_SYSTEM_XDR)
 531
 532 # Process nonbonded accelerated kernels settings
 533 string(TOUPPER ${GMX_ACCELERATION} ${GMX_ACCELERATION})
 534 if(${GMX_ACCELERATION} STREQUAL "NONE")
 535   # nothing to do
 536 elseif(${GMX_ACCELERATION} STREQUAL "SSE")
 537
 538     if (GMX_64_BIT)
 539       set(GMX_X86_64_ASM ON CACHE BOOL "Add SSE assembly files for x86_64" FORCE)
 540     else (GMX_64_BIT)
 541       set(GMX_IA32_ASM ON CACHE BOOL "Add SSE assembly files for i386" FORCE)
 542     endif (GMX_64_BIT)
 543
 544     if(CMAKE_GENERATOR MATCHES "Visual Studio" OR CMAKE_GENERATOR MATCHES NMake )
 545       option(GMX_ASM_USEASM_NASM "Use Nasm for assembly instead of compiler (necessary on windows)" ON)
 546     else()
 547       option(GMX_ASM_USEASM_NASM "Use Nasm for assembly instead of compiler (necessary on windows)" OFF)
 548     endif()
 549         mark_as_advanced(GMX_ASM_USEASM_NASM)
 550
 551     if (NOT GMX_64_BIT)
 552         # for 32-bit compiles, we might need to turn on sse
 553         CHECK_C_COMPILER_FLAG("-msse2" XFLAGS_SSE)
 554         if (XFLAGS_SSE)
 555             set(GROMACS_C_FLAGS "-msse2 ${GROMACS_C_FLAGS}")
 556         endif (XFLAGS_SSE)
 557         CHECK_CXX_COMPILER_FLAG("-msse2" XXFLAGS_SSE)
 558         if (XXFLAGS_SSE)
 559             set(GROMACS_CXX_FLAGS "-msse2 ${GROMACS_CXX_FLAGS}")
 560         endif (XXFLAGS_SSE)
 561     endif (NOT GMX_64_BIT)
 562
 563     if(GMX_IA32_ASM)
 564       if(GMX_DOUBLE)
 565         set(GMX_IA32_SSE2 1)
 566       else()
 567        set(GMX_IA32_SSE 1)
 568       endif()
 569     elseif(GMX_X86_64_ASM)
 570       if(GMX_DOUBLE)
 571        set(GMX_X86_64_SSE2 1)
 572       else()
 573         set(GMX_X86_64_SSE 1)
 574       endif()
 575     endif()
 576
 577 #    if(HAVE_PMMINTRIN_H)
 578 #        set(GMX_SSE3 1)
 579 #    endif(HAVE_PMMINTRIN_H)
 580 #    if(HAVE_SMMINTRIN_H)
 581 #        set(GMX_SSE4_1 1)
 582 #    endif(HAVE_SMMINTRIN_H)
 583
 584 elseif(${GMX_ACCELERATION} STREQUAL "FORTRAN")
 585     set(GMX_FORTRAN 1)
 586     #these are switch on by default sometimes
 587     set(GMX_IA32_ASM 0)
 588     set(GMX_GMX_X86_64_ASM 0)
 589 elseif(${GMX_ACCELERATION} STREQUAL "BLUEGENE")
 590 # GMX_ACCELERATION=BlueGene should be set in the Toolchain-BlueGene?-???.cmake file
 591     message(STATUS "Configuring for BlueGene")
 592     set(GMX_BLUEGENE 1)
 593     if (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 594         set(SHARED_LIBS_DEFAULT OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 595         set(BUILD_SHARED_LIBS OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 596     endif (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 597     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on BlueGene" FORCE)
 598     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on BlueGene" FORCE)
 599     set(GMX_X11 OFF CACHE BOOL "X11 not compatible with BlueGene, disabled!" FORCE)
 600     set(GMX_THREAD_MPI OFF CACHE BOOL "Thread-MPI not compatible with BlueGene, disabled!" FORCE)
 601     set(GMX_MPI ON CACHE BOOL "Use MPI on BlueGene" FORCE)
 602 elseif(${GMX_ACCELERATION} STREQUAL "POWER6")
 603     set(GMX_POWER6 1)
 604     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on Power6" FORCE)
 605     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on Power6" FORCE)
 606 elseif(${GMX_ACCELERATION} STREQUAL "IA64")
 607     set(GMX_IA64_ASM 1)
 608     set(DISABLE_WATERWATER_NLIST 1)
 609     set(DISABLE_WATER_NLIST 1)
 610 elseif(${GMX_ACCELERATION} STREQUAL "ALTIVEC")
 611     check_include_files(altivec.h HAVE_ALTIVEC_H)
 612     if(HAVE_ALTIVEC_H)
 613         set(GMX_PPC_ALTIVEC 1)
 614     endif(HAVE_ALTIVEC_H)
 615 else(${GMX_ACCELERATION} STREQUAL "NONE")
 616     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_ACCELERATION}. Pick one of auto, none, SSE, Fortran, BlueGene, Power6, ia64, altivec")
 617 endif(${GMX_ACCELERATION} STREQUAL "NONE")
 618
 619 if(GMX_FORTRAN OR GMX_POWER6)
 620     if (GMX_THREAD_MPI)
 621         message(FATAL_ERROR "FORTRAN/POWER6 is incompatible with thread-MPI and only provides a speed-up on certain IBM compilers. Disable FORTRAN (or threads if you really want to use FORTRAN kernels).")
 622     endif(GMX_THREAD_MPI)
 623     enable_language(Fortran)
 624     include(FortranCInterface)
 625     discover_fortran_mangling(prefix isupper suffix extra_under_score found)
 626     if(extra_under_score)
 627         set(extrasuffix "_")
 628     endif(extra_under_score)
 629     if(prefix)
 630       set(prefix "${prefix} ##")
 631     endif(prefix)
 632     if(suffix)
 633       set(suffix "## ${suffix}")
 634       if(extrasuffix)
 635         set(extrasuffix "${suffix}${extrasuffix}")
 636       endif(extrasuffix)
 637     else(suffix)
 638       if(extrasuffix)
 639         # Don't know if this is needed, but it can't hurt
 640         set(extrasuffix "## ${extrasuffix}")
 641       endif(extrasuffix)
 642     endif(suffix)
 643
 644     if(isupper)
 645         set(F77_FUNCDEF   "${prefix} NAME ${suffix}")
 646         set(F77_FUNCDEF_  "${prefix} NAME ${extrasuffix}")
 647     else(isupper)
 648         set(F77_FUNCDEF   "${prefix} name ${suffix}")
 649         set(F77_FUNCDEF_  "${prefix} name ${extrasuffix}")
 650     endif(isupper)
 651 else(GMX_FORTRAN OR GMX_POWER6)
 652         set(F77_FUNCDEF   "name ## _")
 653         set(F77_FUNCDEF_  "name ## _")
 654 endif(GMX_FORTRAN OR GMX_POWER6)
 655
 656 # Process QM/MM Settings
 657 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 658 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 659     set(GMX_QMMM_GAUSSIAN 1)
 660 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 661     set(GMX_QMMM_MOPAC 1)
 662 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 663     set(GMX_QMMM_GAMESS 1)
 664 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 665     set(GMX_QMMM_ORCA 1)
 666 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 667     # nothing to do
 668 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 669     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 670 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 671
 672 # Process FFT library settings - if not OpenMM build
 673 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 674 set(PKG_FFT "")
 675 set(PKG_FFT_LIBS "")
 676 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 677 #    MESSAGE(STATUS "Using external FFT library - fftw3")
 678     if(GMX_DOUBLE)
 679         find_package(FFTW3 REQUIRED)
 680                 include_directories(${FFTW3_INCLUDE_DIR})
 681         set(FFT_LIBRARIES ${FFTW3_LIBRARIES})
 682         set(PKG_FFT "fftw3")
 683     else(GMX_DOUBLE)
 684         find_package(FFTW3F REQUIRED)
 685         include_directories(${FFTW3F_INCLUDE_DIR})
 686         set(FFT_LIBRARIES ${FFTW3F_LIBRARIES})
 687         set(PKG_FFT "fftw3f")
 688     endif(GMX_DOUBLE)
 689
 690     if(NOT FFTW3_FOUND AND NOT FFTW3F_FOUND)
 691         MESSAGE(FATAL_ERROR "Cannot find fftw3 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 692     endif(NOT FFTW3_FOUND AND NOT FFTW3F_FOUND)
 693
 694     set(GMX_FFT_FFTW3 1)
 695
 696 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 697 #    MESSAGE(STATUS "Using external FFT library - fftw2")
 698     if(GMX_DOUBLE)
 699         find_package(FFTW2 REQUIRED)
 700     else(GMX_DOUBLE)
 701         find_package(FFTW2F REQUIRED)
 702     endif(GMX_DOUBLE)
 703
 704     if(NOT FFTW2_FOUND)
 705            MESSAGE(FATAL_ERROR "Cannot find fftw2 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 706     endif(NOT FFTW2_FOUND)
 707     include_directories(${FFTW2_INCLUDE_DIR})
 708     set(FFT_LIBRARIES ${FFTW2_LIBRARIES})
 709     set(PKG_FFT_LIBS ${FFTW2_LIBRARIES})
 710
 711     if("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 712         set(FFTW2_NAME_DFFTW 1)
 713     elseif("${FFTW2_LIBRARIES}" MATCHES "sfftw")
 714         set(FFTW2_NAME_SFFTW 1)
 715     else("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 716         set(FFTW2_NAME_FFTW 1)
 717     endif("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 718
 719     set(GMX_FFT_FFTW2 1)
 720 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 721 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 722     find_package(MKL REQUIRED)
 723     include_directories(${MKL_INCLUDE_DIR})
 724     set(FFT_LIBRARIES ${MKL_LIBRARIES})
 725     set(PKG_FFT_LIBS ${MKL_LIBRARIES})
 726
 727     set(GMX_FFT_MKL 1)
 728     set(HAVE_MKL 1)
 729
 730 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 731 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 732 #    set(GMX_FFT_ACML 1)
 733 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 734     MESSAGE(STATUS "Using internal FFT library - fftpack")
 735     set(GMX_FFT_FFTPACK 1)
 736 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 737     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, fftw2, mkl, acml, fftpack")
 738 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 739
 740 # MKL has BLAS/LAPACK routines
 741 if(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 742   set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 743   set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 744 else(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 745   set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external BLAS instead of built-in")
 746   set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 747   if(GMX_EXTERNAL_BLAS)
 748     #FindBLAS needs Fortran
 749     enable_language(Fortran)
 750     if (GMX_BLAS_USER)
 751         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_BLAS_USER})
 752     else(GMX_BLAS_USER)
 753         find_package(BLAS REQUIRED)
 754         list(APPEND GMX_EXTRA_LIBRARIES ${BLAS_LIBRARIES})
 755     endif(GMX_BLAS_USER)
 756   endif(GMX_EXTERNAL_BLAS)
 757   if(GMX_EXTERNAL_LAPACK)
 758     #FindLAPACK needs Fortran
 759     enable_language(Fortran)
 760         if (GMX_LAPACK_USER)
 761         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_LAPACK_USER})
 762         else(GMX_LAPACK_USER)
 763         find_package(LAPACK REQUIRED)
 764         list(APPEND GMX_EXTRA_LIBRARIES ${LAPACK_LIBRARIES})
 765     endif(GMX_LAPACK_USER)
 766   endif(GMX_EXTERNAL_LAPACK)
 767 endif(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 768 mark_as_advanced(GMX_EXTERNAL_LAPACK)
 769 mark_as_advanced(GMX_EXTERNAL_BLAS)
 770
 771 set(GMX_USE_PLUGINS OFF CACHE INTERNAL "Whether GROMACS will really try to compile support for VMD plugins")
 772 set(GMX_VMD_PLUGIN_PATH)
 773 mark_as_advanced(GMX_VMD_PLUGIN_PATH)
 774
 775 if(GMX_LOAD_PLUGINS)
 776   if(CYGWIN OR NOT WIN32)
 777     # Native Windows does not have, nor need dlopen
 778     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 779     include(gmxTestdlopen)
 780     gmx_test_dlopen(HAVE_DLOPEN)
 781   endif()
 782
 783   find_package(VMD)
 784
 785   # Test for unsuitable versions of VMD
 786
 787   if(VMD_FOUND AND NOT GMX_VMD_PLUGIN_PATH)
 788     message(STATUS "Checking for suitable VMD version")
 789     exec_program(${VMD_EXECUTABLE}
 790       ARGS --help
 791       OUTPUT_VARIABLE VMD_HELP
 792       RETURN_VALUE VMD_EXEC_RETURN)
 793
 794     if(VMD_EXEC_RETURN EQUAL 0)
 795       # This is the accepted idiom for subexpression matching, unfortunately
 796       string(REGEX REPLACE ".*VMD for .*, version ([0-9]+\\.[0-9]*\\.?[0-9]*).*" "\\1" VMD_VERSION ${VMD_HELP})
 797       string(REGEX REPLACE ".*VMD for (.*), version .*" "\\1" VMD_ARCH ${VMD_HELP})
 798
 799       if(VMD_VERSION VERSION_LESS "1.8")
 800         MESSAGE(WARNING "Found VMD version ${VMD_VERSION}, but GROMACS needs at least 1.8")
 801         unset(VMD_EXECUTABLE)
 802         set(VMD_FOUND FALSE)
 803       else()
 804         message(STATUS "VMD version ${VMD_VERSION} is suitable")
 805         if(DEFINED ENV{VMDDIR})
 806           # This permits GROMACS to avoid hard-coding a fall-back
 807           # path that it can tell right now would be useless.
 808           set(GMX_VMD_PLUGIN_PATH "$ENV{VMDDIR}/plugins/${VMD_ARCH}/molfile" CACHE PATH "Path to VMD plugins for molfile I/O")
 809         else()
 810           set(GMX_VMD_PLUGIN_PATH "/usr/local/lib/vmd/plugins/*/molfile" CACHE PATH "Path to VMD plugins for molfile I/O")
 811         endif()
 812       endif()
 813
 814       # clean up
 815       unset(VMD_HELP)
 816       unset(VMD_VERSION)
 817       unset(VMD_ARCH)
 818     endif()
 819   endif()
 820
 821   # so, should we use plug-ins?
 822   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 823     if (NOT VMD_QUIETLY)
 824       MESSAGE(STATUS "Found the ability to use plug-ins when building shared libaries, so will compile to use plug-ins (e.g. to read VMD-supported file formats).")
 825     endif(NOT VMD_QUIETLY)
 826     set(GMX_USE_PLUGINS ON)
 827     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 828     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 829   else()
 830     set(PKG_DL_LIBS)
 831   endif()
 832 endif(GMX_LOAD_PLUGINS)
 833 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 834
 835 # Math and thread libraries must often come after all others when linking...
 836 if(HAVE_LIBM)
 837     list(APPEND GMX_EXTRA_LIBRARIES m)
 838 endif(HAVE_LIBM)
 839
 840 if(GMX_FAHCORE)
 841   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 842       "Path to swindirect.h")
 843   include_directories(${COREWRAP_INCLUDE_DIR})
 844 endif(GMX_FAHCORE)
 845
 846 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 847 # these are set after everything else
 848 if (NOT DEFINED GROMACS_C_FLAGS_SET)
 849     set(GROMACS_C_FLAGS_SET true CACHE INTERNAL "Whether to reset the C flags"
 850         FORCE)
 851     set(CMAKE_C_FLAGS "${GROMACS_C_FLAGS} ${CMAKE_C_FLAGS}" CACHE STRING
 852         "Flags used by the compiler during all build types" FORCE)
 853     set(CMAKE_CXX_FLAGS "${GROMACS_CXX_FLAGS} ${CMAKE_CXX_FLAGS}" CACHE STRING
 854         "Flags used by the compiler during all build types" FORCE)
 855     set(CMAKE_EXE_LINKER_FLAGS
 856         "${GROMACS_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}"
 857         CACHE STRING "Linker flags" FORCE)
 858 endif (NOT DEFINED GROMACS_C_FLAGS_SET)
 859
 860 ########################################################################
 861 # Specify install locations and which subdirectories to process        #
 862 ########################################################################
 863 if ( DEFINED GMXLIB )
 864     set(LIB_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/${GMXLIB}")
 865 else()
 866     set(LIB_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/lib)
 867 endif()
 868 set(BIN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/bin)
 869 set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/gromacs)
 870 set(MAN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/share/man)
 871 set(INCL_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/include)
 872
 873 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
 874
 875 ##################################################################
 876 # Shared library settings - Darwin uses INSTALL_NAME_DIR instead!
 877 ##################################################################
 878 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 879     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
 880     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
 881     set(CMAKE_INSTALL_RPATH "${LIB_INSTALL_DIR}")
 882     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 883 endif()
 884
 885 add_subdirectory(share)
 886 add_subdirectory(include)
 887 add_subdirectory(man)
 888 add_subdirectory(src)
 889 add_subdirectory(scripts)
 890
 891 #######################
 892 ## uninstall target
 893 #######################
 894     CONFIGURE_FILE(
 895                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 896                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 897                    IMMEDIATE @ONLY)
 898 ###########################
 899 ADD_CUSTOM_TARGET(uninstall
 900                   "${CMAKE_COMMAND}" -P
 901                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 902 ###########################
 903
 904
 905 ########################################################################
 906 # Tests                                                                #
 907 ########################################################################
 908
 909 include(CTest)
 910 mark_as_advanced(BUILD_TESTING)
 911 IF(BUILD_TESTING)
 912         enable_testing()
 913         add_subdirectory(tests)
 914 ENDIF()
 915