CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014,2015,2016, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 2.8.8)
  36 # When we require cmake >= 2.8.12, it will provide
  37 # CMAKE_MINIMUM_REQUIRED_VERSION automatically, but in the meantime we
  38 # need to set a variable, and it must have a different name.
  39 set(GMX_CMAKE_MINIMUM_REQUIRED_VERSION "2.8.8")
  40
  41 # CMake modules/macros are in a subdirectory to keep this file cleaner
  42 # This needs to be set before project() in order to pick up toolchain files
  43 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  44
  45 project(Gromacs)
  46
  47 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  48 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  49 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  50
  51 # Set up common version variables, as well as general information about
  52 # the build tree (whether the build is from a source package or from a git
  53 # repository).  Also declares a few functions that will be used for generating
  54 # version info files later.
  55 include(gmxVersionInfo)
  56
  57 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  58     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  59 endif()
  60 if("${CMAKE_INSTALL_PREFIX}" STREQUAL "${CMAKE_BINARY_DIR}")
  61     message(FATAL_ERROR "GROMACS cannot be installed into the build tree, choose a different location for CMAKE_INSTALL_PREFIX")
  62 endif()
  63
  64 include(gmxBuildTypeReference)
  65 include(gmxBuildTypeProfile)
  66 include(gmxBuildTypeTSAN)
  67 include(gmxBuildTypeASAN)
  68 include(gmxBuildTypeMSAN)
  69 include(gmxBuildTypeReleaseWithAssert)
  70
  71 if(NOT CMAKE_BUILD_TYPE)
  72     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert Profile." FORCE)
  73     # There's no need to offer a user the choice of ThreadSanitizer
  74     # Set the possible values of build type for cmake-gui
  75     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
  76         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert" "Profile")
  77 endif()
  78 if(CMAKE_CONFIGURATION_TYPES)
  79     # Add appropriate GROMACS-specific build types for the Visual
  80     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
  81     # are already present by default).
  82     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
  83     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
  84     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
  85         "List of configuration types"
  86         FORCE)
  87 endif()
  88 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
  89
  90 set_property(GLOBAL PROPERTY FIND_LIBRARY_USE_LIB64_PATHS ON)
  91
  92 # Set a default valgrind suppression file.
  93 # This unfortunately needs to duplicate information from CTest to work as
  94 # expected...
  95 set(MEMORYCHECK_SUPPRESSIONS_FILE
  96     "${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp"
  97     CACHE FILEPATH
  98     "File that contains suppressions for the memory checker")
  99 include(CTest)
 100
 101 include(gmxCPackUtilities)
 102 gmx_cpack_init()
 103
 104 # Variables that accumulate stuff influencing the installed headers
 105 set(INSTALLED_HEADER_INCLUDE_DIRS "")
 106 set(INSTALLED_HEADER_DEFINITIONS "")
 107
 108 ########################################################################
 109 # Check and warn if cache generated on a different host is being reused
 110 ########################################################################
 111 if(CMAKE_HOST_UNIX)
 112     execute_process(COMMAND hostname
 113                     OUTPUT_VARIABLE TMP_HOSTNAME
 114                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 115     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 116         message(WARNING "
 117             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 118             is being reused! This could lead to inconsistencies; therefore, it is
 119             recommended to regenerate the cache!")
 120     endif()
 121     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 122             "Hostname of the machine where the cache was generated.")
 123 endif()
 124
 125 ########################################################################
 126 # Detect architecture before setting options so we can alter defaults
 127 ########################################################################
 128 # Detect the architecture the compiler is targetting, detect
 129 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 130 # to use if none is specified, and populate the cache option for CPU
 131 # SIMD.
 132 include(gmxDetectTargetArchitecture)
 133 gmx_detect_target_architecture()
 134
 135 ########################################################################
 136 # User input options                                                   #
 137 ########################################################################
 138 include(gmxOptionUtilities)
 139
 140 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 141
 142 if(GMX_TARGET_FUJITSU_SPARC64)
 143     # Fujitsu only has SIMD in double precision, so this will be faster
 144     set(GMX_DOUBLE_DEFAULT ON)
 145 else()
 146     set(GMX_DOUBLE_DEFAULT OFF)
 147 endif()
 148 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" ${GMX_DOUBLE_DEFAULT})
 149 option(GMX_RELAXED_DOUBLE_PRECISION "Accept single precision 1/sqrt(x) when using Fujitsu HPC-ACE SIMD" OFF)
 150 mark_as_advanced(GMX_RELAXED_DOUBLE_PRECISION)
 151
 152 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 153 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 154 gmx_dependent_option(
 155     GMX_MPI_IN_PLACE
 156     "Enable MPI_IN_PLACE for MPIs that have it defined"
 157     ON
 158     GMX_MPI)
 159 mark_as_advanced(GMX_MPI_IN_PLACE)
 160 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 161 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 162 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 163 mark_as_advanced(GMX_FAHCORE)
 164
 165 option(GMX_COOL_QUOTES "Enable GROMACS cool quotes" ON)
 166 mark_as_advanced(GMX_COOL_QUOTES)
 167 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 168
 169 option(GMX_USE_OPENCL "Enable OpenCL acceleration" OFF)
 170
 171 # Decide on GPU settings based on user-settings and GPU/CUDA detection.
 172 # We support CUDA >=v4.0 on *nix, but <= v4.1 doesn't work with MSVC
 173 if(MSVC)
 174     set(REQUIRED_CUDA_VERSION 4.1)
 175 else()
 176     set(REQUIRED_CUDA_VERSION 4.0)
 177 endif()
 178 set(REQUIRED_CUDA_COMPUTE_CAPABILITY 2.0)
 179
 180 # OpenCL required version: 1.1 or newer
 181 set(REQUIRED_OPENCL_MIN_VERSION 1.1)
 182
 183 if(NOT GMX_USE_OPENCL)
 184     # CUDA detection is done only if GMX_USE_OPENCL is OFF
 185     include(gmxManageGPU)
 186 else()
 187     #Now the OpenCL path
 188     if(GMX_GPU)
 189         include(gmxManageOpenCL)
 190     else(GMX_GPU)
 191         message(FATAL_ERROR "OpenCL requested but GPU option is not enabled (try -DGMX_GPU=on) ")
 192     endif(GMX_GPU)
 193 endif()
 194
 195 include(gmxDetectSimd)
 196 gmx_detect_simd(GMX_SUGGESTED_SIMD)
 197
 198 gmx_option_multichoice(
 199     GMX_SIMD
 200     "SIMD instruction set for CPU kernels and compiler optimization"
 201     "${GMX_SUGGESTED_SIMD}"
 202     None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 AVX_512F AVX_512ER MIC ARM_NEON ARM_NEON_ASIMD IBM_QPX IBM_VMX IBM_VSX Sparc64_HPC_ACE Reference)
 203
 204 if(GMX_TARGET_MIC)
 205     set(GMX_FFT_LIBRARY_DEFAULT "mkl")
 206 else()
 207     set(GMX_FFT_LIBRARY_DEFAULT "fftw3")
 208 endif()
 209
 210 gmx_option_multichoice(
 211     GMX_FFT_LIBRARY
 212     "FFT library"
 213     "${GMX_FFT_LIBRARY_DEFAULT}"
 214     fftw3 mkl "fftpack[built-in]")
 215 gmx_dependent_option(
 216     GMX_BUILD_OWN_FFTW
 217     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 218     OFF
 219     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 220 gmx_dependent_option(
 221     GMX_DISABLE_FFTW_MEASURE
 222     "Do not optimize FFTW setups (not needed with SSE)"
 223     OFF
 224     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 225 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 226 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 227
 228 gmx_option_multichoice(
 229     GMX_QMMM_PROGRAM
 230     "QM package for QM/MM"
 231     None
 232     none gaussian mopac gamess orca)
 233
 234 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 235 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 236
 237 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 238
 239 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 240 mark_as_advanced(GMX_BROKEN_CALLOC)
 241 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 242 mark_as_advanced(GMX_LOAD_PLUGINS)
 243
 244 option(GMX_GPU  "Enable GPU acceleration" ON)
 245 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 246
 247 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 248
 249 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 250
 251 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 252 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 253
 254 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 255 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 256
 257 option(GMX_BUILD_FOR_COVERAGE
 258        "Tune build for better code coverage metrics (e.g., disable asserts)"
 259        OFF)
 260 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 261
 262 option(GMX_DEVELOPER_BUILD
 263     "Enable Developer convenience features: always build unit-tests"
 264     OFF)
 265 mark_as_advanced(GMX_DEVELOPER_BUILD)
 266
 267 option(GMX_BUILD_SHARED_EXE
 268     "Build exectuables as shared binaries. If not set, this disables rpath and dynamic linker flags in an attempt to build a static binary, but this may require setting up the toolchain properly and making appropriate libraries available."
 269     ON)
 270 mark_as_advanced(GMX_BUILD_SHARED_EXE)
 271
 272 ######################################################################
 273 # Detect OpenMP support
 274 ######################################################################
 275 # The OpenMP detection _must_ come before tests for other CFLAGS.
 276 include(gmxManageOpenMP)
 277
 278
 279
 280 ######################################################################
 281 # Compiler tests
 282 # These need to be done early (before further tests).
 283 #####################################################################
 284
 285 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 286 # are used with permission from CMake v3.0.0 so that GROMACS can detect
 287 # invalid options with the Intel Compilers, and we have added a line
 288 # to detect warnings with the Fujitsu compilers on K computer and ICC.
 289 # CMake-3.0 also has a bug where the FAIL_REGEX pattern for AIX contains
 290 # a semicolon. Since this is also used as a separator in lists inside CMake,
 291 # that string ends up being split into two separate patterns, and the last
 292 # part is just a single word that also matches other messages. We solved this
 293 # by replacing the semicolon with a period that matches any character.
 294 #
 295 # These files should be removed from the source tree when a CMake version that
 296 # includes the features in question becomes required for building GROMACS.
 297 include(CheckCCompilerFlag)
 298 include(CheckCXXCompilerFlag)
 299
 300 include(gmxCFlags)
 301 gmx_c_flags()
 302
 303 # This variable should be used for additional compiler flags which are not
 304 # generated in gmxCFlags nor are SIMD or MPI related.
 305 set(EXTRA_C_FLAGS "")
 306 set(EXTRA_CXX_FLAGS "")
 307
 308 # Run through a number of tests for buggy compilers and other issues
 309 include(gmxTestCompilerProblems)
 310 gmx_test_compiler_problems()
 311 # GMX_SIMD will not be set automatically until the second
 312 # pass (which is not strictly guaranteed to occur), so putting this
 313 # check here among logically-related tests is inefficient, but the
 314 # potential loss is likely zero.
 315 if(GMX_SIMD STREQUAL "AVX_256"
 316         AND CMAKE_COMPILER_IS_GNUCC
 317         AND (C_COMPILER_VERSION VERSION_EQUAL "4.6.1"
 318             OR CXX_COMPILER_VERSION VERSION_EQUAL "4.6.1"))
 319     message(FATAL_ERROR "gcc 4.6.1 has buggy support for AVX, and GROMACS mdrun will not work. If you want simulation performance, use a more recent compiler. Otherwise, use GMX_SIMD=SSE4.1")
 320     # See http://gcc.gnu.org/bugzilla/show_bug.cgi?id=49002
 321 endif()
 322
 323
 324 if(GMX_DOUBLE)
 325     add_definitions(-DGMX_DOUBLE)
 326     list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_DOUBLE")
 327     if(GMX_RELAXED_DOUBLE_PRECISION)
 328         add_definitions(-DGMX_RELAXED_DOUBLE_PRECISION)
 329     endif()
 330 endif()
 331 if(GMX_SOFTWARE_INVSQRT)
 332     list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_SOFTWARE_INVSQRT")
 333 endif()
 334
 335 if(WIN32)
 336     list(APPEND GMX_EXTRA_LIBRARIES "wsock32")
 337     add_definitions(-DGMX_HAVE_WINSOCK)
 338 endif()
 339
 340
 341
 342 ########################################################################
 343 # Basic system tests (standard libraries, headers, functions, types)   #
 344 ########################################################################
 345 include(CheckIncludeFiles)
 346 include(CheckIncludeFileCXX)
 347 check_include_files(unistd.h     HAVE_UNISTD_H)
 348 check_include_files(pwd.h        HAVE_PWD_H)
 349 check_include_files(dirent.h     HAVE_DIRENT_H)
 350 check_include_files(time.h       HAVE_TIME_H)
 351 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 352 check_include_files(io.h         HAVE_IO_H)
 353 check_include_files(sched.h      HAVE_SCHED_H)
 354
 355 check_include_files(regex.h      HAVE_POSIX_REGEX)
 356 # TODO: It could be nice to inform the user if no regex support is found,
 357 # as selections won't be fully functional.
 358
 359 include(CheckCXXSymbolExists)
 360 check_cxx_symbol_exists(posix_memalign    stdlib.h     HAVE_POSIX_MEMALIGN)
 361 check_cxx_symbol_exists(memalign          stdlib.h     HAVE_MEMALIGN)
 362 check_cxx_symbol_exists(_aligned_malloc   stdlib.h     HAVE__ALIGNED_MALLOC)
 363 check_cxx_symbol_exists(gettimeofday      sys/time.h   HAVE_GETTIMEOFDAY)
 364 check_cxx_symbol_exists(sysconf           unistd.h     HAVE_SYSCONF)
 365 check_cxx_symbol_exists(nice              unistd.h     HAVE_NICE)
 366 check_cxx_symbol_exists(fsync             unistd.h     HAVE_FSYNC)
 367 check_cxx_symbol_exists(_fileno           stdio.h      HAVE__FILENO)
 368 check_cxx_symbol_exists(fileno            stdio.h      HAVE_FILENO)
 369 check_cxx_symbol_exists(_commit           io.h         HAVE__COMMIT)
 370 check_cxx_symbol_exists(sigaction         signal.h     HAVE_SIGACTION)
 371 check_cxx_symbol_exists(rsqrt             math.h       HAVE_RSQRT)
 372 check_cxx_symbol_exists(rsqrtf            math.h       HAVE_RSQRTF)
 373 check_cxx_symbol_exists(sqrtf             math.h       HAVE_SQRTF)
 374
 375 include(CheckLibraryExists)
 376 find_library(HAVE_LIBM m)
 377 mark_as_advanced(HAVE_LIBM)
 378 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 379 check_library_exists(m feenableexcept "" HAVE_FEENABLEEXCEPT)
 380
 381 include(TestSchedAffinity)
 382 test_sched_affinity(HAVE_SCHED_AFFINITY)
 383
 384 include(TestBigEndian)
 385 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 386
 387 set(GMX_USE_NICE 0)
 388 if (HAVE_UNISTD_H AND HAVE_NICE)
 389     set(GMX_USE_NICE 1)
 390 endif()
 391
 392 # Management of GROMACS options for specific toolchains should go
 393 # here. Because the initial settings for some of the main options have
 394 # already happened, but things like library detection and MPI compiler
 395 # feature detection have not, the docstrings for any over-rides of
 396 # GROMACS defaults or user settings will make sense. Also, any
 397 # toolchain-related reasons for choosing whether to detect various
 398 # things can be sorted out now, before the detection takes place.
 399 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 400     include(gmxManageBlueGene)
 401 endif()
 402
 403 if(GMX_TARGET_FUJITSU_SPARC64)
 404     include(gmxManageFujitsuSparc64)
 405 endif()
 406
 407 ########################################################################
 408 #Process MPI settings
 409 ########################################################################
 410 include(gmxManageMPI)
 411
 412
 413 ########################################################################
 414 #Process shared/static library settings
 415 ########################################################################
 416 include(gmxManageSharedLibraries)
 417
 418
 419 ########################################################################
 420 # Find external packages                                               #
 421 ########################################################################
 422
 423 # TNG wants zlib if it is available. And static libxml2 might have a dependency
 424 find_package(ZLIB QUIET)
 425 include(gmxTestZLib)
 426 gmx_test_zlib(HAVE_ZLIB)
 427
 428 # Unconditionally find the package, as it is also required for unit
 429 # tests. This exports LIBXML2_FOUND, which we should not use because
 430 # it does not tell us that linking will succeed. Instead, we test that
 431 # next.
 432 if(DEFINED LIBXML2_LIBRARIES)
 433   set(LibXml2_FIND_QUIETLY TRUE)
 434 endif()
 435 find_package(LibXml2)
 436 include(gmxTestLibXml2)
 437 gmx_test_libxml2(HAVE_LIBXML2)
 438 option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 439 set(PKG_XML "")
 440 mark_as_advanced(GMX_XML)
 441 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 442 #if(GMX_XML AND NOT HAVE_LIBXML2)
 443 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 444 #endif()
 445 #if(GMX_XML)
 446 #    include_directories(${LIBXML2_INCLUDE_DIR})
 447 #    set(PKG_XML libxml-2.0)
 448 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 449 #endif()
 450
 451 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 452 mark_as_advanced(GMX_EXTRAE)
 453
 454 if (GMX_EXTRAE)
 455   find_package(EXTRAE)
 456   if(EXTRAE_FOUND)
 457     include_directories(SYSTEM ${EXTRAE_INCLUDE_DIR})
 458     set(HAVE_EXTRAE 1)
 459   else()
 460     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 461   endif()
 462 endif()
 463
 464 option(GMX_X11 "Use X window system" OFF)
 465 if (GMX_X11)
 466     find_package(X11)
 467     # X11 includes/libraries are only set in the ngmx subdirectory!
 468     if(NOT X11_FOUND)
 469         message(FATAL_ERROR
 470                 "X11 include files and/or libraries were not found. "
 471                 "Set GMX_X11=OFF to compile without X11 support. "
 472                 "gmx view will not be available.")
 473     endif()
 474     include_directories(SYSTEM ${X11_INCLUDE_DIR})
 475 endif()
 476
 477 include(ThreadMPI)
 478 # Enable core threading facilities
 479 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 480 # Enable tMPI C++ support
 481 tmpi_enable_cxx()
 482 if(GMX_THREAD_MPI)
 483     # enable MPI functions
 484     tmpi_enable()
 485     set(MPI_IN_PLACE_EXISTS 1)
 486 endif()
 487 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 488 if (TMPI_ATOMICS_DISABLED)
 489    add_definitions(-DTMPI_ATOMICS_DISABLED)
 490 endif()
 491
 492 if(GMX_GPU)
 493     # now that we have detected the dependencies, do the second configure pass
 494     gmx_gpu_setup()
 495 else()
 496     mark_as_advanced(CUDA_HOST_COMPILER)
 497 endif()
 498
 499 if(CYGWIN)
 500     set(GMX_CYGWIN 1)
 501 endif()
 502
 503 if(WIN32)
 504     set(GMX_NATIVE_WINDOWS 1)
 505     # This makes windows.h not declare min/max as macros that would break
 506     # C++ code using std::min/std::max.
 507     add_definitions(-DNOMINMAX)
 508 endif()
 509
 510 if(CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Work-around for cmake bug #10837
 511     if (CMAKE_COMPILER_IS_GNUCC OR CMAKE_C_COMPILER_ID MATCHES "Intel" OR CMAKE_C_COMPILER_ID MATCHES "Clang")
 512         set(CMAKE_INCLUDE_SYSTEM_FLAG_C "-isystem ")
 513     endif()
 514     if (CMAKE_COMPILER_IS_GNUCXX OR CMAKE_CXX_COMPILER_ID MATCHES "Intel" OR CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 515         set(CMAKE_INCLUDE_SYSTEM_FLAG_CXX "-isystem ")
 516     endif()
 517 endif()
 518
 519 # Detect boost unless GMX_EXTERNAL_BOOST is explicitly OFF
 520 # Used for default if GMX_EXTERNAL_BOOST is not defined (first CMake pass)
 521 if(NOT DEFINED GMX_EXTERNAL_BOOST OR GMX_EXTERNAL_BOOST)
 522     if(DEFINED Boost_INCLUDE_DIR)
 523         set(Boost_FIND_QUIETLY TRUE)
 524     endif()
 525     find_package(Boost 1.44.0)
 526     if(Boost_FOUND AND Boost_VERSION VERSION_LESS "104400")
 527         set(Boost_FOUND FALSE)
 528     endif()
 529     # Print the notification only on first run, when determining the default
 530     if(NOT DEFINED GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 531         message("Boost >= 1.44 not found. Using minimal internal version. "
 532                 "This may cause trouble if you plan on compiling/linking other "
 533                 "software that uses Boost against GROMACS.")
 534     endif()
 535 endif()
 536 option(GMX_EXTERNAL_BOOST "Use external Boost instead of minimal built-in version"
 537        ${Boost_FOUND})
 538 if(GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 539     message(FATAL_ERROR
 540         "Boost >= 1.44 not found. "
 541         "You can set GMX_EXTERNAL_BOOST=OFF to compile against minimal "
 542         "version of Boost included with GROMACS.")
 543 endif()
 544
 545 if(NOT DEFINED GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 546     message(WARNING "libxml2 not found. Will build GROMACS without unit-tests. This is not recommended, because the unit-tests help to verify that GROMACS functions correctly. Most likely you are missing the libxml2-dev(el) package. After you installed it, set GMX_BUILD_UNITTESTS=ON.")
 547 endif()
 548 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ${HAVE_LIBXML2})
 549 mark_as_advanced(GMX_BUILD_UNITTESTS)
 550 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 551 if (GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 552     message(FATAL_ERROR
 553         "Cannot build unit tests without libxml2. "
 554         "Either set GMX_BUILD_UNITTESTS=OFF or tell CMake how to find a working version of libxml2.")
 555 endif()
 556
 557 ########################################################################
 558 # Our own GROMACS tests
 559 ########################################################################
 560
 561 add_definitions( -DHAVE_CONFIG_H )
 562 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src)
 563 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include)
 564 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 565 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src)
 566
 567 include(gmxTestInlineASM)
 568 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 569
 570 include(gmxSetBuildInformation)
 571 gmx_set_build_information()
 572 # Turn on RDTSCP if:
 573 # - the build system's CPU supports it
 574 # - the acceleration is set to AVX as all AVX-capable CPUs support AVX (which
 575 #   at this point means that the user set it).
 576 # Note: it's better to not use the later set value of GMX_SIMD because
 577 # it reflects the system's capability of both compiling and running AVX code.
 578 # TODO: After merge with 5.0 one could implement a cache variable dependency
 579 # such that GMX_USE_RDTSCP can change if GMX_SIMD is changed to AVX
 580 # after the first cmake pass.
 581 if (BUILD_CPU_FEATURES MATCHES "rdtscp" OR GMX_SIMD MATCHES "AVX")
 582     set(GMX_USE_RDTSCP_DEFAULT_VALUE ON)
 583 else()
 584     set(GMX_USE_RDTSCP_DEFAULT_VALUE OFF)
 585 endif()
 586 option(GMX_USE_RDTSCP "Use RDTSCP for better CPU-based timers (available on recent x86 CPUs; might need to be off when compiling for heterogeneous environments)" ${GMX_USE_RDTSCP_DEFAULT_VALUE})
 587 mark_as_advanced(GMX_USE_RDTSCP)
 588 if(GMX_USE_RDTSCP)
 589     set(HAVE_RDTSCP 1)
 590 endif()
 591
 592 include(gmxTestFloatFormat)
 593 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 594                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 595                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 596
 597 include(gmxTestLargeFiles)
 598 gmx_test_large_files(GMX_LARGEFILES)
 599
 600 include(gmxTestSignal)
 601 gmx_test_sigusr1(HAVE_SIGUSR1)
 602
 603 include(gmxTestPipes)
 604 gmx_test_pipes(HAVE_PIPES)
 605
 606 include(gmxTestIsfinite)
 607 gmx_test_isfinite(HAVE_ISFINITE)
 608 gmx_test__isfinite(HAVE__ISFINITE)
 609 gmx_test__finite(HAVE__FINITE)
 610
 611 include(gmxTestCXX11)
 612 gmx_test_cxx11(GMX_CXX11_SUPPORTED GMX_CXX11_FLAGS)
 613 include(CMakeDependentOption)
 614 # clang with some older versions of boost fail to work with C++11
 615 if(CMAKE_CXX_COMPILER_ID MATCHES Clang AND
 616     (Boost_VERSION VERSION_EQUAL 104601 OR Boost_VERSION VERSION_EQUAL 104700))
 617     set(CLANG_AND_OLD_EXTERNAL_BOOST TRUE)
 618 endif()
 619 # nvcc does not support C++11 flags, so with GPUs we prefer to skip C++11 flags
 620 # entirely to keep the compilation environment uniform.
 621 cmake_dependent_option(GMX_CXX11
 622     "Use C++11 features"
 623     ON "GMX_CXX11_SUPPORTED AND NOT GMX_GPU AND NOT CLANG_AND_OLD_EXTERNAL_BOOST" OFF)
 624 mark_as_advanced(GMX_CXX11)
 625 if(GMX_CXX11)
 626     set(EXTRA_CXX_FLAGS "${EXTRA_CXX_FLAGS} ${GMX_CXX11_FLAGS}")
 627 endif()
 628
 629 # Now we can test for CXX11_REGEX include file
 630 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 631
 632 include(gmxTestXDR)
 633 gmx_test_xdr(GMX_SYSTEM_XDR)
 634 if(NOT GMX_SYSTEM_XDR)
 635     set(GMX_INTERNAL_XDR 1)
 636 endif()
 637
 638
 639 ##################################################
 640 # Process SIMD instruction settings
 641 ##################################################
 642 # This checks what flags to add in order to
 643 # support the SIMD instructions we need, it sets
 644 # correct defines for the SIMD instructions supported,
 645 # and adds advanced options to control accuracy
 646 # for SIMD math operations.
 647 include(gmxManageSimd)
 648 gmx_manage_simd()
 649
 650 # Process QM/MM Settings
 651 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 652     set(GMX_QMMM_GAUSSIAN 1)
 653 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 654     set(GMX_QMMM_MOPAC 1)
 655 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 656     set(GMX_QMMM_GAMESS 1)
 657 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 658     set(GMX_QMMM_ORCA 1)
 659 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 660     # nothing to do
 661 else()
 662     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 663 endif()
 664
 665
 666 ##################################################
 667 # Process FFT library settings
 668 ##################################################
 669 include(gmxManageFFTLibraries)
 670
 671
 672 include(gmxManageLinearAlgebraLibraries)
 673
 674 # Whether GROMACS will really try to compile support for VMD plugins
 675 set(GMX_USE_PLUGINS OFF)
 676
 677 if(GMX_LOAD_PLUGINS)
 678   if(NOT WIN32)
 679     # Native Windows does not have, nor need dlopen
 680     include(gmxTestdlopen)
 681     gmx_test_dlopen(HAVE_DLOPEN)
 682   endif()
 683
 684   # so, should we use plug-ins?
 685   if(WIN32 OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 686     if(NOT VMD_QUIETLY)
 687       MESSAGE(STATUS "Using dynamic plugins (e.g VMD-supported file formats)")
 688     endif()
 689     if(NOT GMX_VMD_PLUGIN_PATH)
 690       find_package(VMD)
 691     endif()
 692     set(GMX_USE_PLUGINS ON)
 693     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 694     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 695   else()
 696     set(PKG_DL_LIBS)
 697   endif()
 698 endif()
 699 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 700
 701 # Link real-time library for POSIX timers. The check for clock_gettime
 702 # confirms the linkability of rt.
 703 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 704     list(APPEND GMX_EXTRA_LIBRARIES rt)
 705 endif()
 706
 707 # Math and thread libraries must often come after all others when linking...
 708 if(HAVE_LIBM)
 709     list(APPEND GMX_EXTRA_LIBRARIES m)
 710 endif()
 711
 712 option(GMX_NACL "Configure for Native Client builds" OFF)
 713 if (GMX_NACL)
 714   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 715   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 716   # TODO: Is this still necessary with the check for its presence?
 717   set(GMX_USE_NICE 0)
 718   set(GMX_NO_RENAME 1)
 719 endif()
 720 mark_as_advanced(GMX_NACL)
 721
 722 if(GMX_FAHCORE)
 723   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 724       "Path to swindirect.h")
 725   include_directories(${COREWRAP_INCLUDE_DIR})
 726 endif()
 727
 728 # Value of GMX_BUILD_HELP=AUTO tries to generate things, but will only
 729 # produce warnings if that fails.
 730 set(build_help_default AUTO)
 731 if (SOURCE_IS_SOURCE_DISTRIBUTION OR CMAKE_CROSSCOMPILING)
 732     set(build_help_default OFF)
 733 endif()
 734 gmx_option_trivalue(GMX_BUILD_HELP "Build completions automatically (requires that compiled binaries can be executed on the build host) and install man pages if built (requires building the 'man' target manually)" ${build_help_default})
 735 mark_as_advanced(GMX_BUILD_HELP)
 736 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND BUILD_IS_INSOURCE)
 737     message(FATAL_ERROR
 738         "Rebuilding shell completions or man pages is not supported for "
 739         "in-source builds from a source distribution. "
 740         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 741 endif()
 742
 743 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 744 # these are set after everything else
 745 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 746     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 747     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 748     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 749     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 750 else()
 751     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 752     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 753     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 754     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 755     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 756     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 757     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 758     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 759     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
 760 endif()
 761
 762 if(NOT GMX_OPENMP)
 763     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 764     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 765     unset(OpenMP_C_FLAGS CACHE)
 766     unset(OpenMP_CXX_FLAGS CACHE)
 767 else()
 768     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 769     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 770 endif()
 771
 772 ########################################################################
 773 # Specify install locations
 774 ########################################################################
 775 # Use GNUInstallDirs to set paths on multiarch systems.
 776 include(GNUInstallDirs)
 777
 778 # Customization for the installation tree paths.
 779 set(GMX_LIB_INSTALL_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING
 780     "Library installation directory (default: ${CMAKE_INSTALL_LIBDIR})")
 781 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 782     "Data installation directory under share/ (default: gromacs)")
 783 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 784
 785 # These variables are used internally to provide a central location for
 786 # customizing the install locations.
 787 set(LIB_INSTALL_DIR       ${GMX_LIB_INSTALL_DIR})
 788 set(BIN_INSTALL_DIR       bin)
 789 # This variable also gets written into config.h for use in finding the data
 790 # directories.
 791 set(DATA_INSTALL_DIR      share/${GMX_DATA_INSTALL_DIR})
 792 set(MAN_INSTALL_DIR       share/man)
 793 # If the nesting level wrt. the installation root is changed,
 794 # gromacs-config.cmake.cmakein needs to be adapted.
 795 set(CMAKE_INSTALL_DIR     share/cmake)
 796 # TODO: Make GMXRC adapt if this is changed
 797 set(PKGCONFIG_INSTALL_DIR ${LIB_INSTALL_DIR}/pkgconfig)
 798 set(OCL_INSTALL_DIR       ${DATA_INSTALL_DIR}/opencl)
 799 set(INCL_INSTALL_DIR      include)
 800
 801 list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${INCL_INSTALL_DIR})
 802
 803 # Binary and library suffix options
 804 include(gmxManageSuffixes)
 805
 806 ################################################################
 807 # Shared library load path settings
 808 ################################################################
 809 # CMake supports RPATH on OS X only from 2.8.12 upwards.
 810 # CMAKE_SYSTEM_VERSION > 8.0 matches OS X 10.5 and above, where RPATH support
 811 # was added.
 812
 813 if(NOT GMX_BUILD_SHARED_EXE)
 814     # No rpath
 815     set(CMAKE_SKIP_RPATH TRUE)
 816     set(CMAKE_EXE_LINK_DYNAMIC_C_FLAGS) # remove -Wl,-Bdynamic
 817     set(CMAKE_EXE_LINK_DYNAMIC_CXX_FLAGS)
 818 elseif((NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin") OR
 819    ((CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) AND (NOT CMAKE_VERSION VERSION_LESS 2.8.12)))
 820     # The build folder always has bin/ and lib/; if we are also going to
 821     # install to lib/, then the installation RPATH works also in the build
 822     # tree.  This makes installation slightly faster (no need to rewrite the
 823     # RPATHs), and makes the binaries in the build tree relocatable.
 824     if(GMX_LIB_INSTALL_DIR STREQUAL "lib")
 825         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 826     endif()
 827     # Set the RPATH as relative to the executable location to make the
 828     # binaries relocatable.
 829     if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 830         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${GMX_LIB_INSTALL_DIR}")
 831     else()
 832         set(CMAKE_INSTALL_RPATH "@executable_path/../${GMX_LIB_INSTALL_DIR}")
 833     endif()
 834     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 835     set(CMAKE_MACOSX_RPATH 1)
 836 else()
 837     # We are on Darwin/OSX, and CMake cannot handle RPATHs automatically.
 838     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0)
 839         # Set the RPATH options manually.
 840         set(CMAKE_INSTALL_NAME_DIR "@rpath")
 841         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../${GMX_LIB_INSTALL_DIR}")
 842     else()
 843         # Use the old INSTALL_NAME_DIR mechanism if RPATH is not supported.
 844         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
 845     endif()
 846 endif()
 847
 848 #COPYING file: Only necessary for binary distributions.
 849 #Simpler to always install.
 850 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 851
 852 if(GMX_EXTERNAL_BOOST)
 853     include_directories(SYSTEM ${Boost_INCLUDE_DIRS})
 854     list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${Boost_INCLUDE_DIRS})
 855 else()
 856     include_directories(BEFORE SYSTEM ${CMAKE_SOURCE_DIR}/src/external/boost)
 857     list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${INCL_INSTALL_DIR}/gromacs/external/boost)
 858     list(APPEND INSTALLED_HEADED_DEFINITIONS "-DBOOST_NO_TYPEID")
 859     # typeid not supported for minimal internal version
 860     # (would add significant amount of code)
 861     add_definitions(-DBOOST_NO_TYPEID)
 862     if (NOT GMX_BUILD_MDRUN_ONLY)
 863         install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
 864                 DESTINATION ${INCL_INSTALL_DIR}/gromacs/external/boost
 865                 COMPONENT development)
 866     endif()
 867 endif()
 868
 869 if (GMX_BUILD_FOR_COVERAGE)
 870     # Code heavy with asserts makes conditional coverage close to useless metric,
 871     # as by design most of the false branches are impossible to trigger in
 872     # correctly functioning code.  And the benefit of testing those that could
 873     # be triggered by using an API against its specification isn't usually
 874     # worth the effort.
 875     add_definitions(-DNDEBUG -DBOOST_DISABLE_ASSERTS -DGMX_DISABLE_ASSERTS)
 876 endif()
 877
 878 if (BUILD_TESTING)
 879     # "tests" target builds all the separate test binaries.
 880     add_custom_target(tests)
 881     # "run-ctest" is an internal target that actually runs the tests.
 882     # This is necessary to be able to add separate targets that execute as part
 883     # of 'make check', but are ensured to be executed after the actual tests.
 884     add_custom_target(run-ctest
 885                       COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure
 886                       COMMENT "Running all tests"
 887                       VERBATIM)
 888     add_dependencies(run-ctest tests)
 889     # "check" target builds and runs all tests.
 890     add_custom_target(check DEPENDS run-ctest)
 891 endif()
 892
 893 if (NOT GMX_BUILD_MDRUN_ONLY)
 894     add_subdirectory(docs)
 895     add_subdirectory(share)
 896     add_subdirectory(scripts)
 897 endif()
 898 add_subdirectory(src)
 899
 900 if (BUILD_TESTING)
 901     add_subdirectory(tests)
 902 endif()
 903
 904 gmx_cpack_write_config()
 905
 906 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 907 # Don't bother the user after the first configure pass.
 908 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 909     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 910 endif()
 911 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 912
 913 #######################
 914 ## uninstall target
 915 #######################
 916 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 917                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 918                   IMMEDIATE @ONLY)
 919 ###########################
 920 ADD_CUSTOM_TARGET(uninstall
 921                   "${CMAKE_COMMAND}" -P
 922                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 923 ###########################
 924 set_directory_properties(PROPERTIES
 925             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")