CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8)
   2 # Keep CMake suitably quiet on Cygwin
   3 set(CMAKE_LEGACY_CYGWIN_WIN32 0) # Remove when CMake >= 2.8.4 is required
   4
   5 # override bugs on OS X where Cmake picks gcc (GNU) for C instead of system default cc (Clang).
   6 if(APPLE)
   7     set(CMAKE_C_COMPILER_INIT "cc")
   8 endif(APPLE)
   9
  10 project(Gromacs)
  11 include(Dart)
  12 mark_as_advanced(DART_ROOT)
  13
  14 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  15 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  16 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  17
  18 # PROJECT_VERSION should have the following structure:
  19 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  20 #
  21 # The "-dev" suffix is important to keep because it makes possible to distinguish
  22 # between a build from official release and a build from git release branch on a
  23 # machine with no git.
  24 #
  25 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  26 set(PROJECT_VERSION "5.0-dev")
  27 set(CUSTOM_VERSION_STRING ""
  28     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  29 mark_as_advanced(CUSTOM_VERSION_STRING)
  30 if (CUSTOM_VERSION_STRING)
  31     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  32 endif (CUSTOM_VERSION_STRING)
  33 set(SOVERSION 6)
  34 # It is a bit irritating, but this has to be set separately for now!
  35 SET(CPACK_PACKAGE_VERSION_MAJOR "5")
  36 SET(CPACK_PACKAGE_VERSION_MINOR "0")
  37 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  38
  39 # The numerical gromacs version. It is 40600 for 4.6.0.
  40 # The #define GMX_VERSION in gmx_header_config_h is set to this value.
  41 math(EXPR NUM_VERSION
  42     "${CPACK_PACKAGE_VERSION_MAJOR}*10000 + ${CPACK_PACKAGE_VERSION_MINOR}*100")
  43 if(CPACK_PACKAGE_VERSION_PATCH)
  44     math(EXPR NUM_VERSION
  45          "${NUM_VERSION} + ${CPACK_PACKAGE_VERSION_PATCH}")
  46 endif()
  47
  48 # The API version tracks the numerical Gromacs version (for now).
  49 # It is potentially different from the Gromacs version in the future, if
  50 # the programs/libraries diverge from the presumably more stable API.
  51 # The #define GMX_API_VERSION in version.h is set to this value to
  52 # provide backward compatibility of software written against the Gromacs API.
  53 set(API_VERSION ${NUM_VERSION})
  54
  55 # Cmake modules/macros are in a subdirectory to keep this file cleaner
  56 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  57
  58 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  59 set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  60 endif()
  61
  62 if (GMX_USE_RELATIVE_INSTALL_PATH)
  63     set(GMX_INSTALL_PREFIX "" CACHE STRING "Prefix gets appended to CMAKE_INSTALL_PREFIX. For cpack it sets the root folder of the archive.")
  64     mark_as_advanced(GMX_INSTALL_PREFIX)
  65 else()
  66     set(GMX_INSTALL_PREFIX "${CMAKE_INSTALL_PREFIX}/")
  67 endif()
  68
  69 if(NOT CMAKE_BUILD_TYPE)
  70     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
  71 endif(NOT CMAKE_BUILD_TYPE)
  72
  73 enable_language(C)
  74 enable_language(CXX)
  75
  76 set(GMX_USE_RELATIVE_INSTALL_PATH OFF CACHE STRING "Use relative paths not absolute paths for cmake install. Has only an effect on cpack.")
  77 mark_as_advanced(GMX_USE_RELATIVE_INSTALL_PATH)
  78
  79 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
  80 set(CPACK_PACKAGE_VENDOR "gromacs.org")
  81 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
  82 if (NOT GMX_USE_RELATIVE_INSTALL_PATH)
  83     set(CPACK_SET_DESTDIR "ON")
  84 endif()
  85 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
  86 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
  87 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/COPYING")
  88 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
  89 set(CPACK_SOURCE_IGNORE_FILES ".isreposource;.git;.gitignore")
  90 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
  91 SET(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/man;man")
  92 set(CPACK_PACKAGE_CONTACT "gmx-users@gromacs.org")
  93
  94 #must come after all cpack settings!
  95 include(CPack)
  96
  97 set(SOURCE_IS_GIT_REPOSITORY OFF)
  98 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
  99     set(SOURCE_IS_GIT_REPOSITORY ON)
 100 endif()
 101
 102 ########################################################################
 103 # Check and warn if cache generated on a different host is being reused
 104 ########################################################################
 105 if(CMAKE_HOST_UNIX)
 106     execute_process(COMMAND hostname
 107                     OUTPUT_VARIABLE TMP_HOSTNAME
 108                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 109     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 110         message(WARNING "
 111             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 112             is being reused! This could lead to inconsitencies; therefore, it is
 113             recommended to regenerate the cache!")
 114     endif()
 115     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 116             "Hostname of the machine where the cache was generated.")
 117 endif()
 118
 119 ########################################################################
 120 # Fix stupid flags on Windows
 121 ########################################################################
 122 SET(SHARED_LIBS_DEFAULT ON)
 123 IF( WIN32 AND NOT CYGWIN)
 124   option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static system libraries (MT instead of MD)!" ON)
 125   mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 126   SET(SHARED_LIBS_DEFAULT OFF)  #is currently not working on Windows
 127   # This makes windows.h not declare min/max as macros that would break
 128   # C++ code using std::min/std::max.
 129   add_definitions(-DNOMINMAX)
 130
 131   IF (GMX_PREFER_STATIC_LIBS)
 132     #Only setting Debug and Release flags. Others configurations current not used.
 133     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
 134     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
 135     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
 136     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
 137     STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE})
 138     SET(CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE} CACHE STRING "" FORCE)
 139     STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 140     SET(CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG} CACHE STRING "" FORCE)
 141   ENDIF()
 142
 143   #Workaround for cmake bug 13174. Replace deprecated options.
 144   IF( CMAKE_C_COMPILER_ID MATCHES "Intel" )
 145     STRING(REPLACE /GZ /RTC1 CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
 146     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
 147   ENDIF()
 148   IF( CMAKE_CXX_COMPILER_ID MATCHES "Intel" )
 149     STRING(REPLACE /GZ /RTC1 CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 150     STRING(REPLACE /GX /EHsc CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 151     SET(CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG} CACHE STRING "" FORCE)
 152
 153     STRING(REPLACE /GX /EHsc CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE})
 154     SET(CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE} CACHE STRING "" FORCE)
 155   ENDIF()
 156 ENDIF()
 157
 158
 159 ########################################################################
 160 # User input options                                                   #
 161 ########################################################################
 162 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 163 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 164 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 165 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 166 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 167 option(GMX_POWERPC_INVSQRT "Use PowerPC hardware 1/sqrt" OFF)
 168 mark_as_advanced(GMX_POWERPC_INVSQRT)
 169 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 170 mark_as_advanced(GMX_FAHCORE)
 171 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library (rerun cmake after changing to see relevant options)" OFF)
 172
 173 include(gmxDetectAcceleration)
 174 if(NOT DEFINED GMX_ACCELERATION)
 175     if(CMAKE_CROSSCOMPILING)
 176         set(GMX_SUGGESTED_ACCELERATION "None")
 177     else(CMAKE_CROSSCOMPILING)
 178         gmx_detect_acceleration(GMX_SUGGESTED_ACCELERATION)
 179     endif(CMAKE_CROSSCOMPILING)
 180 endif(NOT DEFINED GMX_ACCELERATION)
 181
 182 set(GMX_ACCELERATION "@GMX_SUGGESTED_ACCELERATION@"
 183     CACHE STRING "Accelerated kernels. Pick one of: None, SSE2, SSE4.1, AVX_128_FMA, AVX_256, BlueGene, Power6, Fortran")
 184
 185 set(GMX_FFT_LIBRARY "fftw3"
 186     CACHE STRING "FFT library choices: fftw3,mkl,fftpack[built-in]")
 187 option(GMX_DISABLE_FFTW_MEASURE
 188        "Do not optimize FFTW setups (not needed with SSE)" OFF)
 189 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 190 set(GMX_QMMM_PROGRAM "none"
 191     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
 192 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 193 mark_as_advanced(GMX_BROKEN_CALLOC)
 194 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
 195 mark_as_advanced(GMX_MPI_IN_PLACE)
 196 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 197 mark_as_advanced(GMX_LOAD_PLUGINS)
 198
 199 option(GMX_GPU  "Enable GPU acceleration" ON)
 200 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 201
 202 option(GMX_GIT_VERSION_INFO "Generate git version information" ${SOURCE_IS_GIT_REPOSITORY})
 203 mark_as_advanced(GMX_GIT_VERSION_INFO)
 204
 205 option(GMX_DEFAULT_SUFFIX "Use default suffixes for GROMACS binaries and libs (_d for double, _mpi for MPI; rerun cmake after changing to see relevant options)" ON)
 206
 207 if(UNIX)
 208     option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static archives (not available on non-*nix platforms and it will only work if static versions of external dependencies are available and found)!" OFF)
 209     mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 210 endif()
 211
 212 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 213 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 214
 215 ######################################################################
 216 # compiler tests
 217 # these need ot be done early (before further tests).
 218 #####################################################################
 219
 220 # cmake/Check{C,CXX}CompilerFlag.cmake are lifted from CMake git next
 221 # branch (proposed for v2.8.9) to be able to detect invalid options
 222 # with the Intel Compilers.
 223 # Remove these files from the source tree when a CMake version that
 224 # includes the features in question becomes required.
 225 include(CheckCCompilerFlag)
 226 include(CheckCXXCompilerFlag)
 227
 228 # OpenMP check must come before other CFLAGS!
 229 if(GMX_OPENMP)
 230     find_package(OpenMP)
 231     if(OPENMP_FOUND)
 232         #- only set linker flag, if user didn't set them manual
 233         #- cmake on windows doesn't support linker flags passed to target_link_libraries
 234         #  (cmake treats /openmp as \openmp library file) and no openmp linker flags are needed
 235         if(NOT (WIN32 AND NOT CYGWIN))
 236             if(CMAKE_COMPILER_IS_GNUCC AND GMX_PREFER_STATIC_OPENMP)
 237                 set(OpenMP_LINKER_FLAGS "-Wl,-static -lgomp -lrt -Wl,-Bdynamic -lpthread")
 238                 set(OpenMP_SHARED_LINKER_FLAGS "")
 239             else()
 240                 if(NOT DEFINED OpenMP_LINKER_FLAGS)
 241                     set(OpenMP_LINKER_FLAGS "${OpenMP_C_FLAGS}")
 242                 endif()
 243                 if(NOT DEFINED OpenMP_SHARED_LINKER_FLAGS)
 244                     set(OpenMP_SHARED_LINKER_FLAGS "${OpenMP_C_FLAGS}")
 245                 endif()
 246             endif()
 247         endif()
 248     else(OPENMP_FOUND)
 249         message(WARNING
 250                 "Compiler not supporting OpenMP. This might hurt your performance a lot, "
 251                 "in particular with GPUs. Try using a different compiler (Intel is good on x86) "
 252                 "if you can - for now we are proceeding by turning off OpenMP.")
 253         set(GMX_OPENMP OFF CACHE STRING "Compiler does not support OpenMP." FORCE)
 254     endif(OPENMP_FOUND)
 255 endif()
 256
 257
 258 include(gmxCFlags)
 259 gmx_c_flags()
 260
 261 include(gmxGetCompilerVersion)
 262 get_compiler_version()
 263
 264 # gcc 4.4.x is buggy and crashes when compiling some files with O3 and OpenMP on.
 265 # Detect here whether applying a workaround is needed and will apply it later
 266 # on the affected files.
 267 include(gmxGCC44O3BugWorkaround)
 268 gmx_check_gcc44_bug_workaround_needed(GMX_USE_GCC44_BUG_WORKAROUND)
 269
 270 ########################################################################
 271 # Set up binary and library suffixing
 272 ########################################################################
 273 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 274 set(GMX_LIBS_SUFFIX ""
 275   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 276 if (GMX_DEFAULT_SUFFIX)
 277   set(GMX_BINARY_SUFFIX "")
 278   set(GMX_LIBS_SUFFIX "")
 279   if (GMX_MPI)
 280     set(GMX_BINARY_SUFFIX "_mpi")
 281     set(GMX_LIBS_SUFFIX "_mpi")
 282   endif(GMX_MPI)
 283   if (GMX_DOUBLE)
 284     set (GMX_BINARY_SUFFIX "${GMX_BINARY_SUFFIX}_d")
 285     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
 286   endif(GMX_DOUBLE)
 287   if (GMX_OPENMM)
 288     set (GMX_BINARY_SUFFIX "-openmm")
 289     set (GMX_LIBS_SUFFIX "_openmm")
 290   endif(GMX_OPENMM)
 291   mark_as_advanced(FORCE GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 292   if (NOT SUFFIX_QUIETLY)
 293     message(STATUS "Using default binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 294     message(STATUS "Using default library suffix: \"${GMX_LIBS_SUFFIX}\"")
 295   endif (NOT SUFFIX_QUIETLY)
 296 else(GMX_DEFAULT_SUFFIX)
 297   mark_as_advanced(CLEAR GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 298   if (NOT SUFFIX_QUIETLY)
 299     message(STATUS "Using manually set binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 300     message(STATUS "Using manually set library suffix: \"${GMX_LIBS_SUFFIX}\"")
 301   endif (NOT SUFFIX_QUIETLY)
 302 endif(GMX_DEFAULT_SUFFIX)
 303 set(SUFFIX_QUIETLY TRUE CACHE INTERNAL "")
 304
 305 set(PKG_CFLAGS "")
 306 if(GMX_DOUBLE)
 307     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 308 endif(GMX_DOUBLE)
 309 if(GMX_SOFTWARE_INVSQRT)
 310   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 311 endif(GMX_SOFTWARE_INVSQRT)
 312 if(GMX_POWERPC_INVSQRT)
 313   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_POWERPC_INVSQRT")
 314 endif(GMX_POWERPC_INVSQRT)
 315
 316 ########################################################################
 317 #Process MPI settings
 318 ########################################################################
 319 include(gmxManageMPI)
 320
 321 #######################################################################
 322 # Check for options incompatible with OpenMM build                    #
 323 #######################################################################
 324 if(GMX_OPENMM)
 325     # we'll use the built-in fft to avoid unnecessary dependencies
 326     string(TOUPPER ${GMX_FFT_LIBRARY} GMX_FFT_LIBRARY)
 327     if(NOT ${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 328         message(STATUS "No external FFT libraries needed for the OpenMM build, switching to fftpack!")
 329         set(GMX_FFT_LIBRARY "fftpack" CACHE STRING
 330                 "No external FFT libraries needed for the OpenMM build, switching to  fftpack!" FORCE)
 331     endif()
 332     if(GMX_MPI)
 333         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
 334     endif(GMX_MPI)
 335     if(GMX_THREAD_MPI)
 336         message(STATUS "Thread-MPI not compatible with OpenMM, disabled!")
 337         set(GMX_THREAD_MPI OFF CACHE BOOL
 338                 "Thread-MPI not compatible with OpenMM build, disabled!" FORCE)
 339     endif(GMX_THREAD_MPI)
 340     if(GMX_OPENMP)
 341         message(STATUS "OpenMP multithreading not compatible with OpenMM, disabled")
 342         set(GMX_OPENMP OFF CACHE BOOL
 343             "OpenMP multithreading not compatible with OpenMM, disabled!" FORCE)
 344     endif()
 345     if(GMX_SOFTWARE_INVSQRT)
 346         set(GMX_SOFTWARE_INVSQRT OFF CACHE STRING
 347                 "The OpenMM build does not need GROMACS software 1/sqrt!" FORCE)
 348     endif(GMX_SOFTWARE_INVSQRT)
 349     string(TOUPPER ${GMX_ACCELERATION} GMX_ACCELERATION)
 350     if(NOT GMX_ACCELERATION STREQUAL "NONE")
 351         message(STATUS "Switching off CPU-based acceleration, the OpenMM build does not support/need any!")
 352         set(GMX_ACCELERATION "none" CACHE STRING
 353                 "Switching off CPU-based acceleration, the OpenMM build does not support/need any!" FORCE)
 354     endif()
 355     if(GMX_FAHCORE)
 356         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
 357     endif(GMX_FAHCORE)
 358     if(GMX_DOUBLE)
 359         message(FATAL_ERROR  "The OpenMM-build does not support double precision calculations!")
 360     endif()
 361     # mark as advanced the unused variables
 362     mark_as_advanced(FORCE GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 363         GMX_QMMM_PROGRAM GMX_THREAD_MPI GMX_DOUBLE)
 364 else(GMX_OPENMM)
 365      mark_as_advanced(CLEAR GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 366         GMX_QMMM_PROGRAM GMX_THREAD_MPI GMX_DOUBLE)
 367 endif(GMX_OPENMM)
 368
 369
 370 ########################################################################
 371 # Basic system tests (standard libraries, headers, functions, types)   #
 372 ########################################################################
 373 include(CheckIncludeFiles)
 374 include(CheckIncludeFileCXX)
 375 check_include_files(unistd.h     HAVE_UNISTD_H)
 376 check_include_files(pwd.h        HAVE_PWD_H)
 377 check_include_files(pthread.h    HAVE_PTHREAD_H)
 378 check_include_files(dirent.h     HAVE_DIRENT_H)
 379 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 380 check_include_files(io.h                 HAVE_IO_H)
 381 check_include_files(sched.h      HAVE_SCHED_H)
 382
 383 check_include_files(regex.h      HAVE_POSIX_REGEX)
 384 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 385 # TODO: It could be nice to inform the user if no regex support is found,
 386 # as selections won't be fully functional.
 387
 388 include(CheckFunctionExists)
 389 check_function_exists(strdup            HAVE_STRDUP)
 390 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 391 check_function_exists(memalign          HAVE_MEMALIGN)
 392 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 393 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 394 check_function_exists(fsync             HAVE_FSYNC)
 395 check_function_exists(_fileno           HAVE__FILENO)
 396 check_function_exists(fileno            HAVE_FILENO)
 397 check_function_exists(_commit           HAVE__COMMIT)
 398 check_function_exists(lstat             HAVE_LSTAT)
 399 check_function_exists(sigaction         HAVE_SIGACTION)
 400 check_function_exists(sysconf           HAVE_SYSCONF)
 401 check_function_exists(sched_setaffinity HAVE_SCHED_SETAFFINITY)
 402 check_function_exists(sched_getaffinity HAVE_SCHED_GETAFFINITY)
 403 check_function_exists(rsqrt             HAVE_RSQRT)
 404 check_function_exists(rsqrtf            HAVE_RSQRTF)
 405 check_function_exists(sqrtf             HAVE_SQRTF)
 406
 407 include(CheckLibraryExists)
 408 check_library_exists(m sqrt "" HAVE_LIBM)
 409 check_library_exists(m cbrt "" HAVE_CBRT)
 410
 411
 412 include(CheckTypeSize)
 413
 414 check_type_size("int"           SIZEOF_INT)
 415 check_type_size("long int"      SIZEOF_LONG_INT)
 416 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 417 check_type_size("off_t"         SIZEOF_OFF_T)
 418 check_type_size("void *"        SIZEOF_VOIDP)
 419
 420 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 421     set(GMX_64_BIT TRUE)
 422 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 423     set(GMX_64_BIT FALSE)
 424 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 425
 426 include(TestBigEndian)
 427 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 428
 429
 430
 431
 432 ########################################################################
 433 # Find external packages                                               #
 434 ########################################################################
 435 if(UNIX)
 436     if(GMX_PREFER_STATIC_LIBS)
 437         # On Linux .a is the static library suffix, on Mac OS X .lib can also
 438         # be used, so we'll add both to the preference list.
 439         SET(CMAKE_FIND_LIBRARY_SUFFIXES ".lib;.a" ${CMAKE_FIND_LIBRARY_SUFFIXES})
 440         if(SHARED_LIBS_DEFAULT)
 441             if(BUILD_SHARED_LIBS) #Warn the user about the combination. But don't overwrite the request.
 442                 message(WARNING "Static libraries requested, and shared Gromacs libraries requested.")
 443             elseif(NOT DEFINED BUILD_SHARED_LIBS) #Change default to OFF. Don't warn if it's already off.
 444                 message(WARNING "Static libraries requested, the GROMACS libraries will also be build static (BUILD_SHARED_LIBS=OFF)")
 445                 set(SHARED_LIBS_DEFAULT OFF)
 446             endif()
 447         endif()
 448     endif()
 449 endif()
 450 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI, Windows)" ${SHARED_LIBS_DEFAULT})
 451
 452 option(GMX_XML "Use libxml2 to parse xml files" ON)
 453 if (GMX_XML)
 454   find_package(LibXml2)
 455   set(PKG_XML "")
 456   if(LIBXML2_FOUND)
 457     include_directories(${LIBXML2_INCLUDE_DIR})
 458     set(PKG_XML libxml-2.0)
 459     set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 460   endif(LIBXML2_FOUND)
 461 endif(GMX_XML)
 462
 463 option(GMX_GSL "Add support for gsl" OFF)
 464 if (GMX_GSL)
 465   find_package(gsl)
 466   set(PKG_GSL "")
 467   if(GSL_FOUND)
 468     include_directories(${GSL_INCLUDE_DIR})
 469     set(PKG_GSL gsl)
 470     set(HAVE_LIBGSL 1)
 471   endif(GSL_FOUND)
 472 endif (GMX_GSL)
 473
 474 option(GMX_X11 "Use X window system" OFF)
 475 if (GMX_X11)
 476         find_package(X11)
 477         # X11 includes/libraries are only set in the ngmx subdirectory!
 478         if(X11_FOUND)
 479         set(HAVE_X11 1)
 480         endif(X11_FOUND)
 481 endif(GMX_X11)
 482
 483 include(ThreadMPI)
 484 set(THREAD_MPI_LIB thread_mpi)
 485 if(GMX_THREAD_MPI)
 486     tmpi_get_source_list(THREAD_MPI_SRC CXX)
 487     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREAD_MPI")
 488     set(GMX_MPI 1)
 489 else(GMX_THREAD_MPI)
 490     tmpi_get_source_list(THREAD_MPI_SRC CXX NOMPI)
 491 endif(GMX_THREAD_MPI)
 492
 493 if(GMX_OPENMM)
 494     set(CUDA_BUILD_EMULATION OFF)
 495     find_package(CUDA 3.1 REQUIRED)
 496     add_definitions(-DGMX_OPENMM)
 497     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 498         set(CUDA_VERBOSE_BUILD ON)
 499     endif()
 500     find_package(OpenMM)
 501 endif(GMX_OPENMM)
 502
 503
 504 if(GMX_GPU)
 505     if(GMX_DOUBLE)
 506         message(WARNING "GPU acceleration is not available in double precision, disabled!")
 507         set(GMX_GPU OFF CACHE BOOL "Enable GPU acceleration" FORCE)
 508     endif()
 509 endif(GMX_GPU)
 510
 511 if(GMX_GPU)
 512
 513     # We support CUDA >=v3.2 on *nix, but <= v4.1 doesn't work with MSVC
 514     if(MSVC)
 515         find_package(CUDA 4.1)
 516     else()
 517         find_package(CUDA 3.2)
 518     endif()
 519
 520     if (NOT EXISTS ${CUDA_TOOLKIT_ROOT_DIR})
 521         message(FATAL_ERROR "
 522     mdrun supports native GPU acceleration on NVIDIA hardware with compute
 523     capability >=2.0. This requires the NVIDIA CUDA library, which was not
 524     found; the location can be hinted by setting CUDA_TOOLKIT_ROOT_DIR.
 525
 526     CPU or GPU acceleration can be selected at runtime, but if you are
 527     sure you can not make use of GPU acceleration, disable it by setting
 528     the CMake variable GMX_GPU=OFF.")
 529     endif()
 530
 531     if(NOT GMX_OPENMP)
 532         message(WARNING "
 533     In order to use GPU acceleration efficiently, mdrun requires OpenMP multithreding.
 534     Without OpenMP only a single CPU core per GPU can be used which is suboptimal.
 535     Note that with MPI multiple processes can be forced to use a single GPU, but this
 536     typically inefficient.")
 537     endif()
 538
 539     include(gmxManageNvccConfig)
 540
 541     # Check whether we can use atomic operations needed for polling wait for GPU
 542     # (to avoid the cudaStreamSynchronize + ECC bug).
 543     # With thread-MPI testing atomics has already been carried out, but without
 544     # thread-MPI we need to invoke the atomics test independently.
 545     if (NOT GMX_THREAD_MPI)
 546         set(TEST_TMPI_ATOMICS_ONLY ON CACHE INTERNAL
 547             "Test only the atomic operations of thread-MPI.")
 548         include(ThreadMPI)
 549     endif()
 550
 551     # we need this linker flag in case if we have ld >= 2.22 (typically with gcc 4.5+),
 552     # but it's too cumbersome to check the ld version and the flag should not hurt
 553     if(CMAKE_COMPILER_IS_GNUCC)
 554         set(GROMACS_LINKER_FLAGS "-Wl,--add-needed ${GROMACS_LINKER_FLAGS}")
 555     endif()
 556
 557     # annoyingly enough, FindCUDA leaves a few variables behind as non-advanced
 558     mark_as_advanced(CUDA_BUILD_CUBIN CUDA_BUILD_EMULATION CUDA_SDK_ROOT_DIR CUDA_VERBOSE_BUILD)
 559 endif()
 560
 561 if(APPLE)
 562    find_library(ACCELERATE_FRAMEWORK Accelerate)
 563    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 564 endif(APPLE)
 565
 566 if(CYGWIN)
 567     set(GMX_CYGWIN 1)
 568 endif(CYGWIN)
 569
 570 if(WIN32 AND NOT CYGWIN)
 571     set(GMX_NATIVE_WINDOWS 1)
 572 endif()
 573
 574 # only bother with finding git and using version.h if the source is a git repo
 575 if(GMX_GIT_VERSION_INFO)
 576     if (NOT SOURCE_IS_GIT_REPOSITORY)
 577         message(FATAL_ERROR
 578             "Cannot generate git version information from source tree not under git. "
 579             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 580     endif ()
 581     # We need at least git v1.5.3 be able to parse git's date output. If not
 582     # found or the version is too small, we can't generate version information.
 583     find_package(Git)
 584
 585     # Find out the git version
 586     if(GIT_FOUND AND NOT GIT_VERSION)
 587       execute_process(COMMAND ${GIT_EXECUTABLE} "--version"
 588         OUTPUT_VARIABLE _exec_out
 589         OUTPUT_STRIP_TRAILING_WHITESPACE)
 590       string(REGEX REPLACE "git version (.*)" "\\1" GIT_VERSION ${_exec_out})
 591       set(GIT_VERSION ${GIT_VERSION} CACHE STRING "Git version")
 592       mark_as_advanced(GIT_VERSION)
 593     endif()
 594
 595     if(NOT GIT_FOUND OR GIT_VERSION VERSION_LESS "1.5.3")
 596         message(FATAL_ERROR
 597             "No compatible git version found (>= 1.5.3 required). "
 598             "Won't be able to generate development version information. "
 599             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 600     endif()
 601 endif()
 602
 603 option(GMX_INTERNAL_BOOST "Use minimal internal version of boost" OFF)
 604 if ( NOT GMX_INTERNAL_BOOST )
 605   find_package( Boost 1.44.0 )
 606 else ( NOT GMX_INTERNAL_BOOST )
 607   set (Boost_FOUND FALSE)
 608 endif( NOT GMX_INTERNAL_BOOST )
 609
 610 if(Boost_FOUND AND NOT Boost_VERSION VERSION_LESS "104400" )
 611   include_directories(${Boost_INCLUDE_DIRS})
 612 else()
 613   if(NOT BOOST_QUIETLY)
 614     message("Boost >= 1.44 not found. Using minimal internal version. Not recommended if GROMACS is used as library!")
 615   endif()
 616   include_directories(${CMAKE_SOURCE_DIR}/src/external/boost)
 617   add_definitions( -DBOOST_NO_TYPEID )  #TYPEID not supported for minimal internal version (would add significant more code)
 618   # TODO: Propagate the above settings to the installed CMakeFiles.txt template
 619   # (from share/template/)
 620   # TODO: Reorder stuff such that INCL_INSTALL_DIR could be used here
 621   set(PKG_CFLAGS "${PKG_CFLAGS} -DBOOST_NO_TYPEID -I${GMX_INSTALL_PREFIX}include/gromacs/external/boost")
 622   install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
 623           DESTINATION ${GMX_INSTALL_PREFIX}include/gromacs/external/boost
 624           COMPONENT development)
 625 endif()
 626 set(BOOST_QUIETLY TRUE CACHE INTERNAL "")
 627
 628 if (LIBXML2_FOUND)
 629     option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ON)
 630 else (LIBXML2_FOUND)
 631     set(GMX_BUILD_UNITTESTS OFF)
 632 endif (LIBXML2_FOUND)
 633 mark_as_advanced(GMX_BUILD_UNITTESTS)
 634 set(MEMORYCHECK_SUPPRESSIONS_FILE ${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp)
 635
 636 ########################################################################
 637 # Generate development version info for cache
 638 ########################################################################
 639 # set(GEN_VERSION_INFO_INTERNAL "ON")
 640 # include(gmxGenerateVersionString)
 641
 642 ########################################################################
 643 # Our own GROMACS tests
 644 ########################################################################
 645
 646 add_definitions( -DHAVE_CONFIG_H )
 647 include_directories(${CMAKE_SOURCE_DIR}/src)
 648 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 649 include_directories(${CMAKE_BINARY_DIR}/src)
 650 # Required for gmx_header_config_gen.h to be found before installation
 651 include_directories(${CMAKE_BINARY_DIR}/src/gromacs/utility)
 652 # Required for now to make old code compile
 653 include_directories(${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders)
 654
 655 include(gmxTestInlineASM)
 656 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 657
 658 include(gmxSetBuildInformation)
 659 gmx_set_build_information()
 660 if(BUILD_CPU_FEATURES MATCHES "rdtscp")
 661     # The timestep counter headers do not include config.h
 662     add_definitions(-DHAVE_RDTSCP)
 663 endif(BUILD_CPU_FEATURES MATCHES "rdtscp")
 664
 665 include(gmxTestFloatFormat)
 666 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 667                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 668                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 669
 670 include(gmxTestLargeFiles)
 671 gmx_test_large_files(GMX_LARGEFILES)
 672
 673 include(gmxTestSignal)
 674 gmx_test_sigusr1(HAVE_SIGUSR1)
 675
 676 include(gmxTestInline)
 677 gmx_test_inline(INLINE_KEYWORD)
 678
 679 include(gmxTestRestrict)
 680 gmx_test_restrict(RESTRICT_KEYWORD)
 681
 682 include(gmxTestPipes)
 683 gmx_test_pipes(HAVE_PIPES)
 684
 685 include(gmxTestIsfinite)
 686 gmx_test_isfinite(HAVE_ISFINITE)
 687 gmx_test__isfinite(HAVE__ISFINITE)
 688 gmx_test__finite(HAVE__FINITE)
 689
 690 include(gmxTestCXX11)
 691 gmx_test_cxx11(GMX_CXX11 CXX11_FLAG)
 692 set(GROMACS_CXX_FLAGS "${CXX11_FLAG} ${GROMACS_CXX_FLAGS}")
 693 if(CXX11_FLAG)
 694     #FIXME: add proper solution for progate all but cxx11 flag
 695     set(CUDA_PROPAGATE_HOST_FLAGS no)
 696     message(WARNING "Please manually add compiler flags to CUDA_NVCC_FLAGS. Automatic propogation temporary not working.")
 697 endif()
 698
 699 include(gmxTestXDR)
 700 gmx_test_xdr(GMX_SYSTEM_XDR)
 701 if(NOT GMX_SYSTEM_XDR)
 702     set(GMX_INTERNAL_XDR 1)
 703     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 704 endif(NOT GMX_SYSTEM_XDR)
 705
 706 # Process nonbonded accelerated kernels settings
 707 string(TOUPPER ${GMX_ACCELERATION} ${GMX_ACCELERATION})
 708 if(${GMX_ACCELERATION} STREQUAL "NONE")
 709     # nothing to do
 710 elseif(${GMX_ACCELERATION} STREQUAL "SSE2")
 711
 712     GMX_TEST_CFLAG(GNU_SSE2_CFLAG "-msse2" GROMACS_C_FLAGS)
 713     if(NOT GNU_SSE2_CFLAG)
 714         GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" GROMACS_C_FLAGS)
 715     endif(NOT GNU_SSE2_CFLAG)
 716
 717     GMX_TEST_CXXFLAG(GNU_SSE2_CXXFLAG "-msse2" GROMACS_CXX_FLAGS)
 718     if(NOT GNU_SSE2_CXXFLAG)
 719         GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" GROMACS_CXX_FLAGS)
 720     endif(NOT GNU_SSE2_CXXFLAG)
 721
 722     # We dont warn for lacking SSE2 flag support, since that is probably standard today.
 723
 724     # Only test the include after we have tried to add the correct flag for SSE2 support
 725     check_include_file(emmintrin.h  HAVE_EMMINTRIN_H ${GROMACS_C_FLAGS})
 726
 727     if(NOT HAVE_EMMINTRIN_H)
 728         message(FATAL_ERROR "Cannot find emmintrin.h, which is required for SSE2 intrinsics support.")
 729     endif(NOT HAVE_EMMINTRIN_H)
 730
 731     # The user should not be able to set this orthogonally to the acceleration
 732     set(GMX_X86_SSE2 1)
 733     if (NOT ACCELERATION_QUIETLY)
 734       message(STATUS "Enabling SSE2 Gromacs acceleration, and it will help compiler optimization.")
 735     endif()
 736
 737 elseif(${GMX_ACCELERATION} STREQUAL "SSE4.1")
 738
 739     GMX_TEST_CFLAG(GNU_SSE4_CFLAG "-msse4.1" GROMACS_C_FLAGS)
 740     if (NOT GNU_SSE4_CFLAG)
 741         GMX_TEST_CFLAG(MSVC_SSE4_CFLAG "/arch:SSE4.1" GROMACS_C_FLAGS)
 742     endif(NOT GNU_SSE4_CFLAG)
 743     if (NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 744         message(WARNING "No C SSE4.1 flag found. Consider a newer compiler, or disable SSE4.1 for slightly lower performance.")
 745         # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 746         # intrinsics when SSE2 support is enabled, so we try that instead.
 747         GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" GROMACS_C_FLAGS)
 748     endif(NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 749
 750     GMX_TEST_CXXFLAG(GNU_SSE4_CXXFLAG "-msse4.1" GROMACS_CXX_FLAG)
 751     if (NOT GNU_SSE4_CXXFLAG)
 752        GMX_TEST_CXXFLAG(MSVC_SSE4_CXXFLAG "/arch:SSE4.1" GROMACS_CXX_FLAGS)
 753     endif(NOT GNU_SSE4_CXXFLAG)
 754     if (NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 755         message(WARNING "No C++ SSE4.1 flag found. Consider a newer compiler, or disable SSE4.1 for slightly lower performance.")
 756         # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 757         # intrinsics when SSE2 support is enabled, so we try that instead.
 758         GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" GROMACS_CXX_FLAGS)
 759     endif(NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 760
 761     # This must come after we have added the -msse4.1 flag on some platforms.
 762     check_include_file(smmintrin.h  HAVE_SMMINTRIN_H ${GROMACS_C_FLAGS})
 763
 764     if(NOT HAVE_SMMINTRIN_H)
 765         message(FATAL_ERROR "Cannot find smmintrin.h, which is required for SSE4.1 intrinsics support.")
 766     endif(NOT HAVE_SMMINTRIN_H)
 767
 768     # The user should not be able to set this orthogonally to the acceleration
 769     set(GMX_X86_SSE4_1 1)
 770     set(GMX_X86_SSE2   1)
 771     if (NOT ACCELERATION_QUIETLY)
 772       message(STATUS "Enabling SSE4.1 Gromacs acceleration, and it will help compiler optimization.")
 773     endif()
 774
 775 elseif(${GMX_ACCELERATION} STREQUAL "AVX_128_FMA" OR ${GMX_ACCELERATION} STREQUAL "AVX_256")
 776
 777     # Set the AVX compiler flag for both these choices!
 778
 779     GMX_TEST_CFLAG(GNU_AVX_CFLAG "-mavx" GROMACS_C_FLAGS)
 780     if (NOT GNU_AVX_CFLAG)
 781         GMX_TEST_CFLAG(MSVC_AVX_CFLAG "/arch:AVX" GROMACS_C_FLAGS)
 782     endif (NOT GNU_AVX_CFLAG)
 783     if (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 784         message(WARNING "No C AVX flag found. Consider a newer compiler, or disable AVX for much lower performance.")
 785     endif (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 786
 787     GMX_TEST_CXXFLAG(GNU_AVX_CXXFLAG "-mavx" GROMACS_CXX_FLAGS)
 788     if (NOT GNU_AVX_CXXFLAG)
 789        GMX_TEST_CXXFLAG(MSVC_AVX_CXXFLAG "/arch:AVX" GROMACS_CXX_FLAGS)
 790     endif (NOT GNU_AVX_CXXFLAG)
 791     if (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 792        message(WARNING "No C++ AVX flag found. Consider a newer compiler, or disable AVX for much lower performance.")
 793     endif (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 794
 795     # Only test the header after we have tried to add the flag for AVX support
 796     check_include_file(immintrin.h  HAVE_IMMINTRIN_H ${GROMACS_C_FLAGS})
 797
 798     if(NOT HAVE_IMMINTRIN_H)
 799         message(FATAL_ERROR "Cannot find immintrin.h, which is required for AVX intrinsics support. Consider switching compiler.")
 800     endif(NOT HAVE_IMMINTRIN_H)
 801
 802     # AMD says we should include x86intrin.h for FMA support, but MSVC seems to do fine without it, so don't require it.
 803     check_include_file(x86intrin.h HAVE_X86INTRIN_H ${GROMACS_C_FLAGS})
 804
 805     # The user should not be able to set this orthogonally to the acceleration
 806     set(GMX_X86_SSE4_1 1)
 807     set(GMX_X86_SSE2   1)
 808
 809     # But just enable one of the choices internally...
 810     if(${GMX_ACCELERATION} STREQUAL "AVX_128_FMA")
 811         set(GMX_X86_AVX_128_FMA 1)
 812         if (NOT ACCELERATION_QUIETLY)
 813           message(STATUS "Enabling 128-bit AVX Gromacs acceleration (with fused-multiply add), and it will help compiler optimization.")
 814         endif()
 815     else()
 816         # If we are not doing AVX_128, it must be AVX_256...
 817         set(GMX_X86_AVX_256 1)
 818         if (NOT ACCELERATION_QUIETLY)
 819           message(STATUS "Enabling 256-bit AVX Gromacs acceleration, and it will help compiler optimization.")
 820         endif()
 821     endif()
 822
 823 elseif(${GMX_ACCELERATION} STREQUAL "FORTRAN")
 824
 825 #    Fortran is temporarily disabled while we push in nbNxN kernels.
 826 #    We need to fake it a bit here to avoid jenkins build errors!
 827 #    add_definitions(-DGMX_FORTRAN)
 828
 829 elseif(${GMX_ACCELERATION} STREQUAL "BLUEGENE")
 830 # GMX_ACCELERATION=BlueGene should be set in the Toolchain-BlueGene?-???.cmake file
 831     if (NOT ACCELERATION_QUIETLY)
 832       message(STATUS "Configuring for BlueGene")
 833     endif()
 834     set(GMX_BLUEGENE 1)
 835     if (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 836         set(SHARED_LIBS_DEFAULT OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 837         set(BUILD_SHARED_LIBS OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 838     endif (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 839     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on BlueGene" FORCE)
 840     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on BlueGene" FORCE)
 841     set(GMX_X11 OFF CACHE BOOL "X11 not compatible with BlueGene, disabled!" FORCE)
 842     set(GMX_THREAD_MPI OFF CACHE BOOL "Thread-MPI not compatible with BlueGene, disabled!" FORCE)
 843     set(GMX_MPI ON CACHE BOOL "Use MPI on BlueGene" FORCE)
 844 # Access to /etc/passwd is not available on the back end of BlueGene,
 845 # despite being detected by CMake. This can cause linker warnings
 846 # about harmless things in src/gmxlib/string2.h.
 847     set(HAVE_PWD_H OFF)
 848 # The automatic testing for endianness does not work for the BlueGene cross-compiler
 849     set(GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER 1 CACHE INTERNAL "BlueGene has big endian FP byte order (by default)" FORCE)
 850     set(GMX_IEEE754_BIG_ENDIAN_WORD_ORDER 1 CACHE INTERNAL "BlueGene has big endian FP word order (by default)" FORCE)
 851 elseif(${GMX_ACCELERATION} STREQUAL "POWER6")
 852     set(GMX_POWER6 1)
 853     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on Power6" FORCE)
 854     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on Power6" FORCE)
 855 else(${GMX_ACCELERATION} STREQUAL "NONE")
 856     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_ACCELERATION}. Pick one of None, SSE2, SSE4.1, AVX_128_FMA, AVX_256, Fortran, BlueGene, Power6")
 857 endif(${GMX_ACCELERATION} STREQUAL "NONE")
 858 set(ACCELERATION_QUIETLY TRUE CACHE INTERNAL "")
 859
 860 if(GMX_FORTRAN OR GMX_POWER6)
 861     if (GMX_THREAD_MPI)
 862         message(FATAL_ERROR "FORTRAN/POWER6 is incompatible with thread-MPI and only provides a speed-up on certain IBM compilers. Disable FORTRAN (or threads if you really want to use FORTRAN kernels).")
 863     endif(GMX_THREAD_MPI)
 864     enable_language(Fortran)
 865     include(FortranCInterface)
 866     discover_fortran_mangling(prefix isupper suffix extra_under_score found)
 867     if(extra_under_score)
 868         set(extrasuffix "_")
 869     endif(extra_under_score)
 870     if(prefix)
 871       set(prefix "${prefix} ##")
 872     endif(prefix)
 873     if(suffix)
 874       set(suffix "## ${suffix}")
 875       if(extrasuffix)
 876         set(extrasuffix "${suffix}${extrasuffix}")
 877       endif(extrasuffix)
 878     else(suffix)
 879       if(extrasuffix)
 880         # Don't know if this is needed, but it can't hurt
 881         set(extrasuffix "## ${extrasuffix}")
 882       endif(extrasuffix)
 883     endif(suffix)
 884
 885     if(isupper)
 886         set(F77_FUNCDEF   "${prefix} NAME ${suffix}")
 887         # The underscored versions are not currently used.
 888         #set(F77_FUNCDEF_  "${prefix} NAME ${extrasuffix}")
 889     else(isupper)
 890         set(F77_FUNCDEF   "${prefix} name ${suffix}")
 891         #set(F77_FUNCDEF_  "${prefix} name ${extrasuffix}")
 892     endif(isupper)
 893 else(GMX_FORTRAN OR GMX_POWER6)
 894         set(F77_FUNCDEF   "name ## _")
 895         #set(F77_FUNCDEF_  "name ## _")
 896 endif(GMX_FORTRAN OR GMX_POWER6)
 897
 898 # Process QM/MM Settings
 899 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 900 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 901     set(GMX_QMMM_GAUSSIAN 1)
 902 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 903     set(GMX_QMMM_MOPAC 1)
 904 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 905     set(GMX_QMMM_GAMESS 1)
 906 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 907     set(GMX_QMMM_ORCA 1)
 908 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 909     # nothing to do
 910 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 911     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 912 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 913
 914 # Process FFT library settings - if not OpenMM build
 915 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 916 set(PKG_FFT "")
 917 set(PKG_FFT_LIBS "")
 918 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 919     if(GMX_DOUBLE)
 920         set(FFTW fftw)
 921     else(GMX_DOUBLE)
 922         set(FFTW fftwf)
 923     endif(GMX_DOUBLE)
 924     find_package(FFTW COMPONENTS ${FFTW})
 925     string(TOUPPER "${FFTW}" FFTW)
 926     set(PKG_FFT "${${FFTW}_PKG}")
 927     include_directories(${${FFTW}_INCLUDE_DIRS})
 928     set(FFT_LIBRARIES ${${FFTW}_LIBRARIES})
 929     if(NOT ${FFTW}_FOUND)
 930       MESSAGE(FATAL_ERROR "Cannot find FFTW3 (with correct precision - libfftw3f for single precision GROMACS or libfftw3 for double precision GROMACS). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 931     endif(NOT ${FFTW}_FOUND)
 932
 933     set(GMX_FFT_FFTW3 1)
 934
 935     if (NOT ${GMX_ACCELERATION} STREQUAL "NONE" AND NOT ${FFTW}_HAVE_SIMD)
 936       message(WARNING "The fftw library found is compiled without SIMD support, which makes it slow. Consider recompiling it or contact your admin")
 937     endif (NOT ${GMX_ACCELERATION} STREQUAL "NONE" AND NOT ${FFTW}_HAVE_SIMD)
 938
 939 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 940 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 941     find_package(MKL REQUIRED)
 942     include_directories(${MKL_INCLUDE_DIR})
 943     set(FFT_LIBRARIES ${MKL_LIBRARIES})
 944     set(PKG_FFT_LIBS ${MKL_LIBRARIES})
 945
 946     set(GMX_FFT_MKL 1)
 947     set(HAVE_MKL 1)
 948
 949 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 950 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 951 #    set(GMX_FFT_ACML 1)
 952 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 953     MESSAGE(STATUS "Using internal FFT library - fftpack")
 954     set(GMX_FFT_FFTPACK 1)
 955 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 956     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, mkl, fftpack")
 957 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 958
 959 # enable threaded fftw3 if we've found it
 960 if(FFTW3_THREADS OR FFTW3F_THREADS)
 961     add_definitions(-DFFT5D_FFTW_THREADS)
 962 endif()
 963
 964 set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 965 set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 966 # MKL has BLAS/LAPACK routines
 967 if(NOT HAVE_MKL AND NOT ACCELERATE_FRAMEWORK)
 968   if(GMX_EXTERNAL_BLAS)
 969     if (GMX_BLAS_USER)
 970         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_BLAS_USER})
 971     else(GMX_BLAS_USER)
 972         set(BLAS_FIND_QUIETLY ON)
 973         find_package(BLAS)
 974         if (BLAS_FOUND)
 975           list(APPEND GMX_EXTRA_LIBRARIES ${BLAS_LIBRARIES})
 976         else()
 977           MESSAGE(STATUS "Using internal BLAS library")
 978           set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external BLAS instead of built-in" FORCE)
 979         endif()
 980     endif(GMX_BLAS_USER)
 981   endif(GMX_EXTERNAL_BLAS)
 982   if(GMX_EXTERNAL_LAPACK)
 983     if (GMX_LAPACK_USER)
 984         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_LAPACK_USER})
 985     else(GMX_LAPACK_USER)
 986         set(LAPACK_FIND_QUIETLY ON)
 987         find_package(LAPACK)
 988         if (LAPACK_FOUND)
 989           list(APPEND GMX_EXTRA_LIBRARIES ${LAPACK_LIBRARIES})
 990         else()
 991           MESSAGE(STATUS "Using internal LAPACK library")
 992           set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in" FORCE)
 993         endif()
 994     endif(GMX_LAPACK_USER)
 995   endif(GMX_EXTERNAL_LAPACK)
 996 endif()
 997 mark_as_advanced(GMX_EXTERNAL_LAPACK)
 998 mark_as_advanced(GMX_EXTERNAL_BLAS)
 999
1000 set(GMX_USE_PLUGINS OFF CACHE INTERNAL "Whether GROMACS will really try to compile support for VMD plugins")
1001
1002 if(GMX_LOAD_PLUGINS)
1003   if(CYGWIN OR NOT WIN32)
1004     # Native Windows does not have, nor need dlopen
1005     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
1006     include(gmxTestdlopen)
1007     gmx_test_dlopen(HAVE_DLOPEN)
1008   endif()
1009
1010   # so, should we use plug-ins?
1011   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
1012     if(NOT VMD_QUIETLY)
1013       MESSAGE(STATUS
1014           "Found the ability to use plug-ins when building shared libaries, "
1015           "so will compile to use plug-ins (e.g. to read VMD-supported file "
1016           "formats).")
1017     endif()
1018     if(NOT GMX_VMD_PLUGIN_PATH)
1019       find_package(VMD)
1020     endif()
1021     set(GMX_USE_PLUGINS ON)
1022     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
1023     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
1024   else()
1025     set(PKG_DL_LIBS)
1026   endif()
1027 endif(GMX_LOAD_PLUGINS)
1028 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
1029
1030 if(EXISTS "${CMAKE_SOURCE_DIR}/admin/.isreposource")
1031     if(NOT CMAKE_CROSSCOMPILING)
1032         option(GMX_BUILD_MANPAGES "Build man pages" ON)
1033     else()
1034         message(STATUS "Building the man pages is not available when "
1035             "cross-compiling the developer version from git")
1036     endif()
1037 else()
1038     #make sure source package contains all man pages
1039     if(NOT EXISTS "${CMAKE_SOURCE_DIR}/man/man1/ngmx.1")
1040         message(FATAL_ERROR "Man pages are missing from source package.")
1041     endif()
1042 endif()
1043 mark_as_advanced(GMX_BUILD_MANPAGES)
1044
1045 # Math and thread libraries must often come after all others when linking...
1046 if(HAVE_LIBM)
1047     list(APPEND GMX_EXTRA_LIBRARIES m)
1048 endif(HAVE_LIBM)
1049
1050 if(GMX_FAHCORE)
1051   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
1052       "Path to swindirect.h")
1053   include_directories(${COREWRAP_INCLUDE_DIR})
1054 endif(GMX_FAHCORE)
1055
1056 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
1057 # these are set after everything else
1058 if (NOT DEFINED GROMACS_C_FLAGS_SET)
1059     set(GROMACS_C_FLAGS_SET true CACHE INTERNAL "Whether to reset the C flags"
1060         FORCE)
1061     set(CMAKE_C_FLAGS "${GROMACS_C_FLAGS} ${CMAKE_C_FLAGS}" CACHE STRING
1062         "Flags used by the compiler during all build types" FORCE)
1063     set(CMAKE_CXX_FLAGS "${GROMACS_CXX_FLAGS} ${CMAKE_CXX_FLAGS}" CACHE STRING
1064         "Flags used by the compiler during all build types" FORCE)
1065     set(CMAKE_EXE_LINKER_FLAGS
1066         "${GROMACS_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}"
1067         CACHE STRING "Linker flags for creating executables" FORCE)
1068     set(CMAKE_SHARED_LINKER_FLAGS
1069         "${GROMACS_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}"
1070         CACHE STRING "Linker flags for creating shared libraries" FORCE)
1071 endif (NOT DEFINED GROMACS_C_FLAGS_SET)
1072
1073 if(NOT GMX_OPENMP)
1074     #Unset all OpenMP flags in case OpenMP was disabled either by the user
1075     #or because it was only partially detected (e.g. only for C but not C++ compiler)
1076     unset(OpenMP_C_FLAGS CACHE)
1077     unset(OpenMP_CXX_FLAGS CACHE)
1078     unset(OpenMP_LINKER_FLAGS CACHE)
1079     unset(OpenMP_SHARED_LINKER_FLAGS)
1080 endif()
1081 ######################################
1082 # Output compiler and CFLAGS used
1083 ######################################
1084 execute_process(COMMAND ${CMAKE_C_COMPILER} --version RESULT_VARIABLE TMP_RESULT OUTPUT_VARIABLE CC_VERSION ERROR_VARIABLE CC_VERSION)
1085 #try executing just the compiler command if that failed...
1086 if(TMP_RESULT)
1087     execute_process(COMMAND ${CMAKE_C_COMPILER} RESULT_VARIABLE TMP_RESULT OUTPUT_VARIABLE CC_VERSION ERROR_VARIABLE CC_VERSION)
1088 endif()
1089 string(LENGTH "${CC_VERSION}" len)
1090 if(len)
1091     string(REGEX MATCH "[^\n]+" CC_VERSION "${CC_VERSION}")
1092 endif()
1093
1094 set(BUILD_COMPILER "@CMAKE_C_COMPILER@ @CMAKE_C_COMPILER_ID@ @CC_VERSION@")
1095 set(BUILD_CFLAGS "@CMAKE_C_FLAGS@")
1096 if(CMAKE_BUILD_TYPE STREQUAL "Debug")
1097     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_DEBUG@")
1098 elseif(CMAKE_BUILD_TYPE STREQUAL "Release")
1099     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_RELEASE@")
1100 elseif(CMAKE_BUILD_TYPE STREQUAL "MinSizeRel")
1101     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_MINSIZEREL@")
1102 elseif(CMAKE_BUILD_TYPE STREQUAL "RelWithDebInfo")
1103     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_RELWITHDEBINFO@")
1104 endif()
1105
1106
1107 ########################################################################
1108 # Specify install locations and which subdirectories to process        #
1109 ########################################################################
1110 if ( NOT DEFINED GMXLIB )
1111     set(GMXLIB lib)
1112 endif()
1113 set(LIB_INSTALL_DIR "${GMX_INSTALL_PREFIX}${GMXLIB}")
1114 set(BIN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}bin)
1115 set(DATA_INSTALL_DIR ${GMX_INSTALL_PREFIX}share/gromacs)
1116 set(MAN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}share/man)
1117 set(INCL_INSTALL_DIR ${GMX_INSTALL_PREFIX}include)
1118
1119 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
1120
1121 ##################################################################
1122 # Shared library settings - Darwin uses INSTALL_NAME_DIR instead!
1123 ##################################################################
1124 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
1125     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
1126     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
1127     set(CMAKE_INSTALL_RPATH "\\\$ORIGIN/../${GMXLIB}")
1128     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
1129 endif()
1130
1131 #COPYING file: Only necessary for binary distributions.
1132 #Simpler to always install.
1133 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
1134
1135 add_subdirectory(doxygen)
1136 add_subdirectory(share)
1137 add_subdirectory(src)
1138 add_subdirectory(scripts)
1139
1140 #######################
1141 ## uninstall target
1142 #######################
1143     CONFIGURE_FILE(
1144                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
1145                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
1146                    IMMEDIATE @ONLY)
1147 ###########################
1148 ADD_CUSTOM_TARGET(uninstall
1149                   "${CMAKE_COMMAND}" -P
1150                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
1151 ###########################
1152
1153
1154 ########################################################################
1155 # Tests                                                                #
1156 ########################################################################
1157
1158 include(CTest)
1159 mark_as_advanced(BUILD_TESTING)
1160 IF(BUILD_TESTING)
1161     enable_testing()
1162     add_subdirectory(tests)
1163 ENDIF()
1164