CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2012,2013, by the GROMACS development team, led by
   5 # David van der Spoel, Berk Hess, Erik Lindahl, and including many
   6 # others, as listed in the AUTHORS file in the top-level source
   7 # directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34 #
  35 cmake_minimum_required(VERSION 2.8)
  36 # Keep CMake suitably quiet on Cygwin
  37 set(CMAKE_LEGACY_CYGWIN_WIN32 0) # Remove when CMake >= 2.8.4 is required
  38
  39 # Allows CPack to act differently for normal tools and mdrun (e.g. because of MPI)
  40 set(CPACK_COMPONENT_GROUP_TOOLS_DESCRIPTION "All GROMACS executable tools")
  41 set(CPACK_COMPONENT_GROUP_MDRUN_DESCRIPTION "GROMACS executable for running simulations")
  42
  43 # CMake modules/macros are in a subdirectory to keep this file cleaner
  44 # This needs to be set before project() in order to pick up toolchain files
  45 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  46
  47 project(Gromacs C)
  48 include(Dart)
  49 mark_as_advanced(DART_ROOT)
  50
  51 # PROJECT_VERSION should have the following structure:
  52 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  53 #
  54 # The "-dev" suffix is important to keep because it makes possible to distinguish
  55 # between a build from official release and a build from git release branch on a
  56 # machine with no git.
  57 #
  58 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  59 set(PROJECT_VERSION "4.6.4-dev")
  60 # The version number of the regressiontest tarball against which this
  61 # git branch can be tested. Normally, this will be the version of the
  62 # last patch release. Comment the next line out for branches leading
  63 # to a major/minor release.
  64 set(REGRESSIONTEST_VERSION "4.6.2")
  65 set(CUSTOM_VERSION_STRING ""
  66     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  67 mark_as_advanced(CUSTOM_VERSION_STRING)
  68 if (CUSTOM_VERSION_STRING)
  69     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  70 endif (CUSTOM_VERSION_STRING)
  71 set(SOVERSION 8)
  72 # It is a bit irritating, but this has to be set separately for now!
  73 SET(CPACK_PACKAGE_VERSION_MAJOR "4")
  74 SET(CPACK_PACKAGE_VERSION_MINOR "6")
  75 SET(CPACK_PACKAGE_VERSION_PATCH "1")
  76
  77 # The numerical gromacs version. It is 40600 for 4.6.0.
  78 # The #define GMX_VERSION in gmx_header_config_h is set to this value.
  79 math(EXPR NUM_VERSION
  80     "${CPACK_PACKAGE_VERSION_MAJOR}*10000 + ${CPACK_PACKAGE_VERSION_MINOR}*100")
  81 if(CPACK_PACKAGE_VERSION_PATCH)
  82     math(EXPR NUM_VERSION
  83          "${NUM_VERSION} + ${CPACK_PACKAGE_VERSION_PATCH}")
  84 endif()
  85
  86 # The API version tracks the numerical Gromacs version (for now).
  87 # It is potentially different from the Gromacs version in the future, if
  88 # the programs/libraries diverge from the presumably more stable API.
  89 # The #define GMX_API_VERSION in version.h is set to this value to
  90 # provide backward compatibility of software written against the Gromacs API.
  91 set(API_VERSION ${NUM_VERSION})
  92
  93 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  94 set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  95 endif()
  96
  97 include(gmxBuildTypeReference)
  98
  99 if(NOT CMAKE_BUILD_TYPE)
 100     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference." FORCE)
 101 endif(NOT CMAKE_BUILD_TYPE)
 102
 103 enable_language(C)
 104
 105 set(GMX_USE_RELATIVE_INSTALL_PATH OFF CACHE STRING "Use relative paths not absolute paths for cmake install. Has only an effect on cpack.")
 106 mark_as_advanced(GMX_USE_RELATIVE_INSTALL_PATH)
 107
 108 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
 109 set(CPACK_PACKAGE_VENDOR "gromacs.org")
 110 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
 111 if (NOT GMX_USE_RELATIVE_INSTALL_PATH)
 112     set(CPACK_SET_DESTDIR "ON")
 113 endif()
 114 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
 115 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
 116 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/COPYING")
 117 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
 118 set(CPACK_SOURCE_IGNORE_FILES "\\\\.isreposource$;\\\\.git/;\\\\.gitignore$")
 119 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
 120 SET(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/man;man")
 121 set(CPACK_PACKAGE_CONTACT "gmx-users@gromacs.org")
 122
 123 #must come after all cpack settings!
 124 include(CPack)
 125
 126 ########################################################################
 127 # Check and warn if cache generated on a different host is being reused
 128 ########################################################################
 129 if(CMAKE_HOST_UNIX)
 130     execute_process(COMMAND hostname
 131                     OUTPUT_VARIABLE TMP_HOSTNAME
 132                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 133     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 134         message(WARNING "
 135             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 136             is being reused! This could lead to inconsitencies; therefore, it is
 137             recommended to regenerate the cache!")
 138     endif()
 139     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 140             "Hostname of the machine where the cache was generated.")
 141 endif()
 142
 143 ########################################################################
 144 # User input options - enable C++ - before any CXX flags are changed   #
 145 ########################################################################
 146
 147 # decide on GPU settings based on user-settings and GPU/CUDA detection
 148 include(gmxManageGPU)
 149
 150 option(GMX_FORCE_CXX "Enable C++ compilation even if not necessary" OFF)
 151 mark_as_advanced(GMX_FORCE_CXX)
 152
 153 option(GMX_COOL_QUOTES "Enable Gromacs cool quotes" ON)
 154 mark_as_advanced(GMX_COOL_QUOTES)
 155
 156 if(GMX_GPU OR GMX_FORCE_CXX OR GMX_OPENMM)
 157     enable_language(CXX)
 158 endif()
 159 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 160
 161 ########################################################################
 162 # User input options                                                   #
 163 ########################################################################
 164 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 165 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 166 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 167 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 168 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 169 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 170 mark_as_advanced(GMX_FAHCORE)
 171
 172 include(gmxDetectAcceleration)
 173 if(NOT DEFINED GMX_CPU_ACCELERATION)
 174     if(CMAKE_CROSSCOMPILING)
 175         if("${CMAKE_SYSTEM_NAME}" MATCHES "BlueGeneQ")
 176             set(GMX_SUGGESTED_CPU_ACCELERATION "IBM_QPX")
 177         else()
 178             set(GMX_SUGGESTED_CPU_ACCELERATION "None")
 179         endif()
 180     else(CMAKE_CROSSCOMPILING)
 181         gmx_detect_acceleration(GMX_SUGGESTED_CPU_ACCELERATION)
 182     endif(CMAKE_CROSSCOMPILING)
 183 endif(NOT DEFINED GMX_CPU_ACCELERATION)
 184
 185 set(GMX_CPU_ACCELERATION "@GMX_SUGGESTED_CPU_ACCELERATION@"
 186     CACHE STRING "Accelerated CPU kernels. Pick one of: None, SSE2, SSE4.1, AVX_128_FMA, AVX_256, IBM_QPX, Sparc64_HPC_ACE")
 187
 188 set(GMX_FFT_LIBRARY "fftw3"
 189     CACHE STRING "FFT library choices: fftw3,mkl,fftpack[built-in]")
 190 option(GMX_BUILD_OWN_FFTW "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack." OFF)
 191 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 192 option(GMX_DISABLE_FFTW_MEASURE
 193        "Do not optimize FFTW setups (not needed with SSE)" OFF)
 194 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 195 set(GMX_QMMM_PROGRAM "none"
 196     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
 197 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 198 mark_as_advanced(GMX_BROKEN_CALLOC)
 199 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
 200 mark_as_advanced(GMX_MPI_IN_PLACE)
 201 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 202 mark_as_advanced(GMX_LOAD_PLUGINS)
 203
 204 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 205
 206 option(USE_VERSION_H "Generate development version string/information" ON)
 207 mark_as_advanced(USE_VERSION_H)
 208
 209 option(GMX_DEFAULT_SUFFIX "Use default suffixes for GROMACS binaries and libs (_d for double, _mpi for MPI; rerun cmake after changing to see relevant options)" ON)
 210
 211 if(UNIX)
 212     option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static archives (not available on non-*nix platforms and it will only work if static versions of external dependencies are available and found)!" OFF)
 213     mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 214 endif()
 215
 216 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 217 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 218
 219 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 220 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 221
 222 ######################################################################
 223 # Compiler tests
 224 # These need to be done early (before further tests).
 225 #####################################################################
 226
 227 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 228 # are used with permission from CMake v2.8.9 so that GROMACS can detect
 229 # invalid options with the Intel Compilers.
 230 # These files should be removed from the source tree when a CMake version that
 231 # includes the features in question becomes required for building GROMACS.
 232 include(CheckCCompilerFlag)
 233 if(CMAKE_CXX_COMPILER_LOADED)
 234     include(CheckCXXCompilerFlag)
 235 endif()
 236
 237 # Get compiler version information, needs to be done early as check that depend
 238 # on compiler verison follow below.
 239 include(gmxGetCompilerInfo)
 240 get_compiler_version()
 241
 242 # First exclude compilers known to not work with OpenMP although claim to support it:
 243 # gcc 4.2.1 and gcc-llvm 4.2.1 (also claims to be 4.2.1) on Mac OS X
 244 # This fixes redmine 900 and needs to run before OpenMP flags are set below.
 245 if (CMAKE_SYSTEM_NAME STREQUAL "Darwin" AND
 246     (CMAKE_COMPILER_IS_GNUCC AND C_COMPILER_VERSION AND C_COMPILER_VERSION VERSION_LESS 4.3))
 247     message(STATUS "OpenMP multithreading not supported with gcc/llvm-gcc 4.2 on Mac OS X, disabled")
 248     set(GMX_OPENMP OFF CACHE BOOL
 249         "OpenMP multithreading not not supported with gcc/llvm-gcc 4.2 on Mac OS X, disabled!" FORCE)
 250 endif()
 251
 252 # OpenMP check must come before other CFLAGS!
 253 if(GMX_OPENMP)
 254     find_package(OpenMP)
 255     if(OPENMP_FOUND)
 256         # CMake on Windows doesn't support linker flags passed to target_link_libraries
 257         # (i.e. it treats /openmp as \openmp library file). Also, no OpenMP linker flags are needed.
 258         if(NOT (WIN32 AND NOT CYGWIN))
 259             if(CMAKE_COMPILER_IS_GNUCC AND GMX_PREFER_STATIC_OPENMP)
 260                 set(OpenMP_LINKER_FLAGS "-Wl,-static -lgomp -lrt -Wl,-Bdynamic -lpthread")
 261                 set(OpenMP_SHARED_LINKER_FLAGS "")
 262             else()
 263                 # Only set a linker flag if the user didn't set them manually
 264                 if(NOT DEFINED OpenMP_LINKER_FLAGS)
 265                     set(OpenMP_LINKER_FLAGS "${OpenMP_C_FLAGS}")
 266                 endif()
 267                 if(NOT DEFINED OpenMP_SHARED_LINKER_FLAGS)
 268                     set(OpenMP_SHARED_LINKER_FLAGS "${OpenMP_C_FLAGS}")
 269                 endif()
 270             endif()
 271         endif()
 272     else(OPENMP_FOUND)
 273         message(WARNING
 274                 "The compiler you are using does not support OpenMP parallelism. This might hurt your performance a lot, in particular with GPUs. Try using a more recent version, or a different compiler. For now, we are proceeding by turning off OpenMP.")
 275         set(GMX_OPENMP OFF CACHE STRING "Whether GROMACS will use OpenMP parallelism." FORCE)
 276     endif(OPENMP_FOUND)
 277 endif()
 278
 279
 280 include(gmxCFlags)
 281 gmx_c_flags()
 282
 283 # This variable should be used for additional compiler flags which are not
 284 # generated in gmxCFlags nor are acceleration or MPI related.
 285 set(EXTRA_C_FLAGS "")
 286
 287 # gcc 4.4.x is buggy and crashes when compiling some files with O3 and OpenMP on.
 288 # Detect here whether applying a workaround is needed and will apply it later
 289 # on the affected files.
 290 include(gmxGCC44O3BugWorkaround)
 291 gmx_check_gcc44_bug_workaround_needed(GMX_USE_GCC44_BUG_WORKAROUND)
 292
 293 # clang 3.0 is buggy for some unknown reason detected during adding
 294 # the SSE2 group kernels for GROMACS 4.6. If we ever work out what
 295 # that is, we should replace these tests with a compiler feature test,
 296 # update GROMACS Redmine task #1039 and perhaps report a clang bug.
 297 #
 298 # In the meantime, until we require CMake 2.8.10 we cannot rely on it to detect
 299 # the compiler version for us. So we need a manual check for clang 3.0.
 300 include(gmxDetectClang30)
 301 gmx_detect_clang_3_0(COMPILER_IS_CLANG_3_0)
 302 if(COMPILER_IS_CLANG_3_0)
 303     message(FATAL_ERROR "Your compiler is clang version 3.0, which is known to be buggy for GROMACS. Use a different compiler.")
 304 endif()
 305
 306 # clang <=3.2 contains a bug that causes incorrect code to be generated for the
 307 # vfmaddps instruction and therefore the bug is triggered with AVX_128_FMA.
 308 # (see: http://llvm.org/bugs/show_bug.cgi?id=15040).
 309 # We can work around this by not using the integrated assembler (except on OS X
 310 # which has an outdated assembler that does not support AVX instructions).
 311 if (${CMAKE_C_COMPILER_ID} MATCHES "Clang" AND C_COMPILER_VERSION VERSION_LESS "3.3")
 312     set(GMX_USE_CLANG_FMA_BUG_WORKAROUND TRUE)
 313 endif()
 314
 315 if (CMAKE_C_COMPILER_ID STREQUAL "PGI")
 316     message(WARNING "All tested PGI compiler versions (up to 12.9.0) generate binaries which produce incorrect results, or even fail to compile Gromacs. Highly recommended to use a different compiler. If you choose to use PGI, make sure to run the regressiontests.")
 317 endif()
 318
 319 if(CMAKE_C_COMPILER_ID MATCHES "Intel" AND C_COMPILER_VERSION VERSION_LESS "12.0.0")
 320     message(WARNING "Intel compilers before 12.0.0 are not routinely tested, so there may be problems. Version 11.1 with SSE4.1 is known to produce incorrect results. It is highly recommended to use a more up-to-date compiler. If you choose to use this version, make sure you run the regressiontests.")
 321 endif()
 322
 323 ########################################################################
 324 # Set up binary and library suffixing
 325 ########################################################################
 326 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 327 set(GMX_LIBS_SUFFIX ""
 328   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 329 if (GMX_DEFAULT_SUFFIX)
 330   set(GMX_BINARY_SUFFIX "")
 331   set(GMX_LIBS_SUFFIX "")
 332   if (GMX_MPI)
 333     set(GMX_BINARY_SUFFIX "_mpi")
 334     set(GMX_LIBS_SUFFIX "_mpi")
 335   endif(GMX_MPI)
 336   if (GMX_DOUBLE)
 337     set (GMX_BINARY_SUFFIX "${GMX_BINARY_SUFFIX}_d")
 338     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
 339   endif(GMX_DOUBLE)
 340   mark_as_advanced(FORCE GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 341   if (NOT SUFFIX_QUIETLY)
 342     message(STATUS "Using default binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 343     message(STATUS "Using default library suffix: \"${GMX_LIBS_SUFFIX}\"")
 344   endif (NOT SUFFIX_QUIETLY)
 345 else(GMX_DEFAULT_SUFFIX)
 346   mark_as_advanced(CLEAR GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 347   if (NOT SUFFIX_QUIETLY)
 348     message(STATUS "Using manually set binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 349     message(STATUS "Using manually set library suffix: \"${GMX_LIBS_SUFFIX}\"")
 350   endif (NOT SUFFIX_QUIETLY)
 351 endif(GMX_DEFAULT_SUFFIX)
 352 set(SUFFIX_QUIETLY TRUE CACHE INTERNAL "")
 353
 354 set(PKG_CFLAGS "")
 355 if(GMX_DOUBLE)
 356     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 357 endif(GMX_DOUBLE)
 358 if(GMX_SOFTWARE_INVSQRT)
 359   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 360 endif(GMX_SOFTWARE_INVSQRT)
 361
 362
 363
 364 ########################################################################
 365 # Basic system tests (standard libraries, headers, functions, types)   #
 366 ########################################################################
 367 include(CheckIncludeFiles)
 368 check_include_files(string.h     HAVE_STRING_H)
 369 check_include_files(math.h       HAVE_MATH_H)
 370 check_include_files(limits.h     HAVE_LIMITS_H)
 371 check_include_files(memory.h     HAVE_MEMORY_H)
 372 check_include_files(unistd.h     HAVE_UNISTD_H)
 373 check_include_files(direct.h     HAVE_DIRECT_H)
 374 check_include_files(pwd.h        HAVE_PWD_H)
 375 check_include_files(stdint.h     HAVE_STDINT_H)
 376 check_include_files(stdlib.h     HAVE_STDLIB_H)
 377 check_include_files(pthread.h    HAVE_PTHREAD_H)
 378 check_include_files(dirent.h     HAVE_DIRENT_H)
 379 check_include_files(inttypes.h   HAVE_INTTYPES_H)
 380 check_include_files(regex.h      HAVE_REGEX_H)
 381 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 382 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
 383 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 384 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
 385 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
 386 check_include_files(io.h                 HAVE_IO_H)
 387 check_include_files(sched.h      HAVE_SCHED_H)
 388
 389 include(CheckFunctionExists)
 390 check_function_exists(strcasecmp        HAVE_STRCASECMP)
 391 check_function_exists(strdup            HAVE_STRDUP)
 392 check_function_exists(vprintf           HAVE_VPRINTF)
 393 check_function_exists(memcmp            HAVE_MEMCMP)
 394 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 395 check_function_exists(memalign          HAVE_MEMALIGN)
 396 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 397 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 398 check_function_exists(isnan             HAVE_ISNAN)
 399 check_function_exists(_isnan            HAVE__ISNAN)
 400 check_function_exists(fsync             HAVE_FSYNC)
 401 check_function_exists(_fileno           HAVE__FILENO)
 402 check_function_exists(fileno            HAVE_FILENO)
 403 check_function_exists(_commit           HAVE__COMMIT)
 404 check_function_exists(sigaction         HAVE_SIGACTION)
 405 check_function_exists(sysconf           HAVE_SYSCONF)
 406 check_function_exists(sched_setaffinity HAVE_SCHED_SETAFFINITY)
 407 check_function_exists(sched_getaffinity HAVE_SCHED_GETAFFINITY)
 408 check_function_exists(rsqrt             HAVE_RSQRT)
 409 check_function_exists(rsqrtf            HAVE_RSQRTF)
 410 check_function_exists(sqrtf             HAVE_SQRTF)
 411
 412 include(CheckLibraryExists)
 413 check_library_exists(m sqrt "" HAVE_LIBM)
 414 check_library_exists(m cbrt "" HAVE_CBRT)
 415
 416
 417 include(CheckTypeSize)
 418
 419 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 420 check_type_size("int"           SIZEOF_INT)
 421 check_type_size("long int"      SIZEOF_LONG_INT)
 422 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 423 check_type_size("off_t"         SIZEOF_OFF_T)
 424 check_type_size("void *"        SIZEOF_VOIDP)
 425
 426 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 427     set(GMX_64_BIT TRUE)
 428 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 429     set(GMX_64_BIT FALSE)
 430 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 431
 432 # Check for some basic types that we *need*, so set these to int if they are not present
 433 check_type_size(uid_t uid_t)
 434 if(NOT uid_t)
 435   set(uid_t int)
 436 else(NOT uid_t)
 437   set(uid_t 0)
 438 endif(NOT uid_t)
 439
 440 check_type_size(gid_t gid_t)
 441 if(NOT gid_t)
 442   set(gid_t 1)
 443 else(NOT gid_t)
 444   set(gid_t 0)
 445 endif(NOT gid_t)
 446
 447 check_type_size(size_t size_t)
 448 if(NOT size_t)
 449   set(size_t int)
 450 else(NOT size_t)
 451   set(size_t 0)
 452 endif(NOT size_t)
 453
 454 check_type_size(off_t off_t)
 455 if(NOT off_t)
 456   set(off_t int)
 457 else(NOT off_t)
 458   set(off_t 0)
 459 endif(NOT off_t)
 460
 461 include(TestBigEndian)
 462 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 463
 464
 465 if(APPLE OR CYGWIN OR ${CMAKE_SYSTEM_NAME} MATCHES "Linux|.*BSD")
 466     # Maybe Solaris should be here? Patch this if you know!
 467     SET(SHARED_LIBS_DEFAULT ON)
 468 elseif(WIN32 OR ${CMAKE_SYSTEM_NAME} MATCHES "BlueGene")
 469     # Support for shared libs on native Windows is a bit new. Its
 470     # default might change later if/when we sort things out. Also,
 471     # Cray should go here. What variable value can detect it?
 472     SET(SHARED_LIBS_DEFAULT OFF)
 473 else()
 474     message(STATUS "Defaulting to building static libraries")
 475     SET(SHARED_LIBS_DEFAULT OFF)
 476 endif()
 477
 478 # Management of GROMACS options for specific toolchains should go
 479 # here. Because the initial settings for some of the main options have
 480 # already happened, but things like library detection and MPI compiler
 481 # feature detection have not, the docstrings for any over-rides of
 482 # GROMACS defaults or user settings will make sense. Also, any
 483 # toolchain-related reasons for choosing whether to detect various
 484 # things can be sorted out now, before the detection takes place.
 485 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 486     include(gmxManageBlueGene)
 487 endif()
 488
 489 if(UNIX AND GMX_PREFER_STATIC_LIBS AND SHARED_LIBS_DEFAULT)
 490     if(BUILD_SHARED_LIBS)
 491         # Warn the user about the combination. But don't overwrite the request.
 492         message(WARNING "Searching for static libraries requested, and building shared Gromacs libraries requested. This might cause problems linking later.")
 493     elseif(NOT DEFINED BUILD_SHARED_LIBS)
 494         # Change default to OFF. Don't warn if it's already off.
 495         message(WARNING "Searching for static libraries requested, so the GROMACS libraries will also be built statically (BUILD_SHARED_LIBS=OFF)")
 496         set(SHARED_LIBS_DEFAULT OFF)
 497     endif()
 498 endif()
 499
 500 # By now, all tool chains should have spoken up if they care about
 501 # the setting of SHARED_LIBS_DEFAULT.
 502 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic e.g. with MPI, or on some HPC systems)" ${SHARED_LIBS_DEFAULT})
 503
 504 ########################################################################
 505 #Process MPI settings
 506 ########################################################################
 507 include(gmxManageMPI)
 508
 509 ########################################################################
 510 # Find external packages                                               #
 511 ########################################################################
 512 if(UNIX AND GMX_PREFER_STATIC_LIBS)
 513     # On Linux .a is the static library suffix, on Mac OS X .lib can also
 514     # be used, so we'll add both to the preference list.
 515     SET(CMAKE_FIND_LIBRARY_SUFFIXES ".lib;.a" ${CMAKE_FIND_LIBRARY_SUFFIXES})
 516 endif()
 517
 518 IF( WIN32 AND NOT CYGWIN)
 519   if (NOT BUILD_SHARED_LIBS)
 520       option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static system libraries (MT instead of MD)!" ON)
 521       if(NOT GMX_PREFER_STATIC_LIBS)
 522           message(WARNING "Shared system libraries requested, and static Gromacs libraries requested.")
 523       endif()
 524   else()
 525       option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static system libraries (MT instead of MD)!" OFF)
 526       if(GMX_PREFER_STATIC_LIBS)
 527           #this combination segfaults (illigal passing of file handles)
 528           message(FATAL_ERROR "Static system libraries requested, and shared Gromacs libraries requested.")
 529       endif()
 530       add_definitions(-DUSE_VISIBILITY -DTMPI_USE_VISIBILITY)
 531       set(PKG_CFLAGS "$PKG_CFLAGS -DUSE_VISIBILITY -DTMPI_USE_VISIBILITY")
 532   endif()
 533   mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 534
 535   IF (GMX_PREFER_STATIC_LIBS)
 536       #Only setting Debug and Release flags. Others configurations are current not used.
 537       STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
 538       STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
 539       if(CMAKE_CXX_COMPILER_LOADED)
 540           STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE})
 541           STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 542       endif()
 543   ENDIF()
 544   IF( CMAKE_C_COMPILER_ID MATCHES "Intel" )
 545     if(BUILD_SHARED_LIBS) #not sure why incremental building with shared libs doesn't work
 546         STRING(REPLACE "/INCREMENTAL:YES" "" CMAKE_SHARED_LINKER_FLAGS ${CMAKE_SHARED_LINKER_FLAGS})
 547     endif()
 548   ENDIF()
 549 ENDIF()
 550
 551 option(GMX_GSL "Add support for gsl" OFF)
 552 if (GMX_GSL)
 553   find_package(GSL)
 554   set(PKG_GSL "")
 555   if(GSL_FOUND)
 556     include_directories(${GSL_INCLUDE_DIR})
 557     set(PKG_GSL gsl)
 558     set(HAVE_LIBGSL 1)
 559   endif(GSL_FOUND)
 560 endif (GMX_GSL)
 561
 562 option(GMX_X11 "Use X window system" OFF)
 563 if (GMX_X11)
 564     find_package(X11)
 565     # X11 includes/libraries are only set in the ngmx subdirectory!
 566     if(NOT X11_FOUND)
 567         message(WARNING "X11 include files and/or libraries were not found. Will not build the GROMACS X11-binaries, such as ngmx")
 568     endif()
 569 endif(GMX_X11)
 570
 571 include(ThreadMPI)
 572 set(THREAD_MPI_LIB thread_mpi)
 573 # Enable core threading facilities
 574 tmpi_enable_core("${CMAKE_SOURCE_DIR}/include")
 575 # Enable tMPI C++ support
 576 # tmpi_enable_cxx()
 577 if(GMX_THREAD_MPI)
 578     # enable MPI functions
 579     tmpi_enable()
 580     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREAD_MPI")
 581     set(GMX_MPI 1)
 582 endif(GMX_THREAD_MPI)
 583 tmpi_get_source_list(THREAD_MPI_SRC)
 584
 585 if(GMX_GPU)
 586     # now that we have detected the dependencies, do the second configure pass
 587     gmx_gpu_setup()
 588 endif(GMX_GPU)
 589
 590 if(APPLE)
 591    find_library(ACCELERATE_FRAMEWORK Accelerate)
 592    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 593 endif(APPLE)
 594
 595 if(CYGWIN)
 596     set(GMX_CYGWIN 1)
 597 endif(CYGWIN)
 598
 599 if(WIN32 AND NOT CYGWIN)
 600     set(GMX_NATIVE_WINDOWS 1)
 601 endif()
 602
 603 # only bother with finding git and using version.h if the source is a git repo
 604 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 605     if(USE_VERSION_H)
 606         # We need at least git v1.5.3 be able to parse git's date output. If not
 607         # found or the version is too small, we can't generate version information.
 608         find_package(Git)
 609
 610         # Find out the git version
 611         if(GIT_FOUND AND NOT GIT_VERSION)
 612           execute_process(COMMAND ${GIT_EXECUTABLE} "--version"
 613             OUTPUT_VARIABLE _exec_out
 614             OUTPUT_STRIP_TRAILING_WHITESPACE)
 615           string(REGEX REPLACE "git version (.*)" "\\1" GIT_VERSION ${_exec_out})
 616           set(GIT_VERSION ${GIT_VERSION} CACHE STRING "Git version")
 617           mark_as_advanced(GIT_VERSION)
 618         endif()
 619
 620         if(NOT GIT_FOUND OR GIT_VERSION VERSION_LESS "1.5.3")
 621           message("No compatible git version found, won't be able to generate proper development version information.")
 622           set(USE_VERSION_H OFF)
 623         endif()
 624     endif()
 625 else()
 626     set(USE_VERSION_H OFF)
 627 endif()
 628
 629 ########################################################################
 630 # Generate development version info for cache
 631 ########################################################################
 632 # set(GEN_VERSION_INFO_INTERNAL "ON")
 633 # include(gmxGenerateVersionString)
 634
 635 ########################################################################
 636 # Our own GROMACS tests
 637 ########################################################################
 638
 639 add_definitions( -DHAVE_CONFIG_H )
 640 include_directories(${CMAKE_BINARY_DIR}/src)
 641 include_directories(${CMAKE_BINARY_DIR}/include)
 642 include_directories(${CMAKE_SOURCE_DIR}/include)
 643
 644 include(gmxTestInlineASM)
 645 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 646
 647 include(gmxSetBuildInformation)
 648 gmx_set_build_information()
 649 if(BUILD_CPU_FEATURES MATCHES "rdtscp" AND NOT GMX_DISTRIBUTABLE_BUILD)
 650     # The timestep counter headers do not include config.h
 651     add_definitions(-DHAVE_RDTSCP)
 652 endif(BUILD_CPU_FEATURES MATCHES "rdtscp" AND NOT GMX_DISTRIBUTABLE_BUILD)
 653
 654 include(gmxTestFloatFormat)
 655 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 656                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 657                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 658
 659 include(gmxTestLargeFiles)
 660 gmx_test_large_files(GMX_LARGEFILES)
 661
 662 include(gmxTestSignal)
 663 gmx_test_sigusr1(HAVE_SIGUSR1)
 664
 665 include(gmxTestInline)
 666 gmx_test_inline(INLINE_KEYWORD)
 667
 668 include(gmxTestRestrict)
 669 gmx_test_restrict(RESTRICT_KEYWORD)
 670
 671 include(gmxTestPipes)
 672 gmx_test_pipes(HAVE_PIPES)
 673
 674 include(gmxTestIsfinite)
 675 gmx_test_isfinite(HAVE_ISFINITE)
 676 gmx_test__isfinite(HAVE__ISFINITE)
 677 gmx_test__finite(HAVE__FINITE)
 678
 679 include(gmxTestXDR)
 680 gmx_test_xdr(GMX_SYSTEM_XDR)
 681 if(NOT GMX_SYSTEM_XDR)
 682     set(GMX_INTERNAL_XDR 1)
 683     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 684 endif(NOT GMX_SYSTEM_XDR)
 685
 686 # include avx test source, used if the AVX flags are set below
 687 include(gmxTestAVXMaskload)
 688
 689 # Process nonbonded accelerated kernels settings
 690 #
 691 # Note that for the backward-compatible x86 SIMD architectures, the
 692 # GMX_CPU_ACCELERATION determines the maximum level of the instruction
 693 # set used (e.g. GMX_CPU_ACCLERATION=SSE4.1 implies
 694 # SSE2). Accordingly, there are a set of CMake variables
 695 # GMX_<arch>_<feature-set> that are exported to the C code to specify
 696 # CPU features that should be used. This means that the logic for
 697 # requiring such backward compatibility is all located here.
 698 string(TOUPPER ${GMX_CPU_ACCELERATION} GMX_CPU_ACCELERATION)
 699 if(${GMX_CPU_ACCELERATION} STREQUAL "NONE")
 700     # nothing to do
 701 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SSE2")
 702
 703     GMX_TEST_CFLAG(GNU_SSE2_CFLAG "-msse2" ACCELERATION_C_FLAGS)
 704     if(NOT GNU_SSE2_CFLAG AND GMX_NATIVE_WINDOWS)
 705         GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" ACCELERATION_C_FLAGS)
 706     endif(NOT GNU_SSE2_CFLAG AND GMX_NATIVE_WINDOWS)
 707
 708     if (CMAKE_CXX_COMPILER_LOADED)
 709         GMX_TEST_CXXFLAG(GNU_SSE2_CXXFLAG "-msse2" ACCELERATION_CXX_FLAGS)
 710         if(NOT GNU_SSE2_CXXFLAG AND GMX_NATIVE_WINDOWS)
 711             GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" ACCELERATION_CXX_FLAGS)
 712         endif(NOT GNU_SSE2_CXXFLAG AND GMX_NATIVE_WINDOWS)
 713     endif()
 714
 715     # We dont warn for lacking SSE2 flag support, since that is probably standard today.
 716
 717     # Only test the include after we have tried to add the correct flag for SSE2 support
 718     check_include_file(emmintrin.h  HAVE_EMMINTRIN_H ${ACCELERATION_C_FLAGS})
 719
 720     if(NOT HAVE_EMMINTRIN_H)
 721         message(FATAL_ERROR "Cannot find emmintrin.h, which is required for SSE2 intrinsics support.")
 722     endif(NOT HAVE_EMMINTRIN_H)
 723
 724     set(GMX_CPU_ACCELERATION_X86_SSE2 1)
 725     # The user should not be able to set this orthogonally to the acceleration
 726     set(GMX_X86_SSE2 1)
 727     if (NOT ACCELERATION_QUIETLY)
 728       message(STATUS "Enabling SSE2 Gromacs acceleration, and it will help compiler optimization.")
 729     endif()
 730
 731 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SSE4.1")
 732
 733     GMX_TEST_CFLAG(GNU_SSE4_CFLAG "-msse4.1" ACCELERATION_C_FLAGS)
 734     if (NOT GNU_SSE4_CFLAG AND GMX_NATIVE_WINDOWS)
 735         GMX_TEST_CFLAG(MSVC_SSE4_CFLAG "/arch:SSE4.1" ACCELERATION_C_FLAGS)
 736     endif(NOT GNU_SSE4_CFLAG AND GMX_NATIVE_WINDOWS)
 737     if (NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 738         # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 739         # intrinsics when SSE2 support is enabled, so we try that instead first.
 740         if (GMX_NATIVE_WINDOWS)
 741             GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" ACCELERATION_C_FLAGS)
 742             message(WARNING "Neither SSE4.1 or SSE2 seems to be supported by your Windows compiler. Something is likely broken.")
 743         else()
 744             message(WARNING "No C SSE4.1 flag found. Consider a newer compiler, or use SSE2 for slightly lower performance")
 745         endif()
 746     endif(NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 747
 748     if (CMAKE_CXX_COMPILER_LOADED)
 749         GMX_TEST_CXXFLAG(GNU_SSE4_CXXFLAG "-msse4.1" ACCELERATION_CXX_FLAGS)
 750         if (NOT GNU_SSE4_CXXFLAG AND GMX_NATIVE_WINDOWS)
 751             GMX_TEST_CXXFLAG(MSVC_SSE4_CXXFLAG "/arch:SSE4.1" ACCELERATION_CXX_FLAGS)
 752         endif(NOT GNU_SSE4_CXXFLAG AND GMX_NATIVE_WINDOWS)
 753         if (NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 754             message(WARNING "No C++ SSE4.1 flag found. Consider a newer compiler, or use SSE2 for slightly lower performance.")
 755             # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 756             # intrinsics when SSE2 support is enabled, so we try that instead.
 757             if (GMX_NATIVE_WINDOWS)
 758                 GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" ACCELERATION_CXX_FLAGS)
 759             endif()
 760         endif(NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 761     endif()
 762
 763     # This must come after we have added the -msse4.1 flag on some platforms.
 764     check_include_file(smmintrin.h  HAVE_SMMINTRIN_H ${ACCELERATION_C_FLAGS})
 765
 766     if(NOT HAVE_SMMINTRIN_H)
 767         message(FATAL_ERROR "Cannot find smmintrin.h, which is required for SSE4.1 intrinsics support.")
 768     endif(NOT HAVE_SMMINTRIN_H)
 769
 770     set(GMX_CPU_ACCELERATION_X86_SSE4_1 1)
 771     # The user should not be able to set this orthogonally to the acceleration
 772     set(GMX_X86_SSE4_1 1)
 773     set(GMX_X86_SSE2   1)
 774     if (NOT ACCELERATION_QUIETLY)
 775       message(STATUS "Enabling SSE4.1 Gromacs acceleration, and it will help compiler optimization.")
 776     endif()
 777
 778     if(CMAKE_C_COMPILER_ID MATCHES "Intel" AND C_COMPILER_VERSION VERSION_EQUAL "11.1")
 779         message(FATAL_ERROR "You are using Intel compiler version 11.1, and that compiler is known to produce incorrect results with SSE4.1 acceleration. You need to use another compiler (e.g. icc 12 or newer) or different acceleration (probably slower simulations).")
 780     endif()
 781 elseif(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA" OR ${GMX_CPU_ACCELERATION} STREQUAL "AVX_256")
 782
 783     # Set the AVX compiler flag for both these choices!
 784
 785     GMX_TEST_CFLAG(GNU_AVX_CFLAG "-mavx" ACCELERATION_C_FLAGS)
 786     if (NOT GNU_AVX_CFLAG AND GMX_NATIVE_WINDOWS)
 787         GMX_TEST_CFLAG(MSVC_AVX_CFLAG "/arch:AVX" ACCELERATION_C_FLAGS)
 788     endif (NOT GNU_AVX_CFLAG AND GMX_NATIVE_WINDOWS)
 789     if (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 790         message(WARNING "No C AVX flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 791     endif (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 792
 793     if (CMAKE_CXX_COMPILER_LOADED)
 794         GMX_TEST_CXXFLAG(GNU_AVX_CXXFLAG "-mavx" ACCELERATION_CXX_FLAGS)
 795         if (NOT GNU_AVX_CXXFLAG AND GMX_NATIVE_WINDOWS)
 796             GMX_TEST_CXXFLAG(MSVC_AVX_CXXFLAG "/arch:AVX" ACCELERATION_CXX_FLAGS)
 797         endif (NOT GNU_AVX_CXXFLAG AND GMX_NATIVE_WINDOWS)
 798         if (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 799             message(WARNING "No C++ AVX flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 800         endif (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 801     endif()
 802
 803     # Set the FMA4 flags (MSVC doesn't require any)
 804     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA" AND NOT MSVC)
 805         GMX_TEST_CFLAG(GNU_FMA_CFLAG "-mfma4" ACCELERATION_C_FLAGS)
 806         if (NOT GNU_FMA_CFLAG)
 807             message(WARNING "No C FMA4 flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 808         endif(NOT GNU_FMA_CFLAG)
 809         GMX_TEST_CFLAG(GNU_XOP_CFLAG "-mxop" ACCELERATION_C_FLAGS)
 810         # No big deal if we do not have xop, so no point yelling warnings about it.
 811         if (CMAKE_CXX_COMPILER_LOADED)
 812             GMX_TEST_CXXFLAG(GNU_FMA_CXXFLAG "-mfma4" ACCELERATION_CXX_FLAGS)
 813             if (NOT GNU_FMA_CXXFLAG)
 814                 message(WARNING "No C++ FMA flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 815             endif (NOT GNU_FMA_CXXFLAG)
 816             GMX_TEST_CXXFLAG(GNU_XOP_CXXFLAG "-mxop" ACCELERATION_CXX_FLAGS)
 817             # No big deal if we do not have xop, so no point yelling warnings about it.
 818         endif()
 819     endif()
 820
 821     # Only test the header after we have tried to add the flag for AVX support
 822     check_include_file(immintrin.h  HAVE_IMMINTRIN_H ${ACCELERATION_C_FLAGS})
 823
 824     if(NOT HAVE_IMMINTRIN_H)
 825         message(FATAL_ERROR "Cannot find immintrin.h, which is required for AVX intrinsics support. Consider switching compiler.")
 826     endif(NOT HAVE_IMMINTRIN_H)
 827
 828     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_256")
 829         try_compile(TEST_AVX ${CMAKE_BINARY_DIR}
 830             "${CMAKE_SOURCE_DIR}/cmake/TestAVX.c"
 831             COMPILE_DEFINITIONS "${ACCELERATION_C_FLAGS}")
 832         if(NOT TEST_AVX)
 833             message(FATAL_ERROR "Cannot compile AVX intrinsics. Consider switching compiler.")
 834         endif()
 835     endif()
 836
 837     # GCC requires x86intrin.h for FMA support. MSVC 2010 requires intrin.h for FMA support.
 838     check_include_file(x86intrin.h HAVE_X86INTRIN_H ${ACCELERATION_C_FLAGS})
 839     check_include_file(intrin.h HAVE_INTRIN_H ${ACCELERATION_C_FLAGS})
 840
 841     # The user should not be able to set this orthogonally to the acceleration
 842     set(GMX_X86_SSE4_1 1)
 843     set(GMX_X86_SSE2   1)
 844
 845     # But just enable one of the choices internally...
 846     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA")
 847         set(GMX_CPU_ACCELERATION_X86_AVX_128_FMA 1)
 848         set(GMX_X86_AVX_128_FMA 1)
 849         if (NOT ACCELERATION_QUIETLY)
 850           message(STATUS "Enabling 128-bit AVX Gromacs acceleration (with fused-multiply add), and it will help compiler optimization.")
 851         endif()
 852
 853         # We don't have the full compiler version string yet (BUILD_C_COMPILER),
 854         # so we can't distinguish vanilla and Apple clang, but catering for AMD
 855         # hackintoshes is not worth the effort.
 856         if (APPLE AND ${CMAKE_C_COMPILER_ID} STREQUAL "Clang")
 857             message(WARNING "Due to a known compiler bug, Clang up to version 3.2 (and Apple Clang up to version 4.1) produces incorrect code with AVX_128_FMA acceleration. As we can not work around this bug on OS X, you will have to select a different compiler or CPU acceleration.")
 858         endif()
 859
 860         if (GMX_USE_CLANG_FMA_BUG_WORKAROUND)
 861             # we assume that we have an external assembler that supports AVX
 862             message(STATUS "Clang ${C_COMPILER_VERSION} detected, enabling FMA bug workaround")
 863             set(EXTRA_C_FLAGS "${EXTRA_C_FLAGS} -no-integrated-as")
 864         endif()
 865
 866     else()
 867         # If we are not doing AVX_128, it must be AVX_256...
 868         set(GMX_CPU_ACCELERATION_X86_AVX_256 1)
 869         set(GMX_X86_AVX_256 1)
 870         if (NOT ACCELERATION_QUIETLY)
 871           message(STATUS "Enabling 256-bit AVX Gromacs acceleration, and it will help compiler optimization.")
 872         endif()
 873     endif()
 874
 875     # Unfortunately gcc-4.5.2 and gcc-4.6.0 has a bug where they use the wrong datatype for the formal
 876     # parameter of the mask for maskload/maskstore arguments. Check if this is present, since we can work around it.
 877     gmx_test_avx_gcc_maskload_bug(${ACCELERATION_C_FLAGS} GMX_X86_AVX_GCC_MASKLOAD_BUG)
 878
 879 elseif(${GMX_CPU_ACCELERATION} STREQUAL "IBM_QPX")
 880     # Used on BlueGene/Q
 881     if (CMAKE_C_COMPILER_ID MATCHES "XL")
 882         GMX_TEST_CFLAG(XLC_BLUEGENEQ_CFLAG "-qarch=qp -qtune=qp" ACCELERATION_C_FLAGS)
 883         try_compile(TEST_QPX ${CMAKE_BINARY_DIR}
 884             "${CMAKE_SOURCE_DIR}/cmake/TestQPX.c"
 885             COMPILE_DEFINITIONS "${ACCELERATION_C_FLAGS}")
 886         if(NOT TEST_QPX)
 887             message(FATAL_ERROR "Cannot compile the requested IBM QPX intrinsics.")
 888         endif()
 889     endif()
 890     if (CMAKE_CXX_COMPILER_ID MATCHES "XL" AND CMAKE_CXX_COMPILER_LOADED)
 891         GMX_TEST_CXXFLAG(XLC_BLUEGENEQ_CXXFLAG "-qarch=qp -qtune=qp" ACCELERATION_CXX_FLAGS)
 892         try_compile(TEST_QPX ${CMAKE_BINARY_DIR}
 893             "${CMAKE_SOURCE_DIR}/cmake/TestQPX.c"
 894             COMPILE_DEFINITIONS "${ACCELERATION_CXX_FLAGS}")
 895         if(NOT TEST_QPX)
 896             message(FATAL_ERROR "Cannot compile the requested IBM QPX intrinsics.")
 897         endif()
 898     endif()
 899
 900     if (TEST_QPX)
 901         message(WARNING "IBM QPX acceleration was selected and could be compiled, but the accelerated kernels are not yet available.")
 902         set(GMX_CPU_ACCELERATION_IBM_QPX 1)
 903     else()
 904         message(FATAL_ERROR "Cannot compile IBM QPX intrinsics without the XL compiler. If you are compiling for BlueGene/Q, use 'cmake .. -DCMAKE_TOOLCHAIN_FILE=BlueGeneQ-static-XL-C' to set up the tool chain.")
 905     endif()
 906 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SPARC64_HPC_ACE")
 907     set(GMX_CPU_ACCELERATION_SPARC64_HPC_ACE 1)
 908 else(${GMX_CPU_ACCELERATION} STREQUAL "NONE")
 909     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_CPU_ACCELERATION}. Pick one of None, SSE2, SSE4.1, AVX_128_FMA, AVX_256, IBM_QPX, Sparc64_HPC_ACE")
 910 endif(${GMX_CPU_ACCELERATION} STREQUAL "NONE")
 911 set(ACCELERATION_QUIETLY TRUE CACHE INTERNAL "")
 912
 913 # Process QM/MM Settings
 914 string(TOUPPER ${GMX_QMMM_PROGRAM} GMX_QMMM_PROGRAM)
 915 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 916     set(GMX_QMMM_GAUSSIAN 1)
 917 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 918     set(GMX_QMMM_MOPAC 1)
 919 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 920     set(GMX_QMMM_GAMESS 1)
 921 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 922     set(GMX_QMMM_ORCA 1)
 923 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 924     # nothing to do
 925 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 926     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 927 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 928
 929 # Process FFT library settings
 930 string(TOUPPER ${GMX_FFT_LIBRARY} GMX_FFT_LIBRARY)
 931 set(PKG_FFT "")
 932 set(PKG_FFT_LIBS "")
 933 set(MKL_LIBRARIES_FORMAT_DESCRIPTION "Use full paths to library files, in the right order, and separated by semicolons.")
 934 set(MKL_LIBRARIES "" CACHE STRING "List of libraries for linking to MKL. Only used with GMX_FFT_LIBRARY=mkl. ${MKL_LIBRARIES_FORMAT_DESCRIPTION}")
 935 set(MKL_INCLUDE_DIR "" CACHE PATH "Path to mkl.h (non-inclusive). Only used with GMX_FFT_LIBRARY=mkl.")
 936 mark_as_advanced(FORCE MKL_LIBRARIES)
 937 mark_as_advanced(FORCE MKL_INCLUDE_DIR)
 938 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 939     if(GMX_DOUBLE)
 940         set(FFTW fftw)
 941     else()
 942         set(FFTW fftwf)
 943     endif()
 944
 945     if(GMX_BUILD_OWN_FFTW)
 946       add_subdirectory(src/contrib/fftw)
 947     else()
 948       find_package(FFTW COMPONENTS ${FFTW})
 949     endif()
 950
 951     string(TOUPPER "${FFTW}" FFTW)
 952     set(PKG_FFT "${${FFTW}_PKG}")
 953     include_directories(${${FFTW}_INCLUDE_DIRS})
 954     set(FFT_LIBRARIES ${${FFTW}_LIBRARIES})
 955     if(NOT ${FFTW}_FOUND)
 956       MESSAGE(FATAL_ERROR "Cannot find FFTW 3 (with correct precision - libfftw3f for single-precision GROMACS or libfftw3 for double-precision GROMACS). Either choose the right precision, choose another FFT(W) library, enable the advanced option to let GROMACS build FFTW 3 for you, or use the really slow GROMACS built-in fftpack library.")
 957     endif()
 958
 959     set(GMX_FFT_FFTW3 1)
 960
 961     if ((${GMX_CPU_ACCELERATION} MATCHES "SSE" OR ${GMX_CPU_ACCELERATION} MATCHES "AVX") AND NOT ${FFTW}_HAVE_SIMD)
 962       message(WARNING "The fftw library found is compiled without SIMD support, which makes it slow. Consider recompiling it or contact your admin")
 963     endif()
 964
 965     if((${GMX_CPU_ACCELERATION} MATCHES "SSE" OR ${GMX_CPU_ACCELERATION} MATCHES "AVX") AND ${FFTW}_HAVE_AVX)
 966         # If we're not doing CPU acceleration, we don't care about FFTW performance on x86 either
 967         message(WARNING "The FFTW library was compiled with --enable-avx to enable AVX SIMD instructions. That might sound like a good idea for your processor, but for FFTW versions up to 3.3.3, these are slower than the SSE/SSE2 SIMD instructions for the way GROMACS uses FFTs. Limitations in the way FFTW allows GROMACS to measure performance make it awkward for either GROMACS or FFTW to make the decision for you based on runtime performance. You should compile a different FFTW library with --enable-sse or --enable-sse2. If you have a more recent FFTW, you may like to compare the performance of GROMACS with FFTW libraries compiled with and without --enable-avx. However, the GROMACS developers do not really expect the FFTW AVX optimization to help, because the performance is limited by memory access, not computation.")
 968     endif()
 969
 970     if(NOT "${GMX_FFT_LIBRARY}" STREQUAL "${GMX_FFT_LIBRARY_PREVIOUS_VALUE}")
 971         MESSAGE(STATUS "Using external FFT library - FFTW3")
 972     endif()
 973 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 974     # Intel 11 and up makes life somewhat easy if you just want to use
 975     # all their stuff. It's not easy if you only want some of their
 976     # stuff...
 977     if (CMAKE_C_COMPILER_ID MATCHES "Intel" AND C_COMPILER_VERSION VERSION_GREATER "11")
 978         # The next line takes care of everything for MKL
 979         if (WIN32)
 980             set(FFT_LINKER_FLAGS "/Qmkl=sequential")
 981         else()
 982             set(FFT_LINKER_FLAGS "-mkl=sequential")
 983         endif()
 984         set(MKL_ERROR_MESSAGE "Make sure you have configured your compiler so that ${FFT_LINKER_FLAGS} will work.")
 985     else()
 986         # The user will have to provide the set of magic libraries in
 987         # MKL_LIBRARIES, which we cache (non-advanced), so that they
 988         # don't have to keep specifying it, and can easily see that
 989         # CMake is still using that information.
 990         set(MKL_LIBRARIES "${MKL_LIBRARIES}" CACHE STRING "User-specified libraries for linking to MKL")
 991         mark_as_advanced(CLEAR MKL_LIBRARIES)
 992         include_directories(${MKL_INCLUDE_DIR})
 993         mark_as_advanced(CLEAR MKL_INCLUDE_DIR)
 994         set(FFT_LIBRARIES "${MKL_LIBRARIES}")
 995         set(MKL_ERROR_MESSAGE "The include path to mkl.h in MKL_INCLUDE_DIR, and the link libraries in MKL_LIBRARIES=${MKL_LIBRARIES} need to match what the MKL documentation says you need for your system. ${MKL_LIBRARIES_FORMAT_DESCRIPTION}")
 996         # Convert the semi-colon separated list to a list of
 997         # command-line linker arguments so that code using our
 998         # pkgconfig setup can use it.
 999         string(REGEX REPLACE ";" " " PKG_FFT_LIBS "${MKL_LIBRARIES}")
1000     endif()
1001
1002     # Check MKL works. If we were in a non-global scope, we wouldn't
1003     # have to play nicely.
1004     set(old_CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
1005     set(CMAKE_REQUIRED_FLAGS "${FFT_LINKER_FLAGS}")
1006     set(old_CMAKE_REQUIRED_LIBRARIES "${CMAKE_REQUIRED_LIBRARIES}")
1007     set(CMAKE_REQUIRED_LIBRARIES "${FFT_LIBRARIES}")
1008
1009     check_function_exists(DftiCreateDescriptor TEST_MKL)
1010
1011     set(CMAKE_REQUIRED_FLAGS "${old_CMAKE_REQUIRED_FLAGS}")
1012     set(CMAKE_REQUIRED_LIBRARIES "${old_CMAKE_REQUIRED_LIBRARIES}")
1013
1014     if(NOT TEST_MKL)
1015         # Hack to help the user vary MKL settings until they work.
1016         # TODO Make this logic more useful.
1017         unset(TEST_MKL CACHE)
1018         message(FATAL_ERROR "Linking with MKL was requested, but was not successful. ${MKL_ERROR_MESSAGE}")
1019     endif()
1020
1021     # Set variables to signal that we have MKL available and should use it for FFTs.
1022     set(GMX_FFT_MKL 1)
1023     set(HAVE_LIBMKL 1)
1024
1025     if(NOT "${GMX_FFT_LIBRARY}" STREQUAL "${GMX_FFT_LIBRARY_PREVIOUS_VALUE}")
1026         MESSAGE(STATUS "Using external FFT library - Intel MKL")
1027     endif()
1028
1029 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
1030 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
1031 #    set(GMX_FFT_ACML 1)
1032 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
1033     set(GMX_FFT_FFTPACK 1)
1034     if(NOT "${GMX_FFT_LIBRARY}" STREQUAL "${GMX_FFT_LIBRARY_PREVIOUS_VALUE}")
1035         MESSAGE(STATUS "Using internal FFT library - fftpack")
1036     endif()
1037 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
1038     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, mkl, fftpack")
1039 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
1040 set(GMX_FFT_LIBRARY_PREVIOUS_VALUE ${GMX_FFT_LIBRARY} CACHE INTERNAL "Previous value for GMX_FFT_LIBRARY, so that we can detect when it changes.")
1041
1042 # enable threaded fftw3 if we've found it
1043 if(FFTW3_THREADS OR FFTW3F_THREADS)
1044     add_definitions(-DFFT5D_FFTW_THREADS)
1045 endif()
1046
1047 set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
1048 set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
1049 # MKL has BLAS/LAPACK routines
1050 if(NOT HAVE_LIBMKL AND NOT ACCELERATE_FRAMEWORK)
1051   if(GMX_EXTERNAL_BLAS)
1052     if (GMX_BLAS_USER)
1053         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_BLAS_USER})
1054     else(GMX_BLAS_USER)
1055         set(BLAS_FIND_QUIETLY ON)
1056         find_package(BLAS)
1057         if (BLAS_FOUND)
1058           list(APPEND GMX_EXTRA_LIBRARIES ${BLAS_LIBRARIES})
1059         else()
1060           MESSAGE(STATUS "Using internal BLAS library")
1061           set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external BLAS instead of built-in" FORCE)
1062         endif()
1063     endif(GMX_BLAS_USER)
1064   endif(GMX_EXTERNAL_BLAS)
1065   if(GMX_EXTERNAL_LAPACK)
1066     if (GMX_LAPACK_USER)
1067         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_LAPACK_USER})
1068     else(GMX_LAPACK_USER)
1069         set(LAPACK_FIND_QUIETLY ON)
1070         find_package(LAPACK)
1071         if (LAPACK_FOUND)
1072           list(APPEND GMX_EXTRA_LIBRARIES ${LAPACK_LIBRARIES})
1073         else()
1074           MESSAGE(STATUS "Using internal LAPACK library")
1075           set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in" FORCE)
1076         endif()
1077     endif(GMX_LAPACK_USER)
1078   endif(GMX_EXTERNAL_LAPACK)
1079 endif()
1080 mark_as_advanced(GMX_EXTERNAL_LAPACK)
1081 mark_as_advanced(GMX_EXTERNAL_BLAS)
1082
1083 set(GMX_USE_PLUGINS OFF CACHE INTERNAL "Whether GROMACS will really try to compile support for VMD plugins")
1084
1085 if(GMX_LOAD_PLUGINS)
1086   if(CYGWIN OR NOT WIN32)
1087     # Native Windows does not have, nor need dlopen
1088     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
1089     include(gmxTestdlopen)
1090     gmx_test_dlopen(HAVE_DLOPEN)
1091   endif()
1092
1093   # so, should we use plug-ins?
1094   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
1095     if(NOT VMD_QUIETLY)
1096       MESSAGE(STATUS
1097           "Found the ability to use plug-ins when building shared libaries, "
1098           "so will compile to use plug-ins (e.g. to read VMD-supported file "
1099           "formats).")
1100     endif()
1101     if(NOT GMX_VMD_PLUGIN_PATH)
1102       find_package(VMD)
1103     endif()
1104     set(GMX_USE_PLUGINS ON)
1105     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
1106     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
1107   else()
1108     set(PKG_DL_LIBS)
1109   endif()
1110 endif(GMX_LOAD_PLUGINS)
1111 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
1112
1113 if(EXISTS "${CMAKE_SOURCE_DIR}/admin/.isreposource")
1114     if(NOT CMAKE_CROSSCOMPILING)
1115         option(GMX_BUILD_MANPAGES "Build man pages" ON)
1116     else()
1117         message(STATUS "Building the man pages is not available when "
1118             "cross-compiling the developer version from git")
1119     endif()
1120 else()
1121     #make sure source package contains all man pages
1122     if(NOT EXISTS "${CMAKE_SOURCE_DIR}/man/man1/ngmx.1")
1123         message(FATAL_ERROR "Man pages are missing from source package.")
1124     endif()
1125 endif()
1126 mark_as_advanced(GMX_BUILD_MANPAGES)
1127
1128 # Math and thread libraries must often come after all others when linking...
1129 if(HAVE_LIBM)
1130     list(APPEND GMX_EXTRA_LIBRARIES m)
1131 endif(HAVE_LIBM)
1132
1133 if(GMX_FAHCORE)
1134   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
1135       "Path to swindirect.h")
1136   include_directories(${COREWRAP_INCLUDE_DIR})
1137   set_property(CACHE GMX_COOL_QUOTES PROPERTY VALUE OFF)
1138 endif(GMX_FAHCORE)
1139
1140 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
1141 # these are set after everything else
1142 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
1143     set(CMAKE_C_FLAGS "${ACCELERATION_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
1144     set(CMAKE_CXX_FLAGS "${ACCELERATION_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${CMAKE_CXX_FLAGS}")
1145     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
1146     set(CMAKE_SHARED_LINKER_FLAGS "${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
1147 else()
1148     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
1149     message("CMAKE_C_FLAGS: ${ACCELERATION_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
1150     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
1151     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
1152     if(CMAKE_CXX_COMPILER_LOADED)
1153         message("CMAKE_CXX_FLAGS: ${ACCELERATION_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${GMXC_CXXFLAGS}")
1154         message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
1155         message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
1156     endif()
1157     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
1158     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
1159 endif()
1160
1161 if(NOT GMX_OPENMP)
1162     #Unset all OpenMP flags in case OpenMP was disabled either by the user
1163     #or because it was only partially detected (e.g. only for C but not C++ compiler)
1164     unset(OpenMP_C_FLAGS CACHE)
1165     unset(OpenMP_CXX_FLAGS CACHE)
1166     unset(OpenMP_LINKER_FLAGS CACHE)
1167     unset(OpenMP_SHARED_LINKER_FLAGS)
1168 endif()
1169 set(PKG_CFLAGS "${PKG_CFLAGS} ${OpenMP_C_FLAGS}")
1170
1171 ######################################
1172 # Output compiler and CFLAGS used
1173 ######################################
1174 get_compiler_info(C BUILD_C_COMPILER BUILD_CFLAGS)
1175 if (CMAKE_CXX_COMPILER_LOADED)
1176     get_compiler_info(CXX BUILD_CXX_COMPILER BUILD_CXXFLAGS)
1177 endif ()
1178 if(GMX_GPU)
1179     get_cuda_compiler_info(CUDA_NVCC_COMPILER_INFO CUDA_NVCC_COMPILER_FLAGS)
1180 endif(GMX_GPU)
1181
1182
1183 ########################################################################
1184 # Specify install locations and which subdirectories to process        #
1185 ########################################################################
1186 if (GMX_USE_RELATIVE_INSTALL_PATH)
1187     set(GMX_INSTALL_PREFIX "" CACHE STRING "Prefix gets appended to CMAKE_INSTALL_PREFIX. For cpack it sets the root folder of the archive.")
1188     mark_as_advanced(GMX_INSTALL_PREFIX)
1189 else()
1190     set(GMX_INSTALL_PREFIX "${CMAKE_INSTALL_PREFIX}/")
1191 endif()
1192
1193 if ( NOT DEFINED GMXLIB )
1194     set(GMXLIB lib)
1195 endif()
1196 set(LIB_INSTALL_DIR "${GMX_INSTALL_PREFIX}${GMXLIB}")
1197 set(BIN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}bin)
1198 set(DATA_INSTALL_DIR ${GMX_INSTALL_PREFIX}share/gromacs)
1199 set(MAN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}share/man)
1200 set(INCL_INSTALL_DIR ${GMX_INSTALL_PREFIX}include)
1201
1202 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
1203
1204 ##################################################################
1205 # Shared library settings - Darwin uses INSTALL_NAME_DIR instead!
1206 ##################################################################
1207 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
1208     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
1209     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
1210     set(CMAKE_INSTALL_RPATH "\\\$ORIGIN/../${GMXLIB}")
1211     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
1212 endif()
1213
1214 #COPYING file: Only necessary for binary distributions.
1215 #Simpler to always install.
1216 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
1217
1218 add_subdirectory(share)
1219 add_subdirectory(include)
1220 add_subdirectory(src)
1221 add_subdirectory(scripts)
1222
1223 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
1224 # Don't bother the user after the first configure pass.
1225 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
1226     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
1227     unset(CUDA_NOTFOUND_AUTO)
1228     unset(CUDA_NOTFOUND_MESSAGE)
1229 endif()
1230 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
1231
1232 #######################
1233 ## uninstall target
1234 #######################
1235     CONFIGURE_FILE(
1236                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
1237                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
1238                    IMMEDIATE @ONLY)
1239 ###########################
1240 ADD_CUSTOM_TARGET(uninstall
1241                   "${CMAKE_COMMAND}" -P
1242                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
1243 ###########################
1244
1245 ########################################################################
1246 # Tests                                                                #
1247 ########################################################################
1248
1249 include(CTest)
1250 mark_as_advanced(BUILD_TESTING)
1251 #gmxtests target builds all binaries required for running gmxtest
1252 add_custom_target(gmxtests DEPENDS grompp mdrun pdb2gmx gmxcheck editconf)
1253 IF(BUILD_TESTING)
1254     enable_testing()
1255     add_subdirectory(tests)
1256     if(REGRESSIONTEST_PATH)
1257         #check target builds all to run tests and the runs tests
1258         add_custom_target(check COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure)
1259         add_dependencies(check gmxtests)
1260     else()
1261         add_custom_target(check COMMAND ${CMAKE_COMMAND} -E echo "WARNING: No tests are run. Running the tests requires either of the cmake variables REGRESSIONTEST_PATH or REGRESSIONTEST_DOWNLOAD to be set.")
1262     endif()
1263 ENDIF()
1264