CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 2.8.8)
  36
  37 # CMake modules/macros are in a subdirectory to keep this file cleaner
  38 # This needs to be set before project() in order to pick up toolchain files
  39 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  40
  41 project(Gromacs)
  42
  43 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  44 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  45 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  46
  47 # PROJECT_VERSION should have the following structure:
  48 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  49 #
  50 # The "-dev" suffix is important to keep because it makes possible to distinguish
  51 # between a build from official release and a build from git release branch on a
  52 # machine with no git.
  53 #
  54 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  55 set(PROJECT_VERSION "5.0-dev")
  56 # The version number of the regressiontest tarball against which this
  57 # git branch can be tested. Normally, this will be the version of the
  58 # last patch release. Comment the next line out for branches leading
  59 # to a major/minor release.
  60 set(REGRESSIONTEST_VERSION "4.6.4")
  61 set(CUSTOM_VERSION_STRING ""
  62     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  63 mark_as_advanced(CUSTOM_VERSION_STRING)
  64 if (CUSTOM_VERSION_STRING)
  65     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  66 endif (CUSTOM_VERSION_STRING)
  67 set(SOVERSION 8)
  68 # It is a bit irritating, but this has to be set separately for now!
  69 SET(CPACK_PACKAGE_VERSION_MAJOR "5")
  70 SET(CPACK_PACKAGE_VERSION_MINOR "0")
  71 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  72
  73 # The numerical gromacs version. It is 40600 for 4.6.0.
  74 # The #define GMX_VERSION in gmx_header_config_h is set to this value.
  75 math(EXPR NUM_VERSION
  76     "${CPACK_PACKAGE_VERSION_MAJOR}*10000 + ${CPACK_PACKAGE_VERSION_MINOR}*100")
  77 if(CPACK_PACKAGE_VERSION_PATCH)
  78     math(EXPR NUM_VERSION
  79          "${NUM_VERSION} + ${CPACK_PACKAGE_VERSION_PATCH}")
  80 endif()
  81
  82 # The API version tracks the numerical Gromacs version (for now).
  83 # It is potentially different from the Gromacs version in the future, if
  84 # the programs/libraries diverge from the presumably more stable API.
  85 # The #define GMX_API_VERSION in version.h is set to this value to
  86 # provide backward compatibility of software written against the Gromacs API.
  87 set(API_VERSION ${NUM_VERSION})
  88
  89 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  90     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  91 endif()
  92
  93 set(GMX_INSTALL_PREFIX "" CACHE STRING "Prefix gets appended to CMAKE_INSTALL_PREFIX. For cpack it sets the root folder of the archive.")
  94 mark_as_advanced(GMX_INSTALL_PREFIX)
  95
  96 include(gmxBuildTypeReference)
  97
  98 if(NOT CMAKE_BUILD_TYPE)
  99     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference." FORCE)
 100     # Set the possible values of build type for cmake-gui
 101     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
 102         "MinSizeRel" "RelWithDebInfo")
 103 endif(NOT CMAKE_BUILD_TYPE)
 104
 105 enable_language(C)
 106 enable_language(CXX)
 107
 108 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
 109 set(CPACK_PACKAGE_VENDOR "gromacs.org")
 110 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
 111 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
 112 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
 113 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/COPYING")
 114 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
 115 set(CPACK_SOURCE_IGNORE_FILES "\\\\.isreposource$;\\\\.git/;\\\\.gitignore$")
 116 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
 117 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/share/man;share/man")
 118 set(CPACK_PACKAGE_CONTACT "gmx-users@gromacs.org")
 119
 120 #must come after all cpack settings!
 121 include(CPack)
 122
 123 # Set a default valgrind suppression file.
 124 # This unfortunately needs to duplicate information from CTest to work as
 125 # expected...
 126 set(MEMORYCHECK_SUPPRESSIONS_FILE
 127     "${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp"
 128     CACHE FILEPATH
 129     "File that contains suppressions for the memory checker")
 130 include(CTest)
 131
 132 set(SOURCE_IS_GIT_REPOSITORY OFF)
 133 set(SOURCE_IS_SOURCE_DISTRIBUTION OFF)
 134 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 135     set(SOURCE_IS_GIT_REPOSITORY ON)
 136 endif()
 137 if(NOT EXISTS "${CMAKE_SOURCE_DIR}/admin/.isreposource")
 138     set(SOURCE_IS_SOURCE_DISTRIBUTION ON)
 139 endif()
 140
 141 ########################################################################
 142 # Check and warn if cache generated on a different host is being reused
 143 ########################################################################
 144 if(CMAKE_HOST_UNIX)
 145     execute_process(COMMAND hostname
 146                     OUTPUT_VARIABLE TMP_HOSTNAME
 147                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 148     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 149         message(WARNING "
 150             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 151             is being reused! This could lead to inconsitencies; therefore, it is
 152             recommended to regenerate the cache!")
 153     endif()
 154     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 155             "Hostname of the machine where the cache was generated.")
 156 endif()
 157
 158 ########################################################################
 159 # User input options                                                   #
 160 ########################################################################
 161 include(gmxOptionUtilities)
 162
 163 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 164
 165 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 166 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 167 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 168 gmx_dependent_option(
 169     GMX_MPI_IN_PLACE
 170     "Enable MPI_IN_PLACE for MPIs that have it defined"
 171     ON
 172     GMX_MPI)
 173 mark_as_advanced(GMX_MPI_IN_PLACE)
 174 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 175 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 176 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 177 mark_as_advanced(GMX_FAHCORE)
 178
 179 option(GMX_COOL_QUOTES "Enable Gromacs cool quotes" ON)
 180 mark_as_advanced(GMX_COOL_QUOTES)
 181 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 182
 183 # decide on GPU settings based on user-settings and GPU/CUDA detection
 184 include(gmxManageGPU)
 185
 186 # Detect the architecture the compiler is targetting, detect
 187 # acceleration possibilities on that hardware, suggest an acceleration
 188 # to use if none is specified, and populate the cache option for CPU
 189 # accleration.
 190 include(gmxDetectTargetArchitecture)
 191 gmx_detect_target_architecture()
 192 include(gmxDetectAcceleration)
 193 gmx_detect_acceleration(GMX_SUGGESTED_CPU_ACCELERATION)
 194
 195 gmx_option_multichoice(
 196     GMX_CPU_ACCELERATION
 197     "Acceleration for CPU kernels and compiler optimization"
 198     "${GMX_SUGGESTED_CPU_ACCELERATION}"
 199     None SSE2 SSE4.1 AVX_128_FMA AVX_256 IBM_QPX Sparc64_HPC_ACE)
 200
 201 gmx_option_multichoice(
 202     GMX_FFT_LIBRARY
 203     "FFT library"
 204     "fftw3"
 205     fftw3 mkl "fftpack[built-in]")
 206 gmx_dependent_option(
 207     GMX_BUILD_OWN_FFTW
 208     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 209     OFF
 210     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 211 gmx_dependent_option(
 212     GMX_DISABLE_FFTW_MEASURE
 213     "Do not optimize FFTW setups (not needed with SSE)"
 214     OFF
 215     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 216 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 217 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 218
 219 gmx_option_multichoice(
 220     GMX_QMMM_PROGRAM
 221     "QM package for QM/MM"
 222     None
 223     none gaussian mopac gamess orca)
 224
 225 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 226 mark_as_advanced(GMX_BROKEN_CALLOC)
 227 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 228 mark_as_advanced(GMX_LOAD_PLUGINS)
 229
 230 option(GMX_GPU  "Enable GPU acceleration" ON)
 231 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 232
 233 option(GMX_GIT_VERSION_INFO "Generate git version information" ${SOURCE_IS_GIT_REPOSITORY})
 234 mark_as_advanced(GMX_GIT_VERSION_INFO)
 235
 236 if(UNIX)
 237     option(GMX_SYMLINK_OLD_BINARY_NAMES "Create symbolic links for pre-5.0 binary names" ON)
 238 endif()
 239 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 240
 241 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 242 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 243
 244 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 245 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 246
 247 option(GMX_BUILD_FOR_COVERAGE
 248        "Tune build for better code coverage metrics (e.g., disable asserts)"
 249        OFF)
 250 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 251
 252 ######################################################################
 253 # Compiler tests
 254 # These need to be done early (before further tests).
 255 #####################################################################
 256
 257 # Warn if C and C++ compilers do not match
 258 if(NOT "${CMAKE_C_COMPILER_ID}" STREQUAL "${CMAKE_CXX_COMPILER_ID}")
 259     message(WARNING "The ids of the C and C++ compilers do not match (respectively ${CMAKE_C_COMPILER_ID} and ${CMAKE_CXX_COMPILER_ID}). Note that mixing different C/C++ compilers can cause problems!")
 260 endif()
 261 if(NOT "${CMAKE_C_COMPILER_VERSION}" STREQUAL "${CMAKE_CXX_COMPILER_VERSION}")
 262     message(WARNING "The versions of the C and C++ compilers do not match (respectively ${CMAKE_C_COMPILER_VERSION} and ${CMAKE_CXX_COMPILER_VERSION}). Note that mixing different C/C++ compilers can cause problems!")
 263 endif()
 264
 265 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 266 # are used with permission from CMake v2.8.9 so that GROMACS can detect
 267 # invalid options with the Intel Compilers.
 268 # These files should be removed from the source tree when a CMake version that
 269 # includes the features in question becomes required for building GROMACS.
 270 include(CheckCCompilerFlag)
 271 include(CheckCXXCompilerFlag)
 272
 273 # First exclude compilers known to not work with OpenMP although claim to support it:
 274 # gcc 4.2.1 and gcc-llvm 4.2.1 (also claims to be 4.2.1) on Mac OS X
 275 # This fixes redmine 900 and needs to run before OpenMP flags are set below.
 276 if (CMAKE_SYSTEM_NAME STREQUAL "Darwin" AND
 277     (CMAKE_COMPILER_IS_GNUCC AND CMAKE_C_COMPILER_VERSION AND CMAKE_C_COMPILER_VERSION VERSION_LESS 4.3))
 278     message(STATUS "OpenMP multithreading not supported with gcc/llvm-gcc 4.2 on Mac OS X, disabled")
 279     set(GMX_OPENMP OFF CACHE BOOL
 280         "OpenMP multithreading not not supported with gcc/llvm-gcc 4.2 on Mac OS X, disabled!" FORCE)
 281 endif()
 282
 283 # OpenMP check must come before other CFLAGS!
 284 if(GMX_OPENMP)
 285     find_package(OpenMP)
 286     if(OPENMP_FOUND)
 287         # CMake on Windows doesn't support linker flags passed to target_link_libraries
 288         # (i.e. it treats /openmp as \openmp library file). Also, no OpenMP linker flags are needed.
 289         if(NOT (WIN32 AND NOT CYGWIN))
 290             if(CMAKE_COMPILER_IS_GNUCC AND GMX_PREFER_STATIC_OPENMP AND NOT APPLE)
 291                 set(OpenMP_LINKER_FLAGS "-Wl,-static -lgomp -lrt -Wl,-Bdynamic -lpthread")
 292                 set(OpenMP_SHARED_LINKER_FLAGS "")
 293             else()
 294                 # Only set a linker flag if the user didn't set them manually
 295                 if(NOT DEFINED OpenMP_LINKER_FLAGS)
 296                     set(OpenMP_LINKER_FLAGS "${OpenMP_C_FLAGS}")
 297                 endif()
 298                 if(NOT DEFINED OpenMP_SHARED_LINKER_FLAGS)
 299                     set(OpenMP_SHARED_LINKER_FLAGS "${OpenMP_C_FLAGS}")
 300                 endif()
 301             endif()
 302         endif()
 303     else(OPENMP_FOUND)
 304         message(WARNING
 305                 "The compiler you are using does not support OpenMP parallelism. This might hurt your performance a lot, in particular with GPUs. Try using a more recent version, or a different compiler. For now, we are proceeding by turning off OpenMP.")
 306         set(GMX_OPENMP OFF CACHE STRING "Whether GROMACS will use OpenMP parallelism." FORCE)
 307     endif(OPENMP_FOUND)
 308 endif()
 309
 310
 311 include(gmxCFlags)
 312 gmx_c_flags()
 313
 314 # This variable should be used for additional compiler flags which are not
 315 # generated in gmxCFlags nor are acceleration or MPI related.
 316 set(EXTRA_C_FLAGS "")
 317 set(EXTRA_CXX_FLAGS "")
 318
 319 # gcc 4.4.x is buggy and crashes when compiling some files with O3 and OpenMP on.
 320 # Detect here whether applying a workaround is needed and will apply it later
 321 # on the affected files.
 322 include(gmxGCC44O3BugWorkaround)
 323 gmx_check_gcc44_bug_workaround_needed(GMX_USE_GCC44_BUG_WORKAROUND)
 324
 325 # clang 3.0 is buggy for some unknown reason detected during adding
 326 # the SSE2 group kernels for GROMACS 4.6. If we ever work out what
 327 # that is, we should replace these tests with a compiler feature test,
 328 # update GROMACS Redmine task #1039 and perhaps report a clang bug.
 329 #
 330 # In the meantime, until we require CMake 2.8.10 we cannot rely on it to detect
 331 # the compiler version for us. So we need a manual check for clang 3.0.
 332 include(gmxDetectClang30)
 333 gmx_detect_clang_3_0(COMPILER_IS_CLANG_3_0)
 334 if(COMPILER_IS_CLANG_3_0)
 335     message(FATAL_ERROR "Your compiler is clang version 3.0, which is known to be buggy for GROMACS. Use a different compiler.")
 336 endif()
 337
 338 # clang <=3.2 contains a bug that causes incorrect code to be generated for the
 339 # vfmaddps instruction and therefore the bug is triggered with AVX_128_FMA.
 340 # (see: http://llvm.org/bugs/show_bug.cgi?id=15040).
 341 # We can work around this by not using the integrated assembler (except on OS X
 342 # which has an outdated assembler that does not support AVX instructions).
 343 if (${CMAKE_C_COMPILER_ID} MATCHES "Clang" AND CMAKE_C_COMPILER_VERSION VERSION_LESS "3.3")
 344     set(GMX_USE_CLANG_C_FMA_BUG_WORKAROUND TRUE)
 345 endif()
 346 if (${CMAKE_CXX_COMPILER_ID} MATCHES "Clang" AND CMAKE_CXX_COMPILER_VERSION VERSION_LESS "3.3")
 347     set(GMX_USE_CLANG_CXX_FMA_BUG_WORKAROUND TRUE)
 348 endif()
 349
 350 if (CMAKE_C_COMPILER_ID STREQUAL "PGI")
 351     message(WARNING "All tested PGI compiler versions (up to 12.9.0) generate binaries which produce incorrect results, or even fail to compile Gromacs. Highly recommended to use a different compiler. If you choose to use PGI, make sure to run the regressiontests.")
 352 endif()
 353
 354 if(CMAKE_C_COMPILER_ID MATCHES "Intel" AND CMAKE_C_COMPILER_VERSION VERSION_LESS "12.0.0")
 355     message(WARNING "Intel compilers before 12.0.0 are not routinely tested, so there may be problems. Version 11.1 with SSE4.1 is known to produce incorrect results. It is highly recommended to use a more up-to-date compiler. If you choose to use this version, make sure you run the regressiontests.")
 356 endif()
 357
 358 set(PKG_CFLAGS "")
 359 if(GMX_DOUBLE)
 360     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 361 endif(GMX_DOUBLE)
 362 if(GMX_SOFTWARE_INVSQRT)
 363   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 364 endif(GMX_SOFTWARE_INVSQRT)
 365
 366
 367
 368 ########################################################################
 369 # Basic system tests (standard libraries, headers, functions, types)   #
 370 ########################################################################
 371 include(CheckIncludeFiles)
 372 include(CheckIncludeFileCXX)
 373 check_include_files(unistd.h     HAVE_UNISTD_H)
 374 check_include_files(pwd.h        HAVE_PWD_H)
 375 check_include_files(dirent.h     HAVE_DIRENT_H)
 376 check_include_files(time.h       HAVE_TIME_H)
 377 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 378 check_include_files(io.h         HAVE_IO_H)
 379 check_include_files(sched.h      HAVE_SCHED_H)
 380
 381 check_include_files(regex.h      HAVE_POSIX_REGEX)
 382 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 383 # TODO: It could be nice to inform the user if no regex support is found,
 384 # as selections won't be fully functional.
 385
 386 include(CheckFunctionExists)
 387 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 388 check_function_exists(memalign          HAVE_MEMALIGN)
 389 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 390 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 391 check_function_exists(fsync             HAVE_FSYNC)
 392 check_function_exists(_fileno           HAVE__FILENO)
 393 check_function_exists(fileno            HAVE_FILENO)
 394 check_function_exists(_commit           HAVE__COMMIT)
 395 check_function_exists(sigaction         HAVE_SIGACTION)
 396 check_function_exists(sysconf           HAVE_SYSCONF)
 397 check_function_exists(sched_setaffinity HAVE_SCHED_SETAFFINITY)
 398 check_function_exists(sched_getaffinity HAVE_SCHED_GETAFFINITY)
 399 check_function_exists(rsqrt             HAVE_RSQRT)
 400 check_function_exists(rsqrtf            HAVE_RSQRTF)
 401 check_function_exists(sqrtf             HAVE_SQRTF)
 402
 403 include(CheckLibraryExists)
 404 check_library_exists(m sqrt "" HAVE_LIBM)
 405 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 406
 407
 408 include(CheckTypeSize)
 409
 410 check_type_size("int"           SIZEOF_INT)
 411 check_type_size("long int"      SIZEOF_LONG_INT)
 412 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 413 check_type_size("off_t"         SIZEOF_OFF_T)
 414 check_type_size("void *"        SIZEOF_VOIDP)
 415
 416 include(TestBigEndian)
 417 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 418
 419 # Management of GROMACS options for specific toolchains should go
 420 # here. Because the initial settings for some of the main options have
 421 # already happened, but things like library detection and MPI compiler
 422 # feature detection have not, the docstrings for any over-rides of
 423 # GROMACS defaults or user settings will make sense. Also, any
 424 # toolchain-related reasons for choosing whether to detect various
 425 # things can be sorted out now, before the detection takes place.
 426 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 427     include(gmxManageBlueGene)
 428 endif()
 429
 430 ########################################################################
 431 #Process MPI settings
 432 ########################################################################
 433 include(gmxManageMPI)
 434
 435 ########################################################################
 436 # Shared/static library settings
 437 ########################################################################
 438 # Determine the defaults (this block has no effect if the variables have
 439 # already been set)
 440 if(APPLE OR CYGWIN OR ${CMAKE_SYSTEM_NAME} MATCHES "Linux|.*BSD")
 441     # Maybe Solaris should be here? Patch this if you know!
 442     SET(SHARED_LIBS_DEFAULT ON)
 443 elseif(WIN32 OR ${CMAKE_SYSTEM_NAME} MATCHES "BlueGene")
 444     # Support for shared libs on native Windows is a bit new. Its
 445     # default might change later if/when we sort things out. Also,
 446     # Cray should go here. What variable value can detect it?
 447     SET(SHARED_LIBS_DEFAULT OFF)
 448 else()
 449     if (NOT DEFINED BUILD_SHARED_LIBS)
 450         message(STATUS "Defaulting to building static libraries")
 451     endif()
 452     SET(SHARED_LIBS_DEFAULT OFF)
 453 endif()
 454 if (GMX_PREFER_STATIC_LIBS)
 455     if (NOT DEFINED BUILD_SHARED_LIBS AND SHARED_LIBS_DEFAULT)
 456         message("Searching for static libraries requested, so the GROMACS libraries will also be built statically (BUILD_SHARED_LIBS=OFF)")
 457     endif()
 458     set(SHARED_LIBS_DEFAULT OFF)
 459 endif()
 460 set(GMX_PREFER_STATIC_LIBS_DEFAULT OFF)
 461 if (WIN32 AND NOT CYGWIN AND NOT BUILD_SHARED_LIBS)
 462     set(GMX_PREFER_STATIC_LIBS_DEFAULT ON)
 463 endif()
 464
 465 # Declare the user-visible options
 466 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic e.g. with MPI, or on some HPC systems)" ${SHARED_LIBS_DEFAULT})
 467 if (UNIX)
 468     set(GMX_PREFER_STATIC_LIBS_DESCRIPTION
 469         "When finding libraries prefer static archives (it will only work if static versions of external dependencies are available and found)")
 470 elseif (WIN32 AND NOT CYGWIN)
 471     set(GMX_PREFER_STATIC_LIBS_DESCRIPTION
 472         "When finding libraries prefer static system libraries (MT instead of MD)")
 473 endif()
 474 option(GMX_PREFER_STATIC_LIBS "${GMX_PREFER_STATIC_LIBS_DESCRIPTION}"
 475        ${GMX_PREFER_STATIC_LIBS_DEFAULT})
 476 mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 477
 478 # Act on the set values
 479 if (UNIX AND GMX_PREFER_STATIC_LIBS)
 480     if(BUILD_SHARED_LIBS)
 481         # Warn the user about the combination. But don't overwrite the request.
 482         message(WARNING "Searching for static libraries requested, and building shared Gromacs libraries requested. This might cause problems linking later.")
 483     endif()
 484     # On Linux .a is the static library suffix, on Mac OS X .lib can also
 485     # be used, so we'll add both to the preference list.
 486     SET(CMAKE_FIND_LIBRARY_SUFFIXES ".lib;.a" ${CMAKE_FIND_LIBRARY_SUFFIXES})
 487 endif()
 488 IF( WIN32 AND NOT CYGWIN)
 489   if (NOT BUILD_SHARED_LIBS)
 490       if(NOT GMX_PREFER_STATIC_LIBS)
 491           message(WARNING "Shared system libraries requested, and static Gromacs libraries requested.")
 492       endif()
 493   else()
 494       message(FATAL_ERROR "BUILD_SHARED_LIBS=ON not yet working for Windows in the master branch")
 495       if(GMX_PREFER_STATIC_LIBS)
 496           #this combination segfaults (illegal passing of file handles)
 497           message(FATAL_ERROR "Static system libraries requested, and shared Gromacs libraries requested.")
 498       endif()
 499       add_definitions(-DUSE_VISIBILITY -DTMPI_USE_VISIBILITY)
 500       set(PKG_CFLAGS "$PKG_CFLAGS -DUSE_VISIBILITY -DTMPI_USE_VISIBILITY")
 501   endif()
 502
 503   IF (GMX_PREFER_STATIC_LIBS)
 504       #Only setting Debug and Release flags. Others configurations are current not used.
 505       STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
 506       STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
 507       STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE})
 508       STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 509   ENDIF()
 510   IF( CMAKE_C_COMPILER_ID MATCHES "Intel" )
 511     if(BUILD_SHARED_LIBS) #not sure why incremental building with shared libs doesn't work
 512         STRING(REPLACE "/INCREMENTAL:YES" "" CMAKE_SHARED_LINKER_FLAGS ${CMAKE_SHARED_LINKER_FLAGS})
 513     endif()
 514   ENDIF()
 515 ENDIF()
 516
 517 ########################################################################
 518 # Find external packages                                               #
 519 ########################################################################
 520
 521 # Unconditionally find the package, as it is also required for unit tests
 522 find_package(LibXml2)
 523 option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${LIBXML2_FOUND})
 524 set(PKG_XML "")
 525 mark_as_advanced(GMX_XML)
 526 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 527 #if(GMX_XML AND NOT LIBXML2_FOUND)
 528 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 529 #endif()
 530 #if(GMX_XML)
 531 #    include_directories(${LIBXML2_INCLUDE_DIR})
 532 #    set(PKG_XML libxml-2.0)
 533 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 534 #endif(GMX_XML)
 535
 536 option(GMX_GSL "Add support for gsl" OFF)
 537 if (GMX_GSL)
 538   find_package(GSL)
 539   set(PKG_GSL "")
 540   if(GSL_FOUND)
 541     include_directories(${GSL_INCLUDE_DIR})
 542     set(PKG_GSL gsl)
 543     set(HAVE_LIBGSL 1)
 544   endif(GSL_FOUND)
 545 endif (GMX_GSL)
 546
 547 option(GMX_X11 "Use X window system" OFF)
 548 if (GMX_X11)
 549     find_package(X11)
 550     # X11 includes/libraries are only set in the ngmx subdirectory!
 551     if(NOT X11_FOUND)
 552         message(FATAL_ERROR
 553                 "X11 include files and/or libraries were not found. "
 554                 "Set GMX_X11=OFF to compile without X11 support. "
 555                 "gmx view will not be available.")
 556     endif()
 557     include_directories(${X11_INCLUDE_DIR})
 558 endif(GMX_X11)
 559
 560 include(ThreadMPI)
 561 set(THREAD_MPI_LIB thread_mpi)
 562 # Enable core threading facilities
 563 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders")
 564 # Enable tMPI C++ support
 565 tmpi_enable_cxx()
 566 if(GMX_THREAD_MPI)
 567     # enable MPI functions
 568     tmpi_enable()
 569     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREAD_MPI")
 570     set(GMX_MPI 1)
 571     set(MPI_IN_PLACE_EXISTS 1)
 572 endif(GMX_THREAD_MPI)
 573 tmpi_get_source_list(THREAD_MPI_SRC)
 574
 575 if(GMX_GPU)
 576     # now that we have detected the dependencies, do the second configure pass
 577     gmx_gpu_setup()
 578 endif(GMX_GPU)
 579
 580 if(CYGWIN)
 581     set(GMX_CYGWIN 1)
 582 endif(CYGWIN)
 583
 584 if(WIN32 AND NOT CYGWIN)
 585     set(GMX_NATIVE_WINDOWS 1)
 586     # This makes windows.h not declare min/max as macros that would break
 587     # C++ code using std::min/std::max.
 588     add_definitions(-DNOMINMAX)
 589 endif()
 590
 591 # only bother with finding git and using version.h if the source is a git repo
 592 if(GMX_GIT_VERSION_INFO)
 593     if (NOT SOURCE_IS_GIT_REPOSITORY)
 594         message(FATAL_ERROR
 595             "Cannot generate git version information from source tree not under git. "
 596             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 597     endif ()
 598     # We need at least git v1.5.3 be able to parse git's date output. If not
 599     # found or the version is too small, we can't generate version information.
 600     find_package(Git)
 601
 602     if(NOT GIT_FOUND OR GIT_VERSION_STRING VERSION_LESS "1.5.3")
 603         message(FATAL_ERROR
 604             "No compatible git version found (>= 1.5.3 required). "
 605             "Won't be able to generate development version information. "
 606             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 607     endif()
 608 endif()
 609
 610 # Detect boost unless GMX_EXTERNAL_BOOST is explicitly OFF
 611 # Used for default if GMX_EXTERNAL_BOOST is not defined (first CMake pass)
 612 if(NOT DEFINED GMX_EXTERNAL_BOOST OR GMX_EXTERNAL_BOOST)
 613     find_package(Boost 1.44.0)
 614     if(Boost_FOUND AND Boost_VERSION VERSION_LESS "104400")
 615         set(Boost_FOUND FALSE)
 616     endif()
 617     # Print the notification only on first run, when determining the default
 618     if(NOT DEFINED GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 619         message("Boost >= 1.44 not found. Using minimal internal version. "
 620                 "This may cause trouble if you plan on compiling/linking other "
 621                 "software that uses Boost against Gromacs.")
 622     endif()
 623 endif()
 624 option(GMX_EXTERNAL_BOOST "Use external Boost instead of minimal built-in version"
 625        ${Boost_FOUND})
 626 if(GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 627     message(FATAL_ERROR
 628         "Boost >= 1.44 not found. "
 629         "You can set GMX_EXTERNAL_BOOST=OFF to compile against minimal "
 630         "version of Boost included with Gromacs.")
 631 endif()
 632
 633 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ${LIBXML2_FOUND})
 634 mark_as_advanced(GMX_BUILD_UNITTESTS)
 635 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 636 if (GMX_BUILD_UNITTESTS AND NOT LIBXML2_FOUND)
 637     message(FATAL_ERROR
 638         "Cannot build unit tests without libxml2. "
 639         "Either set GMX_BUILD_UNITTESTS=OFF or tell CMake how to find libxml2.")
 640 endif()
 641
 642 ########################################################################
 643 # Generate development version info for cache
 644 ########################################################################
 645 # set(GEN_VERSION_INFO_INTERNAL "ON")
 646 # include(gmxGenerateVersionString)
 647
 648 ########################################################################
 649 # Our own GROMACS tests
 650 ########################################################################
 651
 652 add_definitions( -DHAVE_CONFIG_H )
 653 include_directories(${CMAKE_SOURCE_DIR}/src)
 654 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 655 include_directories(${CMAKE_BINARY_DIR}/src)
 656 # Required for gmx_header_config_gen.h to be found before installation
 657 include_directories(${CMAKE_BINARY_DIR}/src/gromacs/utility)
 658 # Required for now to make old code compile
 659 include_directories(${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders)
 660
 661 include(gmxTestInlineASM)
 662 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 663
 664 include(gmxSetBuildInformation)
 665 gmx_set_build_information()
 666 if(BUILD_CPU_FEATURES MATCHES "rdtscp" AND NOT GMX_DISTRIBUTABLE_BUILD)
 667     set(HAVE_RDTSCP 1)
 668 endif(BUILD_CPU_FEATURES MATCHES "rdtscp" AND NOT GMX_DISTRIBUTABLE_BUILD)
 669
 670 include(gmxTestFloatFormat)
 671 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 672                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 673                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 674
 675 include(gmxTestLargeFiles)
 676 gmx_test_large_files(GMX_LARGEFILES)
 677
 678 include(gmxTestSignal)
 679 gmx_test_sigusr1(HAVE_SIGUSR1)
 680
 681 include(gmxTestInline)
 682 gmx_test_inline(INLINE_KEYWORD)
 683
 684 include(gmxTestRestrict)
 685 gmx_test_restrict(RESTRICT_KEYWORD)
 686
 687 include(gmxTestPipes)
 688 gmx_test_pipes(HAVE_PIPES)
 689
 690 include(gmxTestIsfinite)
 691 gmx_test_isfinite(HAVE_ISFINITE)
 692 gmx_test__isfinite(HAVE__ISFINITE)
 693 gmx_test__finite(HAVE__FINITE)
 694
 695 include(gmxTestCXX11)
 696 gmx_test_cxx11(GMX_CXX11 GMX_CXX11_FLAGS)
 697 if(CXX11_FLAG AND GMX_GPU)
 698     #FIXME: add proper solution for progate all but cxx11 flag
 699     set(CUDA_PROPAGATE_HOST_FLAGS no)
 700     message(WARNING "Please manually add compiler flags to CUDA_NVCC_FLAGS. Automatic propogation temporary not working.")
 701 endif()
 702
 703 include(gmxTestXDR)
 704 gmx_test_xdr(GMX_SYSTEM_XDR)
 705 if(NOT GMX_SYSTEM_XDR)
 706     set(GMX_INTERNAL_XDR 1)
 707 endif(NOT GMX_SYSTEM_XDR)
 708
 709 # include avx test source, used if the AVX flags are set below
 710 include(gmxTestAVXMaskload)
 711
 712 # Process nonbonded accelerated kernels settings
 713 #
 714 # Note that for the backward-compatible x86 SIMD architectures, the
 715 # GMX_CPU_ACCELERATION determines the maximum level of the instruction
 716 # set used (e.g. GMX_CPU_ACCLERATION=SSE4.1 implies
 717 # SSE2). Accordingly, there are a set of CMake variables
 718 # GMX_<arch>_<feature-set> that are exported to the C code to specify
 719 # CPU features that should be used. This means that the logic for
 720 # requiring such backward compatibility is all located here.
 721 if(${GMX_CPU_ACCELERATION} STREQUAL "NONE")
 722     # nothing to do
 723     set(ACCELERATION_STATUS_MESSAGE "CPU acceleration disabled")
 724
 725 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SSE2")
 726
 727     GMX_TEST_CFLAG(GNU_SSE2_CFLAG "-msse2" ACCELERATION_C_FLAGS)
 728     if(NOT GNU_SSE2_CFLAG AND GMX_NATIVE_WINDOWS)
 729         GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" ACCELERATION_C_FLAGS)
 730     endif(NOT GNU_SSE2_CFLAG AND GMX_NATIVE_WINDOWS)
 731
 732     GMX_TEST_CXXFLAG(GNU_SSE2_CXXFLAG "-msse2" ACCELERATION_CXX_FLAGS)
 733     if(NOT GNU_SSE2_CXXFLAG AND GMX_NATIVE_WINDOWS)
 734         GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" ACCELERATION_CXX_FLAGS)
 735     endif(NOT GNU_SSE2_CXXFLAG AND GMX_NATIVE_WINDOWS)
 736
 737     # We dont warn for lacking SSE2 flag support, since that is probably standard today.
 738
 739     # Only test the include after we have tried to add the correct flag for SSE2 support
 740     check_include_file(emmintrin.h  HAVE_EMMINTRIN_H ${ACCELERATION_C_FLAGS})
 741
 742     if(NOT HAVE_EMMINTRIN_H)
 743         message(FATAL_ERROR "Cannot find emmintrin.h, which is required for SSE2 intrinsics support.")
 744     endif(NOT HAVE_EMMINTRIN_H)
 745
 746     set(GMX_CPU_ACCELERATION_X86_SSE2 1)
 747     # The user should not be able to set this orthogonally to the acceleration
 748     set(GMX_X86_SSE2 1)
 749     set(ACCELERATION_STATUS_MESSAGE
 750         "Enabling SSE2 Gromacs acceleration")
 751
 752 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SSE4.1")
 753
 754     GMX_TEST_CFLAG(GNU_SSE4_CFLAG "-msse4.1" ACCELERATION_C_FLAGS)
 755     if (NOT GNU_SSE4_CFLAG AND GMX_NATIVE_WINDOWS)
 756         GMX_TEST_CFLAG(MSVC_SSE4_CFLAG "/arch:SSE4.1" ACCELERATION_C_FLAGS)
 757     endif(NOT GNU_SSE4_CFLAG AND GMX_NATIVE_WINDOWS)
 758     if (NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 759         # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 760         # intrinsics when SSE2 support is enabled, so we try that instead first.
 761         if (GMX_NATIVE_WINDOWS)
 762             GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" ACCELERATION_C_FLAGS)
 763             message(WARNING "Neither SSE4.1 or SSE2 seems to be supported by your Windows compiler. Something is likely broken.")
 764         else()
 765             message(WARNING "No C SSE4.1 flag found. Consider a newer compiler, or use SSE2 for slightly lower performance")
 766         endif()
 767     endif(NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 768
 769     GMX_TEST_CXXFLAG(GNU_SSE4_CXXFLAG "-msse4.1" ACCELERATION_CXX_FLAGS)
 770     if (NOT GNU_SSE4_CXXFLAG AND GMX_NATIVE_WINDOWS)
 771         GMX_TEST_CXXFLAG(MSVC_SSE4_CXXFLAG "/arch:SSE4.1" ACCELERATION_CXX_FLAGS)
 772     endif(NOT GNU_SSE4_CXXFLAG AND GMX_NATIVE_WINDOWS)
 773     if (NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 774         message(WARNING "No C++ SSE4.1 flag found. Consider a newer compiler, or use SSE2 for slightly lower performance.")
 775         # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 776         # intrinsics when SSE2 support is enabled, so we try that instead.
 777         if (GMX_NATIVE_WINDOWS)
 778             GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" ACCELERATION_CXX_FLAGS)
 779         endif()
 780     endif(NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 781
 782     # This must come after we have added the -msse4.1 flag on some platforms.
 783     check_include_file(smmintrin.h  HAVE_SMMINTRIN_H ${ACCELERATION_C_FLAGS})
 784
 785     if(NOT HAVE_SMMINTRIN_H)
 786         message(FATAL_ERROR "Cannot find smmintrin.h, which is required for SSE4.1 intrinsics support.")
 787     endif(NOT HAVE_SMMINTRIN_H)
 788
 789     if(CMAKE_C_COMPILER_ID MATCHES "Intel" AND CMAKE_C_COMPILER_VERSION VERSION_EQUAL "11.1")
 790         message(FATAL_ERROR "You are using Intel compiler version 11.1, and that compiler is known to produce incorrect results with SSE4.1 acceleration. You need to use another compiler (e.g. icc 12 or newer) or different acceleration (probably slower simulations).")
 791     endif()
 792
 793     set(GMX_CPU_ACCELERATION_X86_SSE4_1 1)
 794     # The user should not be able to set this orthogonally to the acceleration
 795     set(GMX_X86_SSE4_1 1)
 796     set(GMX_X86_SSE2   1)
 797     set(ACCELERATION_STATUS_MESSAGE
 798         "Enabling SSE4.1 Gromacs acceleration")
 799
 800 elseif(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA" OR ${GMX_CPU_ACCELERATION} STREQUAL "AVX_256")
 801
 802     # Set the AVX compiler flag for both these choices!
 803
 804     GMX_TEST_CFLAG(GNU_AVX_CFLAG "-mavx" ACCELERATION_C_FLAGS)
 805     if (NOT GNU_AVX_CFLAG AND GMX_NATIVE_WINDOWS)
 806         GMX_TEST_CFLAG(MSVC_AVX_CFLAG "/arch:AVX" ACCELERATION_C_FLAGS)
 807     endif (NOT GNU_AVX_CFLAG AND GMX_NATIVE_WINDOWS)
 808     if (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 809         message(WARNING "No C AVX flag found. Consider a newer compiler, or try SSE4.1 (lower performance) giving the -DGMX_CPU_ACCELERATION=SSE4.1 to cmake.")
 810     endif (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 811
 812     GMX_TEST_CXXFLAG(GNU_AVX_CXXFLAG "-mavx" ACCELERATION_CXX_FLAGS)
 813     if (NOT GNU_AVX_CXXFLAG AND GMX_NATIVE_WINDOWS)
 814         GMX_TEST_CXXFLAG(MSVC_AVX_CXXFLAG "/arch:AVX" ACCELERATION_CXX_FLAGS)
 815     endif (NOT GNU_AVX_CXXFLAG AND GMX_NATIVE_WINDOWS)
 816     if (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 817         message(WARNING "No C++ AVX flag found. Consider a newer compiler, or try SSE4.1 (lower performance) giving the -DGMX_CPU_ACCELERATION=SSE4.1 to cmake.")
 818     endif (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 819
 820     # Set the FMA4 flags (MSVC doesn't require any)
 821     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA" AND NOT MSVC)
 822         GMX_TEST_CFLAG(GNU_FMA_CFLAG "-mfma4" ACCELERATION_C_FLAGS)
 823         if (NOT GNU_FMA_CFLAG)
 824             message(WARNING "No C FMA4 flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 825         endif(NOT GNU_FMA_CFLAG)
 826         GMX_TEST_CFLAG(GNU_XOP_CFLAG "-mxop" ACCELERATION_C_FLAGS)
 827         # No big deal if we do not have xop, so no point yelling warnings about it.
 828         GMX_TEST_CXXFLAG(GNU_FMA_CXXFLAG "-mfma4" ACCELERATION_CXX_FLAGS)
 829         if (NOT GNU_FMA_CXXFLAG)
 830             message(WARNING "No C++ FMA flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 831         endif (NOT GNU_FMA_CXXFLAG)
 832         GMX_TEST_CXXFLAG(GNU_XOP_CXXFLAG "-mxop" ACCELERATION_CXX_FLAGS)
 833         # No big deal if we do not have xop, so no point yelling warnings about it.
 834     endif()
 835
 836     # Only test the header after we have tried to add the flag for AVX support
 837     check_include_file(immintrin.h  HAVE_IMMINTRIN_H ${ACCELERATION_C_FLAGS})
 838
 839     if(NOT HAVE_IMMINTRIN_H)
 840         message(FATAL_ERROR "Cannot find immintrin.h, which is required for AVX intrinsics support. Consider switching compiler.")
 841     endif(NOT HAVE_IMMINTRIN_H)
 842
 843     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_256")
 844         try_compile(TEST_AVX ${CMAKE_BINARY_DIR}
 845             "${CMAKE_SOURCE_DIR}/cmake/TestAVX.c"
 846             COMPILE_DEFINITIONS "${ACCELERATION_C_FLAGS}")
 847         if(NOT TEST_AVX)
 848             message(FATAL_ERROR "Cannot compile AVX intrinsics. Consider switching compiler.")
 849         endif()
 850     endif()
 851
 852     # GCC requires x86intrin.h for FMA support. MSVC 2010 requires intrin.h for FMA support.
 853     check_include_file(x86intrin.h HAVE_X86INTRIN_H ${ACCELERATION_C_FLAGS})
 854     check_include_file(intrin.h HAVE_INTRIN_H ${ACCELERATION_C_FLAGS})
 855
 856     # The user should not be able to set this orthogonally to the acceleration
 857     set(GMX_X86_SSE4_1 1)
 858     set(GMX_X86_SSE2   1)
 859
 860     # But just enable one of the choices internally...
 861     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA")
 862         # We don't have the full compiler version string yet (BUILD_C_COMPILER),
 863         # so we can't distinguish vanilla and Apple clang, but catering for AMD
 864         # hackintoshes is not worth the effort.
 865         if (APPLE AND (${CMAKE_C_COMPILER_ID} STREQUAL "Clang" OR
 866                     ${CMAKE_CXX_COMPILER_ID} STREQUAL "Clang"))
 867             message(WARNING "Due to a known compiler bug, Clang up to version 3.2 (and Apple Clang up to version 4.1) produces incorrect code with AVX_128_FMA acceleration. As we can not work around this bug on OS X, you will have to select a different compiler or CPU acceleration.")
 868         endif()
 869
 870         if (GMX_USE_CLANG_C_FMA_BUG_WORKAROUND)
 871             # we assume that we have an external assembler that supports AVX
 872             message(STATUS "Clang ${CMAKE_C_COMPILER_VERSION} detected, enabling FMA bug workaround")
 873             set(EXTRA_C_FLAGS "${EXTRA_C_FLAGS} -no-integrated-as")
 874         endif()
 875         if (GMX_USE_CLANG_CXX_FMA_BUG_WORKAROUND)
 876             # we assume that we have an external assembler that supports AVX
 877             message(STATUS "Clang ${CMAKE_CXX_COMPILER_VERSION} detected, enabling FMA bug workaround")
 878             set(EXTRA_CXX_FLAGS "${EXTRA_CXX_FLAGS} -no-integrated-as")
 879         endif()
 880
 881         set(GMX_CPU_ACCELERATION_X86_AVX_128_FMA 1)
 882         set(GMX_X86_AVX_128_FMA 1)
 883         set(ACCELERATION_STATUS_MESSAGE
 884             "Enabling 128-bit AVX Gromacs acceleration (with fused-multiply add)")
 885
 886     else()
 887         # If we are not doing AVX_128, it must be AVX_256...
 888         set(GMX_CPU_ACCELERATION_X86_AVX_256 1)
 889         set(GMX_X86_AVX_256 1)
 890         set(ACCELERATION_STATUS_MESSAGE
 891             "Enabling 256-bit AVX Gromacs acceleration")
 892     endif()
 893
 894     # Unfortunately gcc-4.5.2 and gcc-4.6.0 has a bug where they use the wrong datatype for the formal
 895     # parameter of the mask for maskload/maskstore arguments. Check if this is present, since we can work around it.
 896     gmx_test_avx_gcc_maskload_bug(${ACCELERATION_C_FLAGS} GMX_X86_AVX_GCC_MASKLOAD_BUG)
 897
 898 elseif(${GMX_CPU_ACCELERATION} STREQUAL "IBM_QPX")
 899     try_compile(TEST_QPX ${CMAKE_BINARY_DIR}
 900         "${CMAKE_SOURCE_DIR}/cmake/TestQPX.c")
 901
 902     if (TEST_QPX)
 903         message(WARNING "IBM QPX acceleration was selected. This will work, but SIMD-accelerated kernels are only available for the Verlet cut-off scheme. The plain C kernels that are used for the group cut-off scheme kernels will be slow, so please consider using the Verlet cut-off scheme.")
 904         set(GMX_CPU_ACCELERATION_IBM_QPX 1)
 905     else()
 906         message(FATAL_ERROR "Cannot compile the requested IBM QPX intrinsics. If you are compiling for BlueGene/Q with the XL compilers, use 'cmake .. -DCMAKE_TOOLCHAIN_FILE=Platform/BlueGeneQ-static-XL-C' to set up the tool chain.")
 907     endif()
 908 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SPARC64_HPC_ACE")
 909     set(GMX_CPU_ACCELERATION_SPARC64_HPC_ACE 1)
 910 else()
 911     gmx_invalid_option_value(GMX_CPU_ACCELERATION)
 912 endif()
 913 gmx_check_if_changed(ACCELERATION_CHANGED GMX_CPU_ACCELERATION)
 914 if (ACCELERATION_CHANGED AND DEFINED ACCELERATION_STATUS_MESSAGE)
 915     message(STATUS "${ACCELERATION_STATUS_MESSAGE}")
 916 endif()
 917
 918 # Process QM/MM Settings
 919 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 920     set(GMX_QMMM_GAUSSIAN 1)
 921 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 922     set(GMX_QMMM_MOPAC 1)
 923 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 924     set(GMX_QMMM_GAMESS 1)
 925 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 926     set(GMX_QMMM_ORCA 1)
 927 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 928     # nothing to do
 929 else()
 930     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 931 endif()
 932
 933 # Process FFT library settings
 934 set(PKG_FFT "")
 935 set(PKG_FFT_LIBS "")
 936 # Intel 11 and up makes life somewhat easy if you just want to use
 937 # all their stuff. It's not easy if you only want some of their
 938 # stuff...
 939 set(MKL_MANUALLY FALSE)
 940 if (GMX_FFT_LIBRARY STREQUAL "MKL" AND
 941     NOT (CMAKE_C_COMPILER_ID MATCHES "Intel" AND CMAKE_C_COMPILER_VERSION VERSION_GREATER "11"))
 942     # The user will have to provide the set of magic libraries in
 943     # MKL_LIBRARIES (see below), which we cache (non-advanced), so that they
 944     # don't have to keep specifying it, and can easily see that
 945     # CMake is still using that information.
 946     set(MKL_MANUALLY TRUE)
 947 endif()
 948 set(MKL_LIBRARIES_FORMAT_DESCRIPTION "Use full paths to library files, in the right order, and separated by semicolons.")
 949 gmx_dependent_cache_variable(
 950     MKL_LIBRARIES
 951     "List of libraries for linking to MKL. ${MKL_LIBRARIES_FORMAT_DESCRIPTION}"
 952     STRING ""
 953     MKL_MANUALLY)
 954 gmx_dependent_cache_variable(
 955     MKL_INCLUDE_DIR
 956     "Path to mkl.h (non-inclusive)."
 957     PATH ""
 958     MKL_MANUALLY)
 959 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 960     if(GMX_DOUBLE)
 961         set(FFTW fftw)
 962     else()
 963         set(FFTW fftwf)
 964     endif()
 965
 966     if(GMX_BUILD_OWN_FFTW)
 967       add_subdirectory(src/contrib/fftw)
 968     else()
 969       find_package(FFTW COMPONENTS ${FFTW})
 970     endif()
 971
 972     string(TOUPPER "${FFTW}" FFTW)
 973     if(NOT ${FFTW}_FOUND)
 974       MESSAGE(FATAL_ERROR "Cannot find FFTW 3 (with correct precision - libfftw3f for single-precision GROMACS or libfftw3 for double-precision GROMACS). Either choose the right precision, choose another FFT(W) library (-DGMX_FFT_LIBRARY), enable the advanced option to let GROMACS build FFTW 3 for you (-DGMX_BUILD_OWN_FFTW=ON) , or use the really slow GROMACS built-in fftpack library (-DGMX_FFT_LIBRARY=fftpack).")
 975     endif()
 976
 977     set(PKG_FFT "${${FFTW}_PKG}")
 978     include_directories(${${FFTW}_INCLUDE_DIRS})
 979     set(FFT_LIBRARIES ${${FFTW}_LIBRARIES})
 980     set(GMX_FFT_FFTW3 1)
 981
 982     if ((${GMX_CPU_ACCELERATION} MATCHES "SSE" OR ${GMX_CPU_ACCELERATION} MATCHES "AVX") AND NOT ${FFTW}_HAVE_SIMD)
 983       message(WARNING "The fftw library found is compiled without SIMD support, which makes it slow. Consider recompiling it or contact your admin")
 984     endif()
 985
 986     if((${GMX_CPU_ACCELERATION} MATCHES "SSE" OR ${GMX_CPU_ACCELERATION} MATCHES "AVX") AND ${FFTW}_HAVE_AVX)
 987         # If we're not doing CPU acceleration, we don't care about FFTW performance on x86 either
 988         message(WARNING "The FFTW library was compiled with --enable-avx to enable AVX SIMD instructions. That might sound like a good idea for your processor, but for FFTW versions up to 3.3.3, these are slower than the SSE/SSE2 SIMD instructions for the way GROMACS uses FFTs. Limitations in the way FFTW allows GROMACS to measure performance make it awkward for either GROMACS or FFTW to make the decision for you based on runtime performance. You should compile a different FFTW library with --enable-sse or --enable-sse2. If you have a more recent FFTW, you may like to compare the performance of GROMACS with FFTW libraries compiled with and without --enable-avx. However, the GROMACS developers do not really expect the FFTW AVX optimization to help, because the performance is limited by memory access, not computation.")
 989     endif()
 990
 991     set(FFT_STATUS_MESSAGE "Using external FFT library - FFTW3")
 992 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 993     # Intel 11 and up makes life somewhat easy if you just want to use
 994     # all their stuff. It's not easy if you only want some of their
 995     # stuff...
 996     if (NOT MKL_MANUALLY)
 997         # The next line takes care of everything for MKL
 998         if (WIN32)
 999             set(FFT_LINKER_FLAGS "/Qmkl=sequential")
1000         else()
1001             set(FFT_LINKER_FLAGS "-mkl=sequential")
1002         endif()
1003         # Some versions of icc require this in order that mkl.h can be
1004         # found at compile time.
1005         set(EXTRA_C_FLAGS "${EXTRA_C_FLAGS} ${FFT_LINKER_FLAGS}")
1006
1007         set(MKL_ERROR_MESSAGE "Make sure you have configured your compiler so that ${FFT_LINKER_FLAGS} will work.")
1008     else()
1009         include_directories(${MKL_INCLUDE_DIR})
1010         set(FFT_LIBRARIES "${MKL_LIBRARIES}")
1011         set(MKL_ERROR_MESSAGE "The include path to mkl.h in MKL_INCLUDE_DIR, and the link libraries in MKL_LIBRARIES=${MKL_LIBRARIES} need to match what the MKL documentation says you need for your system. ${MKL_LIBRARIES_FORMAT_DESCRIPTION}")
1012         # Convert the semi-colon separated list to a list of
1013         # command-line linker arguments so that code using our
1014         # pkgconfig setup can use it.
1015         string(REGEX REPLACE ";" " " PKG_FFT_LIBS "${MKL_LIBRARIES}")
1016     endif()
1017
1018     # Check MKL works. If we were in a non-global scope, we wouldn't
1019     # have to play nicely.
1020     set(old_CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
1021     set(CMAKE_REQUIRED_FLAGS "${FFT_LINKER_FLAGS}")
1022     set(old_CMAKE_REQUIRED_LIBRARIES "${CMAKE_REQUIRED_LIBRARIES}")
1023     set(CMAKE_REQUIRED_LIBRARIES "${FFT_LIBRARIES}")
1024
1025     check_function_exists(DftiCreateDescriptor TEST_MKL)
1026
1027     set(CMAKE_REQUIRED_FLAGS "${old_CMAKE_REQUIRED_FLAGS}")
1028     set(CMAKE_REQUIRED_LIBRARIES "${old_CMAKE_REQUIRED_LIBRARIES}")
1029
1030     if(NOT TEST_MKL)
1031         # Hack to help the user vary MKL settings until they work.
1032         # TODO Make this logic more useful.
1033         unset(TEST_MKL CACHE)
1034         message(FATAL_ERROR "Linking with MKL was requested, but was not successful. ${MKL_ERROR_MESSAGE}")
1035     endif()
1036
1037     # Set variables to signal that we have MKL available and should use it for FFTs.
1038     set(GMX_FFT_MKL 1)
1039     set(HAVE_LIBMKL 1)
1040
1041     set(FFT_STATUS_MESSAGE "Using external FFT library - Intel MKL")
1042 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
1043     set(GMX_FFT_FFTPACK 1)
1044     set(FFT_STATUS_MESSAGE "Using internal FFT library - fftpack")
1045 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
1046     gmx_invalid_option_value(GMX_FFT_LIBRARY)
1047 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
1048 gmx_check_if_changed(FFT_CHANGED GMX_FFT_LIBRARY)
1049 if (FFT_CHANGED)
1050     message(STATUS "${FFT_STATUS_MESSAGE}")
1051 endif()
1052
1053 # enable threaded fftw3 if we've found it
1054 if(FFTW3_THREADS OR FFTW3F_THREADS)
1055     add_definitions(-DFFT5D_FFTW_THREADS)
1056 endif()
1057
1058 include(gmxManageLinearAlgebraLibraries)
1059
1060 # Whether GROMACS will really try to compile support for VMD plugins
1061 set(GMX_USE_PLUGINS OFF)
1062
1063 if(GMX_LOAD_PLUGINS)
1064   if(CYGWIN OR NOT WIN32)
1065     # Native Windows does not have, nor need dlopen
1066     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
1067     include(gmxTestdlopen)
1068     gmx_test_dlopen(HAVE_DLOPEN)
1069   endif()
1070
1071   # so, should we use plug-ins?
1072   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
1073     if(NOT VMD_QUIETLY)
1074       MESSAGE(STATUS
1075           "Found the ability to use plug-ins when building shared libaries, "
1076           "so will compile to use plug-ins (e.g. to read VMD-supported file "
1077           "formats).")
1078     endif()
1079     if(NOT GMX_VMD_PLUGIN_PATH)
1080       find_package(VMD)
1081     endif()
1082     set(GMX_USE_PLUGINS ON)
1083     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
1084     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
1085   else()
1086     set(PKG_DL_LIBS)
1087   endif()
1088 endif(GMX_LOAD_PLUGINS)
1089 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
1090
1091 # Link real-time library for POSIX timers. The check for clock_gettime
1092 # confirms the linkability of rt.
1093 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
1094     list(APPEND GMX_EXTRA_LIBRARIES rt)
1095 endif()
1096
1097 # Math and thread libraries must often come after all others when linking...
1098 if(HAVE_LIBM)
1099     list(APPEND GMX_EXTRA_LIBRARIES m)
1100 endif(HAVE_LIBM)
1101 if (${CMAKE_SYSTEM_NAME} MATCHES "BlueGene")
1102     check_library_exists(mass_simd atan2f4 "" HAVE_MASS_SIMD)
1103     if(HAVE_MASS_SIMD)
1104         list(APPEND GMX_EXTRA_LIBRARIES mass_simd)
1105     else()
1106         message(FATAL_ERROR "Could not link to the SIMD version of the IBM MASS library. Please adjust your CMAKE_PREFIX_PATH to contain it")
1107     endif()
1108 endif()
1109
1110 if(GMX_FAHCORE)
1111   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
1112       "Path to swindirect.h")
1113   include_directories(${COREWRAP_INCLUDE_DIR})
1114 endif(GMX_FAHCORE)
1115
1116 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
1117 # these are set after everything else
1118 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
1119     set(CMAKE_C_FLAGS "${ACCELERATION_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
1120     set(CMAKE_CXX_FLAGS "${ACCELERATION_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${GMX_CXX11_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
1121     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
1122     set(CMAKE_SHARED_LINKER_FLAGS "${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
1123 else()
1124     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
1125     message("CMAKE_C_FLAGS: ${ACCELERATION_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
1126     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
1127     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
1128     message("CMAKE_CXX_FLAGS: ${ACCELERATION_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${GMX_CXX11_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
1129     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
1130     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
1131     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
1132     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
1133 endif()
1134
1135 if(NOT GMX_OPENMP)
1136     #Unset all OpenMP flags in case OpenMP was disabled either by the user
1137     #or because it was only partially detected (e.g. only for C but not C++ compiler)
1138     unset(OpenMP_C_FLAGS CACHE)
1139     unset(OpenMP_CXX_FLAGS CACHE)
1140 else()
1141     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
1142     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
1143 endif()
1144 set(PKG_CFLAGS "${PKG_CFLAGS} ${OpenMP_C_FLAGS}")
1145
1146 ########################################################################
1147 # Specify install locations
1148 ########################################################################
1149 set(GMX_LIB_INSTALL_DIR lib CACHE STRING
1150     "Library installation directory (default: lib)")
1151 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
1152     "Data installation directory under share/ (default: gromacs)")
1153 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
1154
1155 set(LIB_INSTALL_DIR  ${GMX_INSTALL_PREFIX}${GMX_LIB_INSTALL_DIR})
1156 set(BIN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}bin)
1157 set(DATA_INSTALL_DIR ${GMX_INSTALL_PREFIX}share/${GMX_DATA_INSTALL_DIR})
1158 set(MAN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}share/man)
1159 set(INCL_INSTALL_DIR ${GMX_INSTALL_PREFIX}include)
1160
1161 set(GMXLIB_SEARCH_DIR share/${GMX_DATA_INSTALL_DIR}/top)
1162 set(GMXLIB_FALLBACK   ${CMAKE_INSTALL_PREFIX}/${DATA_INSTALL_DIR}/top)
1163
1164 ########################################################################
1165 # Set up binary and library suffixing
1166 ########################################################################
1167 option(
1168     GMX_DEFAULT_SUFFIX
1169     "Use default suffixes for GROMACS binaries and libs (_d for double, _mpi for MPI; rerun cmake after changing to see relevant options)"
1170     ON)
1171 gmx_dependent_cache_variable(
1172     GMX_BINARY_SUFFIX
1173     "Suffix for GROMACS binaries (default: _d for double, _mpi for MPI, _mpi_d for MPI and double)."
1174     STRING ""
1175     "NOT GMX_DEFAULT_SUFFIX")
1176 gmx_dependent_cache_variable(
1177     GMX_LIBS_SUFFIX
1178     "Suffix for GROMACS libraries (default: _d for double, _mpi for MPI, _mpi_d for MPI and double)."
1179     STRING ""
1180     "NOT GMX_DEFAULT_SUFFIX")
1181 if (GMX_DEFAULT_SUFFIX)
1182   gmx_check_if_changed(SUFFIXES_CHANGED GMX_DEFAULT_SUFFIX)
1183   set(GMX_BINARY_SUFFIX "")
1184   set(GMX_LIBS_SUFFIX "")
1185   if (GMX_LIB_MPI)
1186     set(GMX_BINARY_SUFFIX "_mpi")
1187     set(GMX_LIBS_SUFFIX "_mpi")
1188   endif()
1189   if (GMX_DOUBLE)
1190     set (GMX_BINARY_SUFFIX "${GMX_BINARY_SUFFIX}_d")
1191     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
1192   endif(GMX_DOUBLE)
1193   if (SUFFIXES_CHANGED)
1194     message(STATUS "Using default binary suffix: \"${GMX_BINARY_SUFFIX}\"")
1195     message(STATUS "Using default library suffix: \"${GMX_LIBS_SUFFIX}\"")
1196   endif ()
1197 else(GMX_DEFAULT_SUFFIX)
1198   gmx_check_if_changed(SUFFIXES_CHANGED
1199                        GMX_DEFAULT_SUFFIX GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
1200   if (SUFFIXES_CHANGED)
1201     message(STATUS "Using manually set binary suffix: \"${GMX_BINARY_SUFFIX}\"")
1202     message(STATUS "Using manually set library suffix: \"${GMX_LIBS_SUFFIX}\"")
1203   endif ()
1204 endif(GMX_DEFAULT_SUFFIX)
1205 if (GMX_BUILD_MDRUN_ONLY)
1206     set(GMX_LIBS_SUFFIX "_mdrun${GMX_LIBS_SUFFIX}")
1207 endif ()
1208
1209 ##################################################################
1210 # Shared library settings
1211 ##################################################################
1212 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
1213     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
1214     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
1215     set(CMAKE_INSTALL_RPATH "\\\$ORIGIN/../${GMXLIB}")
1216     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
1217 else()
1218     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) #rpath supported for >10.4
1219         set(CMAKE_INSTALL_NAME_DIR "@rpath")
1220         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../lib")
1221     else()
1222         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
1223     endif()
1224 endif()
1225
1226 #COPYING file: Only necessary for binary distributions.
1227 #Simpler to always install.
1228 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
1229
1230 if(GMX_EXTERNAL_BOOST)
1231     include_directories(${Boost_INCLUDE_DIRS})
1232 else()
1233     include_directories(${CMAKE_SOURCE_DIR}/src/external/boost)
1234     # typeid not supported for minimal internal version
1235     # (would add significant amount of code)
1236     add_definitions(-DBOOST_NO_TYPEID)
1237     # TODO: Propagate the above settings to the installed CMakeFiles.txt template
1238     # (from share/template/)
1239     set(PKG_CFLAGS "${PKG_CFLAGS} -DBOOST_NO_TYPEID -I${INCL_INSTALL_DIR}/gromacs/external/boost")
1240     if (NOT GMX_BUILD_MDRUN_ONLY)
1241         install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
1242                 DESTINATION ${INCL_INSTALL_DIR}/gromacs/external/boost
1243                 COMPONENT development)
1244     endif ()
1245 endif()
1246
1247 if (GMX_BUILD_FOR_COVERAGE)
1248     # Code heavy with asserts makes conditional coverage close to useless metric,
1249     # as by design most of the false branches are impossible to trigger in
1250     # correctly functioning code.  And the benefit of testing those that could
1251     # be triggered by using an API against its specification isn't usually
1252     # worth the effort.
1253     add_definitions(-DNDEBUG -DBOOST_DISABLE_ASSERTS -DGMX_DISABLE_ASSERTS)
1254 endif ()
1255
1256 if (NOT GMX_BUILD_MDRUN_ONLY)
1257     add_subdirectory(doxygen)
1258     add_subdirectory(share)
1259     add_subdirectory(scripts)
1260 endif ()
1261 add_subdirectory(src)
1262
1263 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
1264 # Don't bother the user after the first configure pass.
1265 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
1266     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
1267 endif()
1268 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
1269
1270 #######################
1271 ## uninstall target
1272 #######################
1273     CONFIGURE_FILE(
1274                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
1275                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
1276                    IMMEDIATE @ONLY)
1277 ###########################
1278 ADD_CUSTOM_TARGET(uninstall
1279                   "${CMAKE_COMMAND}" -P
1280                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
1281 ###########################
1282
1283 ########################################################################
1284 # Tests                                                                #
1285 ########################################################################
1286
1287 IF(BUILD_TESTING)
1288     enable_testing()
1289     #"check" target builds and runs all tests
1290     add_custom_target(check COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure)
1291     add_dependencies(check tests)
1292     # TODO: This would be better within tests/CMakeLists.txt
1293     if (NOT GMX_BUILD_MDRUN_ONLY)
1294         #gmxtests target builds all binaries required for running gmxtest
1295         add_custom_target(gmxtests DEPENDS gmx links)
1296         add_dependencies(check gmxtests)
1297         add_subdirectory(tests)
1298     endif()
1299     #TODO: Add warning if NOT REGRESSIONTEST_PATH OR NOT GMX_XML that regression/unit tests are not run.
1300 ENDIF()
1301
1302 ########################################################################
1303 # Manual                                                               #
1304 ########################################################################
1305
1306 option(GMX_BUILD_MANUAL "Whether to try to configure to build the PDF manual" OFF)
1307 mark_as_advanced(GMX_BUILD_MANUAL)
1308 if(GMX_BUILD_MANUAL)
1309     # Make sure we only do detection of manual-building dependencies
1310     # when the user opted in for that.
1311     add_subdirectory(manual)
1312 endif()