CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8)
   2 # Keep CMake suitably quiet on Cygwin
   3 set(CMAKE_LEGACY_CYGWIN_WIN32 0) # Remove when CMake >= 2.8.4 is required
   4
   5 # CMake modules/macros are in a subdirectory to keep this file cleaner
   6 # This needs to be set before project() in order to pick up toolchain files
   7 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
   8
   9 project(Gromacs)
  10 include(Dart)
  11 mark_as_advanced(DART_ROOT)
  12
  13 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  14 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  15 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  16
  17 # PROJECT_VERSION should have the following structure:
  18 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  19 #
  20 # The "-dev" suffix is important to keep because it makes possible to distinguish
  21 # between a build from official release and a build from git release branch on a
  22 # machine with no git.
  23 #
  24 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  25 set(PROJECT_VERSION "5.0-dev")
  26 # The version number of the regressiontest tarball against which this
  27 # git branch can be tested. Normally, this will be the version of the
  28 # last patch release. Comment the next line out for branches leading
  29 # to a major/minor release.
  30 set(REGRESSIONTEST_VERSION "4.6.2")
  31 set(CUSTOM_VERSION_STRING ""
  32     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  33 mark_as_advanced(CUSTOM_VERSION_STRING)
  34 if (CUSTOM_VERSION_STRING)
  35     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  36 endif (CUSTOM_VERSION_STRING)
  37 set(SOVERSION 8)
  38 # It is a bit irritating, but this has to be set separately for now!
  39 SET(CPACK_PACKAGE_VERSION_MAJOR "5")
  40 SET(CPACK_PACKAGE_VERSION_MINOR "0")
  41 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  42
  43 # The numerical gromacs version. It is 40600 for 4.6.0.
  44 # The #define GMX_VERSION in gmx_header_config_h is set to this value.
  45 math(EXPR NUM_VERSION
  46     "${CPACK_PACKAGE_VERSION_MAJOR}*10000 + ${CPACK_PACKAGE_VERSION_MINOR}*100")
  47 if(CPACK_PACKAGE_VERSION_PATCH)
  48     math(EXPR NUM_VERSION
  49          "${NUM_VERSION} + ${CPACK_PACKAGE_VERSION_PATCH}")
  50 endif()
  51
  52 # The API version tracks the numerical Gromacs version (for now).
  53 # It is potentially different from the Gromacs version in the future, if
  54 # the programs/libraries diverge from the presumably more stable API.
  55 # The #define GMX_API_VERSION in version.h is set to this value to
  56 # provide backward compatibility of software written against the Gromacs API.
  57 set(API_VERSION ${NUM_VERSION})
  58
  59 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  60     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  61 endif()
  62
  63 set(GMX_INSTALL_PREFIX "" CACHE STRING "Prefix gets appended to CMAKE_INSTALL_PREFIX. For cpack it sets the root folder of the archive.")
  64 mark_as_advanced(GMX_INSTALL_PREFIX)
  65
  66 include(gmxBuildTypeReference)
  67
  68 if(NOT CMAKE_BUILD_TYPE)
  69     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference." FORCE)
  70 endif(NOT CMAKE_BUILD_TYPE)
  71
  72 enable_language(C)
  73 enable_language(CXX)
  74
  75 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
  76 set(CPACK_PACKAGE_VENDOR "gromacs.org")
  77 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
  78 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
  79 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
  80 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/COPYING")
  81 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
  82 set(CPACK_SOURCE_IGNORE_FILES "\\\\.isreposource$;\\\\.git/;\\\\.gitignore$")
  83 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
  84 SET(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/man;man")
  85 set(CPACK_PACKAGE_CONTACT "gmx-users@gromacs.org")
  86
  87 #must come after all cpack settings!
  88 include(CPack)
  89
  90 set(SOURCE_IS_GIT_REPOSITORY OFF)
  91 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
  92     set(SOURCE_IS_GIT_REPOSITORY ON)
  93 endif()
  94
  95 ########################################################################
  96 # Check and warn if cache generated on a different host is being reused
  97 ########################################################################
  98 if(CMAKE_HOST_UNIX)
  99     execute_process(COMMAND hostname
 100                     OUTPUT_VARIABLE TMP_HOSTNAME
 101                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 102     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 103         message(WARNING "
 104             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 105             is being reused! This could lead to inconsitencies; therefore, it is
 106             recommended to regenerate the cache!")
 107     endif()
 108     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 109             "Hostname of the machine where the cache was generated.")
 110 endif()
 111
 112 ########################################################################
 113 option(GMX_COOL_QUOTES "Enable Gromacs cool quotes" ON)
 114 mark_as_advanced(GMX_COOL_QUOTES)
 115
 116 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 117 # User input options                                                   #
 118 ########################################################################
 119 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 120 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 121 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 122 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 123 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 124 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 125 mark_as_advanced(GMX_FAHCORE)
 126
 127 # decide on GPU settings based on user-settings and GPU/CUDA detection
 128 include(gmxManageGPU)
 129
 130 include(gmxDetectAcceleration)
 131 if(NOT DEFINED GMX_CPU_ACCELERATION)
 132     if(CMAKE_CROSSCOMPILING)
 133         if("${CMAKE_SYSTEM_NAME}" MATCHES "BlueGeneQ")
 134             set(GMX_SUGGESTED_CPU_ACCELERATION "IBM_QPX")
 135         else()
 136             set(GMX_SUGGESTED_CPU_ACCELERATION "None")
 137         endif()
 138     else(CMAKE_CROSSCOMPILING)
 139         gmx_detect_acceleration(GMX_SUGGESTED_CPU_ACCELERATION)
 140     endif(CMAKE_CROSSCOMPILING)
 141 endif(NOT DEFINED GMX_CPU_ACCELERATION)
 142
 143 set(GMX_CPU_ACCELERATION "@GMX_SUGGESTED_CPU_ACCELERATION@"
 144     CACHE STRING "Accelerated CPU kernels. Pick one of: None, SSE2, SSE4.1, AVX_128_FMA, AVX_256, IBM_QPX, Sparc64_HPC_ACE")
 145
 146 set(GMX_FFT_LIBRARY "fftw3"
 147     CACHE STRING "FFT library choices: fftw3,mkl,fftpack[built-in]")
 148 option(GMX_BUILD_OWN_FFTW "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack." OFF)
 149 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 150 option(GMX_DISABLE_FFTW_MEASURE
 151        "Do not optimize FFTW setups (not needed with SSE)" OFF)
 152 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 153 set(GMX_QMMM_PROGRAM "none"
 154     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
 155 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 156 mark_as_advanced(GMX_BROKEN_CALLOC)
 157 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
 158 mark_as_advanced(GMX_MPI_IN_PLACE)
 159 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 160 mark_as_advanced(GMX_LOAD_PLUGINS)
 161
 162 option(GMX_GPU  "Enable GPU acceleration" ON)
 163 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 164
 165 option(GMX_GIT_VERSION_INFO "Generate git version information" ${SOURCE_IS_GIT_REPOSITORY})
 166 mark_as_advanced(GMX_GIT_VERSION_INFO)
 167
 168 option(GMX_DEFAULT_SUFFIX "Use default suffixes for GROMACS binaries and libs (_d for double, _mpi for MPI; rerun cmake after changing to see relevant options)" ON)
 169 if(UNIX)
 170     option(GMX_SYMLINK_OLD_BINARY_NAMES "Create symbolic links for pre-5.0 binary names" ON)
 171 endif()
 172
 173 if(UNIX)
 174     option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static archives (not available on non-*nix platforms and it will only work if static versions of external dependencies are available and found)!" OFF)
 175     mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 176 endif()
 177
 178 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 179 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 180
 181 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 182 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 183
 184 option(GMX_BUILD_FOR_COVERAGE
 185        "Tune build for better code coverage metrics (e.g., disable asserts)"
 186        OFF)
 187 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 188
 189 ######################################################################
 190 # Compiler tests
 191 # These need to be done early (before further tests).
 192 #####################################################################
 193
 194 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 195 # are used with permission from CMake v2.8.9 so that GROMACS can detect
 196 # invalid options with the Intel Compilers.
 197 # These files should be removed from the source tree when a CMake version that
 198 # includes the features in question becomes required for building GROMACS.
 199 include(CheckCCompilerFlag)
 200 include(CheckCXXCompilerFlag)
 201
 202 # Get compiler version information, needs to be done early as check that depend
 203 # on compiler verison follow below.
 204 include(gmxGetCompilerInfo)
 205 get_compiler_version()
 206
 207 # First exclude compilers known to not work with OpenMP although claim to support it:
 208 # gcc 4.2.1 and gcc-llvm 4.2.1 (also claims to be 4.2.1) on Mac OS X
 209 # This fixes redmine 900 and needs to run before OpenMP flags are set below.
 210 if (CMAKE_SYSTEM_NAME STREQUAL "Darwin" AND
 211     (CMAKE_COMPILER_IS_GNUCC AND C_COMPILER_VERSION AND C_COMPILER_VERSION VERSION_LESS 4.3))
 212     message(STATUS "OpenMP multithreading not supported with gcc/llvm-gcc 4.2 on Mac OS X, disabled")
 213     set(GMX_OPENMP OFF CACHE BOOL
 214         "OpenMP multithreading not not supported with gcc/llvm-gcc 4.2 on Mac OS X, disabled!" FORCE)
 215 endif()
 216
 217 # OpenMP check must come before other CFLAGS!
 218 if(GMX_OPENMP)
 219     find_package(OpenMP)
 220     if(OPENMP_FOUND)
 221         # CMake on Windows doesn't support linker flags passed to target_link_libraries
 222         # (i.e. it treats /openmp as \openmp library file). Also, no OpenMP linker flags are needed.
 223         if(NOT (WIN32 AND NOT CYGWIN))
 224             if(CMAKE_COMPILER_IS_GNUCC AND GMX_PREFER_STATIC_OPENMP AND NOT APPLE)
 225                 set(OpenMP_LINKER_FLAGS "-Wl,-static -lgomp -lrt -Wl,-Bdynamic -lpthread")
 226                 set(OpenMP_SHARED_LINKER_FLAGS "")
 227             else()
 228                 # Only set a linker flag if the user didn't set them manually
 229                 if(NOT DEFINED OpenMP_LINKER_FLAGS)
 230                     set(OpenMP_LINKER_FLAGS "${OpenMP_C_FLAGS}")
 231                 endif()
 232                 if(NOT DEFINED OpenMP_SHARED_LINKER_FLAGS)
 233                     set(OpenMP_SHARED_LINKER_FLAGS "${OpenMP_C_FLAGS}")
 234                 endif()
 235             endif()
 236         endif()
 237     else(OPENMP_FOUND)
 238         message(WARNING
 239                 "The compiler you are using does not support OpenMP parallelism. This might hurt your performance a lot, in particular with GPUs. Try using a more recent version, or a different compiler. For now, we are proceeding by turning off OpenMP.")
 240         set(GMX_OPENMP OFF CACHE STRING "Whether GROMACS will use OpenMP parallelism." FORCE)
 241     endif(OPENMP_FOUND)
 242 endif()
 243
 244
 245 include(gmxCFlags)
 246 gmx_c_flags()
 247
 248 # This variable should be used for additional compiler flags which are not
 249 # generated in gmxCFlags nor are acceleration or MPI related.
 250 set(EXTRA_C_FLAGS "")
 251 set(EXTRA_CXX_FLAGS "")
 252
 253 # gcc 4.4.x is buggy and crashes when compiling some files with O3 and OpenMP on.
 254 # Detect here whether applying a workaround is needed and will apply it later
 255 # on the affected files.
 256 include(gmxGCC44O3BugWorkaround)
 257 gmx_check_gcc44_bug_workaround_needed(GMX_USE_GCC44_BUG_WORKAROUND)
 258
 259 # clang 3.0 is buggy for some unknown reason detected during adding
 260 # the SSE2 group kernels for GROMACS 4.6. If we ever work out what
 261 # that is, we should replace these tests with a compiler feature test,
 262 # update GROMACS Redmine task #1039 and perhaps report a clang bug.
 263 #
 264 # In the meantime, until we require CMake 2.8.10 we cannot rely on it to detect
 265 # the compiler version for us. So we need a manual check for clang 3.0.
 266 include(gmxDetectClang30)
 267 gmx_detect_clang_3_0(COMPILER_IS_CLANG_3_0)
 268 if(COMPILER_IS_CLANG_3_0)
 269     message(FATAL_ERROR "Your compiler is clang version 3.0, which is known to be buggy for GROMACS. Use a different compiler.")
 270 endif()
 271
 272 # clang <=3.2 contains a bug that causes incorrect code to be generated for the
 273 # vfmaddps instruction and therefore the bug is triggered with AVX_128_FMA.
 274 # (see: http://llvm.org/bugs/show_bug.cgi?id=15040).
 275 # We can work around this by not using the integrated assembler (except on OS X
 276 # which has an outdated assembler that does not support AVX instructions).
 277 if (${CMAKE_C_COMPILER_ID} MATCHES "Clang" AND C_COMPILER_VERSION VERSION_LESS "3.3")
 278     set(GMX_USE_CLANG_C_FMA_BUG_WORKAROUND TRUE)
 279 endif()
 280 if (${CMAKE_CXX_COMPILER_ID} MATCHES "Clang" AND CXX_COMPILER_VERSION VERSION_LESS "3.3")
 281     set(GMX_USE_CLANG_CXX_FMA_BUG_WORKAROUND TRUE)
 282 endif()
 283
 284 if (CMAKE_C_COMPILER_ID STREQUAL "PGI")
 285     message(WARNING "All tested PGI compiler versions (up to 12.9.0) generate binaries which produce incorrect results, or even fail to compile Gromacs. Highly recommended to use a different compiler. If you choose to use PGI, make sure to run the regressiontests.")
 286 endif()
 287
 288 if(CMAKE_C_COMPILER_ID MATCHES "Intel" AND C_COMPILER_VERSION VERSION_LESS "12.0.0")
 289     message(WARNING "Intel compilers before 12.0.0 are not routinely tested, so there may be problems. Version 11.1 with SSE4.1 is known to produce incorrect results. It is highly recommended to use a more up-to-date compiler. If you choose to use this version, make sure you run the regressiontests.")
 290 endif()
 291
 292 ########################################################################
 293 # Set up binary and library suffixing
 294 ########################################################################
 295 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 296 set(GMX_LIBS_SUFFIX ""
 297   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 298 if (GMX_DEFAULT_SUFFIX)
 299   set(GMX_BINARY_SUFFIX "")
 300   set(GMX_LIBS_SUFFIX "")
 301   if (GMX_MPI)
 302     set(GMX_BINARY_SUFFIX "_mpi")
 303     set(GMX_LIBS_SUFFIX "_mpi")
 304   endif(GMX_MPI)
 305   if (GMX_DOUBLE)
 306     set (GMX_BINARY_SUFFIX "${GMX_BINARY_SUFFIX}_d")
 307     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
 308   endif(GMX_DOUBLE)
 309   mark_as_advanced(FORCE GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 310   if (NOT SUFFIX_QUIETLY)
 311     message(STATUS "Using default binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 312     message(STATUS "Using default library suffix: \"${GMX_LIBS_SUFFIX}\"")
 313   endif (NOT SUFFIX_QUIETLY)
 314 else(GMX_DEFAULT_SUFFIX)
 315   mark_as_advanced(CLEAR GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 316   if (NOT SUFFIX_QUIETLY)
 317     message(STATUS "Using manually set binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 318     message(STATUS "Using manually set library suffix: \"${GMX_LIBS_SUFFIX}\"")
 319   endif (NOT SUFFIX_QUIETLY)
 320 endif(GMX_DEFAULT_SUFFIX)
 321 set(SUFFIX_QUIETLY TRUE CACHE INTERNAL "")
 322
 323 set(PKG_CFLAGS "")
 324 if(GMX_DOUBLE)
 325     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 326 endif(GMX_DOUBLE)
 327 if(GMX_SOFTWARE_INVSQRT)
 328   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 329 endif(GMX_SOFTWARE_INVSQRT)
 330
 331
 332
 333 ########################################################################
 334 # Basic system tests (standard libraries, headers, functions, types)   #
 335 ########################################################################
 336 include(CheckIncludeFiles)
 337 include(CheckIncludeFileCXX)
 338 check_include_files(unistd.h     HAVE_UNISTD_H)
 339 check_include_files(pwd.h        HAVE_PWD_H)
 340 check_include_files(pthread.h    HAVE_PTHREAD_H)
 341 check_include_files(dirent.h     HAVE_DIRENT_H)
 342 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 343 check_include_files(io.h                 HAVE_IO_H)
 344 check_include_files(sched.h      HAVE_SCHED_H)
 345
 346 check_include_files(regex.h      HAVE_POSIX_REGEX)
 347 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 348 # TODO: It could be nice to inform the user if no regex support is found,
 349 # as selections won't be fully functional.
 350
 351 include(CheckFunctionExists)
 352 check_function_exists(strdup            HAVE_STRDUP)
 353 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 354 check_function_exists(memalign          HAVE_MEMALIGN)
 355 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 356 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 357 check_function_exists(fsync             HAVE_FSYNC)
 358 check_function_exists(_fileno           HAVE__FILENO)
 359 check_function_exists(fileno            HAVE_FILENO)
 360 check_function_exists(_commit           HAVE__COMMIT)
 361 check_function_exists(sigaction         HAVE_SIGACTION)
 362 check_function_exists(sysconf           HAVE_SYSCONF)
 363 check_function_exists(sched_setaffinity HAVE_SCHED_SETAFFINITY)
 364 check_function_exists(sched_getaffinity HAVE_SCHED_GETAFFINITY)
 365 check_function_exists(rsqrt             HAVE_RSQRT)
 366 check_function_exists(rsqrtf            HAVE_RSQRTF)
 367 check_function_exists(sqrtf             HAVE_SQRTF)
 368
 369 include(CheckLibraryExists)
 370 check_library_exists(m sqrt "" HAVE_LIBM)
 371
 372
 373 include(CheckTypeSize)
 374
 375 check_type_size("int"           SIZEOF_INT)
 376 check_type_size("long int"      SIZEOF_LONG_INT)
 377 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 378 check_type_size("off_t"         SIZEOF_OFF_T)
 379 check_type_size("void *"        SIZEOF_VOIDP)
 380
 381 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 382     set(GMX_64_BIT TRUE)
 383 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 384     set(GMX_64_BIT FALSE)
 385 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 386
 387 include(TestBigEndian)
 388 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 389
 390
 391 if(APPLE OR CYGWIN OR ${CMAKE_SYSTEM_NAME} MATCHES "Linux|.*BSD")
 392     # Maybe Solaris should be here? Patch this if you know!
 393     SET(SHARED_LIBS_DEFAULT ON)
 394 elseif(WIN32 OR ${CMAKE_SYSTEM_NAME} MATCHES "BlueGene")
 395     # Support for shared libs on native Windows is a bit new. Its
 396     # default might change later if/when we sort things out. Also,
 397     # Cray should go here. What variable value can detect it?
 398     SET(SHARED_LIBS_DEFAULT OFF)
 399 else()
 400     message(STATUS "Defaulting to building static libraries")
 401     SET(SHARED_LIBS_DEFAULT OFF)
 402 endif()
 403
 404 # Management of GROMACS options for specific toolchains should go
 405 # here. Because the initial settings for some of the main options have
 406 # already happened, but things like library detection and MPI compiler
 407 # feature detection have not, the docstrings for any over-rides of
 408 # GROMACS defaults or user settings will make sense. Also, any
 409 # toolchain-related reasons for choosing whether to detect various
 410 # things can be sorted out now, before the detection takes place.
 411 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 412     include(gmxManageBlueGene)
 413 endif()
 414
 415 if(UNIX AND GMX_PREFER_STATIC_LIBS AND SHARED_LIBS_DEFAULT)
 416     if(BUILD_SHARED_LIBS)
 417         # Warn the user about the combination. But don't overwrite the request.
 418         message(WARNING "Searching for static libraries requested, and building shared Gromacs libraries requested. This might cause problems linking later.")
 419     elseif(NOT DEFINED BUILD_SHARED_LIBS)
 420         # Change default to OFF. Don't warn if it's already off.
 421         message(WARNING "Searching for static libraries requested, so the GROMACS libraries will also be built statically (BUILD_SHARED_LIBS=OFF)")
 422         set(SHARED_LIBS_DEFAULT OFF)
 423     endif()
 424 endif()
 425
 426 # By now, all tool chains should have spoken up if they care about
 427 # the setting of SHARED_LIBS_DEFAULT.
 428 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic e.g. with MPI, or on some HPC systems)" ${SHARED_LIBS_DEFAULT})
 429
 430 ########################################################################
 431 #Process MPI settings
 432 ########################################################################
 433 include(gmxManageMPI)
 434
 435 ########################################################################
 436 # Find external packages                                               #
 437 ########################################################################
 438 if(UNIX AND GMX_PREFER_STATIC_LIBS)
 439     # On Linux .a is the static library suffix, on Mac OS X .lib can also
 440     # be used, so we'll add both to the preference list.
 441     SET(CMAKE_FIND_LIBRARY_SUFFIXES ".lib;.a" ${CMAKE_FIND_LIBRARY_SUFFIXES})
 442 endif()
 443
 444 IF( WIN32 AND NOT CYGWIN)
 445   # This makes windows.h not declare min/max as macros that would break
 446   # C++ code using std::min/std::max.
 447   add_definitions(-DNOMINMAX)
 448
 449   if (NOT BUILD_SHARED_LIBS)
 450       option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static system libraries (MT instead of MD)!" ON)
 451       if(NOT GMX_PREFER_STATIC_LIBS)
 452           message(WARNING "Shared system libraries requested, and static Gromacs libraries requested.")
 453       endif()
 454   else()
 455       message(FATAL_ERROR "BUILD_SHARED_LIBS not yet working for Windows in the master branch")
 456       option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static system libraries (MT instead of MD)!" OFF)
 457       if(GMX_PREFER_STATIC_LIBS)
 458           #this combination segfaults (illigal passing of file handles)
 459           message(FATAL_ERROR "Static system libraries requested, and shared Gromacs libraries requested.")
 460       endif()
 461       add_definitions(-DUSE_VISIBILITY -DTMPI_USE_VISIBILITY)
 462       set(PKG_CFLAGS "$PKG_CFLAGS -DUSE_VISIBILITY -DTMPI_USE_VISIBILITY")
 463   endif()
 464   mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 465
 466   IF (GMX_PREFER_STATIC_LIBS)
 467       #Only setting Debug and Release flags. Others configurations are current not used.
 468       STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
 469       STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
 470       if(CMAKE_CXX_COMPILER_LOADED)
 471           STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE})
 472           STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 473       endif()
 474   ENDIF()
 475   IF( CMAKE_C_COMPILER_ID MATCHES "Intel" )
 476     if(BUILD_SHARED_LIBS) #not sure why incremental building with shared libs doesn't work
 477         STRING(REPLACE "/INCREMENTAL:YES" "" CMAKE_SHARED_LINKER_FLAGS ${CMAKE_SHARED_LINKER_FLAGS})
 478     endif()
 479   ENDIF()
 480 ENDIF()
 481
 482 # Unconditionally find the package, as it is also required for unit tests
 483 find_package(LibXml2)
 484 option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${LIBXML2_FOUND})
 485 set(PKG_XML "")
 486 mark_as_advanced(GMX_XML)
 487 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 488 #if(GMX_XML AND NOT LIBXML2_FOUND)
 489 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 490 #endif()
 491 #if(GMX_XML)
 492 #    include_directories(${LIBXML2_INCLUDE_DIR})
 493 #    set(PKG_XML libxml-2.0)
 494 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 495 #endif(GMX_XML)
 496
 497 option(GMX_GSL "Add support for gsl" OFF)
 498 if (GMX_GSL)
 499   find_package(GSL)
 500   set(PKG_GSL "")
 501   if(GSL_FOUND)
 502     include_directories(${GSL_INCLUDE_DIR})
 503     set(PKG_GSL gsl)
 504     set(HAVE_LIBGSL 1)
 505   endif(GSL_FOUND)
 506 endif (GMX_GSL)
 507
 508 option(GMX_X11 "Use X window system" OFF)
 509 if (GMX_X11)
 510     find_package(X11)
 511     # X11 includes/libraries are only set in the ngmx subdirectory!
 512     if(NOT X11_FOUND)
 513         message(WARNING "X11 include files and/or libraries were not found. Will not build the GROMACS X11-binaries, such as ngmx")
 514     endif()
 515 endif(GMX_X11)
 516
 517 include(ThreadMPI)
 518 set(THREAD_MPI_LIB thread_mpi)
 519 # Enable core threading facilities
 520 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders")
 521 # Enable tMPI C++ support
 522 tmpi_enable_cxx()
 523 if(GMX_THREAD_MPI)
 524     # enable MPI functions
 525     tmpi_enable()
 526     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREAD_MPI")
 527     set(GMX_MPI 1)
 528 endif(GMX_THREAD_MPI)
 529 tmpi_get_source_list(THREAD_MPI_SRC)
 530
 531 if(GMX_GPU)
 532     # now that we have detected the dependencies, do the second configure pass
 533     gmx_gpu_setup()
 534 endif(GMX_GPU)
 535
 536 if(CYGWIN)
 537     set(GMX_CYGWIN 1)
 538 endif(CYGWIN)
 539
 540 if(WIN32 AND NOT CYGWIN)
 541     set(GMX_NATIVE_WINDOWS 1)
 542 endif()
 543
 544 # only bother with finding git and using version.h if the source is a git repo
 545 if(GMX_GIT_VERSION_INFO)
 546     if (NOT SOURCE_IS_GIT_REPOSITORY)
 547         message(FATAL_ERROR
 548             "Cannot generate git version information from source tree not under git. "
 549             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 550     endif ()
 551     # We need at least git v1.5.3 be able to parse git's date output. If not
 552     # found or the version is too small, we can't generate version information.
 553     find_package(Git)
 554
 555     # Find out the git version
 556     if(GIT_FOUND AND NOT GIT_VERSION)
 557       execute_process(COMMAND ${GIT_EXECUTABLE} "--version"
 558         OUTPUT_VARIABLE _exec_out
 559         OUTPUT_STRIP_TRAILING_WHITESPACE)
 560       string(REGEX REPLACE "git version (.*)" "\\1" GIT_VERSION ${_exec_out})
 561       set(GIT_VERSION ${GIT_VERSION} CACHE STRING "Git version")
 562       mark_as_advanced(GIT_VERSION)
 563     endif()
 564
 565     if(NOT GIT_FOUND OR GIT_VERSION VERSION_LESS "1.5.3")
 566         message(FATAL_ERROR
 567             "No compatible git version found (>= 1.5.3 required). "
 568             "Won't be able to generate development version information. "
 569             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 570     endif()
 571 endif()
 572
 573 # Detect boost unless GMX_EXTERNAL_BOOST is explicitly OFF
 574 # Used for default if GMX_EXTERNAL_BOOST is not defined (first CMake pass)
 575 if(NOT DEFINED GMX_EXTERNAL_BOOST OR GMX_EXTERNAL_BOOST)
 576     find_package(Boost 1.44.0)
 577     if(Boost_FOUND AND Boost_VERSION VERSION_LESS "104400")
 578         set(Boost_FOUND FALSE)
 579     endif()
 580     # Print the notification only on first run, when determining the default
 581     if(NOT DEFINED GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 582         message("Boost >= 1.44 not found. Using minimal internal version. "
 583                 "This may cause trouble if you plan on compiling/linking other "
 584                 "software that uses Boost against Gromacs.")
 585     endif()
 586 endif()
 587 option(GMX_EXTERNAL_BOOST "Use external Boost instead of minimal built-in version"
 588        ${Boost_FOUND})
 589 if(GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 590     message(FATAL_ERROR
 591         "Boost >= 1.44 not found. "
 592         "You can set GMX_EXTERNAL_BOOST=OFF to compile against minimal "
 593         "version of Boost included with Gromacs.")
 594 endif()
 595
 596 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ${LIBXML2_FOUND})
 597 mark_as_advanced(GMX_BUILD_UNITTESTS)
 598 if (GMX_BUILD_UNITTESTS AND NOT LIBXML2_FOUND)
 599     message(FATAL_ERROR
 600         "Cannot build unit tests without libxml2. "
 601         "Either set GMX_BUILD_UNITTESTS=OFF or tell CMake how to find libxml2.")
 602 endif()
 603 set(MEMORYCHECK_SUPPRESSIONS_FILE ${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp)
 604
 605 ########################################################################
 606 # Generate development version info for cache
 607 ########################################################################
 608 # set(GEN_VERSION_INFO_INTERNAL "ON")
 609 # include(gmxGenerateVersionString)
 610
 611 ########################################################################
 612 # Our own GROMACS tests
 613 ########################################################################
 614
 615 add_definitions( -DHAVE_CONFIG_H )
 616 include_directories(${CMAKE_SOURCE_DIR}/src)
 617 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 618 include_directories(${CMAKE_BINARY_DIR}/src)
 619 # Required for gmx_header_config_gen.h to be found before installation
 620 include_directories(${CMAKE_BINARY_DIR}/src/gromacs/utility)
 621 # Required for now to make old code compile
 622 include_directories(${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders)
 623
 624 include(gmxTestInlineASM)
 625 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 626
 627 include(gmxSetBuildInformation)
 628 gmx_set_build_information()
 629 if(BUILD_CPU_FEATURES MATCHES "rdtscp" AND NOT GMX_DISTRIBUTABLE_BUILD)
 630     # The timestep counter headers do not include config.h
 631     add_definitions(-DHAVE_RDTSCP)
 632 endif(BUILD_CPU_FEATURES MATCHES "rdtscp" AND NOT GMX_DISTRIBUTABLE_BUILD)
 633
 634 include(gmxTestFloatFormat)
 635 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 636                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 637                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 638
 639 include(gmxTestLargeFiles)
 640 gmx_test_large_files(GMX_LARGEFILES)
 641
 642 include(gmxTestSignal)
 643 gmx_test_sigusr1(HAVE_SIGUSR1)
 644
 645 include(gmxTestInline)
 646 gmx_test_inline(INLINE_KEYWORD)
 647
 648 include(gmxTestRestrict)
 649 gmx_test_restrict(RESTRICT_KEYWORD)
 650
 651 include(gmxTestPipes)
 652 gmx_test_pipes(HAVE_PIPES)
 653
 654 include(gmxTestIsfinite)
 655 gmx_test_isfinite(HAVE_ISFINITE)
 656 gmx_test__isfinite(HAVE__ISFINITE)
 657 gmx_test__finite(HAVE__FINITE)
 658
 659 include(gmxTestCXX11)
 660 gmx_test_cxx11(GMX_CXX11 GMX_CXX11_FLAGS)
 661 if(CXX11_FLAG AND GMX_GPU)
 662     #FIXME: add proper solution for progate all but cxx11 flag
 663     set(CUDA_PROPAGATE_HOST_FLAGS no)
 664     message(WARNING "Please manually add compiler flags to CUDA_NVCC_FLAGS. Automatic propogation temporary not working.")
 665 endif()
 666
 667 include(gmxTestXDR)
 668 gmx_test_xdr(GMX_SYSTEM_XDR)
 669 if(NOT GMX_SYSTEM_XDR)
 670     set(GMX_INTERNAL_XDR 1)
 671     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 672 endif(NOT GMX_SYSTEM_XDR)
 673
 674 # include avx test source, used if the AVX flags are set below
 675 include(gmxTestAVXMaskload)
 676
 677 # Process nonbonded accelerated kernels settings
 678 #
 679 # Note that for the backward-compatible x86 SIMD architectures, the
 680 # GMX_CPU_ACCELERATION determines the maximum level of the instruction
 681 # set used (e.g. GMX_CPU_ACCLERATION=SSE4.1 implies
 682 # SSE2). Accordingly, there are a set of CMake variables
 683 # GMX_<arch>_<feature-set> that are exported to the C code to specify
 684 # CPU features that should be used. This means that the logic for
 685 # requiring such backward compatibility is all located here.
 686 string(TOUPPER ${GMX_CPU_ACCELERATION} GMX_CPU_ACCELERATION)
 687 if(${GMX_CPU_ACCELERATION} STREQUAL "NONE")
 688     # nothing to do
 689 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SSE2")
 690
 691     GMX_TEST_CFLAG(GNU_SSE2_CFLAG "-msse2" ACCELERATION_C_FLAGS)
 692     if(NOT GNU_SSE2_CFLAG AND GMX_NATIVE_WINDOWS)
 693         GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" ACCELERATION_C_FLAGS)
 694     endif(NOT GNU_SSE2_CFLAG AND GMX_NATIVE_WINDOWS)
 695
 696     GMX_TEST_CXXFLAG(GNU_SSE2_CXXFLAG "-msse2" ACCELERATION_CXX_FLAGS)
 697     if(NOT GNU_SSE2_CXXFLAG AND GMX_NATIVE_WINDOWS)
 698         GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" ACCELERATION_CXX_FLAGS)
 699     endif(NOT GNU_SSE2_CXXFLAG AND GMX_NATIVE_WINDOWS)
 700
 701     # We dont warn for lacking SSE2 flag support, since that is probably standard today.
 702
 703     # Only test the include after we have tried to add the correct flag for SSE2 support
 704     check_include_file(emmintrin.h  HAVE_EMMINTRIN_H ${ACCELERATION_C_FLAGS})
 705
 706     if(NOT HAVE_EMMINTRIN_H)
 707         message(FATAL_ERROR "Cannot find emmintrin.h, which is required for SSE2 intrinsics support.")
 708     endif(NOT HAVE_EMMINTRIN_H)
 709
 710     set(GMX_CPU_ACCELERATION_X86_SSE2 1)
 711     # The user should not be able to set this orthogonally to the acceleration
 712     set(GMX_X86_SSE2 1)
 713     if (NOT ACCELERATION_QUIETLY)
 714       message(STATUS "Enabling SSE2 Gromacs acceleration, and it will help compiler optimization.")
 715     endif()
 716
 717 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SSE4.1")
 718
 719     GMX_TEST_CFLAG(GNU_SSE4_CFLAG "-msse4.1" ACCELERATION_C_FLAGS)
 720     if (NOT GNU_SSE4_CFLAG AND GMX_NATIVE_WINDOWS)
 721         GMX_TEST_CFLAG(MSVC_SSE4_CFLAG "/arch:SSE4.1" ACCELERATION_C_FLAGS)
 722     endif(NOT GNU_SSE4_CFLAG AND GMX_NATIVE_WINDOWS)
 723     if (NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 724         # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 725         # intrinsics when SSE2 support is enabled, so we try that instead first.
 726         if (GMX_NATIVE_WINDOWS)
 727             GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" ACCELERATION_C_FLAGS)
 728             message(WARNING "Neither SSE4.1 or SSE2 seems to be supported by your Windows compiler. Something is likely broken.")
 729         else()
 730             message(WARNING "No C SSE4.1 flag found. Consider a newer compiler, or use SSE2 for slightly lower performance")
 731         endif()
 732     endif(NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 733
 734     GMX_TEST_CXXFLAG(GNU_SSE4_CXXFLAG "-msse4.1" ACCELERATION_CXX_FLAGS)
 735     if (NOT GNU_SSE4_CXXFLAG AND GMX_NATIVE_WINDOWS)
 736         GMX_TEST_CXXFLAG(MSVC_SSE4_CXXFLAG "/arch:SSE4.1" ACCELERATION_CXX_FLAGS)
 737     endif(NOT GNU_SSE4_CXXFLAG AND GMX_NATIVE_WINDOWS)
 738     if (NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 739         message(WARNING "No C++ SSE4.1 flag found. Consider a newer compiler, or use SSE2 for slightly lower performance.")
 740         # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 741         # intrinsics when SSE2 support is enabled, so we try that instead.
 742         if (GMX_NATIVE_WINDOWS)
 743             GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" ACCELERATION_CXX_FLAGS)
 744         endif()
 745     endif(NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 746
 747     # This must come after we have added the -msse4.1 flag on some platforms.
 748     check_include_file(smmintrin.h  HAVE_SMMINTRIN_H ${ACCELERATION_C_FLAGS})
 749
 750     if(NOT HAVE_SMMINTRIN_H)
 751         message(FATAL_ERROR "Cannot find smmintrin.h, which is required for SSE4.1 intrinsics support.")
 752     endif(NOT HAVE_SMMINTRIN_H)
 753
 754     set(GMX_CPU_ACCELERATION_X86_SSE4_1 1)
 755     # The user should not be able to set this orthogonally to the acceleration
 756     set(GMX_X86_SSE4_1 1)
 757     set(GMX_X86_SSE2   1)
 758     if (NOT ACCELERATION_QUIETLY)
 759       message(STATUS "Enabling SSE4.1 Gromacs acceleration, and it will help compiler optimization.")
 760     endif()
 761
 762     if(CMAKE_C_COMPILER_ID MATCHES "Intel" AND C_COMPILER_VERSION VERSION_EQUAL "11.1")
 763         message(FATAL_ERROR "You are using Intel compiler version 11.1, and that compiler is known to produce incorrect results with SSE4.1 acceleration. You need to use another compiler (e.g. icc 12 or newer) or different acceleration (probably slower simulations).")
 764     endif()
 765 elseif(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA" OR ${GMX_CPU_ACCELERATION} STREQUAL "AVX_256")
 766
 767     # Set the AVX compiler flag for both these choices!
 768
 769     GMX_TEST_CFLAG(GNU_AVX_CFLAG "-mavx" ACCELERATION_C_FLAGS)
 770     if (NOT GNU_AVX_CFLAG AND GMX_NATIVE_WINDOWS)
 771         GMX_TEST_CFLAG(MSVC_AVX_CFLAG "/arch:AVX" ACCELERATION_C_FLAGS)
 772     endif (NOT GNU_AVX_CFLAG AND GMX_NATIVE_WINDOWS)
 773     if (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 774         message(WARNING "No C AVX flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 775     endif (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 776
 777     GMX_TEST_CXXFLAG(GNU_AVX_CXXFLAG "-mavx" ACCELERATION_CXX_FLAGS)
 778     if (NOT GNU_AVX_CXXFLAG AND GMX_NATIVE_WINDOWS)
 779         GMX_TEST_CXXFLAG(MSVC_AVX_CXXFLAG "/arch:AVX" ACCELERATION_CXX_FLAGS)
 780     endif (NOT GNU_AVX_CXXFLAG AND GMX_NATIVE_WINDOWS)
 781     if (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 782        message(WARNING "No C++ AVX flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 783     endif (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 784
 785     # Set the FMA4 flags (MSVC doesn't require any)
 786     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA" AND NOT MSVC)
 787         GMX_TEST_CFLAG(GNU_FMA_CFLAG "-mfma4" ACCELERATION_C_FLAGS)
 788         if (NOT GNU_FMA_CFLAG)
 789             message(WARNING "No C FMA4 flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 790         endif(NOT GNU_FMA_CFLAG)
 791         GMX_TEST_CFLAG(GNU_XOP_CFLAG "-mxop" ACCELERATION_C_FLAGS)
 792         # No big deal if we do not have xop, so no point yelling warnings about it.
 793         if (CMAKE_CXX_COMPILER_LOADED)
 794             GMX_TEST_CXXFLAG(GNU_FMA_CXXFLAG "-mfma4" ACCELERATION_CXX_FLAGS)
 795             if (NOT GNU_FMA_CXXFLAG)
 796                 message(WARNING "No C++ FMA flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 797             endif (NOT GNU_FMA_CXXFLAG)
 798             GMX_TEST_CXXFLAG(GNU_XOP_CXXFLAG "-mxop" ACCELERATION_CXX_FLAGS)
 799             # No big deal if we do not have xop, so no point yelling warnings about it.
 800         endif()
 801     endif()
 802
 803     # Only test the header after we have tried to add the flag for AVX support
 804     check_include_file(immintrin.h  HAVE_IMMINTRIN_H ${ACCELERATION_C_FLAGS})
 805
 806     if(NOT HAVE_IMMINTRIN_H)
 807         message(FATAL_ERROR "Cannot find immintrin.h, which is required for AVX intrinsics support. Consider switching compiler.")
 808     endif(NOT HAVE_IMMINTRIN_H)
 809
 810     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_256")
 811         try_compile(TEST_AVX ${CMAKE_BINARY_DIR}
 812             "${CMAKE_SOURCE_DIR}/cmake/TestAVX.c"
 813             COMPILE_DEFINITIONS "${ACCELERATION_C_FLAGS}")
 814         if(NOT TEST_AVX)
 815             message(FATAL_ERROR "Cannot compile AVX intrinsics. Consider switching compiler.")
 816         endif()
 817     endif()
 818
 819     # GCC requires x86intrin.h for FMA support. MSVC 2010 requires intrin.h for FMA support.
 820     check_include_file(x86intrin.h HAVE_X86INTRIN_H ${ACCELERATION_C_FLAGS})
 821     check_include_file(intrin.h HAVE_INTRIN_H ${ACCELERATION_C_FLAGS})
 822
 823     # The user should not be able to set this orthogonally to the acceleration
 824     set(GMX_X86_SSE4_1 1)
 825     set(GMX_X86_SSE2   1)
 826
 827     # But just enable one of the choices internally...
 828     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA")
 829         set(GMX_CPU_ACCELERATION_X86_AVX_128_FMA 1)
 830         set(GMX_X86_AVX_128_FMA 1)
 831         if (NOT ACCELERATION_QUIETLY)
 832           message(STATUS "Enabling 128-bit AVX Gromacs acceleration (with fused-multiply add), and it will help compiler optimization.")
 833         endif()
 834
 835         # We don't have the full compiler version string yet (BUILD_C_COMPILER),
 836         # so we can't distinguish vanilla and Apple clang, but catering for AMD
 837         # hackintoshes is not worth the effort.
 838         if (APPLE AND (${CMAKE_C_COMPILER_ID} STREQUAL "Clang" OR
 839                     ${CMAKE_CXX_COMPILER_ID} STREQUAL "Clang"))
 840             message(WARNING "Due to a known compiler bug, Clang up to version 3.2 (and Apple Clang up to version 4.1) produces incorrect code with AVX_128_FMA acceleration. As we can not work around this bug on OS X, you will have to select a different compiler or CPU acceleration.")
 841         endif()
 842
 843         if (GMX_USE_CLANG_C_FMA_BUG_WORKAROUND)
 844             # we assume that we have an external assembler that supports AVX
 845             message(STATUS "Clang ${C_COMPILER_VERSION} detected, enabling FMA bug workaround")
 846             set(EXTRA_C_FLAGS "${EXTRA_C_FLAGS} -no-integrated-as")
 847         endif()
 848         if (GMX_USE_CLANG_CXX_FMA_BUG_WORKAROUND)
 849             # we assume that we have an external assembler that supports AVX
 850             message(STATUS "Clang ${CXX_COMPILER_VERSION} detected, enabling FMA bug workaround")
 851             set(EXTRA_CXX_FLAGS "${EXTRA_CXX_FLAGS} -no-integrated-as")
 852         endif()
 853
 854     else()
 855         # If we are not doing AVX_128, it must be AVX_256...
 856         set(GMX_CPU_ACCELERATION_X86_AVX_256 1)
 857         set(GMX_X86_AVX_256 1)
 858         if (NOT ACCELERATION_QUIETLY)
 859           message(STATUS "Enabling 256-bit AVX Gromacs acceleration, and it will help compiler optimization.")
 860         endif()
 861     endif()
 862
 863     # Unfortunately gcc-4.5.2 and gcc-4.6.0 has a bug where they use the wrong datatype for the formal
 864     # parameter of the mask for maskload/maskstore arguments. Check if this is present, since we can work around it.
 865     gmx_test_avx_gcc_maskload_bug(${ACCELERATION_C_FLAGS} GMX_X86_AVX_GCC_MASKLOAD_BUG)
 866
 867 elseif(${GMX_CPU_ACCELERATION} STREQUAL "IBM_QPX")
 868     # Used on BlueGene/Q
 869     if (CMAKE_C_COMPILER_ID MATCHES "XL")
 870         GMX_TEST_CFLAG(XLC_BLUEGENEQ_CFLAG "-qarch=qp -qtune=qp" ACCELERATION_C_FLAGS)
 871         try_compile(TEST_QPX ${CMAKE_BINARY_DIR}
 872             "${CMAKE_SOURCE_DIR}/cmake/TestQPX.c"
 873             COMPILE_DEFINITIONS "${ACCELERATION_C_FLAGS}")
 874         if(NOT TEST_QPX)
 875             message(FATAL_ERROR "Cannot compile the requested IBM QPX intrinsics.")
 876         endif()
 877     endif()
 878     if (CMAKE_CXX_COMPILER_ID MATCHES "XL" AND CMAKE_CXX_COMPILER_LOADED)
 879         GMX_TEST_CXXFLAG(XLC_BLUEGENEQ_CXXFLAG "-qarch=qp -qtune=qp" ACCELERATION_CXX_FLAGS)
 880         try_compile(TEST_QPX ${CMAKE_BINARY_DIR}
 881             "${CMAKE_SOURCE_DIR}/cmake/TestQPX.c"
 882             COMPILE_DEFINITIONS "${ACCELERATION_CXX_FLAGS}")
 883         if(NOT TEST_QPX)
 884             message(FATAL_ERROR "Cannot compile the requested IBM QPX intrinsics.")
 885         endif()
 886     endif()
 887
 888     if (TEST_QPX)
 889         message(WARNING "IBM QPX acceleration was selected and could be compiled, but the accelerated kernels are not yet available.")
 890         set(GMX_CPU_ACCELERATION_IBM_QPX 1)
 891     else()
 892         message(FATAL_ERROR "Cannot compile IBM QPX intrinsics without the XL compiler. If you are compiling for BlueGene/Q, use 'cmake .. -DCMAKE_TOOLCHAIN_FILE=BlueGeneQ-static-XL-C' to set up the tool chain.")
 893     endif()
 894 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SPARC64_HPC_ACE")
 895     set(GMX_CPU_ACCELERATION_SPARC64_HPC_ACE 1)
 896 else(${GMX_CPU_ACCELERATION} STREQUAL "NONE")
 897     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_CPU_ACCELERATION}. Pick one of None, SSE2, SSE4.1, AVX_128_FMA, AVX_256, IBM_QPX, Sparc64_HPC_ACE")
 898 endif(${GMX_CPU_ACCELERATION} STREQUAL "NONE")
 899 set(ACCELERATION_QUIETLY TRUE CACHE INTERNAL "")
 900
 901 # Process QM/MM Settings
 902 string(TOUPPER ${GMX_QMMM_PROGRAM} GMX_QMMM_PROGRAM)
 903 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 904     set(GMX_QMMM_GAUSSIAN 1)
 905 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 906     set(GMX_QMMM_MOPAC 1)
 907 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 908     set(GMX_QMMM_GAMESS 1)
 909 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 910     set(GMX_QMMM_ORCA 1)
 911 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 912     # nothing to do
 913 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 914     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 915 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 916
 917 # Process FFT library settings
 918 string(TOUPPER ${GMX_FFT_LIBRARY} GMX_FFT_LIBRARY)
 919 set(PKG_FFT "")
 920 set(PKG_FFT_LIBS "")
 921 set(MKL_LIBRARIES_FORMAT_DESCRIPTION "Use full paths to library files, in the right order, and separated by semicolons.")
 922 set(MKL_LIBRARIES "" CACHE STRING "List of libraries for linking to MKL. Only used with GMX_FFT_LIBRARY=mkl. ${MKL_LIBRARIES_FORMAT_DESCRIPTION}")
 923 set(MKL_INCLUDE_DIR "" CACHE PATH "Path to mkl.h (non-inclusive). Only used with GMX_FFT_LIBRARY=mkl.")
 924 mark_as_advanced(FORCE MKL_LIBRARIES)
 925 mark_as_advanced(FORCE MKL_INCLUDE_DIR)
 926 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 927     if(GMX_DOUBLE)
 928         set(FFTW fftw)
 929     else()
 930         set(FFTW fftwf)
 931     endif()
 932
 933     if(GMX_BUILD_OWN_FFTW)
 934       add_subdirectory(src/contrib/fftw)
 935     else()
 936       find_package(FFTW COMPONENTS ${FFTW})
 937     endif()
 938
 939     string(TOUPPER "${FFTW}" FFTW)
 940     set(PKG_FFT "${${FFTW}_PKG}")
 941     include_directories(${${FFTW}_INCLUDE_DIRS})
 942     set(FFT_LIBRARIES ${${FFTW}_LIBRARIES})
 943     if(NOT ${FFTW}_FOUND)
 944       MESSAGE(FATAL_ERROR "Cannot find FFTW 3 (with correct precision - libfftw3f for single-precision GROMACS or libfftw3 for double-precision GROMACS). Either choose the right precision, choose another FFT(W) library, enable the advanced option to let GROMACS build FFTW 3 for you, or use the really slow GROMACS built-in fftpack library.")
 945     endif()
 946
 947     set(GMX_FFT_FFTW3 1)
 948
 949     if ((${GMX_CPU_ACCELERATION} MATCHES "SSE" OR ${GMX_CPU_ACCELERATION} MATCHES "AVX") AND NOT ${FFTW}_HAVE_SIMD)
 950       message(WARNING "The fftw library found is compiled without SIMD support, which makes it slow. Consider recompiling it or contact your admin")
 951     endif()
 952
 953     if((${GMX_CPU_ACCELERATION} MATCHES "SSE" OR ${GMX_CPU_ACCELERATION} MATCHES "AVX") AND ${FFTW}_HAVE_AVX)
 954         # If we're not doing CPU acceleration, we don't care about FFTW performance on x86 either
 955         message(WARNING "The FFTW library was compiled with --enable-avx to enable AVX SIMD instructions. That might sound like a good idea for your processor, but for FFTW versions up to 3.3.3, these are slower than the SSE/SSE2 SIMD instructions for the way GROMACS uses FFTs. Limitations in the way FFTW allows GROMACS to measure performance make it awkward for either GROMACS or FFTW to make the decision for you based on runtime performance. You should compile a different FFTW library with --enable-sse or --enable-sse2. If you have a more recent FFTW, you may like to compare the performance of GROMACS with FFTW libraries compiled with and without --enable-avx. However, the GROMACS developers do not really expect the FFTW AVX optimization to help, because the performance is limited by memory access, not computation.")
 956     endif()
 957
 958     if(NOT "${GMX_FFT_LIBRARY}" STREQUAL "${GMX_FFT_LIBRARY_PREVIOUS_VALUE}")
 959         MESSAGE(STATUS "Using external FFT library - FFTW3")
 960     endif()
 961 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 962     # Intel 11 and up makes life somewhat easy if you just want to use
 963     # all their stuff. It's not easy if you only want some of their
 964     # stuff...
 965     if (CMAKE_C_COMPILER_ID MATCHES "Intel" AND C_COMPILER_VERSION VERSION_GREATER "11")
 966         # The next line takes care of everything for MKL
 967         if (WIN32)
 968             set(FFT_LINKER_FLAGS "/Qmkl=sequential")
 969         else()
 970             set(FFT_LINKER_FLAGS "-mkl=sequential")
 971         endif()
 972         # Some versions of icc require this in order that mkl.h can be
 973         # found at compile time.
 974         set(EXTRA_C_FLAGS "${EXTRA_C_FLAGS} ${FFT_LINKER_FLAGS}")
 975
 976         set(MKL_ERROR_MESSAGE "Make sure you have configured your compiler so that ${FFT_LINKER_FLAGS} will work.")
 977     else()
 978         # The user will have to provide the set of magic libraries in
 979         # MKL_LIBRARIES, which we cache (non-advanced), so that they
 980         # don't have to keep specifying it, and can easily see that
 981         # CMake is still using that information.
 982         set(MKL_LIBRARIES "${MKL_LIBRARIES}" CACHE STRING "User-specified libraries for linking to MKL")
 983         mark_as_advanced(CLEAR MKL_LIBRARIES)
 984         include_directories(${MKL_INCLUDE_DIR})
 985         mark_as_advanced(CLEAR MKL_INCLUDE_DIR)
 986         set(FFT_LIBRARIES "${MKL_LIBRARIES}")
 987         set(MKL_ERROR_MESSAGE "The include path to mkl.h in MKL_INCLUDE_DIR, and the link libraries in MKL_LIBRARIES=${MKL_LIBRARIES} need to match what the MKL documentation says you need for your system. ${MKL_LIBRARIES_FORMAT_DESCRIPTION}")
 988         # Convert the semi-colon separated list to a list of
 989         # command-line linker arguments so that code using our
 990         # pkgconfig setup can use it.
 991         string(REGEX REPLACE ";" " " PKG_FFT_LIBS "${MKL_LIBRARIES}")
 992     endif()
 993
 994     # Check MKL works. If we were in a non-global scope, we wouldn't
 995     # have to play nicely.
 996     set(old_CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 997     set(CMAKE_REQUIRED_FLAGS "${FFT_LINKER_FLAGS}")
 998     set(old_CMAKE_REQUIRED_LIBRARIES "${CMAKE_REQUIRED_LIBRARIES}")
 999     set(CMAKE_REQUIRED_LIBRARIES "${FFT_LIBRARIES}")
1000
1001     check_function_exists(DftiCreateDescriptor TEST_MKL)
1002
1003     set(CMAKE_REQUIRED_FLAGS "${old_CMAKE_REQUIRED_FLAGS}")
1004     set(CMAKE_REQUIRED_LIBRARIES "${old_CMAKE_REQUIRED_LIBRARIES}")
1005
1006     if(NOT TEST_MKL)
1007         # Hack to help the user vary MKL settings until they work.
1008         # TODO Make this logic more useful.
1009         unset(TEST_MKL CACHE)
1010         message(FATAL_ERROR "Linking with MKL was requested, but was not successful. ${MKL_ERROR_MESSAGE}")
1011     endif()
1012
1013     # Set variables to signal that we have MKL available and should use it for FFTs.
1014     set(GMX_FFT_MKL 1)
1015     set(HAVE_LIBMKL 1)
1016
1017     if(NOT "${GMX_FFT_LIBRARY}" STREQUAL "${GMX_FFT_LIBRARY_PREVIOUS_VALUE}")
1018         MESSAGE(STATUS "Using external FFT library - Intel MKL")
1019     endif()
1020
1021 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
1022 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
1023 #    set(GMX_FFT_ACML 1)
1024 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
1025     set(GMX_FFT_FFTPACK 1)
1026     if(NOT "${GMX_FFT_LIBRARY}" STREQUAL "${GMX_FFT_LIBRARY_PREVIOUS_VALUE}")
1027         MESSAGE(STATUS "Using internal FFT library - fftpack")
1028     endif()
1029 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
1030     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, mkl, fftpack")
1031 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
1032 set(GMX_FFT_LIBRARY_PREVIOUS_VALUE ${GMX_FFT_LIBRARY} CACHE INTERNAL "Previous value for GMX_FFT_LIBRARY, so that we can detect when it changes.")
1033
1034 # enable threaded fftw3 if we've found it
1035 if(FFTW3_THREADS OR FFTW3F_THREADS)
1036     add_definitions(-DFFT5D_FFTW_THREADS)
1037 endif()
1038
1039 include(gmxManageLinearAlgebraLibraries)
1040
1041 set(GMX_USE_PLUGINS OFF CACHE INTERNAL "Whether GROMACS will really try to compile support for VMD plugins")
1042
1043 if(GMX_LOAD_PLUGINS)
1044   if(CYGWIN OR NOT WIN32)
1045     # Native Windows does not have, nor need dlopen
1046     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
1047     include(gmxTestdlopen)
1048     gmx_test_dlopen(HAVE_DLOPEN)
1049   endif()
1050
1051   # so, should we use plug-ins?
1052   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
1053     if(NOT VMD_QUIETLY)
1054       MESSAGE(STATUS
1055           "Found the ability to use plug-ins when building shared libaries, "
1056           "so will compile to use plug-ins (e.g. to read VMD-supported file "
1057           "formats).")
1058     endif()
1059     if(NOT GMX_VMD_PLUGIN_PATH)
1060       find_package(VMD)
1061     endif()
1062     set(GMX_USE_PLUGINS ON)
1063     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
1064     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
1065   else()
1066     set(PKG_DL_LIBS)
1067   endif()
1068 endif(GMX_LOAD_PLUGINS)
1069 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
1070
1071 if(EXISTS "${CMAKE_SOURCE_DIR}/admin/.isreposource")
1072     if(NOT CMAKE_CROSSCOMPILING)
1073         option(GMX_BUILD_MANPAGES "Build man pages" ON)
1074     else()
1075         message(STATUS "Building the man pages is not available when "
1076             "cross-compiling the developer version from git")
1077     endif()
1078 else()
1079     #make sure source package contains all man pages
1080     if(NOT EXISTS "${CMAKE_SOURCE_DIR}/man/man1/ngmx.1")
1081         message(FATAL_ERROR "Man pages are missing from source package.")
1082     endif()
1083 endif()
1084 mark_as_advanced(GMX_BUILD_MANPAGES)
1085
1086 # Math and thread libraries must often come after all others when linking...
1087 if(HAVE_LIBM)
1088     list(APPEND GMX_EXTRA_LIBRARIES m)
1089 endif(HAVE_LIBM)
1090
1091 if(GMX_FAHCORE)
1092   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
1093       "Path to swindirect.h")
1094   include_directories(${COREWRAP_INCLUDE_DIR})
1095   set_property(CACHE GMX_COOL_QUOTES PROPERTY VALUE OFF)
1096 endif(GMX_FAHCORE)
1097
1098 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
1099 # these are set after everything else
1100 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
1101     set(CMAKE_C_FLAGS "${ACCELERATION_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
1102     set(CMAKE_CXX_FLAGS "${ACCELERATION_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${GMX_CXX11_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
1103     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
1104     set(CMAKE_SHARED_LINKER_FLAGS "${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
1105 else()
1106     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
1107     message("CMAKE_C_FLAGS: ${ACCELERATION_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
1108     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
1109     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
1110     message("CMAKE_CXX_FLAGS: ${ACCELERATION_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${GMX_CXX11_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
1111     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
1112     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
1113     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
1114     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
1115 endif()
1116
1117 if(NOT GMX_OPENMP)
1118     #Unset all OpenMP flags in case OpenMP was disabled either by the user
1119     #or because it was only partially detected (e.g. only for C but not C++ compiler)
1120     unset(OpenMP_C_FLAGS CACHE)
1121     unset(OpenMP_CXX_FLAGS CACHE)
1122 else()
1123     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
1124     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
1125 endif()
1126 set(PKG_CFLAGS "${PKG_CFLAGS} ${OpenMP_C_FLAGS}")
1127
1128 ######################################
1129 # Output compiler and CFLAGS used
1130 ######################################
1131 get_compiler_info(C BUILD_C_COMPILER BUILD_CFLAGS)
1132 if (CMAKE_CXX_COMPILER_LOADED)
1133     get_compiler_info(CXX BUILD_CXX_COMPILER BUILD_CXXFLAGS)
1134 endif ()
1135 if(GMX_GPU)
1136     get_cuda_compiler_info(CUDA_NVCC_COMPILER_INFO CUDA_NVCC_COMPILER_FLAGS)
1137 endif(GMX_GPU)
1138
1139
1140 ########################################################################
1141 # Specify install locations
1142 ########################################################################
1143 if ( NOT DEFINED GMXLIB )
1144     set(GMXLIB lib)
1145 endif()
1146 set(LIB_INSTALL_DIR "${GMX_INSTALL_PREFIX}${GMXLIB}")
1147 set(BIN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}bin)
1148 set(DATA_INSTALL_DIR ${GMX_INSTALL_PREFIX}share/gromacs)
1149 set(MAN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}share/man)
1150 set(INCL_INSTALL_DIR ${GMX_INSTALL_PREFIX}include)
1151
1152 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
1153
1154 ##################################################################
1155 # Shared library settings
1156 ##################################################################
1157 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
1158     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
1159     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
1160     set(CMAKE_INSTALL_RPATH "\\\$ORIGIN/../${GMXLIB}")
1161     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
1162 else()
1163     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) #rpath supported for >10.4
1164         set(CMAKE_INSTALL_NAME_DIR "@rpath")
1165         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../lib")
1166     else()
1167         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
1168     endif()
1169 endif()
1170
1171 #COPYING file: Only necessary for binary distributions.
1172 #Simpler to always install.
1173 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
1174
1175 if(GMX_EXTERNAL_BOOST)
1176     include_directories(${Boost_INCLUDE_DIRS})
1177 else()
1178     include_directories(${CMAKE_SOURCE_DIR}/src/external/boost)
1179     # typeid not supported for minimal internal version
1180     # (would add significant amount of code)
1181     add_definitions(-DBOOST_NO_TYPEID)
1182     # TODO: Propagate the above settings to the installed CMakeFiles.txt template
1183     # (from share/template/)
1184     set(PKG_CFLAGS "${PKG_CFLAGS} -DBOOST_NO_TYPEID -I${INCL_INSTALL_DIR}/gromacs/external/boost")
1185     install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
1186             DESTINATION ${INCL_INSTALL_DIR}/gromacs/external/boost
1187             COMPONENT development)
1188 endif()
1189
1190 if (GMX_BUILD_FOR_COVERAGE)
1191     # Code heavy with asserts makes conditional coverage close to useless metric,
1192     # as by design most of the false branches are impossible to trigger in
1193     # correctly functioning code.  And the benefit of testing those that could
1194     # be triggered by using an API against its specification isn't usually
1195     # worth the effort.
1196     add_definitions(-DNDEBUG -DBOOST_DISABLE_ASSERTS -DGMX_DISABLE_ASSERTS)
1197 endif ()
1198
1199 add_subdirectory(doxygen)
1200 add_subdirectory(share)
1201 add_subdirectory(src)
1202 add_subdirectory(scripts)
1203
1204 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
1205 # Don't bother the user after the first configure pass.
1206 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
1207     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
1208     unset(CUDA_NOTFOUND_AUTO)
1209     unset(CUDA_NOTFOUND_MESSAGE)
1210 endif()
1211 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
1212
1213 #######################
1214 ## uninstall target
1215 #######################
1216     CONFIGURE_FILE(
1217                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
1218                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
1219                    IMMEDIATE @ONLY)
1220 ###########################
1221 ADD_CUSTOM_TARGET(uninstall
1222                   "${CMAKE_COMMAND}" -P
1223                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
1224 ###########################
1225
1226 ########################################################################
1227 # Tests                                                                #
1228 ########################################################################
1229
1230 include(CTest)
1231 mark_as_advanced(BUILD_TESTING)
1232 #gmxtests target builds all binaries required for running gmxtest
1233 add_custom_target(gmxtests DEPENDS mdrun gmx links)
1234 IF(BUILD_TESTING)
1235     enable_testing()
1236     add_subdirectory(tests)
1237     #"check" target builds and runs all tests
1238     add_custom_target(check COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure)
1239     add_dependencies(check gmxtests tests)
1240     #TODO: Add warning if NOT REGRESSIONTEST_PATH OR NOT GMX_XML that regression/unit tests are not run.
1241 ENDIF()
1242