CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.6)
   2
   3 project(Gromacs)
   4 include(Dart)
   5 mark_as_advanced(DART_ROOT)
   6 # PROJECT_VERSION should have the following structure:
   7 # VERSION[-dev-SUFFIX] where the VERSION can have any form and the suffix
   8 set(PROJECT_VERSION "4.5.1")
   9 set(CUSTOM_VERSION_STRING ""
  10     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  11 mark_as_advanced(CUSTOM_VERSION_STRING)
  12 if (CUSTOM_VERSION_STRING)
  13     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  14 endif (CUSTOM_VERSION_STRING)
  15 set(SOVERSION 6)
  16 # It is a bit irritating, but this has to be set separately for now!
  17 SET(CPACK_PACKAGE_VERSION_MAJOR "4")
  18 SET(CPACK_PACKAGE_VERSION_MINOR "5")
  19 SET(CPACK_PACKAGE_VERSION_PATCH "1")
  20
  21
  22 # Cmake modules/macros are in a subdirectory to keep this file cleaner
  23 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  24
  25 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  26 set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  27 endif()
  28
  29 if(NOT CMAKE_BUILD_TYPE)
  30     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
  31 endif(NOT CMAKE_BUILD_TYPE)
  32
  33 enable_language(C)
  34
  35 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
  36 set(CPACK_PACKAGE_VENDOR "gromacs.org")
  37 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
  38 set(CPACK_SET_DESTDIR "ON")
  39 set(CPACK_INCLUDE_TOPLEVEL_DIRECTORY 0)
  40 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
  41 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
  42 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/admin/InstallLicense.txt")
  43 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
  44
  45 #must come after all cpack settings!
  46 include(CPack)
  47
  48
  49 ########################################################################
  50 # Fix stupid flags on MSVC
  51 ########################################################################
  52 SET(SHARED_LIBS_DEFAULT ON)
  53 IF(CMAKE_GENERATOR MATCHES "Visual Studio")
  54     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
  55     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
  56     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
  57     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
  58     SET(SHARED_LIBS_DEFAULT OFF)
  59 ENDIF(CMAKE_GENERATOR MATCHES "Visual Studio")
  60
  61 set(GMX_EXTRA_LIBRARIES)
  62
  63
  64
  65 ######################################################################
  66 # compiler tests
  67 # these need ot be done early (before further tests).
  68 #####################################################################
  69
  70 include(CheckCCompilerFlag)
  71 include(CheckCXXCompilerFlag)
  72
  73 include(gmxCFlags)
  74 gmx_c_flags()
  75
  76 ########################################################################
  77 # User input options                                                   #
  78 ########################################################################
  79 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
  80 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
  81 option(GMX_THREADS    "Build a parallel (thread-based) version of GROMACS (cannot be combined with MPI yet)" ON)
  82 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
  83 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
  84 option(GMX_POWERPC_INVSQRT "Use PowerPC hardware 1/sqrt" ON)
  85 mark_as_advanced(GMX_POWERPC_INVSQRT)
  86 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
  87 mark_as_advanced(GMX_FAHCORE)
  88 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library (rerun cmake after changing to see relevant options)" OFF)
  89 set(GMX_ACCELERATION "auto"
  90     CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran")
  91
  92 set(GMX_FFT_LIBRARY "fftw3"
  93     CACHE STRING "FFT library choices: fftw3,fftw2,mkl,fftpack[built-in]")
  94 option(GMX_DISABLE_FFTW_MEASURE
  95        "Do not optimize FFTW setups (not needed with SSE)" OFF)
  96 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
  97 set(GMX_QMMM_PROGRAM "none"
  98     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
  99 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 100 mark_as_advanced(GMX_BROKEN_CALLOC)
 101 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI, Windows)" ${SHARED_LIBS_DEFAULT})
 102 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
 103 mark_as_advanced(GMX_MPI_IN_PLACE)
 104 option(GMX_DLOPEN "Compile with dlopen, needed to read VMD supported file formats" ON)
 105 mark_as_advanced(GMX_DLOPEN)
 106
 107
 108 option(GMX_IA32_ASM "Add SSE assembly files for IA32" OFF)
 109 mark_as_advanced(GMX_IA32_ASM)
 110 option(GMX_X86_64_ASM "Add SSE assembly files for X86_64" OFF)
 111 mark_as_advanced(GMX_X86_64_ASM)
 112
 113 option(USE_VERSION_H "Generate development version string/information" ON)
 114 mark_as_advanced(USE_VERSION_H)
 115
 116 option(GMX_DEFAULT_SUFFIX "Use default suffixes for GROMACS binaries and libs (_d for double, _mpi for MPI; rerun cmake after changing to see relevant options)" ON)
 117
 118 if(UNIX AND NOT APPLE AND NOT CYGWIN)
 119     option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer \".a\" static archives (NOTE: this is enabled only for UNIX (excluding APPLE and CYGWIN) platforms but it might not always work!" OFF)
 120     mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 121 endif()
 122
 123 ########################################################################
 124 # Set up binary and library suffixing
 125 ########################################################################
 126 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 127 set(GMX_LIBS_SUFFIX ""
 128   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 129 if (GMX_DEFAULT_SUFFIX)
 130   set(GMX_BINARY_SUFFIX "")
 131   set(GMX_LIBS_SUFFIX "")
 132   if (GMX_MPI)
 133     set(GMX_BINARY_SUFFIX "_mpi")
 134     set(GMX_LIBS_SUFFIX "_mpi")
 135   endif(GMX_MPI)
 136   if (GMX_DOUBLE)
 137     set (GMX_BINARY_SUFFIX "${GMX_BINARY_SUFFIX}_d")
 138     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
 139   endif(GMX_DOUBLE)
 140   if (GMX_OPENMM)
 141     set (GMX_BINARY_SUFFIX "-gpu")
 142     set (GMX_LIBS_SUFFIX "_gpu")
 143   endif(GMX_OPENMM)
 144   mark_as_advanced(FORCE GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 145   message(STATUS "Using default binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 146   message(STATUS "Using default library suffix: \"${GMX_LIBS_SUFFIX}\"")
 147 else(GMX_DEFAULT_SUFFIX)
 148   mark_as_advanced(CLEAR GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 149   message(STATUS "Using manually set binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 150   message(STATUS "Using manually set library suffix: \"${GMX_LIBS_SUFFIX}\"")
 151 endif(GMX_DEFAULT_SUFFIX)
 152
 153 set(PKG_CFLAGS "")
 154 if(GMX_DOUBLE)
 155     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 156 endif(GMX_DOUBLE)
 157 if(GMX_SOFTWARE_INVSQRT)
 158   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 159 endif(GMX_SOFTWARE_INVSQRT)
 160 if(GMX_POWERPC_INVSQRT)
 161   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_POWERPC_INVSQRT")
 162 endif(GMX_POWERPC_INVSQRT)
 163
 164 ########################################################################
 165 #Process MPI settings
 166 ########################################################################
 167 if(GMX_MPI)
 168         MESSAGE(WARNING "
 169             There are known problems with some MPI implementations:
 170                      OpenMPI version < 1.4.1
 171                      MVAPICH2 version <= 1.4.1                               *")
 172     if(GMX_THREADS)
 173         #message(FATAL_ERROR "Thread-based parallelization conflicts with MPI.")
 174         set(GMX_THREADS OFF CACHE BOOL
 175             "Thread-based parallelization conflicts with MPI." FORCE)
 176     endif(GMX_THREADS)
 177     find_package(MPI)
 178     if(MPI_FOUND)
 179         set(GROMACS_C_FLAGS ${GROMACS_FLAGS} ${MPI_COMPILE_FLAGS})
 180         set(GROMACS_LINKER_FLAGS ${GROMACS_LINKER_FLAGS} ${MPI_LINK_FLAGS})
 181
 182         include_directories(${MPI_INCLUDE_PATH})
 183         list(APPEND GMX_EXTRA_LIBRARIES ${MPI_LIBRARIES})
 184         add_definitions( -DMPI ) #for FAHCORE
 185         include(gmxTestMPI_IN_PLACE)
 186         if (GMX_MPI_IN_PLACE)
 187             gmx_test_mpi_in_place(MPI_IN_PLACE_EXISTS)
 188         endif (GMX_MPI_IN_PLACE)
 189     else(MPI_FOUND)
 190         message(FATAL_ERROR "MPI support requested, but no MPI compiler found.")
 191     endif(MPI_FOUND)
 192     include(gmxTestCatamount)
 193     gmx_test_catamount(GMX_CRAY_XT3)
 194     if(GMX_CRAY_XT3)
 195         set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_CRAY_XT3")
 196         set(GMX_NO_SYSTEM 1)
 197         set(GMX_NO_NICE 1)
 198     endif(GMX_CRAY_XT3)
 199     set(GMX_LIB_MPI 1)
 200     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_LIB_MPI")
 201 endif(GMX_MPI)
 202
 203
 204 #######################################################################
 205 # Check for options incompatible with OpenMM build                    #
 206 #######################################################################
 207 if(GMX_OPENMM)
 208     cmake_minimum_required(VERSION 2.6.4)
 209     # we'll use the built-in fft to avoid unnecessary dependencies
 210     string(TOUPPER ${GMX_FFT_LIBRARY} GMX_FFT_LIBRARY)
 211     if(NOT ${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 212         message(STATUS "No external FFT libraries needed for the OpenMM build, switching to fftpack!")
 213         set(GMX_FFT_LIBRARY "fftpack" CACHE STRING
 214                 "No external FFT libraries needed for the OpenMM build, switching to  fftpack!" FORCE)
 215     endif()
 216     if(GMX_MPI)
 217         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
 218     endif(GMX_MPI)
 219     if(GMX_THREADS)
 220         message(STATUS "Threads are  not compatible with OpenMM build, disabled!")
 221         set(GMX_THREADS OFF CACHE BOOL
 222                 "Threads are not compatible with OpenMM build, disabled!" FORCE)
 223     endif(GMX_THREADS)
 224     if(GMX_SOFTWARE_INVSQRT)
 225         set(GMX_SOFTWARE_INVSQRT OFF CACHE STRING
 226                 "The OpenMM build does not need GROMACS software 1/sqrt!" FORCE)
 227     endif(GMX_SOFTWARE_INVSQRT)
 228     string(TOUPPER ${GMX_ACCELERATION} GMX_ACCELERATION)
 229     if(NOT GMX_ACCELERATION STREQUAL "NONE")
 230         message(STATUS "Switching off CPU-based acceleration, the OpenMM build does not support/need any!")
 231         set(GMX_ACCELERATION "none" CACHE STRING
 232                 "Switching off CPU-based acceleration, the OpenMM build does not support/need any!" FORCE)
 233     endif()
 234     if(GMX_FAHCORE)
 235         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
 236     endif(GMX_FAHCORE)
 237     if(GMX_DOUBLE)
 238         message(FATAL_ERROR  "The OpenMM-build does not support double precision calculations!")
 239     endif()
 240     # mark as advanced the unused variables
 241     mark_as_advanced(FORCE GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 242         GMX_QMMM_PROGRAM GMX_THREADS GMX_DOUBLE)
 243 else(GMX_OPENMM)
 244      mark_as_advanced(CLEAR GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 245         GMX_QMMM_PROGRAM GMX_THREADS GMX_DOUBLE)
 246 endif(GMX_OPENMM)
 247
 248
 249 ########################################################################
 250 # Basic system tests (standard libraries, headers, functions, types)   #
 251 ########################################################################
 252 include(CheckIncludeFiles)
 253 check_include_files(string.h     HAVE_STRING_H)
 254 check_include_files(math.h       HAVE_MATH_H)
 255 check_include_files(limits.h     HAVE_LIMITS_H)
 256 check_include_files(memory.h     HAVE_MEMORY_H)
 257 check_include_files(unistd.h     HAVE_UNISTD_H)
 258 check_include_files(pwd.h        HAVE_PWD_H)
 259 check_include_files(stdint.h     HAVE_STDINT_H)
 260 check_include_files(stdlib.h     HAVE_STDLIB_H)
 261 check_include_files(pthread.h    HAVE_PTHREAD_H)
 262 check_include_files(dirent.h     HAVE_DIRENT_H)
 263 check_include_files(inttypes.h   HAVE_INTTYPES_H)
 264 check_include_files(regex.h      HAVE_REGEX_H)
 265 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 266 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
 267 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 268 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
 269 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
 270 # SSE support
 271 check_include_files(xmmintrin.h  HAVE_XMMINTRIN_H)
 272 check_include_files(emmintrin.h  HAVE_EMMINTRIN_H)
 273 check_include_files(pmmintrin.h  HAVE_PMMINTRIN_H)
 274 check_include_files(smmintrin.h  HAVE_SMMINTRIN_H)
 275 check_include_files(io.h                 HAVE_IO_H)
 276
 277
 278 include(CheckFunctionExists)
 279 check_function_exists(strcasecmp        HAVE_STRCASECMP)
 280 check_function_exists(strdup            HAVE_STRDUP)
 281 check_function_exists(vprintf           HAVE_VPRINTF)
 282 check_function_exists(memcmp            HAVE_MEMCMP)
 283 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 284 check_function_exists(memalign          HAVE_MEMALIGN)
 285 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 286 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 287 check_function_exists(isnan             HAVE_ISNAN)
 288 check_function_exists(_isnan            HAVE__ISNAN)
 289 check_function_exists(isfinite          HAVE_ISFINITE)
 290 check_function_exists(_isfinite         HAVE__ISFINITE)
 291 check_function_exists(fsync             HAVE_FSYNC)
 292 check_function_exists(_fileno           HAVE__FILENO)
 293 check_function_exists(fileno            HAVE_FILENO)
 294 check_function_exists(_commit           HAVE__COMMIT)
 295
 296 include(CheckLibraryExists)
 297 check_library_exists(m sqrt "" HAVE_LIBM)
 298 check_library_exists(m cbrt "" HAVE_CBRT)
 299
 300
 301 include(CheckTypeSize)
 302
 303 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 304 check_type_size("int"           SIZEOF_INT)
 305 check_type_size("long int"      SIZEOF_LONG_INT)
 306 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 307 check_type_size("off_t"         SIZEOF_OFF_T)
 308 check_type_size("void *"        SIZEOF_VOIDP)
 309
 310 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 311     set(GMX_64_BIT TRUE)
 312 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 313     set(GMX_64_BIT FALSE)
 314 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 315
 316 # Check for some basic types that we *need*, so set these to int if they are not present
 317 check_type_size(uid_t uid_t)
 318 if(NOT uid_t)
 319   set(uid_t int)
 320 else(NOT uid_t)
 321   set(uid_t 0)
 322 endif(NOT uid_t)
 323
 324 check_type_size(gid_t gid_t)
 325 if(NOT gid_t)
 326   set(gid_t 1)
 327 else(NOT gid_t)
 328   set(gid_t 0)
 329 endif(NOT gid_t)
 330
 331 check_type_size(size_t size_t)
 332 if(NOT size_t)
 333   set(size_t int)
 334 else(NOT size_t)
 335   set(size_t 0)
 336 endif(NOT size_t)
 337
 338 check_type_size(off_t off_t)
 339 if(NOT off_t)
 340   set(off_t int)
 341 else(NOT off_t)
 342   set(off_t 0)
 343 endif(NOT off_t)
 344
 345 include(TestBigEndian)
 346 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 347
 348
 349
 350
 351 ########################################################################
 352 # Find external packages                                               #
 353 ########################################################################
 354 if(UNIX AND NOT APPLE AND NOT CYGWIN)
 355     if(GMX_PREFER_STATIC_LIBS)
 356         SET(CMAKE_FIND_LIBRARY_SUFFIXES .a ${CMAKE_FIND_LIBRARY_SUFFIXES})
 357         if(BUILD_SHARED_LIBS)
 358             message(WARNING "Static libraries requested, the GROMACS libraries will also be build static (BUILD_SHARED_LIBS=OFF)")
 359             set(BUILD_SHARED_LIBS OFF CACHE BOOL "Enable shared libraries (can be problematic with MPI, Windows)" FORCE)
 360         endif()
 361     endif()
 362 endif()
 363
 364 find_package(LibXml2)
 365 set(PKG_XML "")
 366 if(LIBXML2_FOUND)
 367     include_directories(${LIBXML2_INCLUDE_DIR})
 368     set(PKG_XML libxml-2.0)
 369     set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 370     set(HAVE_LIBXML2 1)
 371 endif(LIBXML2_FOUND)
 372
 373 option(GMX_X11 "Use X window system" OFF)
 374 if (GMX_X11)
 375         find_package(X11)
 376         # X11 includes/libraries are only set in the ngmx subdirectory!
 377         if(X11_FOUND)
 378         set(HAVE_X11 1)
 379         endif(X11_FOUND)
 380 endif(GMX_X11)
 381
 382 if(GMX_THREADS)
 383     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREADS")
 384     include(ThreadMPI)
 385     set(THREAD_MPI_LIB thread_mpi)
 386     set(GMX_MPI 1)
 387     string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 388     if(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 389         message(FATAL_ERROR "FFTW2 can't be used with threads. Try fftw3 or mkl.")
 390     endif()
 391 endif(GMX_THREADS)
 392
 393 if(GMX_OPENMM)
 394     set(CUDA_BUILD_EMULATION OFF)
 395     find_package(CUDA 3.1 REQUIRED)
 396     add_definitions(-DGMX_OPENMM)
 397     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 398         set(CUDA_VERBOSE_BUILD ON)
 399     endif()
 400     find_package(OpenMM)
 401 endif(GMX_OPENMM)
 402
 403 if(APPLE)
 404    find_library(ACCELERATE_FRAMEWORK Accelerate)
 405    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 406 endif(APPLE)
 407
 408 # only bother with finding git and using version.h if the source is a git repo
 409 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 410     if(USE_VERSION_H)
 411         # We need at least git v1.5.1 be able to parse git's date output. If not
 412         # fund or the version is too small, we can't generate version information.
 413         find_package(Git 1.5.1)
 414         # this should at some point become VERSION_LESS
 415         if(NOT Git_FOUND OR Git_VERSION STRLESS "1.5.1")
 416             message("No compatible git version found, won't be able to generate proper development version information.")
 417             set(USE_VERSION_H OFF)
 418         endif()
 419     endif()
 420 else()
 421     set(USE_VERSION_H OFF)
 422 endif()
 423
 424 if (GMX_DLOPEN)
 425     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS})
 426 endif (GMX_DLOPEN)
 427
 428 ########################################################################
 429 # Generate development version info for cache
 430 ########################################################################
 431 # set(GEN_VERSION_INFO_INTERNAL "ON")
 432 # include(gmxGenerateVersionString)
 433
 434 ########################################################################
 435 # Our own GROMACS tests
 436 ########################################################################
 437
 438 add_definitions( -DHAVE_CONFIG_H )
 439 include_directories(${CMAKE_BINARY_DIR}/src)
 440 include_directories(${CMAKE_SOURCE_DIR}/include)
 441
 442 include(gmxCheckBuildUserTime)
 443 gmx_check_build_user_time(BUILD_TIME BUILD_USER BUILD_MACHINE)
 444
 445 include(gmxTestFloatFormat)
 446 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 447                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 448                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 449
 450 include(gmxTestLargeFiles)
 451 gmx_test_large_files(GMX_LARGEFILES)
 452 check_function_exists(fseeko     HAVE_FSEEKO)
 453
 454 include(gmxTestSignal)
 455 gmx_test_retsigtype(RETSIGTYPE)
 456 gmx_test_sigusr1(HAVE_SIGUSR1)
 457
 458 include(gmxTestInline)
 459 gmx_test_inline(INLINE_KEYWORD)
 460
 461 include(gmxTestRestrict)
 462 gmx_test_inline(RESTRICT_KEYWORD)
 463
 464 include(gmxTestPipes)
 465 gmx_test_pipes(HAVE_PIPES)
 466
 467 include(gmxTestInlineASM)
 468 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 469 gmx_test_inline_asm_msvc_x86(GMX_X86_MSVC_INLINE_ASM)
 470
 471 # turn on SSE if supported with reasonable defaults.
 472 if (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 473   if(CMAKE_SYSTEM_PROCESSOR MATCHES "^(i.86|x86|x64|x86_64|AMD64|amd64)")
 474
 475     set(GMX_ACCELERATION "SSE" CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran" FORCE)
 476
 477     if (GMX_64_BIT)
 478       set(GMX_X86_64_ASM ON CACHE BOOL "Add SSE assembly files for x86_64" FORCE)
 479     else (GMX_64_BIT)
 480       set(GMX_IA32_ASM ON CACHE BOOL "Add SSE assembly files for i386" FORCE)
 481     endif (GMX_64_BIT)
 482
 483     # Determine the assembler/compiler to use
 484   else()
 485     set(GMX_ACCELERATION "none" CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran" FORCE)
 486   endif()
 487 endif (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 488
 489 include(gmxTestXDR)
 490 gmx_test_xdr(GMX_SYSTEM_XDR)
 491 if(NOT GMX_SYSTEM_XDR)
 492     set(GMX_INTERNAL_XDR 1)
 493     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 494 endif(NOT GMX_SYSTEM_XDR)
 495
 496 # Process nonbonded accelerated kernels settings
 497 string(TOUPPER ${GMX_ACCELERATION} ${GMX_ACCELERATION})
 498 if(${GMX_ACCELERATION} STREQUAL "NONE")
 499   # nothing to do
 500 elseif(${GMX_ACCELERATION} STREQUAL "SSE")
 501
 502     if(CMAKE_GENERATOR MATCHES "Visual Studio")
 503       option(GMX_ASM_USEASM-NASM "Use Nasm for assembly instead of compiler (necessary on windows)" ON)
 504     else()
 505       option(GMX_ASM_USEASM-NASM "Use Nasm for assembly instead of compiler (necessary on windows)" OFF)
 506     endif()
 507         mark_as_advanced(GMX_ASM_USEASM-NASM)
 508
 509     if (NOT GMX_64_BIT)
 510         # for 32-bit compiles, we might need to turn on sse
 511         CHECK_C_COMPILER_FLAG("-msse2" XFLAGS_SSE)
 512         if (XFLAGS_SSE)
 513             set(GROMACS_C_FLAGS "-msse2 ${GROMACS_C_FLAGS}")
 514         endif (XFLAGS_SSE)
 515         CHECK_CXX_COMPILER_FLAG("-msse2" XXFLAGS_SSE)
 516         if (XXFLAGS_SSE)
 517             set(GROMACS_CXX_FLAGS "-msse2 ${GROMACS_CXX_FLAGS}")
 518         endif (XXFLAGS_SSE)
 519     endif (NOT GMX_64_BIT)
 520
 521     if(GMX_IA32_ASM)
 522       if(GMX_DOUBLE)
 523         set(GMX_IA32_SSE2 1)
 524       else()
 525        set(GMX_IA32_SSE 1)
 526       endif()
 527     elseif(GMX_X86_64_ASM)
 528       if(GMX_DOUBLE)
 529        set(GMX_X86_64_SSE2 1)
 530       else()
 531         set(GMX_X86_64_SSE 1)
 532       endif()
 533     endif()
 534
 535 #    if(HAVE_PMMINTRIN_H)
 536 #        set(GMX_SSE3 1)
 537 #    endif(HAVE_PMMINTRIN_H)
 538 #    if(HAVE_SMMINTRIN_H)
 539 #        set(GMX_SSE4_1 1)
 540 #    endif(HAVE_SMMINTRIN_H)
 541
 542 elseif(${GMX_ACCELERATION} STREQUAL "FORTRAN")
 543     set(GMX_FORTRAN 1)
 544     #these are switch on by default sometimes
 545     set(GMX_IA32_ASM 0)
 546     set(GMX_GMX_X86_64_ASM 0)
 547 elseif(${GMX_ACCELERATION} STREQUAL "BLUEGENE")
 548 # GMX_ACCELERATION=BlueGene should be set in the Toolchain-BlueGene?-???.cmake file
 549     message(STATUS "Configuring for BlueGene")
 550     set(GMX_BLUEGENE 1)
 551     if (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 552         set(SHARED_LIBS_DEFAULT OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 553         set(BUILD_SHARED_LIBS OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 554     endif (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 555     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on BlueGene" FORCE)
 556     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on BlueGene" FORCE)
 557     set(GMX_X11 OFF CACHE BOOL "X11 not compatible with BlueGene, disabled!" FORCE)
 558     set(GMX_THREADS OFF CACHE BOOL "Threads not compatible with BlueGene, disabled!" FORCE)
 559     set(GMX_MPI ON CACHE BOOL "Use MPI on BlueGene" FORCE)
 560     set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use MASSV for BLAS on BlueGene" FORCE)
 561     set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use MASSV for LAPACK on BlueGene" FORCE)
 562     list(APPEND GMX_EXTRA_LIBRARIES massv)
 563 elseif(${GMX_ACCELERATION} STREQUAL "POWER6")
 564     set(GMX_POWER6 1)
 565     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on Power6" FORCE)
 566     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on Power6" FORCE)
 567 elseif(${GMX_ACCELERATION} STREQUAL "IA64")
 568     set(GMX_IA64_ASM 1)
 569     set(DISABLE_WATERWATER_NLIST 1)
 570     set(DISABLE_WATER_NLIST 1)
 571 elseif(${GMX_ACCELERATION} STREQUAL "ALTIVEC")
 572     check_include_files(altivec.h HAVE_ALTIVEC_H)
 573     if(HAVE_ALTIVEC_H)
 574         set(GMX_PPC_ALTIVEC 1)
 575     endif(HAVE_ALTIVEC_H)
 576 else(${GMX_ACCELERATION} STREQUAL "NONE")
 577     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_ACCELERATION}. Pick one of auto, none, SSE, Fortran, BlueGene, Power6, ia64, altivec")
 578 endif(${GMX_ACCELERATION} STREQUAL "NONE")
 579
 580 if(GMX_FORTRAN OR GMX_POWER6)
 581     if (GMX_THREADS)
 582         message(FATAL_ERROR "FORTRAN/POWER6 is incompatible with threads and only provides a speed-up on certain IBM compilers. Disable FORTRAN (or threads if you really want to use FORTRAN kernels).")
 583     endif(GMX_THREADS)
 584     enable_language(Fortran)
 585     include(FortranCInterface)
 586     discover_fortran_mangling(prefix isupper suffix extra_under_score found)
 587     if(extra_under_score)
 588         set(extrasuffix "_")
 589     endif(extra_under_score)
 590     if(prefix)
 591       set(prefix "${prefix} ##")
 592     endif(prefix)
 593
 594     if(isupper)
 595         set(F77_FUNCDEF   "${prefix} NAME ## ${suffix}")
 596         set(F77_FUNCDEF_  "${prefix} NAME ## ${suffix}${extrasuffix}")
 597     else(isupper)
 598         set(F77_FUNCDEF   "${prefix} name ## ${suffix}")
 599         set(F77_FUNCDEF_  "${prefix} name ## ${suffix}${extrasuffix}")
 600     endif(isupper)
 601 else(GMX_FORTRAN OR GMX_POWER6)
 602         set(F77_FUNCDEF   "name ## _")
 603         set(F77_FUNCDEF_  "name ## _")
 604 endif(GMX_FORTRAN OR GMX_POWER6)
 605
 606 # Process QM/MM Settings
 607 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 608 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 609     set(GMX_QMMM_GAUSSIAN 1)
 610 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 611     set(GMX_QMMM_MOPAC 1)
 612 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 613     set(GMX_QMMM_GAMESS 1)
 614 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 615     set(GMX_QMMM_ORCA 1)
 616 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 617     # nothing to do
 618 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 619     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 620 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 621
 622 # Process FFT library settings - if not OpenMM build
 623 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 624 set(PKG_FFT "")
 625 set(PKG_FFT_LIBS "")
 626 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 627 #    MESSAGE(STATUS "Using external FFT library - fftw3")
 628     if(GMX_DOUBLE)
 629         find_package(FFTW3 REQUIRED)
 630                 include_directories(${FFTW3_INCLUDE_DIR})
 631         set(FFT_LIBRARIES ${FFTW3_LIBRARIES})
 632         set(PKG_FFT "fftw3")
 633     else(GMX_DOUBLE)
 634         find_package(FFTW3F REQUIRED)
 635         include_directories(${FFTW3F_INCLUDE_DIR})
 636         set(FFT_LIBRARIES ${FFTW3F_LIBRARIES})
 637         set(PKG_FFT "fftw3f")
 638     endif(GMX_DOUBLE)
 639
 640     if(NOT FFTW3_FOUND AND NOT FFTW3F_FOUND)
 641         MESSAGE(FATAL_ERROR "Cannot find fftw3 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 642     endif(NOT FFTW3_FOUND AND NOT FFTW3F_FOUND)
 643
 644     set(GMX_FFT_FFTW3 1)
 645
 646 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 647 #    MESSAGE(STATUS "Using external FFT library - fftw2")
 648     if(GMX_DOUBLE)
 649         find_package(FFTW2 REQUIRED)
 650     else(GMX_DOUBLE)
 651         find_package(FFTW2F REQUIRED)
 652     endif(GMX_DOUBLE)
 653
 654     if(NOT FFTW2_FOUND)
 655            MESSAGE(FATAL_ERROR "Cannot find fftw2 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 656     endif(NOT FFTW2_FOUND)
 657     include_directories(${FFTW2_INCLUDE_DIR})
 658     set(FFT_LIBRARIES ${FFTW2_LIBRARIES})
 659     set(PKG_FFT_LIBS ${FFTW2_LIBRARIES})
 660
 661     if("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 662         set(FFTW2_NAME_DFFTW 1)
 663     elseif("${FFTW2_LIBRARIES}" MATCHES "sfftw")
 664         set(FFTW2_NAME_SFFTW 1)
 665     else("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 666         set(FFTW2_NAME_FFTW 1)
 667     endif("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 668
 669     set(GMX_FFT_FFTW2 1)
 670 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 671 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 672     find_package(MKL REQUIRED)
 673     include_directories(${MKL_INCLUDE_DIR})
 674     set(FFT_LIBRARIES ${MKL_LIBRARIES})
 675     set(PKG_FFT_LIBS ${MKL_LIBRARIES})
 676
 677     set(GMX_FFT_MKL 1)
 678     set(HAVE_MKL 1)
 679
 680 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 681 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 682 #    set(GMX_FFT_ACML 1)
 683 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 684     MESSAGE(STATUS "Using internal FFT library - fftpack")
 685     set(GMX_FFT_FFTPACK 1)
 686 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 687     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, fftw2, mkl, acml, fftpack")
 688 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 689
 690 # MKL has BLAS/LAPACK routines
 691 if(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 692   set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 693   set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 694 else(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 695   set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 696   set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 697 endif(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 698 mark_as_advanced(GMX_EXTERNAL_LAPACK)
 699 mark_as_advanced(GMX_EXTERNAL_BLAS)
 700
 701 # Math and thread libraries must often come after all others when linking...
 702 if(HAVE_LIBM)
 703     list(APPEND GMX_EXTRA_LIBRARIES m)
 704 endif(HAVE_LIBM)
 705
 706
 707
 708 if(GMX_FAHCORE)
 709   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 710       "Path to swindirect.h")
 711   include_directories(${COREWRAP_INCLUDE_DIR})
 712 endif(GMX_FAHCORE)
 713
 714 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 715 # these are set after everything else
 716 if (NOT DEFINED GROMACS_C_FLAGS_SET)
 717     set(GROMACS_C_FLAGS_SET true CACHE INTERNAL "Whether to reset the C flags"
 718         FORCE)
 719     set(CMAKE_C_FLAGS "${GROMACS_C_FLAGS} ${CMAKE_C_FLAGS}" CACHE STRING
 720         "Flags used by the compiler during all build types" FORCE)
 721     set(CMAKE_CXX_FLAGS "${GROMACS_CXX_FLAGS} ${CMAKE_CXX_FLAGS}" CACHE STRING
 722         "Flags used by the compiler during all build types" FORCE)
 723     set(CMAKE_EXE_LINKER_FLAGS
 724         "${GROMACS_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}"
 725         CACHE STRING "Linker flags" FORCE)
 726 endif (NOT DEFINED GROMACS_C_FLAGS_SET)
 727
 728 ########################################################################
 729 # Specify install locations and which subdirectories to process        #
 730 ########################################################################
 731 if ( DEFINED LIB )
 732     set(LIB_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/${LIB}")
 733 else()
 734     set(LIB_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/lib)
 735 endif()
 736 set(BIN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/bin)
 737 set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/gromacs)
 738 set(MAN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/share/man)
 739 set(INCL_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/include)
 740
 741 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
 742
 743 ##################################################################
 744 # Shared library settings - Darwin uses INSTALL_NAME_DIR instead!
 745 ##################################################################
 746 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 747     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
 748     set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 749     set(CMAKE_INSTALL_RPATH "${LIB_INSTALL_DIR}")
 750     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 751 endif()
 752
 753 add_subdirectory(share)
 754 add_subdirectory(include)
 755 add_subdirectory(man)
 756 add_subdirectory(src)
 757 add_subdirectory(scripts)
 758
 759 #######################
 760 ## uninstall target
 761 #######################
 762     CONFIGURE_FILE(
 763                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 764                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 765                    IMMEDIATE @ONLY)
 766 ###########################
 767 ADD_CUSTOM_TARGET(uninstall
 768                   "${CMAKE_COMMAND}" -P
 769                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 770 ###########################
 771
 772
 773 ########################################################################
 774 # Tests                                                                #
 775 ########################################################################
 776
 777 include(CTest)
 778 mark_as_advanced(BUILD_TESTING)
 779 IF(BUILD_TESTING)
 780         enable_testing()
 781         add_test(TestBuildAll make)
 782         add_subdirectory(tests)
 783 ENDIF()
 784