Update CMake requirement to 3.16.3
[alexxy/gromacs.git] / CMakeLists.txt
1 #
2 # This file is part of the GROMACS molecular simulation package.
3 #
4 # Copyright (c) 2009,2010,2011,2012,2013 by the GROMACS development team.
5 # Copyright (c) 2014,2015,2016,2017,2018 by the GROMACS development team.
6 # Copyright (c) 2019,2020,2021, by the GROMACS development team, led by
7 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
8 # and including many others, as listed in the AUTHORS file in the
9 # top-level source directory and at http://www.gromacs.org.
10 #
11 # GROMACS is free software; you can redistribute it and/or
12 # modify it under the terms of the GNU Lesser General Public License
13 # as published by the Free Software Foundation; either version 2.1
14 # of the License, or (at your option) any later version.
15 #
16 # GROMACS is distributed in the hope that it will be useful,
17 # but WITHOUT ANY WARRANTY; without even the implied warranty of
18 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
19 # Lesser General Public License for more details.
20 #
21 # You should have received a copy of the GNU Lesser General Public
22 # License along with GROMACS; if not, see
23 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
24 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
25 #
26 # If you want to redistribute modifications to GROMACS, please
27 # consider that scientific software is very special. Version
28 # control is crucial - bugs must be traceable. We will be happy to
29 # consider code for inclusion in the official distribution, but
30 # derived work must not be called official GROMACS. Details are found
31 # in the README & COPYING files - if they are missing, get the
32 # official version at http://www.gromacs.org.
33 #
34 # To help us fund GROMACS development, we humbly ask that you cite
35 # the research papers on the package. Check out http://www.gromacs.org.
36
37 cmake_minimum_required(VERSION 3.16.3)
38 cmake_policy(SET CMP0074 NEW) # From CMake 3.12
39 cmake_policy(SET CMP0068 NEW) # From CMake-3.9
40
41 # CMake modules/macros are in a subdirectory to keep this file cleaner
42 # This needs to be set before project() in order to pick up toolchain files
43 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
44
45 if(CMAKE_SYSTEM_NAME STREQUAL "Darwin")
46     # Providing a default value >=10.14 helps to find modern C++ compatibility,
47     # such as by defaulting to the Clang libc++ instead of libstdc++.
48     set(CMAKE_OSX_DEPLOYMENT_TARGET 10.14 CACHE STRING
49         "OS X deployment target affects default SDK version and compiler flags.")
50     # By default, limit the binary architecture to a single 64-bit build.
51     set(CMAKE_OSX_ARCHITECTURES x86_64 CACHE STRING
52         "OS X architecture affects the compatibility of the (potentially fat) binaries produced."
53         FORCE)
54 endif()
55
56 project(Gromacs)
57
58 set(CMAKE_CXX_STANDARD 17)
59 set(CMAKE_CXX_STANDARD_REQUIRED ON)
60 set(CMAKE_CXX_EXTENSIONS OFF)
61
62 include(gmxManageCcache)
63
64 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
65 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
66 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
67
68 find_package(LibStdCpp)
69
70 # Python is first referenced in gmxVersionInfo, so we perform the search early
71 # to find a suitable installation for all components.
72 include(gmxPythonDiscovery)
73 # Set up common version variables, as well as general information about
74 # the build tree (whether the build is from a source package or from a git
75 # repository).  Also declares a few functions that will be used for generating
76 # version info files later.
77 include(gmxBuildTreeInfo)
78 include(gmxVersionInfo)
79
80 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
81     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
82 endif()
83 if("${CMAKE_INSTALL_PREFIX}" STREQUAL "${CMAKE_BINARY_DIR}")
84     message(FATAL_ERROR "GROMACS cannot be installed into the build tree, choose a different location for CMAKE_INSTALL_PREFIX")
85 endif()
86
87 include(gmxBuildTypeReference)
88 include(gmxBuildTypeProfile)
89 include(gmxBuildTypeTSAN)
90 include(gmxBuildTypeASAN)
91 include(gmxBuildTypeMSAN)
92 include(gmxBuildTypeUBSAN)
93 include(gmxBuildTypeReleaseWithAssert)
94
95 if(NOT CMAKE_BUILD_TYPE)
96     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert Profile TSAN ASAN MSAN UBSAN." FORCE)
97     # Set the possible values of build type for cmake-gui
98     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
99         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert" "Profile" "TSAN" "ASAN" "MSAN" "UBSAN")
100 endif()
101 if(CMAKE_CONFIGURATION_TYPES)
102     # Add appropriate GROMACS-specific build types for the Visual
103     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
104     # are already present by default).
105     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
106     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
107     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
108         "List of configuration types"
109         FORCE)
110 endif()
111 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
112
113 set_property(GLOBAL PROPERTY FIND_LIBRARY_USE_LIB64_PATHS ON)
114
115 include(gmxCTestUtilities)
116 gmx_ctest_init()
117
118 include(gmxCPackUtilities)
119 gmx_cpack_init()
120
121 # Variables that accumulate stuff influencing the installed headers
122 set(INSTALLED_HEADER_INCLUDE_DIRS "")
123 set(INSTALLED_HEADER_DEFINITIONS "")
124
125 ########################################################################
126 # Global non-cache variables for implementing the build system
127 ########################################################################
128
129 # These variables collect libraries that GROMACS requires for
130 # linking. They should be appended to with list(APPEND ${name}
131 # new-library) calls. They are:
132 #  - Libraries that are required for libgromacs (only)
133 set(GMX_EXTRA_LIBRARIES "")
134 #  - Libraries that are required for all code in the repository
135 set(GMX_COMMON_LIBRARIES "")
136 #  - Libraries that all code linked against libgromacs needs
137 #    (i.e., something that is exposed in installed headers).
138 set(GMX_PUBLIC_LIBRARIES "")
139
140 ########################################################################
141 # Check and warn if cache generated on a different host is being reused
142 ########################################################################
143 if(CMAKE_HOST_UNIX)
144     execute_process(COMMAND hostname
145                     OUTPUT_VARIABLE TMP_HOSTNAME
146                     OUTPUT_STRIP_TRAILING_WHITESPACE)
147     # Only check for host name if not running in a CI environment, as the cache might
148     # be reused there between different machines in different stages
149     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}"
150             AND NOT DEFINED ENV{CI_JOB_ID})
151         message(WARNING "
152             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
153             is being reused! This could lead to inconsistencies; therefore, it is
154             recommended to regenerate the cache!")
155     endif()
156     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
157             "Hostname of the machine where the cache was generated.")
158 endif()
159
160 ########################################################################
161 # Detect architecture before setting options so we can alter defaults
162 ########################################################################
163 # Detect the architecture the compiler is targetting, detect
164 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
165 # to use if none is specified, and populate the cache option for CPU
166 # SIMD.
167 include(gmxDetectTargetArchitecture)
168 gmx_detect_target_architecture()
169
170 ########################################################################
171 # User input options                                                   #
172 ########################################################################
173 include(gmxOptionUtilities)
174
175 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
176
177 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
178
179 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
180 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
181
182 option(GMX_MIMIC "Enable MiMiC QM/MM interface (CPMD is required)" OFF)
183
184 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
185 mark_as_advanced(GMX_FAHCORE)
186
187 option(GMX_COOL_QUOTES "Enable GROMACS cool quotes" ON)
188 mark_as_advanced(GMX_COOL_QUOTES)
189 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
190
191 option(GMX_INSTALL_LEGACY_API "Install legacy headers" OFF)
192
193 gmx_option_multichoice(
194     GMX_GPU
195     "Framework for GPU acceleration"
196     OFF
197     OFF CUDA OpenCL SYCL)
198
199 gmx_option_multichoice(
200     GMX_SIMD
201     "SIMD instruction set for CPU kernels and compiler optimization"
202     "AUTO"
203     AUTO None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 AVX2_128 AVX_512 AVX_512_KNL ARM_NEON_ASIMD ARM_SVE IBM_VSX Reference)
204
205 set(GMX_FFT_LIBRARY_DEFAULT "fftw3")
206
207 gmx_option_multichoice(
208     GMX_FFT_LIBRARY
209     "FFT library"
210     "${GMX_FFT_LIBRARY_DEFAULT}"
211     fftw3 mkl "fftpack[built-in]")
212 gmx_dependent_option(
213     GMX_BUILD_OWN_FFTW
214     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
215     OFF
216     "GMX_FFT_LIBRARY STREQUAL FFTW3")
217 gmx_dependent_option(
218     GMX_DISABLE_FFTW_MEASURE
219     "Do not optimize FFTW setups (not needed with SSE)"
220     OFF
221     "GMX_FFT_LIBRARY STREQUAL FFTW3")
222 mark_as_advanced(GMX_BUILD_OWN_FFTW)
223 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
224
225 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
226 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
227
228 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
229
230 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
231 mark_as_advanced(GMX_BROKEN_CALLOC)
232
233 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
234
235 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
236
237 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
238 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
239
240 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
241 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
242
243 option(GMX_BUILD_FOR_COVERAGE
244        "Tune build for better code coverage metrics (e.g., disable asserts)"
245        OFF)
246 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
247
248 option(GMX_DEVELOPER_BUILD
249     "Enable Developer convenience features: always build unit-tests"
250     OFF)
251 mark_as_advanced(GMX_DEVELOPER_BUILD)
252
253 gmx_set_boolean(GMX_COMPILER_WARNINGS_DEFAULT "NOT SOURCE_IS_SOURCE_DISTRIBUTION")
254 option(GMX_COMPILER_WARNINGS
255     "Enable a default set of compiler warnings"
256     ${GMX_COMPILER_WARNINGS_DEFAULT})
257 mark_as_advanced(GMX_COMPILER_WARNINGS)
258 # Always turn on compiler warnings with a developer build.
259 gmx_add_cache_dependency(GMX_COMPILER_WARNINGS BOOL "NOT GMX_DEVELOPER_BUILD" ON)
260
261 option(GMX_BUILD_SHARED_EXE
262     "Build exectuables as shared binaries. If not set, this disables rpath and dynamic linker flags in an attempt to build a static binary, but this may require setting up the toolchain properly and making appropriate libraries available."
263     ON)
264 mark_as_advanced(GMX_BUILD_SHARED_EXE)
265
266 option(GMX_PHYSICAL_VALIDATION
267        "Include physical validation tests in ctest environment. These can then be called using 'make check-phys' or
268        'make check-all'. Warning: Running the physical validation tests takes significantly more time than other tests!"
269        OFF)
270 mark_as_advanced(GMX_PHYSICAL_VALIDATION)
271
272 ######################################################################
273 # Detect OpenMP support
274 ######################################################################
275 # The OpenMP detection _must_ come before tests for other CFLAGS.
276 include(gmxManageOpenMP)
277
278
279
280 ######################################################################
281 # Compiler tests
282 # These need to be done early (before further tests).
283 #####################################################################
284
285 include(gmxCFlags)
286 gmx_c_flags()
287
288 # These variables should be used for CMake-style lists (ie. separated
289 # by semicolons) of additional compiler flags which are not generated
290 # in gmxCFlags nor are SIMD or MPI related.
291 #
292 # TODO These variables should be consolidated into
293 # EXTRA_COMPILER_FLAGS so that we we don't perpetrate bugs where
294 # things that work in C compilation (e.g. merging from old branches)
295 # might not also work for C++ compilation.
296 set(EXTRA_C_FLAGS "")
297 set(EXTRA_CXX_FLAGS "")
298
299 # Run through a number of tests for buggy compilers and other issues
300 include(gmxTestCompilerProblems)
301 gmx_test_compiler_problems()
302
303 # Implement double-precision option. This is complicated because we
304 # need installed headers to use the precision mode of the build that
305 # produced the library, but cannot use config.h in that case. We also
306 # want such variables to always have a definition, because #if is more
307 # robust than #ifdef. So, we put this value on the compiler command
308 # line in all cases.
309 if(GMX_DOUBLE)
310     set(GMX_DOUBLE_VALUE 1)
311 else()
312     set(GMX_DOUBLE_VALUE 0)
313 endif()
314 add_definitions(-DGMX_DOUBLE=${GMX_DOUBLE_VALUE})
315 list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_DOUBLE=${GMX_DOUBLE_VALUE}")
316
317 option(GMX_IMD "Enable Interactive Molecular Dynamics (IMD) sessions, e.g. with VMD" ON)
318 if(GMX_IMD AND WIN32)
319     list(APPEND GMX_EXTRA_LIBRARIES "wsock32")
320 endif()
321
322
323
324 ########################################################################
325 # Basic system tests (standard libraries, headers, functions, types)   #
326 ########################################################################
327 include(CheckIncludeFiles)
328 include(CheckIncludeFileCXX)
329 check_include_files(unistd.h     HAVE_UNISTD_H)
330 check_include_files(pwd.h        HAVE_PWD_H)
331 check_include_files(dirent.h     HAVE_DIRENT_H)
332 check_include_files(time.h       HAVE_TIME_H)
333 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
334 check_include_files(io.h         HAVE_IO_H)
335 check_include_files(sched.h      HAVE_SCHED_H)
336 check_include_files(xmmintrin.h  HAVE_XMMINTRIN_H)
337
338 include(CheckCXXSymbolExists)
339 check_cxx_symbol_exists(gettimeofday      sys/time.h   HAVE_GETTIMEOFDAY)
340 check_cxx_symbol_exists(sysconf           unistd.h     HAVE_SYSCONF)
341 check_cxx_symbol_exists(nice              unistd.h     HAVE_NICE)
342 check_cxx_symbol_exists(fsync             unistd.h     HAVE_FSYNC)
343 check_cxx_symbol_exists(_fileno           stdio.h      HAVE__FILENO)
344 check_cxx_symbol_exists(fileno            stdio.h      HAVE_FILENO)
345 check_cxx_symbol_exists(_commit           io.h         HAVE__COMMIT)
346 check_cxx_symbol_exists(sigaction         signal.h     HAVE_SIGACTION)
347
348 # We cannot check for the __builtins as symbols, but check if code compiles
349 check_cxx_source_compiles("int main(){ return __builtin_clz(1);}"   HAVE_BUILTIN_CLZ)
350 check_cxx_source_compiles("int main(){ return __builtin_clzll(1);}" HAVE_BUILTIN_CLZLL)
351 if(MSVC)
352     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned long i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE)
353     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned __int64 i=1;_BitScanReverse64(&r,i);return r;}" HAVE_BITSCANREVERSE64)
354 elseif(CMAKE_CXX_COMPILER_ID MATCHES "XL")
355     check_cxx_source_compiles("int main(){ return __cntlz4(1);}" HAVE_CNTLZ4)
356     check_cxx_source_compiles("int main(){ return __cntlz8(1);}" HAVE_CNTLZ8)
357 endif()
358
359 include(CheckLibraryExists)
360 find_library(HAVE_LIBM m)
361 mark_as_advanced(HAVE_LIBM)
362 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
363 check_library_exists(m feenableexcept "" HAVE_FEENABLEEXCEPT)
364 check_library_exists(m fedisableexcept "" HAVE_FEDISABLEEXCEPT)
365
366 include(TestSchedAffinity)
367 test_sched_affinity(HAVE_SCHED_AFFINITY)
368
369 # Aligned memory allocation. We need to check for both mm_malloc(),
370 # posix_memalign(), memalign(), and on windows also _aligned_malloc()
371 include(gmxTestMMMalloc)
372 gmx_test_mm_malloc(HAVE__MM_MALLOC)
373 check_cxx_symbol_exists(posix_memalign    stdlib.h     HAVE_POSIX_MEMALIGN)
374 check_cxx_symbol_exists(memalign          stdlib.h     HAVE_MEMALIGN)
375 if(MSVC)
376     # No need to waste time on this test on platforms where it will never be true
377     check_cxx_symbol_exists(_aligned_malloc   stdlib.h     HAVE__ALIGNED_MALLOC)
378 endif()
379
380 include(TestBigEndian)
381 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
382
383 gmx_set_boolean(GMX_USE_NICE "HAVE_UNISTD_H AND HAVE_NICE")
384
385 ########################################################################
386 #Process MPI settings
387 ########################################################################
388 include(gmxManageMPI)
389
390 ########################################################################
391 #Process MiMiC settings
392 ########################################################################
393 include(gmxManageMimic)
394
395 ########################################################################
396 #Process shared/static library settings
397 ########################################################################
398 include(gmxManageSharedLibraries)
399
400
401 ########################################################################
402 # Specify install locations
403 ########################################################################
404 # Use GNUInstallDirs to set paths on multiarch systems.
405 include(GNUInstallDirs)
406
407 set(GMX_INSTALL_DATASUBDIR "gromacs" CACHE STRING "Subdirectory for GROMACS data under CMAKE_INSTALL_DATADIR")
408 mark_as_advanced(GMX_INSTALL_DATASUBDIR)
409
410 # Internal convenience so we do not have to join two path segments in the code
411 set(GMX_INSTALL_GMXDATADIR ${CMAKE_INSTALL_DATADIR}/${GMX_INSTALL_DATASUBDIR})
412
413 # If the nesting level wrt. the installation root is changed,
414 # gromacs-config.cmake.cmakein needs to be adapted.
415 set(GMX_INSTALL_CMAKEDIR  ${CMAKE_INSTALL_DATAROOTDIR}/cmake)
416
417 # TODO: Make GMXRC adapt if this is changed
418 set(GMX_INSTALL_PKGCONFIGDIR ${CMAKE_INSTALL_LIBDIR}/pkgconfig)
419
420 list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${CMAKE_INSTALL_INCLUDEDIR})
421
422 # Binary and library suffix options
423 include(gmxManageSuffixes)
424
425
426 ########################################################################
427 # Find external packages                                               #
428 ########################################################################
429
430 # Unconditionally find the package, as it is also required for unit
431 # tests. This exports LIBXML2_FOUND, which we should not use because
432 # it does not tell us that linking will succeed. Instead, we test that
433 # next.
434 #if(DEFINED LIBXML2_LIBRARIES)
435 #  set(LibXml2_FIND_QUIETLY TRUE)
436 #endif()
437 #find_package(LibXml2)
438 #include(gmxTestLibXml2)
439 #gmx_test_libxml2(HAVE_LIBXML2)
440 #option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
441 #set(PKG_XML "")
442 #mark_as_advanced(GMX_XML)
443 # Don't actually do anything, since libxml2 is currently not used by libgromacs
444 #if(GMX_XML AND NOT HAVE_LIBXML2)
445 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
446 #endif()
447 #if(GMX_XML)
448 #    include_directories(${LIBXML2_INCLUDE_DIR})
449 #    set(PKG_XML libxml-2.0)
450 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
451 #endif()
452
453 option(GMX_HWLOC "Use hwloc portable hardware locality library" OFF)
454
455 if (GMX_HWLOC)
456     # Find quietly the second time.
457     if (HWLOC_FIND_QUIETLY_AFTER_FIRST_RUN)
458         set(HWLOC_FIND_QUIETLY TRUE)
459     endif()
460     find_package(HWLOC 1.5) 
461
462     if (HWLOC_FOUND)
463         if (HWLOC_LIBRARIES MATCHES ".a$")
464             set(_STATIC_HWLOC TRUE)
465         endif()
466
467         gmx_check_if_changed(HWLOC_FOUND_CHANGED HWLOC_FOUND)
468         if (_STATIC_HWLOC AND HWLOC_FOUND_CHANGED AND NOT GMX_HWLOC_FORCE)
469             message(STATUS "Static hwloc library found, will not attempt using it as it could lead to link-time errors. To use the detected library, manually set GMX_HWLOC=ON and you will likely have to pass appropriate linker flags too to satisfy the link-time dependencies of your hwloc library. Try \"pkg-config --libs --static hwloc\" for suggestions on what you will need.")
470             set(GMX_USE_HWLOC OFF)
471         else()
472             set(GMX_USE_HWLOC ON)
473         endif()
474
475         if (GMX_USE_HWLOC)
476             include_directories(SYSTEM ${HWLOC_INCLUDE_DIRS})
477             list(APPEND GMX_EXTRA_LIBRARIES ${HWLOC_LIBRARIES})
478         endif()
479     elseif(GMX_HWLOC_FORCE)
480         message(FATAL_ERROR "HWLOC package support required, but not found.")
481     endif()
482
483     if (HWLOC_FOUND AND HWLOC_VERSION VERSION_LESS "2")
484         message(STATUS "Support for hwloc versions 1.x is deprecated")
485     endif()
486
487     set(HWLOC_FIND_QUIETLY_AFTER_FIRST_RUN TRUE CACHE INTERNAL "Be quiet during future attempts to find HWLOC")
488 endif()
489
490 option(GMX_EXTERNAL_TINYXML2 "Use external TinyXML-2 instead of compiling the version bundled with GROMACS." OFF)
491 mark_as_advanced(GMX_EXTERNAL_TINYXML2)
492 if(GMX_EXTERNAL_TINYXML2)
493     # Find an external TinyXML-2 library.
494     find_package(TinyXML-2 3.0.0)
495     set(HAVE_TINYXML2 ${TinyXML2_FOUND})
496     if(NOT HAVE_TINYXML2)
497         message(FATAL_ERROR "External TinyXML-2 could not be found, please adjust your search paths")
498     endif()
499 endif()
500
501 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
502 mark_as_advanced(GMX_EXTRAE)
503
504 if (GMX_EXTRAE)
505   find_package(EXTRAE)
506   if(EXTRAE_FOUND)
507     include_directories(SYSTEM ${EXTRAE_INCLUDE_DIR})
508     set(HAVE_EXTRAE 1)
509   else()
510     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
511   endif()
512 endif()
513
514 option(GMX_X11 "Use X window system" OFF)
515 if (GMX_X11)
516     find_package(X11)
517     # X11 includes/libraries are only set in the ngmx subdirectory!
518     if(NOT X11_FOUND)
519         message(FATAL_ERROR
520                 "X11 include files and/or libraries were not found. "
521                 "Set GMX_X11=OFF to compile without X11 support. "
522                 "gmx view will not be available.")
523     endif()
524     include_directories(SYSTEM ${X11_INCLUDE_DIR})
525 endif()
526
527 include(ThreadMPI)
528 # Enable core threading facilities
529 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
530 if(GMX_THREAD_MPI)
531     # enable MPI functions
532     tmpi_enable()
533 endif()
534 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
535 if (TMPI_ATOMICS_DISABLED)
536    add_definitions(-DTMPI_ATOMICS_DISABLED)
537 endif()
538
539 include(gmxManageTNG)
540
541 include(gmxManageLmfit)
542
543 if(GMX_GPU)
544
545     string(TOUPPER "${GMX_GPU}" _gmx_gpu_uppercase)
546     if(${_gmx_gpu_uppercase} STREQUAL "CUDA")
547         include(gmxManageCuda)
548     elseif(${_gmx_gpu_uppercase} STREQUAL "OPENCL")
549         message(STATUS "GPU support with OpenCL is deprecated. It is still fully supported (and " 
550             "recommended for AMD and Intel GPUs). It may be replaced by different approaches in "
551             "future releases of GROMACS.")
552         include(gmxManageOpenCL)
553     elseif(${_gmx_gpu_uppercase} STREQUAL "SYCL")
554         include(gmxManageSYCL)
555     endif()
556     if(NOT GMX_OPENMP)
557         message(WARNING "To use GPU acceleration efficiently, mdrun requires OpenMP multi-threading, which is currently not enabled.")
558     endif()
559
560 endif()
561
562 if(CYGWIN)
563     set(GMX_CYGWIN 1)
564 endif()
565
566 if(WIN32)
567     set(GMX_NATIVE_WINDOWS 1)
568     # This makes windows.h not declare min/max as macros that would break
569     # C++ code using std::min/std::max.
570     add_definitions(-DNOMINMAX)
571 endif()
572
573 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING" ON)
574 mark_as_advanced(GMX_BUILD_UNITTESTS)
575 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
576
577 ########################################################################
578 # Our own GROMACS tests
579 ########################################################################
580
581 include_directories(SYSTEM ${CMAKE_SOURCE_DIR}/src/external)
582
583 include(gmxTestInlineASM)
584 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
585
586 include(gmxSetBuildInformation)
587 gmx_set_build_information()
588
589 # Anything but truly ancient x86 hardware should support rdtscp, so we enable it by default.
590 # The inline assembly calling it is only ever compiled on x86, so defaulting to ON is OK.
591 option(GMX_USE_RDTSCP "Use low-latency RDTSCP instruction for x86 CPU-based timers for mdrun execution; might need to be off when compiling for heterogeneous environments" ON)
592 mark_as_advanced(GMX_USE_RDTSCP)
593
594 include(gmxTestLargeFiles)
595 gmx_test_large_files(GMX_LARGEFILES)
596
597 include(gmxTestSignal)
598 gmx_test_sigusr1(HAVE_SIGUSR1)
599
600 include(gmxTestPipes)
601 gmx_test_pipes(HAVE_PIPES)
602
603 include(gmxTestXDR)
604 gmx_test_xdr(GMX_SYSTEM_XDR)
605 # Darwin has system XDR, but it uses a three-argument flavour of
606 # xdrproc_t that it guarantees will still work if you pass the normal
607 # two-argument xdr filters, but gcc 8 warns about the cast necessary
608 # to do that, so it's simpler to just use our own XDR library.
609 #
610 # TODO It would be better to craft a cmake test which fails if such
611 # XDR operations cause warnings, and succeeds otherwise, because it is
612 # generally preferable to use system libraries where possible.
613 if(NOT GMX_SYSTEM_XDR OR CMAKE_SYSTEM_NAME STREQUAL "Darwin")
614     set(GMX_INTERNAL_XDR 1)
615 endif()
616
617
618 ##################################################
619 # Process SIMD instruction settings
620 ##################################################
621 # This checks what flags to add in order to
622 # support the SIMD instructions we need, it sets
623 # correct defines for the SIMD instructions supported,
624 # and adds advanced options to control accuracy
625 # for SIMD math operations.
626 include(gmxManageSimd)
627 gmx_manage_simd()
628
629 ##################################################
630 # Process FFT library settings
631 ##################################################
632 include(gmxManageFFTLibraries)
633
634
635 include(gmxManageLinearAlgebraLibraries)
636
637 include(gmxManagePluginSupport)
638 gmx_manage_plugin_support()
639
640 if(GMX_USE_PLUGINS)
641     if(NOT GMX_VMD_PLUGIN_PATH)
642         find_package(VMD)
643     endif()
644 endif()
645
646 # People might want to customize the default location for the DSSP binary
647 set(GMX_DSSP_PROGRAM_PATH "/usr/local/bin/dssp"
648     CACHE PATH
649     "The default location to use for the DSSP binary")
650 mark_as_advanced(GMX_DSSP_PROGRAM_PATH)
651
652 # Link real-time library for POSIX timers. The check for clock_gettime
653 # confirms the linkability of rt.
654 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
655     list(APPEND GMX_EXTRA_LIBRARIES rt)
656 endif()
657
658 # Math and thread libraries must often come after all others when linking...
659 if (HAVE_LIBM)
660     list(APPEND GMX_PUBLIC_LIBRARIES m)
661 endif()
662
663 option(GMX_NACL "Configure for Native Client builds" OFF)
664 if (GMX_NACL)
665   list(APPEND GMX_EXTRA_LIBRARIES nosys)
666   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
667   # TODO: Is this still necessary with the check for its presence?
668   set(GMX_USE_NICE 0)
669   set(GMX_NO_RENAME 1)
670 endif()
671 mark_as_advanced(GMX_NACL)
672
673 if(GMX_FAHCORE)
674   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
675       "Path to swindirect.h")
676   include_directories(${COREWRAP_INCLUDE_DIR})
677 endif()
678
679 option(GMX_BUILD_HELP "Build completions (requires that compiled binaries can be executed on build host) and install man pages if built (requires building the 'man' target manually)" OFF)
680 mark_as_advanced(GMX_BUILD_HELP)
681 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND BUILD_IS_INSOURCE)
682     message(FATAL_ERROR
683         "Rebuilding shell completions or man pages is not supported for "
684         "in-source builds from a source distribution. "
685         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
686 endif()
687
688 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
689 # these are set after everything else
690 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
691     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS} ${DISABLE_SYCL_CXX_FLAGS}")
692     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS} ${DISABLE_SYCL_CXX_FLAGS}")
693 else()
694     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
695     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS};${MPI_COMPILE_FLAGS};${EXTRA_C_FLAGS};${GMXC_CFLAGS}")
696     foreach(build_type ${build_types_with_explicit_flags})
697         message("CMAKE_C_FLAGS_${build_type}: ${GMXC_CFLAGS_${build_type}}")
698     endforeach()
699     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS};${MPI_COMPILE_FLAGS};${EXTRA_CXX_FLAGS};${GMXC_CXXFLAGS}")
700     foreach(build_type ${build_types_with_explicit_flags})
701         message("CMAKE_CXX_FLAGS_${build_type}: ${GMXC_CXXFLAGS_${build_type}}")
702     endforeach()
703     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
704     message("CMAKE_SHARED_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
705 endif()
706 # Allow `admin` directory to be easily conveyed to nested CMake commands.
707 set(GMX_ADMIN_DIR ${CMAKE_SOURCE_DIR}/admin)
708
709 ################################################################
710 # Shared library load path settings
711 ################################################################
712 if(NOT GMX_BUILD_SHARED_EXE)
713     # No rpath
714     set(CMAKE_SKIP_RPATH TRUE)
715     set(CMAKE_EXE_LINK_DYNAMIC_C_FLAGS) # remove -Wl,-Bdynamic
716     set(CMAKE_EXE_LINK_DYNAMIC_CXX_FLAGS)
717 else()
718     # The build folder always has bin/ and lib/; if we are also going to
719     # install to lib/, then the installation RPATH works also in the build
720     # tree.  This makes installation slightly faster (no need to rewrite the
721     # RPATHs), and makes the binaries in the build tree relocatable.
722     if(CMAKE_INSTALL_LIBDIR STREQUAL "lib")
723         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
724         set(CMAKE_BUILD_WITH_INSTALL_NAME_DIR TRUE)
725     endif()
726     # Set the RPATH as relative to the executable location to make the
727     # binaries relocatable.
728     if(CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Assume OS X >=10.5
729         set(CMAKE_INSTALL_RPATH "@loader_path/../${CMAKE_INSTALL_LIBDIR}")
730         set(CMAKE_INSTALL_NAME_DIR ${CMAKE_INSTALL_RPATH})
731     else()
732         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${CMAKE_INSTALL_LIBDIR}")
733     endif()
734     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
735     set(CMAKE_MACOSX_RPATH 1)
736 endif()
737
738 #COPYING file: Only necessary for binary distributions.
739 #Simpler to always install.
740 install(FILES COPYING DESTINATION ${GMX_INSTALL_GMXDATADIR} COMPONENT data)
741
742 if (GMX_BUILD_FOR_COVERAGE)
743     # Code heavy with asserts makes conditional coverage close to useless metric,
744     # as by design most of the false branches are impossible to trigger in
745     # correctly functioning code.  And the benefit of testing those that could
746     # be triggered by using an API against its specification isn't usually
747     # worth the effort.
748     add_definitions(-DNDEBUG -DGMX_DISABLE_ASSERTS)
749 endif()
750
751 if (BUILD_TESTING)
752     include(tests/CheckTarget.cmake)
753 endif()
754
755 # TODO: Determine control flow and defaults for package installation and testing use cases.
756 # Ref: https://gitlab.com/gromacs/gromacs/-/issues/2896
757 option(GMX_PYTHON_PACKAGE "Configure gmxapi Python package" OFF)
758 mark_as_advanced(GMX_PYTHON_PACKAGE)
759
760 find_package(ImageMagick QUIET COMPONENTS convert)
761 include(gmxTestImageMagick)
762 GMX_TEST_IMAGEMAGICK(IMAGE_CONVERT_POSSIBLE)
763 # TODO: Resolve circular dependency between docs, gromacs, and python_packaging
764 add_subdirectory(docs)
765 add_subdirectory(share)
766 add_subdirectory(scripts)
767 add_subdirectory(api)
768 add_subdirectory(src)
769
770 if (BUILD_TESTING)
771     add_subdirectory(tests)
772 endif()
773
774 if(GMX_PYTHON_PACKAGE)
775     add_subdirectory(python_packaging)
776 endif()
777
778 gmx_cpack_write_config()
779
780 #######################
781 ## uninstall target
782 #######################
783 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
784                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
785                   IMMEDIATE @ONLY)
786 ###########################
787 ADD_CUSTOM_TARGET(uninstall
788                   "${CMAKE_COMMAND}" -P
789                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
790 ###########################
791 set_directory_properties(PROPERTIES
792             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")