CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8)
   2 # Keep CMake suitably quiet on Cygwin
   3 set(CMAKE_LEGACY_CYGWIN_WIN32 0) # Remove when CMake >= 2.8.4 is required
   4
   5 # Allows CPack to act differently for normal tools and mdrun (e.g. because of MPI)
   6 set(CPACK_COMPONENT_GROUP_TOOLS_DESCRIPTION "All GROMACS executable tools")
   7 set(CPACK_COMPONENT_GROUP_MDRUN_DESCRIPTION "GROMACS executable for running simulations")
   8
   9 # override bugs on OS X where Cmake picks gcc (GNU) for C instead of system default cc (Clang).
  10 if(APPLE)
  11     set(CMAKE_C_COMPILER_INIT "cc")
  12 endif(APPLE)
  13
  14 project(Gromacs)
  15 include(Dart)
  16 mark_as_advanced(DART_ROOT)
  17
  18 # PROJECT_VERSION should have the following structure:
  19 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  20 #
  21 # The "-dev" suffix is important to keep because it makes possible to distinguish
  22 # between a build from official release and a build from git release branch on a
  23 # machine with no git.
  24 #
  25 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  26 set(PROJECT_VERSION "4.6-dev")
  27 set(CUSTOM_VERSION_STRING ""
  28     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  29 mark_as_advanced(CUSTOM_VERSION_STRING)
  30 if (CUSTOM_VERSION_STRING)
  31     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  32 endif (CUSTOM_VERSION_STRING)
  33 set(SOVERSION 6)
  34 # It is a bit irritating, but this has to be set separately for now!
  35 SET(CPACK_PACKAGE_VERSION_MAJOR "4")
  36 SET(CPACK_PACKAGE_VERSION_MINOR "6")
  37 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  38
  39
  40 # Cmake modules/macros are in a subdirectory to keep this file cleaner
  41 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  42
  43 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  44 set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  45 endif()
  46
  47 if(NOT CMAKE_BUILD_TYPE)
  48     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
  49 endif(NOT CMAKE_BUILD_TYPE)
  50
  51 enable_language(C)
  52
  53 set(GMX_USE_RELATIVE_INSTALL_PATH OFF CACHE STRING "Use relative paths not absolute paths for cmake install. Has only an effect on cpack.")
  54 mark_as_advanced(GMX_USE_RELATIVE_INSTALL_PATH)
  55
  56 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
  57 set(CPACK_PACKAGE_VENDOR "gromacs.org")
  58 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
  59 if (NOT GMX_USE_RELATIVE_INSTALL_PATH)
  60     set(CPACK_SET_DESTDIR "ON")
  61 endif()
  62 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
  63 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
  64 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/admin/InstallLicense.txt")
  65 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
  66 set(CPACK_SOURCE_IGNORE_FILES ".isreposource;.git;.gitignore")
  67 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
  68 SET(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/man;man")
  69
  70 #must come after all cpack settings!
  71 include(CPack)
  72
  73 ########################################################################
  74 # Check and warn if cache generated on a different host is being reused
  75 ########################################################################
  76 if(CMAKE_HOST_UNIX)
  77     execute_process(COMMAND hostname
  78                     OUTPUT_VARIABLE TMP_HOSTNAME
  79                     OUTPUT_STRIP_TRAILING_WHITESPACE)
  80     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
  81         message(WARNING "
  82             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
  83             is being reused! This could lead to inconsitencies; therefore, it is
  84             recommended to regenerate the cache!")
  85     endif()
  86     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
  87             "Hostname of the machine where the cache was generated.")
  88 endif()
  89
  90 ########################################################################
  91 # Fix stupid flags on Windows
  92 ########################################################################
  93 SET(SHARED_LIBS_DEFAULT ON)
  94 IF( WIN32 AND NOT CYGWIN)
  95   option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static system libraries (MT instead of MD)!" ON)
  96   mark_as_advanced(GMX_PREFER_STATIC_LIBS)
  97   SET(SHARED_LIBS_DEFAULT OFF)  #is currently not working on Windows
  98
  99   IF (GMX_PREFER_STATIC_LIBS)
 100     #Only setting Debug and Release flags. Others configurations current not used.
 101     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
 102     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
 103     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
 104     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
 105     STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE})
 106     SET(CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE} CACHE STRING "" FORCE)
 107     STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 108     SET(CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG} CACHE STRING "" FORCE)
 109   ENDIF()
 110
 111   #Workaround for cmake bug 13174. Replace deprecated options.
 112   IF( CMAKE_C_COMPILER_ID MATCHES "Intel" )
 113     STRING(REPLACE /GZ /RTC1 CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
 114     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
 115   ENDIF()
 116   IF( CMAKE_CXX_COMPILER_ID MATCHES "Intel" )
 117     STRING(REPLACE /GZ /RTC1 CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 118     STRING(REPLACE /GX /EHsc CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 119     SET(CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG} CACHE STRING "" FORCE)
 120
 121     STRING(REPLACE /GX /EHsc CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE})
 122     SET(CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE} CACHE STRING "" FORCE)
 123   ENDIF()
 124 ENDIF()
 125
 126 ########################################################################
 127 # User input options                                                   #
 128 ########################################################################
 129 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 130 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 131 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 132 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 133 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 134 option(GMX_POWERPC_INVSQRT "Use PowerPC hardware 1/sqrt" OFF)
 135 mark_as_advanced(GMX_POWERPC_INVSQRT)
 136 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 137 mark_as_advanced(GMX_FAHCORE)
 138 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library (rerun cmake after changing to see relevant options)" OFF)
 139
 140 include(gmxDetectAcceleration)
 141 if(NOT DEFINED GMX_ACCELERATION)
 142     if(CMAKE_CROSSCOMPILING)
 143         set(GMX_SUGGESTED_ACCELERATION "None")
 144     else(CMAKE_CROSSCOMPILING)
 145         gmx_detect_acceleration(GMX_SUGGESTED_ACCELERATION)
 146     endif(CMAKE_CROSSCOMPILING)
 147 endif(NOT DEFINED GMX_ACCELERATION)
 148
 149 set(GMX_ACCELERATION "@GMX_SUGGESTED_ACCELERATION@"
 150     CACHE STRING "Accelerated kernels. Pick one of: None, SSE2, SSE4.1, AVX_128_FMA, AVX_256, BlueGene, Power6, Fortran")
 151
 152 set(GMX_FFT_LIBRARY "fftw3"
 153     CACHE STRING "FFT library choices: fftw3,mkl,fftpack[built-in]")
 154 option(GMX_DISABLE_FFTW_MEASURE
 155        "Do not optimize FFTW setups (not needed with SSE)" OFF)
 156 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 157 set(GMX_QMMM_PROGRAM "none"
 158     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
 159 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 160 mark_as_advanced(GMX_BROKEN_CALLOC)
 161 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
 162 mark_as_advanced(GMX_MPI_IN_PLACE)
 163 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 164 mark_as_advanced(GMX_LOAD_PLUGINS)
 165
 166 option(GMX_OPENMP "Enable OpenMP-based mutithreading. " ON)
 167
 168 option(USE_VERSION_H "Generate development version string/information" ON)
 169 mark_as_advanced(USE_VERSION_H)
 170
 171 option(GMX_DEFAULT_SUFFIX "Use default suffixes for GROMACS binaries and libs (_d for double, _mpi for MPI; rerun cmake after changing to see relevant options)" ON)
 172
 173 if(UNIX AND NOT APPLE)
 174     option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer \".a\" static archives (NOTE: this is enabled only for UNIX (excluding APPLE) platforms but it might not always work!" OFF)
 175     mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 176 endif()
 177
 178
 179 ######################################################################
 180 # compiler tests
 181 # these need ot be done early (before further tests).
 182 #####################################################################
 183
 184 # cmake/Check{C,CXX}CompilerFlag.cmake are lifted from CMake git next
 185 # branch (proposed for v2.8.9) to be able to detect invalid options
 186 # with the Intel Compilers.
 187 # Remove these files from the source tree when a CMake version that
 188 # includes the features in question becomes required.
 189 include(CheckCCompilerFlag)
 190 include(CheckCXXCompilerFlag)
 191
 192 # OpenMP check must come before other CFLAGS!
 193 if(GMX_OPENMP)
 194     find_package(OpenMP)
 195     if(OPENMP_FOUND)
 196         #- only set linker flag, if user didn't set them manual
 197         #- cmake on windows doesn't support linker flags passed to target_link_libraries
 198         #  (cmake treats /openmp as \openmp library file) and no openmp linker flags are needed
 199         if(NOT (WIN32 AND NOT CYGWIN))
 200             if(CMAKE_COMPILER_IS_GNUCC AND GMX_PREFER_STATIC_OPENMP)
 201                 set(OpenMP_LINKER_FLAGS "-Wl,-static -lgomp -lrt -Wl,-Bdynamic -lpthread")
 202                 set(OpenMP_SHARED_LINKER_FLAGS "")
 203             else()
 204                 if(NOT DEFINED OpenMP_LINKER_FLAGS)
 205                     set(OpenMP_LINKER_FLAGS "${OpenMP_C_FLAGS}")
 206                 endif()
 207                 if(NOT DEFINED OpenMP_SHARED_LINKER_FLAGS)
 208                     set(OpenMP_SHARED_LINKER_FLAGS "${OpenMP_C_FLAGS}")
 209                 endif()
 210             endif()
 211         endif()
 212     else(OPENMP_FOUND)
 213         message(WARNING
 214                 "Compiler not supporting OpenMP. This might hurt your performance a lot, "
 215                 "in particular with GPUs. Try using a different compiler (Intel is good on x86) "
 216                 "if you can - for now we are proceeding by turning off OpenMP.")
 217         set(GMX_OPENMP OFF CACHE STRING "Compiler does not support OpenMP." FORCE)
 218     endif(OPENMP_FOUND)
 219 endif()
 220
 221
 222 include(gmxCFlags)
 223 gmx_c_flags()
 224
 225 ########################################################################
 226 # Set up binary and library suffixing
 227 ########################################################################
 228 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 229 set(GMX_LIBS_SUFFIX ""
 230   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 231 if (GMX_DEFAULT_SUFFIX)
 232   set(GMX_BINARY_SUFFIX "")
 233   set(GMX_LIBS_SUFFIX "")
 234   if (GMX_MPI)
 235     set(GMX_BINARY_SUFFIX "_mpi")
 236     set(GMX_LIBS_SUFFIX "_mpi")
 237   endif(GMX_MPI)
 238   if (GMX_DOUBLE)
 239     set (GMX_BINARY_SUFFIX "${GMX_BINARY_SUFFIX}_d")
 240     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
 241   endif(GMX_DOUBLE)
 242   if (GMX_OPENMM)
 243     set (GMX_BINARY_SUFFIX "-openmm")
 244     set (GMX_LIBS_SUFFIX "_openmm")
 245   endif(GMX_OPENMM)
 246   mark_as_advanced(FORCE GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 247   if (NOT SUFFIX_QUIETLY)
 248     message(STATUS "Using default binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 249     message(STATUS "Using default library suffix: \"${GMX_LIBS_SUFFIX}\"")
 250   endif (NOT SUFFIX_QUIETLY)
 251 else(GMX_DEFAULT_SUFFIX)
 252   mark_as_advanced(CLEAR GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 253   if (NOT SUFFIX_QUIETLY)
 254     message(STATUS "Using manually set binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 255     message(STATUS "Using manually set library suffix: \"${GMX_LIBS_SUFFIX}\"")
 256   endif (NOT SUFFIX_QUIETLY)
 257 endif(GMX_DEFAULT_SUFFIX)
 258 set(SUFFIX_QUIETLY TRUE CACHE INTERNAL "")
 259
 260 set(PKG_CFLAGS "")
 261 if(GMX_DOUBLE)
 262     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 263 endif(GMX_DOUBLE)
 264 if(GMX_SOFTWARE_INVSQRT)
 265   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 266 endif(GMX_SOFTWARE_INVSQRT)
 267 if(GMX_POWERPC_INVSQRT)
 268   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_POWERPC_INVSQRT")
 269 endif(GMX_POWERPC_INVSQRT)
 270
 271 ########################################################################
 272 #Process MPI settings
 273 ########################################################################
 274 include(gmxManageMPI)
 275
 276 #######################################################################
 277 # Check for options incompatible with OpenMM build                    #
 278 #######################################################################
 279 if(GMX_OPENMM)
 280     # we'll use the built-in fft to avoid unnecessary dependencies
 281     string(TOUPPER ${GMX_FFT_LIBRARY} GMX_FFT_LIBRARY)
 282     if(NOT ${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 283         message(STATUS "No external FFT libraries needed for the OpenMM build, switching to fftpack!")
 284         set(GMX_FFT_LIBRARY "fftpack" CACHE STRING
 285                 "No external FFT libraries needed for the OpenMM build, switching to  fftpack!" FORCE)
 286     endif()
 287     if(GMX_MPI)
 288         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
 289     endif(GMX_MPI)
 290     if(GMX_THREAD_MPI)
 291         message(STATUS "Thread-MPI not compatible with OpenMM, disabled!")
 292         set(GMX_THREAD_MPI OFF CACHE BOOL
 293                 "Thread-MPI not compatible with OpenMM build, disabled!" FORCE)
 294     endif(GMX_THREAD_MPI)
 295     if(GMX_OPENMP)
 296         message(STATUS "OpenMP multithreading not compatible with OpenMM, disabled")
 297         set(GMX_OPENMP OFF CACHE BOOL
 298             "OpenMP multithreading not compatible with OpenMM, disabled!" FORCE)
 299     endif()
 300     if(GMX_SOFTWARE_INVSQRT)
 301         set(GMX_SOFTWARE_INVSQRT OFF CACHE STRING
 302                 "The OpenMM build does not need GROMACS software 1/sqrt!" FORCE)
 303     endif(GMX_SOFTWARE_INVSQRT)
 304     string(TOUPPER ${GMX_ACCELERATION} GMX_ACCELERATION)
 305     if(NOT GMX_ACCELERATION STREQUAL "NONE")
 306         message(STATUS "Switching off CPU-based acceleration, the OpenMM build does not support/need any!")
 307         set(GMX_ACCELERATION "none" CACHE STRING
 308                 "Switching off CPU-based acceleration, the OpenMM build does not support/need any!" FORCE)
 309     endif()
 310     if(GMX_FAHCORE)
 311         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
 312     endif(GMX_FAHCORE)
 313     if(GMX_DOUBLE)
 314         message(FATAL_ERROR  "The OpenMM-build does not support double precision calculations!")
 315     endif()
 316     # mark as advanced the unused variables
 317     mark_as_advanced(FORCE GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 318         GMX_QMMM_PROGRAM GMX_THREAD_MPI GMX_DOUBLE)
 319 else(GMX_OPENMM)
 320      mark_as_advanced(CLEAR GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 321         GMX_QMMM_PROGRAM GMX_THREAD_MPI GMX_DOUBLE)
 322 endif(GMX_OPENMM)
 323
 324
 325
 326
 327 ########################################################################
 328 # Basic system tests (standard libraries, headers, functions, types)   #
 329 ########################################################################
 330 include(CheckIncludeFiles)
 331 check_include_files(string.h     HAVE_STRING_H)
 332 check_include_files(math.h       HAVE_MATH_H)
 333 check_include_files(limits.h     HAVE_LIMITS_H)
 334 check_include_files(memory.h     HAVE_MEMORY_H)
 335 check_include_files(unistd.h     HAVE_UNISTD_H)
 336 check_include_files(direct.h     HAVE_DIRECT_H)
 337 check_include_files(pwd.h        HAVE_PWD_H)
 338 check_include_files(stdint.h     HAVE_STDINT_H)
 339 check_include_files(stdlib.h     HAVE_STDLIB_H)
 340 check_include_files(pthread.h    HAVE_PTHREAD_H)
 341 check_include_files(dirent.h     HAVE_DIRENT_H)
 342 check_include_files(inttypes.h   HAVE_INTTYPES_H)
 343 check_include_files(regex.h      HAVE_REGEX_H)
 344 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 345 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
 346 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 347 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
 348 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
 349 check_include_files(io.h                 HAVE_IO_H)
 350
 351
 352 include(CheckFunctionExists)
 353 check_function_exists(strcasecmp        HAVE_STRCASECMP)
 354 check_function_exists(strdup            HAVE_STRDUP)
 355 check_function_exists(vprintf           HAVE_VPRINTF)
 356 check_function_exists(memcmp            HAVE_MEMCMP)
 357 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 358 check_function_exists(memalign          HAVE_MEMALIGN)
 359 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 360 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 361 check_function_exists(isnan             HAVE_ISNAN)
 362 check_function_exists(_isnan            HAVE__ISNAN)
 363 check_function_exists(fsync             HAVE_FSYNC)
 364 check_function_exists(_fileno           HAVE__FILENO)
 365 check_function_exists(fileno            HAVE_FILENO)
 366 check_function_exists(_commit           HAVE__COMMIT)
 367 check_function_exists(lstat             HAVE_LSTAT)
 368 check_function_exists(sigaction         HAVE_SIGACTION)
 369
 370 include(CheckLibraryExists)
 371 check_library_exists(m sqrt "" HAVE_LIBM)
 372 check_library_exists(m cbrt "" HAVE_CBRT)
 373
 374
 375 include(CheckTypeSize)
 376
 377 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 378 check_type_size("int"           SIZEOF_INT)
 379 check_type_size("long int"      SIZEOF_LONG_INT)
 380 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 381 check_type_size("off_t"         SIZEOF_OFF_T)
 382 check_type_size("void *"        SIZEOF_VOIDP)
 383
 384 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 385     set(GMX_64_BIT TRUE)
 386 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 387     set(GMX_64_BIT FALSE)
 388 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 389
 390 # Check for some basic types that we *need*, so set these to int if they are not present
 391 check_type_size(uid_t uid_t)
 392 if(NOT uid_t)
 393   set(uid_t int)
 394 else(NOT uid_t)
 395   set(uid_t 0)
 396 endif(NOT uid_t)
 397
 398 check_type_size(gid_t gid_t)
 399 if(NOT gid_t)
 400   set(gid_t 1)
 401 else(NOT gid_t)
 402   set(gid_t 0)
 403 endif(NOT gid_t)
 404
 405 check_type_size(size_t size_t)
 406 if(NOT size_t)
 407   set(size_t int)
 408 else(NOT size_t)
 409   set(size_t 0)
 410 endif(NOT size_t)
 411
 412 check_type_size(off_t off_t)
 413 if(NOT off_t)
 414   set(off_t int)
 415 else(NOT off_t)
 416   set(off_t 0)
 417 endif(NOT off_t)
 418
 419 include(TestBigEndian)
 420 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 421
 422
 423
 424
 425 ########################################################################
 426 # Find external packages                                               #
 427 ########################################################################
 428 if(UNIX AND NOT APPLE)
 429     if(GMX_PREFER_STATIC_LIBS)
 430         SET(CMAKE_FIND_LIBRARY_SUFFIXES .a ${CMAKE_FIND_LIBRARY_SUFFIXES})
 431         if(SHARED_LIBS_DEFAULT)
 432             if(BUILD_SHARED_LIBS) #Warn the user about the combination. But don't overwrite the request.
 433                 message(WARNING "Static libraries requested, and shared Gromacs libraries requested.")
 434             elseif(NOT DEFINED BUILD_SHARED_LIBS) #Change default to OFF. Don't warn if it's already off.
 435                 message(WARNING "Static libraries requested, the GROMACS libraries will also be build static (BUILD_SHARED_LIBS=OFF)")
 436                 set(SHARED_LIBS_DEFAULT OFF)
 437             endif()
 438         endif()
 439     endif()
 440 endif()
 441 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI, Windows)" ${SHARED_LIBS_DEFAULT})
 442
 443 option(GMX_XML "Use libxml2 to parse xml files" ON)
 444 if (GMX_XML)
 445   find_package(LibXml2)
 446   set(PKG_XML "")
 447   if(LIBXML2_FOUND)
 448     include_directories(${LIBXML2_INCLUDE_DIR})
 449     set(PKG_XML libxml-2.0)
 450     set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 451     set(HAVE_LIBXML2 1)
 452   endif(LIBXML2_FOUND)
 453 endif(GMX_XML)
 454
 455 option(GMX_GSL "Add support for gsl" OFF)
 456 if (GMX_GSL)
 457   find_package(gsl)
 458   set(PKG_GSL "")
 459   if(GSL_FOUND)
 460     include_directories(${GSL_INCLUDE_DIR})
 461     set(PKG_GSL gsl)
 462     set(HAVE_LIBGSL 1)
 463   endif(GSL_FOUND)
 464 endif (GMX_GSL)
 465
 466 option(GMX_X11 "Use X window system" OFF)
 467 if (GMX_X11)
 468         find_package(X11)
 469         # X11 includes/libraries are only set in the ngmx subdirectory!
 470         if(X11_FOUND)
 471         set(HAVE_X11 1)
 472         endif(X11_FOUND)
 473 endif(GMX_X11)
 474
 475 if(GMX_THREAD_MPI)
 476     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREAD_MPI")
 477     include(ThreadMPI)
 478     set(THREAD_MPI_LIB thread_mpi)
 479     set(GMX_MPI 1)
 480     string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 481 endif(GMX_THREAD_MPI)
 482
 483 if(GMX_OPENMM)
 484     set(CUDA_BUILD_EMULATION OFF)
 485     find_package(CUDA 3.1 REQUIRED)
 486     add_definitions(-DGMX_OPENMM)
 487     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 488         set(CUDA_VERBOSE_BUILD ON)
 489     endif()
 490     find_package(OpenMM)
 491 endif(GMX_OPENMM)
 492
 493
 494 if(APPLE)
 495    find_library(ACCELERATE_FRAMEWORK Accelerate)
 496    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 497 endif(APPLE)
 498
 499 if(CYGWIN)
 500     set(GMX_CYGWIN 1)
 501 endif(CYGWIN)
 502
 503 if(WIN32 AND NOT CYGWIN)
 504     set(GMX_NATIVE_WINDOWS 1)
 505 endif()
 506
 507 # only bother with finding git and using version.h if the source is a git repo
 508 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 509     if(USE_VERSION_H)
 510         # We need at least git v1.5.3 be able to parse git's date output. If not
 511         # found or the version is too small, we can't generate version information.
 512         find_package(Git)
 513
 514         # Find out the git version
 515         if(GIT_FOUND AND NOT GIT_VERSION)
 516           execute_process(COMMAND ${GIT_EXECUTABLE} "--version"
 517             OUTPUT_VARIABLE _exec_out
 518             OUTPUT_STRIP_TRAILING_WHITESPACE)
 519           string(REGEX REPLACE "git version (.*)" "\\1" GIT_VERSION ${_exec_out})
 520           set(GIT_VERSION ${GIT_VERSION} CACHE STRING "Git version")
 521           mark_as_advanced(GIT_VERSION)
 522         endif()
 523
 524         if(NOT GIT_FOUND OR GIT_VERSION VERSION_LESS "1.5.3")
 525           message("No compatible git version found, won't be able to generate proper development version information.")
 526           set(USE_VERSION_H OFF)
 527         endif()
 528     endif()
 529 else()
 530     set(USE_VERSION_H OFF)
 531 endif()
 532
 533 ########################################################################
 534 # Generate development version info for cache
 535 ########################################################################
 536 # set(GEN_VERSION_INFO_INTERNAL "ON")
 537 # include(gmxGenerateVersionString)
 538
 539 ########################################################################
 540 # Our own GROMACS tests
 541 ########################################################################
 542
 543 add_definitions( -DHAVE_CONFIG_H )
 544 include_directories(${CMAKE_BINARY_DIR}/src)
 545 include_directories(${CMAKE_BINARY_DIR}/include)
 546 include_directories(${CMAKE_SOURCE_DIR}/include)
 547
 548 include(gmxTestInlineASM)
 549 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 550
 551 include(gmxSetBuildInformation)
 552 gmx_set_build_information()
 553 if(BUILD_CPU_FEATURES MATCHES "rdtscp")
 554     # The timestep counter headers do not include config.h
 555     add_definitions(-DHAVE_RDTSCP)
 556 endif(BUILD_CPU_FEATURES MATCHES "rdtscp")
 557
 558 include(gmxTestFloatFormat)
 559 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 560                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 561                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 562
 563 include(gmxTestLargeFiles)
 564 gmx_test_large_files(GMX_LARGEFILES)
 565 check_function_exists(fseeko     HAVE_FSEEKO)
 566
 567 include(gmxTestSignal)
 568 gmx_test_sigusr1(HAVE_SIGUSR1)
 569
 570 include(gmxTestInline)
 571 gmx_test_inline(INLINE_KEYWORD)
 572
 573 include(gmxTestRestrict)
 574 gmx_test_inline(RESTRICT_KEYWORD)
 575
 576 include(gmxTestPipes)
 577 gmx_test_pipes(HAVE_PIPES)
 578
 579 include(gmxTestIsfinite)
 580 gmx_test_isfinite(HAVE_ISFINITE)
 581 gmx_test__isfinite(HAVE__ISFINITE)
 582 gmx_test__finite(HAVE__FINITE)
 583
 584 include(gmxTestXDR)
 585 gmx_test_xdr(GMX_SYSTEM_XDR)
 586 if(NOT GMX_SYSTEM_XDR)
 587     set(GMX_INTERNAL_XDR 1)
 588     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 589 endif(NOT GMX_SYSTEM_XDR)
 590
 591 # Process nonbonded accelerated kernels settings
 592 string(TOUPPER ${GMX_ACCELERATION} ${GMX_ACCELERATION})
 593 if(${GMX_ACCELERATION} STREQUAL "NONE")
 594     # nothing to do
 595 elseif(${GMX_ACCELERATION} STREQUAL "SSE2")
 596
 597     GMX_TEST_CFLAG(GNU_SSE2_CFLAG "-msse2" GROMACS_C_FLAGS)
 598     if(NOT GNU_SSE2_CFLAG)
 599         GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" GROMACS_C_FLAGS)
 600     endif(NOT GNU_SSE2_CFLAG)
 601
 602     GMX_TEST_CXXFLAG(GNU_SSE2_CXXFLAG "-msse2" GROMACS_CXX_FLAGS)
 603     if(NOT GNU_SSE2_CXXFLAG)
 604         GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" GROMACS_CXX_FLAGS)
 605     endif(NOT GNU_SSE2_CXXFLAG)
 606
 607     # We dont warn for lacking SSE2 flag support, since that is probably standard today.
 608
 609     # Only test the include after we have tried to add the correct flag for SSE2 support
 610     check_include_file(emmintrin.h  HAVE_EMMINTRIN_H ${GROMACS_C_FLAGS})
 611
 612     if(NOT HAVE_EMMINTRIN_H)
 613         message(FATAL_ERROR "Cannot find emmintrin.h, which is required for SSE2 intrinsics support.")
 614     endif(NOT HAVE_EMMINTRIN_H)
 615
 616     # The user should not be able to set this orthogonally to the acceleration
 617     set(GMX_X86_SSE2 1)
 618     if (NOT ACCELERATION_QUIETLY)
 619       message(STATUS "Enabling SSE2 Gromacs acceleration, and it will help compiler optimization.")
 620     endif()
 621
 622 elseif(${GMX_ACCELERATION} STREQUAL "SSE4.1")
 623
 624     GMX_TEST_CFLAG(GNU_SSE4_CFLAG "-msse4.1" GROMACS_C_FLAGS)
 625     if (NOT GNU_SSE4_CFLAG)
 626         GMX_TEST_CFLAG(MSVC_SSE4_CFLAG "/arch:SSE4.1" GROMACS_C_FLAGS)
 627     endif(NOT GNU_SSE4_CFLAG)
 628     if (NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 629         message(WARNING "No C SSE4.1 flag found. Consider a newer compiler, or disable SSE4.1 for slightly lower performance.")
 630         # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 631         # intrinsics when SSE2 support is enabled, so we try that instead.
 632         GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" GROMACS_C_FLAGS)
 633     endif(NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 634
 635     GMX_TEST_CXXFLAG(GNU_SSE4_CXXFLAG "-msse4.1" GROMACS_CXX_FLAG)
 636     if (NOT GNU_SSE4_CXXFLAG)
 637        GMX_TEST_CXXFLAG(MSVC_SSE4_CXXFLAG "/arch:SSE4.1" GROMACS_CXX_FLAGS)
 638     endif(NOT GNU_SSE4_CXXFLAG)
 639     if (NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 640         message(WARNING "No C++ SSE4.1 flag found. Consider a newer compiler, or disable SSE4.1 for slightly lower performance.")
 641         # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 642         # intrinsics when SSE2 support is enabled, so we try that instead.
 643         GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" GROMACS_CXX_FLAGS)
 644     endif(NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 645
 646     # This must come after we have added the -msse4.1 flag on some platforms.
 647     check_include_file(smmintrin.h  HAVE_SMMINTRIN_H ${GROMACS_C_FLAGS})
 648
 649     if(NOT HAVE_SMMINTRIN_H)
 650         message(FATAL_ERROR "Cannot find smmintrin.h, which is required for SSE4.1 intrinsics support.")
 651     endif(NOT HAVE_SMMINTRIN_H)
 652
 653     # The user should not be able to set this orthogonally to the acceleration
 654     set(GMX_X86_SSE4_1 1)
 655     set(GMX_X86_SSE2   1)
 656     if (NOT ACCELERATION_QUIETLY)
 657       message(STATUS "Enabling SSE4.1 Gromacs acceleration, and it will help compiler optimization.")
 658     endif()
 659
 660 elseif(${GMX_ACCELERATION} STREQUAL "AVX_128_FMA" OR ${GMX_ACCELERATION} STREQUAL "AVX_256")
 661
 662     # Set the AVX compiler flag for both these choices!
 663
 664     GMX_TEST_CFLAG(GNU_AVX_CFLAG "-mavx" GROMACS_C_FLAGS)
 665     if (NOT GNU_AVX_CFLAG)
 666         GMX_TEST_CFLAG(MSVC_AVX_CFLAG "/arch:AVX" GROMACS_C_FLAGS)
 667     endif (NOT GNU_AVX_CFLAG)
 668     if (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 669         message(WARNING "No C AVX flag found. Consider a newer compiler, or disable AVX for much lower performance.")
 670     endif (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 671
 672     GMX_TEST_CXXFLAG(GNU_AVX_CXXFLAG "-mavx" GROMACS_CXX_FLAGS)
 673     if (NOT GNU_AVX_CXXFLAG)
 674        GMX_TEST_CXXFLAG(MSVC_AVX_CXXFLAG "/arch:AVX" GROMACS_CXX_FLAGS)
 675     endif (NOT GNU_AVX_CXXFLAG)
 676     if (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 677        message(WARNING "No C++ AVX flag found. Consider a newer compiler, or disable AVX for much lower performance.")
 678     endif (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 679
 680     # Only test the header after we have tried to add the flag for AVX support
 681     check_include_file(immintrin.h  HAVE_IMMINTRIN_H ${GROMACS_C_FLAGS})
 682
 683     if(NOT HAVE_IMMINTRIN_H)
 684         message(FATAL_ERROR "Cannot find immintrin.h, which is required for AVX intrinsics support. Consider switching compiler.")
 685     endif(NOT HAVE_IMMINTRIN_H)
 686
 687     # AMD says we should include x86intrin.h for FMA support, but MSVC seems to do fine without it, so don't require it.
 688     check_include_file(x86intrin.h HAVE_X86INTRIN_H ${GROMACS_C_FLAGS})
 689
 690     # The user should not be able to set this orthogonally to the acceleration
 691     set(GMX_X86_SSE4_1 1)
 692     set(GMX_X86_SSE2   1)
 693
 694     # But just enable one of the choices internally...
 695     if(${GMX_ACCELERATION} STREQUAL "AVX_128_FMA")
 696         set(GMX_X86_AVX_128_FMA 1)
 697         if (NOT ACCELERATION_QUIETLY)
 698           message(STATUS "Enabling 128-bit AVX Gromacs acceleration (with fused-multiply add), and it will help compiler optimization.")
 699         endif()
 700     else()
 701         # If we are not doing AVX_128, it must be AVX_256...
 702         set(GMX_X86_AVX_256 1)
 703         if (NOT ACCELERATION_QUIETLY)
 704           message(STATUS "Enabling 256-bit AVX Gromacs acceleration, and it will help compiler optimization.")
 705         endif()
 706     endif()
 707
 708 elseif(${GMX_ACCELERATION} STREQUAL "FORTRAN")
 709
 710 #    Fortran is temporarily disabled while we push in nbNxN kernels.
 711 #    We need to fake it a bit here to avoid jenkins build errors!
 712 #    add_definitions(-DGMX_FORTRAN)
 713
 714 elseif(${GMX_ACCELERATION} STREQUAL "BLUEGENE")
 715 # GMX_ACCELERATION=BlueGene should be set in the Toolchain-BlueGene?-???.cmake file
 716     if (NOT ACCELERATION_QUIETLY)
 717       message(STATUS "Configuring for BlueGene")
 718     endif()
 719     set(GMX_BLUEGENE 1)
 720     if (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 721         set(SHARED_LIBS_DEFAULT OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 722         set(BUILD_SHARED_LIBS OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 723     endif (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 724     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on BlueGene" FORCE)
 725     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on BlueGene" FORCE)
 726     set(GMX_X11 OFF CACHE BOOL "X11 not compatible with BlueGene, disabled!" FORCE)
 727     set(GMX_THREAD_MPI OFF CACHE BOOL "Thread-MPI not compatible with BlueGene, disabled!" FORCE)
 728     set(GMX_MPI ON CACHE BOOL "Use MPI on BlueGene" FORCE)
 729 # Access to /etc/passwd is not available on the back end of BlueGene,
 730 # despite being detected by CMake. This can cause linker warnings
 731 # about harmless things in src/gmxlib/string2.h.
 732     set(HAVE_PWD_H OFF)
 733 # The automatic testing for endianness does not work for the BlueGene cross-compiler
 734     set(GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER 1 CACHE INTERNAL "BlueGene has big endian FP byte order (by default)" FORCE)
 735     set(GMX_IEEE754_BIG_ENDIAN_WORD_ORDER 1 CACHE INTERNAL "BlueGene has big endian FP word order (by default)" FORCE)
 736 elseif(${GMX_ACCELERATION} STREQUAL "POWER6")
 737     set(GMX_POWER6 1)
 738     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on Power6" FORCE)
 739     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on Power6" FORCE)
 740 else(${GMX_ACCELERATION} STREQUAL "NONE")
 741     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_ACCELERATION}. Pick one of None, SSE2, SSE4.1, AVX_128_FMA, AVX_256, Fortran, BlueGene, Power6")
 742 endif(${GMX_ACCELERATION} STREQUAL "NONE")
 743 set(ACCELERATION_QUIETLY TRUE CACHE INTERNAL "")
 744
 745 if(GMX_FORTRAN OR GMX_POWER6)
 746     if (GMX_THREAD_MPI)
 747         message(FATAL_ERROR "FORTRAN/POWER6 is incompatible with thread-MPI and only provides a speed-up on certain IBM compilers. Disable FORTRAN (or threads if you really want to use FORTRAN kernels).")
 748     endif(GMX_THREAD_MPI)
 749     enable_language(Fortran)
 750     include(FortranCInterface)
 751     discover_fortran_mangling(prefix isupper suffix extra_under_score found)
 752     if(extra_under_score)
 753         set(extrasuffix "_")
 754     endif(extra_under_score)
 755     if(prefix)
 756       set(prefix "${prefix} ##")
 757     endif(prefix)
 758     if(suffix)
 759       set(suffix "## ${suffix}")
 760       if(extrasuffix)
 761         set(extrasuffix "${suffix}${extrasuffix}")
 762       endif(extrasuffix)
 763     else(suffix)
 764       if(extrasuffix)
 765         # Don't know if this is needed, but it can't hurt
 766         set(extrasuffix "## ${extrasuffix}")
 767       endif(extrasuffix)
 768     endif(suffix)
 769
 770     if(isupper)
 771         set(F77_FUNCDEF   "${prefix} NAME ${suffix}")
 772         set(F77_FUNCDEF_  "${prefix} NAME ${extrasuffix}")
 773     else(isupper)
 774         set(F77_FUNCDEF   "${prefix} name ${suffix}")
 775         set(F77_FUNCDEF_  "${prefix} name ${extrasuffix}")
 776     endif(isupper)
 777 else(GMX_FORTRAN OR GMX_POWER6)
 778         set(F77_FUNCDEF   "name ## _")
 779         set(F77_FUNCDEF_  "name ## _")
 780 endif(GMX_FORTRAN OR GMX_POWER6)
 781
 782 # Process QM/MM Settings
 783 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 784 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 785     set(GMX_QMMM_GAUSSIAN 1)
 786 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 787     set(GMX_QMMM_MOPAC 1)
 788 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 789     set(GMX_QMMM_GAMESS 1)
 790 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 791     set(GMX_QMMM_ORCA 1)
 792 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 793     # nothing to do
 794 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 795     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 796 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 797
 798 # Process FFT library settings - if not OpenMM build
 799 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 800 set(PKG_FFT "")
 801 set(PKG_FFT_LIBS "")
 802 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 803     if(GMX_DOUBLE)
 804         find_package(FFTW 3 COMPONENTS fftw)
 805     else(GMX_DOUBLE)
 806         find_package(FFTW 3 COMPONENTS fftwf)
 807     endif(GMX_DOUBLE)
 808     if(NOT FFTW_FOUND)
 809       MESSAGE(FATAL_ERROR "Cannot find FFTW3 (with correct precision - libfftw3f for single precision GROMACS or libfftw3 for double precision GROMACS). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 810     endif(NOT FFTW_FOUND)
 811     include_directories(${FFTW_INCLUDE_DIRS})
 812     set(FFT_LIBRARIES ${FFTW_LIBRARIES})
 813     set(PKG_FFT "${FFTW_PKG}")
 814
 815     set(GMX_FFT_FFTW3 1)
 816
 817     if (${GMX_ACCELERATION} STREQUAL "SSE" AND NOT FFTW_HAVE_SSE)
 818       message(WARNING "The fftw library found is compiled without SSE support, which makes it slow. Consider recompiling it or contact your admin")
 819     endif (${GMX_ACCELERATION} STREQUAL "SSE" AND NOT FFTW_HAVE_SSE)
 820
 821 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 822 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 823     find_package(MKL REQUIRED)
 824     include_directories(${MKL_INCLUDE_DIR})
 825     set(FFT_LIBRARIES ${MKL_LIBRARIES})
 826     set(PKG_FFT_LIBS ${MKL_LIBRARIES})
 827
 828     set(GMX_FFT_MKL 1)
 829     set(HAVE_MKL 1)
 830
 831 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 832 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 833 #    set(GMX_FFT_ACML 1)
 834 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 835     MESSAGE(STATUS "Using internal FFT library - fftpack")
 836     set(GMX_FFT_FFTPACK 1)
 837 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 838     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, mkl, fftpack")
 839 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 840
 841 set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 842 set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 843 # MKL has BLAS/LAPACK routines
 844 if(NOT HAVE_MKL AND NOT ACCELERATE_FRAMEWORK)
 845   if(GMX_EXTERNAL_BLAS)
 846     if (GMX_BLAS_USER)
 847         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_BLAS_USER})
 848     else(GMX_BLAS_USER)
 849         set(BLAS_FIND_QUIETLY ON)
 850         find_package(BLAS)
 851         if (BLAS_FOUND)
 852           list(APPEND GMX_EXTRA_LIBRARIES ${BLAS_LIBRARIES})
 853         else()
 854           MESSAGE(STATUS "Using internal BLAS library")
 855           set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external BLAS instead of built-in" FORCE)
 856         endif()
 857     endif(GMX_BLAS_USER)
 858   endif(GMX_EXTERNAL_BLAS)
 859   if(GMX_EXTERNAL_LAPACK)
 860     if (GMX_LAPACK_USER)
 861         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_LAPACK_USER})
 862     else(GMX_LAPACK_USER)
 863         set(LAPACK_FIND_QUIETLY ON)
 864         find_package(LAPACK)
 865         if (LAPACK_FOUND)
 866           list(APPEND GMX_EXTRA_LIBRARIES ${LAPACK_LIBRARIES})
 867         else()
 868           MESSAGE(STATUS "Using internal LAPACK library")
 869           set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in" FORCE)
 870         endif()
 871     endif(GMX_LAPACK_USER)
 872   endif(GMX_EXTERNAL_LAPACK)
 873 endif()
 874 mark_as_advanced(GMX_EXTERNAL_LAPACK)
 875 mark_as_advanced(GMX_EXTERNAL_BLAS)
 876
 877 set(GMX_USE_PLUGINS OFF CACHE INTERNAL "Whether GROMACS will really try to compile support for VMD plugins")
 878
 879 if(GMX_LOAD_PLUGINS)
 880   if(CYGWIN OR NOT WIN32)
 881     # Native Windows does not have, nor need dlopen
 882     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 883     include(gmxTestdlopen)
 884     gmx_test_dlopen(HAVE_DLOPEN)
 885   endif()
 886
 887   # so, should we use plug-ins?
 888   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 889     if(NOT VMD_QUIETLY)
 890       MESSAGE(STATUS
 891           "Found the ability to use plug-ins when building shared libaries, "
 892           "so will compile to use plug-ins (e.g. to read VMD-supported file "
 893           "formats).")
 894     endif()
 895     if(NOT GMX_VMD_PLUGIN_PATH)
 896       find_package(VMD)
 897     endif()
 898     set(GMX_USE_PLUGINS ON)
 899     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 900     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 901   else()
 902     set(PKG_DL_LIBS)
 903   endif()
 904 endif(GMX_LOAD_PLUGINS)
 905 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 906
 907 if(EXISTS "${CMAKE_SOURCE_DIR}/admin/.isreposource")
 908     if(NOT CMAKE_CROSSCOMPILING)
 909         option(GMX_BUILD_MANPAGES "Build man pages" ON)
 910     else()
 911         message(STATUS "Building the man pages is not available when "
 912             "cross-compiling the developer version from git")
 913     endif()
 914 else()
 915     #make sure source package contains all man pages
 916     if(NOT EXISTS "${CMAKE_SOURCE_DIR}/man/man1/ngmx.1")
 917         message(FATAL_ERROR "Man pages are missing from source package.")
 918     endif()
 919 endif()
 920 mark_as_advanced(GMX_BUILD_MANPAGES)
 921
 922 # Math and thread libraries must often come after all others when linking...
 923 if(HAVE_LIBM)
 924     list(APPEND GMX_EXTRA_LIBRARIES m)
 925 endif(HAVE_LIBM)
 926
 927 if(GMX_FAHCORE)
 928   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 929       "Path to swindirect.h")
 930   include_directories(${COREWRAP_INCLUDE_DIR})
 931 endif(GMX_FAHCORE)
 932
 933 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 934 # these are set after everything else
 935 if (NOT DEFINED GROMACS_C_FLAGS_SET)
 936     set(GROMACS_C_FLAGS_SET true CACHE INTERNAL "Whether to reset the C flags"
 937         FORCE)
 938     set(CMAKE_C_FLAGS "${GROMACS_C_FLAGS} ${CMAKE_C_FLAGS}" CACHE STRING
 939         "Flags used by the compiler during all build types" FORCE)
 940     set(CMAKE_CXX_FLAGS "${GROMACS_CXX_FLAGS} ${CMAKE_CXX_FLAGS}" CACHE STRING
 941         "Flags used by the compiler during all build types" FORCE)
 942     set(CMAKE_EXE_LINKER_FLAGS
 943         "${GROMACS_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}"
 944         CACHE STRING "Linker flags for creating executables" FORCE)
 945     set(CMAKE_SHARED_LINKER_FLAGS
 946         "${GROMACS_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}"
 947         CACHE STRING "Linker flags for creating shared libraries" FORCE)
 948 endif (NOT DEFINED GROMACS_C_FLAGS_SET)
 949
 950 ######################################
 951 # Output compiler and CFLAGS used
 952 ######################################
 953 execute_process(COMMAND ${CMAKE_C_COMPILER} --version RESULT_VARIABLE TMP_RESULT OUTPUT_VARIABLE CC_VERSION ERROR_VARIABLE CC_VERSION)
 954 #try executing just the compiler command if that failed...
 955 if(TMP_RESULT)
 956     execute_process(COMMAND ${CMAKE_C_COMPILER} RESULT_VARIABLE TMP_RESULT OUTPUT_VARIABLE CC_VERSION ERROR_VARIABLE CC_VERSION)
 957 endif()
 958 string(LENGTH "${CC_VERSION}" len)
 959 if(len)
 960     string(REGEX MATCH "[^\n]*" CC_VERSION "${CC_VERSION}")
 961 endif()
 962
 963 set(BUILD_COMPILER "@CMAKE_C_COMPILER@ @CMAKE_C_COMPILER_ID@ @CC_VERSION@")
 964 set(BUILD_CFLAGS "@CMAKE_C_FLAGS@")
 965 if(CMAKE_BUILD_TYPE STREQUAL "Debug")
 966     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_DEBUG@")
 967 elseif(CMAKE_BUILD_TYPE STREQUAL "Release")
 968     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_RELEASE@")
 969 elseif(CMAKE_BUILD_TYPE STREQUAL "MinSizeRel")
 970     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_MINSIZEREL@")
 971 elseif(CMAKE_BUILD_TYPE STREQUAL "RelWithDebInfo")
 972     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_RELWITHDEBINFO@")
 973 endif()
 974
 975
 976 ########################################################################
 977 # Specify install locations and which subdirectories to process        #
 978 ########################################################################
 979 if (GMX_USE_RELATIVE_INSTALL_PATH)
 980     set(GMX_INSTALL_PREFIX "" CACHE STRING "Prefix gets appended to CMAKE_INSTALL_PREFIX. For cpack it sets the root folder of the archive.")
 981     mark_as_advanced(GMX_INSTALL_PREFIX)
 982 else()
 983     set(GMX_INSTALL_PREFIX "${CMAKE_INSTALL_PREFIX}/")
 984 endif()
 985
 986 if ( NOT DEFINED GMXLIB )
 987     set(GMXLIB lib)
 988 endif()
 989 set(LIB_INSTALL_DIR "${GMX_INSTALL_PREFIX}${GMXLIB}")
 990 set(BIN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}bin)
 991 set(DATA_INSTALL_DIR ${GMX_INSTALL_PREFIX}share/gromacs)
 992 set(MAN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}share/man)
 993 set(INCL_INSTALL_DIR ${GMX_INSTALL_PREFIX}include)
 994
 995 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
 996
 997 ##################################################################
 998 # Shared library settings - Darwin uses INSTALL_NAME_DIR instead!
 999 ##################################################################
1000 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
1001     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
1002     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
1003     set(CMAKE_INSTALL_RPATH "\\\$ORIGIN/../${GMXLIB}")
1004     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
1005 endif()
1006
1007 add_subdirectory(share)
1008 add_subdirectory(include)
1009 add_subdirectory(src)
1010 add_subdirectory(scripts)
1011
1012 #######################
1013 ## uninstall target
1014 #######################
1015     CONFIGURE_FILE(
1016                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
1017                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
1018                    IMMEDIATE @ONLY)
1019 ###########################
1020 ADD_CUSTOM_TARGET(uninstall
1021                   "${CMAKE_COMMAND}" -P
1022                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
1023 ###########################
1024
1025
1026 ########################################################################
1027 # Tests                                                                #
1028 ########################################################################
1029
1030 include(CTest)
1031 mark_as_advanced(BUILD_TESTING)
1032 IF(BUILD_TESTING)
1033         enable_testing()
1034         add_subdirectory(tests)
1035 ENDIF()
1036