CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014,2015,2016, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 3.4.3)
  36
  37 # CMake modules/macros are in a subdirectory to keep this file cleaner
  38 # This needs to be set before project() in order to pick up toolchain files
  39 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  40
  41 project(Gromacs)
  42
  43 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  44 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  45 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  46
  47 # Set up common version variables, as well as general information about
  48 # the build tree (whether the build is from a source package or from a git
  49 # repository).  Also declares a few functions that will be used for generating
  50 # version info files later.
  51 include(gmxBuildTreeInfo)
  52 include(gmxVersionInfo)
  53
  54 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  55     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  56 endif()
  57 if("${CMAKE_INSTALL_PREFIX}" STREQUAL "${CMAKE_BINARY_DIR}")
  58     message(FATAL_ERROR "GROMACS cannot be installed into the build tree, choose a different location for CMAKE_INSTALL_PREFIX")
  59 endif()
  60
  61 include(gmxBuildTypeReference)
  62 include(gmxBuildTypeProfile)
  63 include(gmxBuildTypeTSAN)
  64 include(gmxBuildTypeASAN)
  65 include(gmxBuildTypeMSAN)
  66 include(gmxBuildTypeReleaseWithAssert)
  67
  68 if(NOT CMAKE_BUILD_TYPE)
  69     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert Profile TSAN ASAN MSAN." FORCE)
  70     # Set the possible values of build type for cmake-gui
  71     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
  72         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert" "Profile" "TSAN" "ASAN" "MSAN")
  73 endif()
  74 if(CMAKE_CONFIGURATION_TYPES)
  75     # Add appropriate GROMACS-specific build types for the Visual
  76     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
  77     # are already present by default).
  78     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
  79     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
  80     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
  81         "List of configuration types"
  82         FORCE)
  83 endif()
  84 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
  85
  86 set_property(GLOBAL PROPERTY FIND_LIBRARY_USE_LIB64_PATHS ON)
  87
  88 include(gmxCTestUtilities)
  89 gmx_ctest_init()
  90
  91 include(gmxCPackUtilities)
  92 gmx_cpack_init()
  93
  94 # Variables that accumulate stuff influencing the installed headers
  95 set(INSTALLED_HEADER_INCLUDE_DIRS "")
  96 set(INSTALLED_HEADER_DEFINITIONS "")
  97
  98 ########################################################################
  99 # Check and warn if cache generated on a different host is being reused
 100 ########################################################################
 101 if(CMAKE_HOST_UNIX)
 102     execute_process(COMMAND hostname
 103                     OUTPUT_VARIABLE TMP_HOSTNAME
 104                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 105     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 106         message(WARNING "
 107             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 108             is being reused! This could lead to inconsistencies; therefore, it is
 109             recommended to regenerate the cache!")
 110     endif()
 111     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 112             "Hostname of the machine where the cache was generated.")
 113 endif()
 114
 115 ########################################################################
 116 # Detect architecture before setting options so we can alter defaults
 117 ########################################################################
 118 # Detect the architecture the compiler is targetting, detect
 119 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 120 # to use if none is specified, and populate the cache option for CPU
 121 # SIMD.
 122 include(gmxDetectTargetArchitecture)
 123 gmx_detect_target_architecture()
 124
 125 # Permit the user to specify a particular standard library, e.g. compiling
 126 # with "-stdlib=libc++" and linking with "-lc++abi -lc++" to get clang's libcxx.
 127 set(GMX_STDLIB_CXX_FLAGS "" CACHE STRING "Compiler flag for a C++ standard library flavour")
 128 set(GMX_STDLIB_LIBRARIES "" CACHE STRING "Linker libraries for a particular C++ standard library")
 129 mark_as_advanced(GMX_STDLIB_CXX_FLAGS)
 130 mark_as_advanced(GMX_STDLIB_LIBRARIES)
 131
 132 ########################################################################
 133 # Detect CXX11 support and flags
 134 ########################################################################
 135 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 136 # are used with permission from CMake v3.0.0 so that GROMACS can detect
 137 # invalid options with the Intel Compilers, and we have added a line
 138 # to detect warnings with the Fujitsu compilers on K computer and ICC.
 139 # CMake-3.0 also has a bug where the FAIL_REGEX pattern for AIX contains
 140 # a semicolon. Since this is also used as a separator in lists inside CMake,
 141 # that string ends up being split into two separate patterns, and the last
 142 # part is just a single word that also matches other messages. We solved this
 143 # by replacing the semicolon with a period that matches any character.
 144 #
 145 # These files should be removed from the source tree when a CMake version that
 146 # includes the features in question becomes required for building GROMACS.
 147 include(CheckCCompilerFlag)
 148 include(CheckCXXCompilerFlag)
 149
 150 # This must come early, since some of our configuration flag tests
 151 # depend on being able to compile C++11 source files.
 152 include(gmxTestCXX11)
 153 gmx_test_cxx11(GMX_CXX11_FLAGS GMX_STDLIB_CXX_FLAGS GMX_STDLIB_LIBRARIES)
 154
 155 # Make sure all C++ code will be compiled in C++11 mode, with the
 156 # expected standard library.
 157 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${GMX_CXX11_FLAGS} ${GMX_STDLIB_CXX_FLAGS}")
 158
 159 ########################################################################
 160 # User input options                                                   #
 161 ########################################################################
 162 include(gmxOptionUtilities)
 163
 164 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 165
 166 # Fujitsu only has SIMD in double precision, so this will be faster
 167 gmx_set_boolean(GMX_DOUBLE_DEFAULT GMX_TARGET_FUJITSU_SPARC64)
 168 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" ${GMX_DOUBLE_DEFAULT})
 169 option(GMX_RELAXED_DOUBLE_PRECISION "Accept single precision 1/sqrt(x) when using Fujitsu HPC-ACE SIMD" OFF)
 170 mark_as_advanced(GMX_RELAXED_DOUBLE_PRECISION)
 171
 172 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 173 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 174 gmx_dependent_option(
 175     GMX_MPI_IN_PLACE
 176     "Enable MPI_IN_PLACE for MPIs that have it defined"
 177     ON
 178     GMX_MPI)
 179 mark_as_advanced(GMX_MPI_IN_PLACE)
 180 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 181 mark_as_advanced(GMX_FAHCORE)
 182
 183 option(GMX_COOL_QUOTES "Enable GROMACS cool quotes" ON)
 184 mark_as_advanced(GMX_COOL_QUOTES)
 185 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 186
 187 option(GMX_USE_OPENCL "Enable OpenCL acceleration" OFF)
 188
 189 # Decide on GPU settings based on user-settings and GPU/CUDA
 190 # detection.  GCC 4.8 requires CUDA 6.0 (but we choose 6.5 for the
 191 # preliminary C++11 support), icc 15 requires CUDA 7.0, and VS2015
 192 # requires CUDA 8.0
 193 if(MSVC)
 194     set(REQUIRED_CUDA_VERSION 8.0)
 195 elseif(CMAKE_CXX_COMPILER_ID MATCHES "Intel")
 196     set(REQUIRED_CUDA_VERSION 7.0)
 197 else()
 198     set(REQUIRED_CUDA_VERSION 6.5)
 199 endif()
 200 set(REQUIRED_CUDA_COMPUTE_CAPABILITY 2.0)
 201
 202 # OpenCL required version: 1.1 or newer
 203 set(REQUIRED_OPENCL_MIN_VERSION 1.1)
 204
 205 if(NOT GMX_USE_OPENCL)
 206     # CUDA detection is done only if GMX_USE_OPENCL is OFF.
 207     include(gmxManageGPU)
 208     set(GMX_USE_CUDA ${GMX_GPU})
 209     if(GMX_GPU)
 210         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_CUDA")
 211     else()
 212         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_NONE")
 213     endif()
 214 else()
 215     #Now the OpenCL path (for both AMD and NVIDIA)
 216     if(GMX_GPU)
 217         include(gmxManageOpenCL)
 218         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_OPENCL")
 219     else()
 220         message(FATAL_ERROR "OpenCL requested but GPU option is not enabled (try -DGMX_GPU=on) ")
 221     endif()
 222 endif()
 223
 224 include(gmxDetectSimd)
 225 gmx_detect_simd(GMX_SUGGESTED_SIMD)
 226
 227 gmx_option_multichoice(
 228     GMX_SIMD
 229     "SIMD instruction set for CPU kernels and compiler optimization"
 230     "${GMX_SUGGESTED_SIMD}"
 231     None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 AVX_512 AVX_512_KNL MIC ARM_NEON ARM_NEON_ASIMD IBM_QPX IBM_VMX IBM_VSX Sparc64_HPC_ACE Reference)
 232
 233 if(GMX_TARGET_MIC)
 234     set(GMX_FFT_LIBRARY_DEFAULT "mkl")
 235 else()
 236     set(GMX_FFT_LIBRARY_DEFAULT "fftw3")
 237 endif()
 238
 239 gmx_option_multichoice(
 240     GMX_FFT_LIBRARY
 241     "FFT library"
 242     "${GMX_FFT_LIBRARY_DEFAULT}"
 243     fftw3 mkl "fftpack[built-in]")
 244 gmx_dependent_option(
 245     GMX_BUILD_OWN_FFTW
 246     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 247     OFF
 248     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 249 gmx_dependent_option(
 250     GMX_DISABLE_FFTW_MEASURE
 251     "Do not optimize FFTW setups (not needed with SSE)"
 252     OFF
 253     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 254 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 255 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 256
 257 gmx_option_multichoice(
 258     GMX_QMMM_PROGRAM
 259     "QM package for QM/MM"
 260     None
 261     none gaussian mopac gamess orca)
 262
 263 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 264 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 265
 266 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 267
 268 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 269 mark_as_advanced(GMX_BROKEN_CALLOC)
 270 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 271 mark_as_advanced(GMX_LOAD_PLUGINS)
 272
 273 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 274
 275 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 276
 277 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 278
 279 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 280 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 281
 282 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 283 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 284
 285 option(GMX_BUILD_FOR_COVERAGE
 286        "Tune build for better code coverage metrics (e.g., disable asserts)"
 287        OFF)
 288 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 289
 290 option(GMX_DEVELOPER_BUILD
 291     "Enable Developer convenience features: always build unit-tests"
 292     OFF)
 293 mark_as_advanced(GMX_DEVELOPER_BUILD)
 294
 295 gmx_set_boolean(GMX_COMPILER_WARNINGS_DEFAULT "NOT SOURCE_IS_SOURCE_DISTRIBUTION")
 296 option(GMX_COMPILER_WARNINGS
 297     "Enable a default set of compiler warnings"
 298     ${GMX_COMPILER_WARNINGS_DEFAULT})
 299 mark_as_advanced(GMX_COMPILER_WARNINGS)
 300 # Always turn on compiler warnings with a developer build.
 301 gmx_add_cache_dependency(GMX_COMPILER_WARNINGS BOOL "NOT GMX_DEVELOPER_BUILD" ON)
 302
 303 option(GMX_BUILD_SHARED_EXE
 304     "Build exectuables as shared binaries. If not set, this disables rpath and dynamic linker flags in an attempt to build a static binary, but this may require setting up the toolchain properly and making appropriate libraries available."
 305     ON)
 306 mark_as_advanced(GMX_BUILD_SHARED_EXE)
 307
 308 ######################################################################
 309 # Detect OpenMP support
 310 ######################################################################
 311 # The OpenMP detection _must_ come before tests for other CFLAGS.
 312 include(gmxManageOpenMP)
 313
 314
 315
 316 ######################################################################
 317 # Compiler tests
 318 # These need to be done early (before further tests).
 319 #####################################################################
 320
 321 include(gmxCFlags)
 322 gmx_c_flags()
 323
 324 # These collect libraries that Gromacs requires for linking:
 325 #  - Libraries that are required for libgromacs (only)
 326 set(GMX_EXTRA_LIBRARIES "")
 327 #  - Libraries that are required for all code in the repository
 328 set(GMX_COMMON_LIBRARIES "")
 329 #  - Libraries that all code linked against libgromacs needs
 330 #    (i.e., something that is exposed in installed headers).
 331 set(GMX_PUBLIC_LIBRARIES "")
 332
 333 # This variable should be used for additional compiler flags which are not
 334 # generated in gmxCFlags nor are SIMD or MPI related.
 335 set(EXTRA_C_FLAGS "")
 336 set(EXTRA_CXX_FLAGS "")
 337
 338 # Run through a number of tests for buggy compilers and other issues
 339 include(gmxTestCompilerProblems)
 340 gmx_test_compiler_problems()
 341
 342 # Implement double-precision option. This is complicated because we
 343 # need installed headers to use the precision mode of the build that
 344 # produced the library, but cannot use config.h in that case. We also
 345 # want such variables to always have a definition, because #if is more
 346 # robust than #ifdef. So, we put this value on the compiler command
 347 # line in all cases.
 348 #
 349 # GMX_RELAXED_DOUBLE_PRECISION does not need to be handled here,
 350 # because no installed header needs it
 351 if(GMX_DOUBLE)
 352     set(GMX_DOUBLE_VALUE 1)
 353 else()
 354     set(GMX_DOUBLE_VALUE 0)
 355 endif()
 356 add_definitions(-DGMX_DOUBLE=${GMX_DOUBLE_VALUE})
 357 list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_DOUBLE=${GMX_DOUBLE_VALUE}")
 358
 359 if(WIN32)
 360     list(APPEND GMX_EXTRA_LIBRARIES "wsock32")
 361     add_definitions(-DGMX_HAVE_WINSOCK)
 362 endif()
 363
 364
 365
 366 ########################################################################
 367 # Basic system tests (standard libraries, headers, functions, types)   #
 368 ########################################################################
 369 include(CheckIncludeFiles)
 370 include(CheckIncludeFileCXX)
 371 check_include_files(unistd.h     HAVE_UNISTD_H)
 372 check_include_files(pwd.h        HAVE_PWD_H)
 373 check_include_files(dirent.h     HAVE_DIRENT_H)
 374 check_include_files(time.h       HAVE_TIME_H)
 375 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 376 check_include_files(io.h         HAVE_IO_H)
 377 check_include_files(sched.h      HAVE_SCHED_H)
 378
 379 check_include_files(regex.h      HAVE_POSIX_REGEX)
 380 # TODO: It could be nice to inform the user if no regex support is found,
 381 # as selections won't be fully functional.
 382
 383 include(CheckCXXSymbolExists)
 384 check_cxx_symbol_exists(gettimeofday      sys/time.h   HAVE_GETTIMEOFDAY)
 385 check_cxx_symbol_exists(sysconf           unistd.h     HAVE_SYSCONF)
 386 check_cxx_symbol_exists(nice              unistd.h     HAVE_NICE)
 387 check_cxx_symbol_exists(fsync             unistd.h     HAVE_FSYNC)
 388 check_cxx_symbol_exists(_fileno           stdio.h      HAVE__FILENO)
 389 check_cxx_symbol_exists(fileno            stdio.h      HAVE_FILENO)
 390 check_cxx_symbol_exists(_commit           io.h         HAVE__COMMIT)
 391 check_cxx_symbol_exists(sigaction         signal.h     HAVE_SIGACTION)
 392
 393 # We cannot check for the __builtins as symbols, but check if code compiles
 394 check_cxx_source_compiles("int main(){ return __builtin_clz(1);}"   HAVE_BUILTIN_CLZ)
 395 check_cxx_source_compiles("int main(){ return __builtin_clzll(1);}" HAVE_BUILTIN_CLZLL)
 396 if(MSVC)
 397     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned long i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE)
 398     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned __int64 i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE64)
 399 elseif(CMAKE_CXX_COMPILER_ID MATCHES "XL")
 400     check_cxx_source_compiles("int main(){ return __cntlz4(1);}" HAVE_CNTLZ4)
 401     check_cxx_source_compiles("int main(){ return __cntlz8(1);}" HAVE_CNTLZ8)
 402 endif()
 403
 404 include(CheckLibraryExists)
 405 find_library(HAVE_LIBM m)
 406 mark_as_advanced(HAVE_LIBM)
 407 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 408 check_library_exists(m feenableexcept "" HAVE_FEENABLEEXCEPT)
 409
 410 include(TestSchedAffinity)
 411 test_sched_affinity(HAVE_SCHED_AFFINITY)
 412
 413 # Aligned memory allocation. We need to check for both mm_malloc(),
 414 # posix_memalign(), memalign(), and on windows also _aligned_malloc()
 415 include(gmxTestMMMalloc)
 416 gmx_test_mm_malloc(HAVE__MM_MALLOC)
 417 check_cxx_symbol_exists(posix_memalign    stdlib.h     HAVE_POSIX_MEMALIGN)
 418 check_cxx_symbol_exists(memalign          stdlib.h     HAVE_MEMALIGN)
 419 if(MSVC)
 420     # No need to waste time on this test on platforms where it will never be true
 421     check_cxx_symbol_exists(_aligned_malloc   stdlib.h     HAVE__ALIGNED_MALLOC)
 422 endif()
 423
 424 include(TestBigEndian)
 425 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 426
 427 gmx_set_boolean(GMX_USE_NICE "HAVE_UNISTD_H AND HAVE_NICE")
 428
 429 # Management of GROMACS options for specific toolchains should go
 430 # here. Because the initial settings for some of the main options have
 431 # already happened, but things like library detection and MPI compiler
 432 # feature detection have not, the docstrings for any over-rides of
 433 # GROMACS defaults or user settings will make sense. Also, any
 434 # toolchain-related reasons for choosing whether to detect various
 435 # things can be sorted out now, before the detection takes place.
 436 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 437     include(gmxManageBlueGene)
 438 endif()
 439
 440 if(GMX_TARGET_FUJITSU_SPARC64)
 441     include(gmxManageFujitsuSparc64)
 442 endif()
 443
 444 ########################################################################
 445 #Process MPI settings
 446 ########################################################################
 447 include(gmxManageMPI)
 448
 449
 450 ########################################################################
 451 #Process shared/static library settings
 452 ########################################################################
 453 include(gmxManageSharedLibraries)
 454
 455
 456 ########################################################################
 457 # Find external packages                                               #
 458 ########################################################################
 459
 460 # Unconditionally find the package, as it is also required for unit
 461 # tests. This exports LIBXML2_FOUND, which we should not use because
 462 # it does not tell us that linking will succeed. Instead, we test that
 463 # next.
 464 #if(DEFINED LIBXML2_LIBRARIES)
 465 #  set(LibXml2_FIND_QUIETLY TRUE)
 466 #endif()
 467 #find_package(LibXml2)
 468 #include(gmxTestLibXml2)
 469 #gmx_test_libxml2(HAVE_LIBXML2)
 470 #option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 471 #set(PKG_XML "")
 472 #mark_as_advanced(GMX_XML)
 473 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 474 #if(GMX_XML AND NOT HAVE_LIBXML2)
 475 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 476 #endif()
 477 #if(GMX_XML)
 478 #    include_directories(${LIBXML2_INCLUDE_DIR})
 479 #    set(PKG_XML libxml-2.0)
 480 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 481 #endif()
 482
 483 if(DEFINED HWLOC_LIBRARIES)
 484   set(Hwloc_FIND_QUIETLY TRUE)
 485 endif()
 486 find_package(Hwloc 1.5)
 487 if (HWLOC_FOUND)
 488     if (HWLOC_LIBRARIES MATCHES ".a$")
 489         set(_STATIC_HWLOC TRUE)
 490     endif()
 491
 492     gmx_check_if_changed(HWLOC_FOUND_CHANGED HWLOC_FOUND)
 493     if (_STATIC_HWLOC AND HWLOC_FOUND_CHANGED)
 494         message(STATUS "Static hwloc library found, will not attempt using it as it could lead to link-time errors. To use the detected library, manually set GMX_HWLOC=ON and you will likely have to pass appropriate linker flags too to satisfy the link-time dependencies of your hwloc library. Try \"pkg-config --libs --static hwloc\" for suggestions on what you will need.")
 495         set(GMX_HWLOC_DEFAULT OFF)
 496     else()
 497         set(GMX_HWLOC_DEFAULT ON)
 498     endif()
 499 else()
 500     set(GMX_HWLOC_DEFAULT OFF)
 501 endif()
 502 option(GMX_HWLOC "Add support for hwloc Portable Hardware locality library" ${GMX_HWLOC_DEFAULT})
 503 if(GMX_HWLOC)
 504     if(HWLOC_FOUND)
 505         include_directories(SYSTEM ${HWLOC_INCLUDE_DIRS})
 506         list(APPEND GMX_EXTRA_LIBRARIES ${HWLOC_LIBRARIES})
 507     else()
 508         message(FATAL_ERROR "Hwloc package support requested, but not found.")
 509     endif()
 510 endif()
 511
 512 option(GMX_EXTERNAL_TINYXML2 "Use external TinyXML-2 instead of compiling the version bundled with GROMACS." OFF)
 513 mark_as_advanced(GMX_EXTERNAL_TINYXML2)
 514 if(GMX_EXTERNAL_TINYXML2)
 515     # Find an external TinyXML-2 library.
 516     find_package(TinyXML-2 3.0.0)
 517     set(HAVE_TINYXML2 ${TinyXML2_FOUND})
 518     if(NOT HAVE_TINYXML2)
 519         message(FATAL_ERROR "External TinyXML-2 could not be found, please adjust your search paths")
 520     endif()
 521 endif()
 522
 523 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 524 mark_as_advanced(GMX_EXTRAE)
 525
 526 if (GMX_EXTRAE)
 527   find_package(EXTRAE)
 528   if(EXTRAE_FOUND)
 529     include_directories(SYSTEM ${EXTRAE_INCLUDE_DIR})
 530     set(HAVE_EXTRAE 1)
 531   else()
 532     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 533   endif()
 534 endif()
 535
 536 option(GMX_X11 "Use X window system" OFF)
 537 if (GMX_X11)
 538     find_package(X11)
 539     # X11 includes/libraries are only set in the ngmx subdirectory!
 540     if(NOT X11_FOUND)
 541         message(FATAL_ERROR
 542                 "X11 include files and/or libraries were not found. "
 543                 "Set GMX_X11=OFF to compile without X11 support. "
 544                 "gmx view will not be available.")
 545     endif()
 546     include_directories(SYSTEM ${X11_INCLUDE_DIR})
 547 endif()
 548
 549 include(ThreadMPI)
 550 # Enable core threading facilities
 551 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 552 # Enable tMPI C++ support
 553 tmpi_enable_cxx()
 554 if(GMX_THREAD_MPI)
 555     # enable MPI functions
 556     tmpi_enable()
 557     set(MPI_IN_PLACE_EXISTS 1)
 558 endif()
 559 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 560 if (TMPI_ATOMICS_DISABLED)
 561    add_definitions(-DTMPI_ATOMICS_DISABLED)
 562 endif()
 563
 564 include(gmxManageTNG)
 565
 566 include(gmxManageLmfit)
 567
 568 if(GMX_GPU)
 569     # now that we have detected the dependencies, do the second configure pass
 570     gmx_gpu_setup()
 571 endif()
 572
 573 if(CYGWIN)
 574     set(GMX_CYGWIN 1)
 575 endif()
 576
 577 if(WIN32)
 578     set(GMX_NATIVE_WINDOWS 1)
 579     # This makes windows.h not declare min/max as macros that would break
 580     # C++ code using std::min/std::max.
 581     add_definitions(-DNOMINMAX)
 582 endif()
 583
 584 if(CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Work-around for cmake bug #10837
 585     if (CMAKE_COMPILER_IS_GNUCC OR CMAKE_C_COMPILER_ID MATCHES "Intel" OR CMAKE_C_COMPILER_ID MATCHES "Clang")
 586         set(CMAKE_INCLUDE_SYSTEM_FLAG_C "-isystem ")
 587     endif()
 588     if (CMAKE_COMPILER_IS_GNUCXX OR CMAKE_CXX_COMPILER_ID MATCHES "Intel" OR CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 589         set(CMAKE_INCLUDE_SYSTEM_FLAG_CXX "-isystem ")
 590     endif()
 591 endif()
 592
 593 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING" ON)
 594 mark_as_advanced(GMX_BUILD_UNITTESTS)
 595 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 596
 597 ########################################################################
 598 # Our own GROMACS tests
 599 ########################################################################
 600
 601 add_definitions( -DHAVE_CONFIG_H )
 602 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src)
 603 # TODO required at high level because both libgromacs and progs/mdrun
 604 # require it, both for thread-MPI and its atomics and mutexes.
 605 include_directories(BEFORE SYSTEM ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include)
 606 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 607 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src)
 608
 609 include(gmxTestInlineASM)
 610 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 611
 612 include(gmxSetBuildInformation)
 613 gmx_set_build_information()
 614 # Turn on RDTSCP if:
 615 # - the build system's CPU supports it
 616 # - the acceleration is set to AVX as all AVX-capable CPUs support AVX (which
 617 #   at this point means that the user set it).
 618 # Note: it's better to not use the later set value of GMX_SIMD because
 619 # it reflects the system's capability of both compiling and running AVX code.
 620 # TODO: After merge with 5.0 one could implement a cache variable dependency
 621 # such that GMX_USE_RDTSCP can change if GMX_SIMD is changed to AVX
 622 # after the first cmake pass.
 623 if (BUILD_CPU_FEATURES MATCHES "rdtscp" OR GMX_SIMD MATCHES "AVX")
 624     set(GMX_USE_RDTSCP_DEFAULT_VALUE ON)
 625 else()
 626     set(GMX_USE_RDTSCP_DEFAULT_VALUE OFF)
 627 endif()
 628 option(GMX_USE_RDTSCP "Use RDTSCP for better CPU-based timers (available on recent x86 CPUs; might need to be off when compiling for heterogeneous environments)" ${GMX_USE_RDTSCP_DEFAULT_VALUE})
 629 mark_as_advanced(GMX_USE_RDTSCP)
 630 if(GMX_USE_RDTSCP)
 631     set(HAVE_RDTSCP 1)
 632 endif()
 633
 634 include(gmxTestLargeFiles)
 635 gmx_test_large_files(GMX_LARGEFILES)
 636
 637 include(gmxTestSignal)
 638 gmx_test_sigusr1(HAVE_SIGUSR1)
 639
 640 include(gmxTestPipes)
 641 gmx_test_pipes(HAVE_PIPES)
 642
 643 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 644
 645 include(gmxTestXDR)
 646 gmx_test_xdr(GMX_SYSTEM_XDR)
 647 if(NOT GMX_SYSTEM_XDR)
 648     set(GMX_INTERNAL_XDR 1)
 649 endif()
 650
 651
 652 ##################################################
 653 # Process SIMD instruction settings
 654 ##################################################
 655 # This checks what flags to add in order to
 656 # support the SIMD instructions we need, it sets
 657 # correct defines for the SIMD instructions supported,
 658 # and adds advanced options to control accuracy
 659 # for SIMD math operations.
 660 include(gmxManageSimd)
 661 gmx_manage_simd()
 662
 663 include(gmxManageCycleCounters)
 664 gmx_manage_cycle_counters()
 665
 666 # Process QM/MM Settings
 667 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 668     set(GMX_QMMM_GAUSSIAN 1)
 669 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 670     set(GMX_QMMM_MOPAC 1)
 671 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 672     set(GMX_QMMM_GAMESS 1)
 673 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 674     set(GMX_QMMM_ORCA 1)
 675 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 676     # nothing to do
 677 else()
 678     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 679 endif()
 680
 681
 682 ##################################################
 683 # Process FFT library settings
 684 ##################################################
 685 include(gmxManageFFTLibraries)
 686
 687
 688 include(gmxManageLinearAlgebraLibraries)
 689
 690 # Whether GROMACS will really try to compile support for VMD plugins
 691 set(GMX_USE_PLUGINS OFF)
 692
 693 if(GMX_LOAD_PLUGINS)
 694   if(NOT WIN32)
 695     # Native Windows does not have, nor need dlopen
 696     include(gmxTestdlopen)
 697     gmx_test_dlopen(HAVE_DLOPEN)
 698   endif()
 699
 700   # so, should we use plug-ins?
 701   if(WIN32 OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 702     if(NOT VMD_QUIETLY)
 703       MESSAGE(STATUS "Using dynamic plugins (e.g VMD-supported file formats)")
 704     endif()
 705     if(NOT GMX_VMD_PLUGIN_PATH)
 706       find_package(VMD)
 707     endif()
 708     set(GMX_USE_PLUGINS ON)
 709     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 710     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 711   else()
 712     set(PKG_DL_LIBS)
 713   endif()
 714 endif()
 715 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 716
 717 # Link real-time library for POSIX timers. The check for clock_gettime
 718 # confirms the linkability of rt.
 719 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 720     list(APPEND GMX_EXTRA_LIBRARIES rt)
 721 endif()
 722
 723 # Math and thread libraries must often come after all others when linking...
 724 if (HAVE_LIBM)
 725     list(APPEND GMX_PUBLIC_LIBRARIES m)
 726 endif()
 727
 728 option(GMX_NACL "Configure for Native Client builds" OFF)
 729 if (GMX_NACL)
 730   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 731   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 732   # TODO: Is this still necessary with the check for its presence?
 733   set(GMX_USE_NICE 0)
 734   set(GMX_NO_RENAME 1)
 735 endif()
 736 mark_as_advanced(GMX_NACL)
 737
 738 if(GMX_FAHCORE)
 739   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 740       "Path to swindirect.h")
 741   include_directories(${COREWRAP_INCLUDE_DIR})
 742 endif()
 743
 744 # Value of GMX_BUILD_HELP=AUTO tries to generate things, but will only
 745 # produce warnings if that fails.
 746 set(build_help_default AUTO)
 747 if (SOURCE_IS_SOURCE_DISTRIBUTION OR CMAKE_CROSSCOMPILING)
 748     set(build_help_default OFF)
 749 endif()
 750 gmx_option_trivalue(GMX_BUILD_HELP "Build completions automatically (requires that compiled binaries can be executed on the build host) and install man pages if built (requires building the 'man' target manually)" ${build_help_default})
 751 mark_as_advanced(GMX_BUILD_HELP)
 752 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND BUILD_IS_INSOURCE)
 753     message(FATAL_ERROR
 754         "Rebuilding shell completions or man pages is not supported for "
 755         "in-source builds from a source distribution. "
 756         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 757 endif()
 758
 759 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 760 # these are set after everything else
 761 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 762     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 763     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 764     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 765     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 766 else()
 767     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 768     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 769     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 770     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 771     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 772     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 773     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 774     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 775     message("CMAKE_SHARED_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 776 endif()
 777
 778 if(NOT GMX_OPENMP)
 779     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 780     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 781     unset(OpenMP_C_FLAGS CACHE)
 782     unset(OpenMP_CXX_FLAGS CACHE)
 783 else()
 784     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 785     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 786 endif()
 787
 788 ########################################################################
 789 # Specify install locations
 790 ########################################################################
 791 # Use GNUInstallDirs to set paths on multiarch systems.
 792 include(GNUInstallDirs)
 793
 794 # Customization for the installation tree paths.
 795 set(GMX_LIB_INSTALL_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING
 796     "Library installation directory (default: ${CMAKE_INSTALL_LIBDIR})")
 797 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 798     "Data installation directory under share/ (default: gromacs)")
 799 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 800
 801 # These variables are used internally to provide a central location for
 802 # customizing the install locations.
 803 set(LIB_INSTALL_DIR       ${GMX_LIB_INSTALL_DIR})
 804 set(BIN_INSTALL_DIR       bin)
 805 # This variable also gets written into config.h for use in finding the data
 806 # directories.
 807 set(DATA_INSTALL_DIR      share/${GMX_DATA_INSTALL_DIR})
 808 set(MAN_INSTALL_DIR       share/man)
 809 # If the nesting level wrt. the installation root is changed,
 810 # gromacs-config.cmake.cmakein needs to be adapted.
 811 set(CMAKE_INSTALL_DIR     share/cmake)
 812 # TODO: Make GMXRC adapt if this is changed
 813 set(PKGCONFIG_INSTALL_DIR ${LIB_INSTALL_DIR}/pkgconfig)
 814 set(OCL_INSTALL_DIR       ${DATA_INSTALL_DIR}/opencl)
 815 set(INCL_INSTALL_DIR      include)
 816
 817 list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${INCL_INSTALL_DIR})
 818
 819 # Binary and library suffix options
 820 include(gmxManageSuffixes)
 821
 822 ################################################################
 823 # Shared library load path settings
 824 ################################################################
 825 if(NOT GMX_BUILD_SHARED_EXE)
 826     # No rpath
 827     set(CMAKE_SKIP_RPATH TRUE)
 828     set(CMAKE_EXE_LINK_DYNAMIC_C_FLAGS) # remove -Wl,-Bdynamic
 829     set(CMAKE_EXE_LINK_DYNAMIC_CXX_FLAGS)
 830 else()
 831     # The build folder always has bin/ and lib/; if we are also going to
 832     # install to lib/, then the installation RPATH works also in the build
 833     # tree.  This makes installation slightly faster (no need to rewrite the
 834     # RPATHs), and makes the binaries in the build tree relocatable.
 835     if(GMX_LIB_INSTALL_DIR STREQUAL "lib")
 836         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 837     endif()
 838     # Set the RPATH as relative to the executable location to make the
 839     # binaries relocatable.
 840     if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Assume OS X >=10.5
 841         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${GMX_LIB_INSTALL_DIR}")
 842     else()
 843         set(CMAKE_INSTALL_RPATH "@executable_path/../${GMX_LIB_INSTALL_DIR}")
 844     endif()
 845     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 846     set(CMAKE_MACOSX_RPATH 1)
 847 endif()
 848
 849 #COPYING file: Only necessary for binary distributions.
 850 #Simpler to always install.
 851 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 852
 853 if (GMX_BUILD_FOR_COVERAGE)
 854     # Code heavy with asserts makes conditional coverage close to useless metric,
 855     # as by design most of the false branches are impossible to trigger in
 856     # correctly functioning code.  And the benefit of testing those that could
 857     # be triggered by using an API against its specification isn't usually
 858     # worth the effort.
 859     add_definitions(-DNDEBUG -DGMX_DISABLE_ASSERTS)
 860 endif()
 861
 862 if (BUILD_TESTING)
 863     include(tests/CheckTarget.cmake)
 864 endif()
 865
 866 if (NOT GMX_BUILD_MDRUN_ONLY)
 867     add_subdirectory(docs)
 868     add_subdirectory(share)
 869     add_subdirectory(scripts)
 870 endif()
 871 add_subdirectory(src)
 872
 873 if (BUILD_TESTING)
 874     add_subdirectory(tests)
 875 endif()
 876
 877 gmx_cpack_write_config()
 878
 879 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 880 # Don't bother the user after the first configure pass.
 881 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 882     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 883 endif()
 884 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 885
 886 #######################
 887 ## uninstall target
 888 #######################
 889 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 890                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 891                   IMMEDIATE @ONLY)
 892 ###########################
 893 ADD_CUSTOM_TARGET(uninstall
 894                   "${CMAKE_COMMAND}" -P
 895                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 896 ###########################
 897 set_directory_properties(PROPERTIES
 898             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")