CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014,2015,2016,2017,2018,2019, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 3.9.6)
  36 if(POLICY CMP0074) #3.12
  37     cmake_policy(SET CMP0074 NEW)
  38 endif()
  39
  40 # CMake modules/macros are in a subdirectory to keep this file cleaner
  41 # This needs to be set before project() in order to pick up toolchain files
  42 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  43
  44 project(Gromacs)
  45
  46 set(CMAKE_CXX_STANDARD 14)
  47 set(CMAKE_CXX_STANDARD_REQUIRED ON)
  48 set(CMAKE_CXX_EXTENSIONS OFF)
  49
  50 include(gmxManageCcache)
  51
  52 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  53 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  54 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  55
  56 # Set up common version variables, as well as general information about
  57 # the build tree (whether the build is from a source package or from a git
  58 # repository).  Also declares a few functions that will be used for generating
  59 # version info files later.
  60 include(gmxBuildTreeInfo)
  61 include(gmxVersionInfo)
  62
  63 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  64     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  65 endif()
  66 if("${CMAKE_INSTALL_PREFIX}" STREQUAL "${CMAKE_BINARY_DIR}")
  67     message(FATAL_ERROR "GROMACS cannot be installed into the build tree, choose a different location for CMAKE_INSTALL_PREFIX")
  68 endif()
  69
  70 include(gmxBuildTypeReference)
  71 include(gmxBuildTypeProfile)
  72 include(gmxBuildTypeTSAN)
  73 include(gmxBuildTypeASAN)
  74 include(gmxBuildTypeMSAN)
  75 include(gmxBuildTypeReleaseWithAssert)
  76
  77 if(NOT CMAKE_BUILD_TYPE)
  78     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert Profile TSAN ASAN MSAN." FORCE)
  79     # Set the possible values of build type for cmake-gui
  80     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
  81         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert" "Profile" "TSAN" "ASAN" "MSAN")
  82 endif()
  83 if(CMAKE_CONFIGURATION_TYPES)
  84     # Add appropriate GROMACS-specific build types for the Visual
  85     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
  86     # are already present by default).
  87     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
  88     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
  89     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
  90         "List of configuration types"
  91         FORCE)
  92 endif()
  93 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
  94
  95 set_property(GLOBAL PROPERTY FIND_LIBRARY_USE_LIB64_PATHS ON)
  96
  97 include(gmxCTestUtilities)
  98 gmx_ctest_init()
  99
 100 include(gmxCPackUtilities)
 101 gmx_cpack_init()
 102
 103 # Variables that accumulate stuff influencing the installed headers
 104 set(INSTALLED_HEADER_INCLUDE_DIRS "")
 105 set(INSTALLED_HEADER_DEFINITIONS "")
 106
 107 ########################################################################
 108 # Global non-cache variables for implementing the build system
 109 ########################################################################
 110
 111 # These variables collect libraries that GROMACS requires for
 112 # linking. They should be appended to with list(APPEND ${name}
 113 # new-library) calls. They are:
 114 #  - Libraries that are required for libgromacs (only)
 115 set(GMX_EXTRA_LIBRARIES "")
 116 #  - Libraries that are required for all code in the repository
 117 set(GMX_COMMON_LIBRARIES "")
 118 #  - Libraries that all code linked against libgromacs needs
 119 #    (i.e., something that is exposed in installed headers).
 120 set(GMX_PUBLIC_LIBRARIES "")
 121
 122 ########################################################################
 123 # Check and warn if cache generated on a different host is being reused
 124 ########################################################################
 125 if(CMAKE_HOST_UNIX)
 126     execute_process(COMMAND hostname
 127                     OUTPUT_VARIABLE TMP_HOSTNAME
 128                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 129     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 130         message(WARNING "
 131             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 132             is being reused! This could lead to inconsistencies; therefore, it is
 133             recommended to regenerate the cache!")
 134     endif()
 135     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 136             "Hostname of the machine where the cache was generated.")
 137 endif()
 138
 139 ########################################################################
 140 # Detect architecture before setting options so we can alter defaults
 141 ########################################################################
 142 # Detect the architecture the compiler is targetting, detect
 143 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 144 # to use if none is specified, and populate the cache option for CPU
 145 # SIMD.
 146 include(gmxDetectTargetArchitecture)
 147 gmx_detect_target_architecture()
 148
 149 ########################################################################
 150 # User input options                                                   #
 151 ########################################################################
 152 include(gmxOptionUtilities)
 153
 154 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 155
 156 # Fujitsu only has SIMD in double precision, so this will be faster
 157 gmx_set_boolean(GMX_DOUBLE_DEFAULT GMX_TARGET_FUJITSU_SPARC64)
 158 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" ${GMX_DOUBLE_DEFAULT})
 159 option(GMX_RELAXED_DOUBLE_PRECISION "Accept single precision 1/sqrt(x) when using Fujitsu HPC-ACE SIMD" OFF)
 160 mark_as_advanced(GMX_RELAXED_DOUBLE_PRECISION)
 161
 162 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 163 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 164 gmx_dependent_option(
 165     GMX_MPI_IN_PLACE
 166     "Enable MPI_IN_PLACE for MPIs that have it defined"
 167     ON
 168     GMX_MPI)
 169 mark_as_advanced(GMX_MPI_IN_PLACE)
 170
 171 option(GMX_MIMIC "Enable MiMiC QM/MM interface (CPMD is required)" OFF)
 172
 173 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 174 mark_as_advanced(GMX_FAHCORE)
 175
 176 option(GMX_COOL_QUOTES "Enable GROMACS cool quotes" ON)
 177 mark_as_advanced(GMX_COOL_QUOTES)
 178 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 179
 180 option(GMX_USE_OPENCL "Enable OpenCL acceleration" OFF)
 181
 182 # The earliest version of the CUDA toolkit that supports c++14 is 9.0
 183 set(REQUIRED_CUDA_VERSION 9.0)
 184 set(REQUIRED_CUDA_COMPUTE_CAPABILITY 3.0)
 185
 186 # OpenCL required version: 1.2 or newer
 187 set(REQUIRED_OPENCL_MIN_VERSION_MAJOR 1)
 188 set(REQUIRED_OPENCL_MIN_VERSION_MINOR 2)
 189 set(REQUIRED_OPENCL_MIN_VERSION ${REQUIRED_OPENCL_MIN_VERSION_MAJOR}.${REQUIRED_OPENCL_MIN_VERSION_MINOR})
 190
 191 if(NOT GMX_USE_OPENCL)
 192     # CUDA detection is done only if GMX_USE_OPENCL is OFF.
 193     include(gmxManageGPU)
 194     set(GMX_USE_CUDA ${GMX_GPU})
 195     if(GMX_GPU)
 196         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_CUDA")
 197     else()
 198         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_NONE")
 199     endif()
 200 else()
 201     #Now the OpenCL path (for both AMD and NVIDIA)
 202     if(GMX_GPU)
 203         include(gmxManageOpenCL)
 204         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_OPENCL")
 205     else()
 206         message(FATAL_ERROR "OpenCL requested but GPU option is not enabled (try -DGMX_GPU=on) ")
 207     endif()
 208 endif()
 209
 210 gmx_option_multichoice(
 211     GMX_SIMD
 212     "SIMD instruction set for CPU kernels and compiler optimization"
 213     "AUTO"
 214     AUTO None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 AVX2_128 AVX_512 AVX_512_KNL MIC ARM_NEON ARM_NEON_ASIMD IBM_VMX IBM_VSX Sparc64_HPC_ACE Reference)
 215
 216 if(GMX_TARGET_MIC)
 217     set(GMX_FFT_LIBRARY_DEFAULT "mkl")
 218 else()
 219     set(GMX_FFT_LIBRARY_DEFAULT "fftw3")
 220 endif()
 221
 222 gmx_option_multichoice(
 223     GMX_FFT_LIBRARY
 224     "FFT library"
 225     "${GMX_FFT_LIBRARY_DEFAULT}"
 226     fftw3 mkl "fftpack[built-in]")
 227 gmx_dependent_option(
 228     GMX_BUILD_OWN_FFTW
 229     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 230     OFF
 231     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 232 gmx_dependent_option(
 233     GMX_DISABLE_FFTW_MEASURE
 234     "Do not optimize FFTW setups (not needed with SSE)"
 235     OFF
 236     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 237 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 238 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 239
 240 gmx_option_multichoice(
 241     GMX_QMMM_PROGRAM
 242     "QM package for QM/MM"
 243     None
 244     none gaussian mopac gamess orca)
 245
 246 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 247 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 248
 249 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 250
 251 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 252 mark_as_advanced(GMX_BROKEN_CALLOC)
 253
 254 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 255
 256 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 257
 258 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 259
 260 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 261 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 262
 263 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 264 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 265
 266 option(GMX_BUILD_FOR_COVERAGE
 267        "Tune build for better code coverage metrics (e.g., disable asserts)"
 268        OFF)
 269 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 270
 271 option(GMX_DEVELOPER_BUILD
 272     "Enable Developer convenience features: always build unit-tests"
 273     OFF)
 274 mark_as_advanced(GMX_DEVELOPER_BUILD)
 275
 276 gmx_set_boolean(GMX_COMPILER_WARNINGS_DEFAULT "NOT SOURCE_IS_SOURCE_DISTRIBUTION")
 277 option(GMX_COMPILER_WARNINGS
 278     "Enable a default set of compiler warnings"
 279     ${GMX_COMPILER_WARNINGS_DEFAULT})
 280 mark_as_advanced(GMX_COMPILER_WARNINGS)
 281 # Always turn on compiler warnings with a developer build.
 282 gmx_add_cache_dependency(GMX_COMPILER_WARNINGS BOOL "NOT GMX_DEVELOPER_BUILD" ON)
 283
 284 option(GMX_BUILD_SHARED_EXE
 285     "Build exectuables as shared binaries. If not set, this disables rpath and dynamic linker flags in an attempt to build a static binary, but this may require setting up the toolchain properly and making appropriate libraries available."
 286     ON)
 287 mark_as_advanced(GMX_BUILD_SHARED_EXE)
 288
 289 option(GMX_PHYSICAL_VALIDATION
 290        "Include physical validation tests in ctest environment. These can then be called using 'make check-phys' or
 291        'make check-all'. Warning: Running the physical validation tests takes significantly more time than other tests!"
 292        OFF)
 293 mark_as_advanced(GMX_PHYSICAL_VALIDATION)
 294
 295 ######################################################################
 296 # Detect OpenMP support
 297 ######################################################################
 298 # The OpenMP detection _must_ come before tests for other CFLAGS.
 299 include(gmxManageOpenMP)
 300
 301
 302
 303 ######################################################################
 304 # Compiler tests
 305 # These need to be done early (before further tests).
 306 #####################################################################
 307
 308 include(gmxCFlags)
 309 gmx_c_flags()
 310
 311 # This variable should be used for additional compiler flags which are not
 312 # generated in gmxCFlags nor are SIMD or MPI related.
 313 #
 314 # TODO These variables should be consolidated into
 315 # EXTRA_COMPILER_FLAGS so that we we don't perpetrate bugs where
 316 # things that work in C compilation (e.g. merging from old branches)
 317 # also work for C++ compilation.
 318 set(EXTRA_C_FLAGS "")
 319 set(EXTRA_CXX_FLAGS "")
 320
 321 # Run through a number of tests for buggy compilers and other issues
 322 include(gmxTestCompilerProblems)
 323 gmx_test_compiler_problems()
 324
 325 # Implement double-precision option. This is complicated because we
 326 # need installed headers to use the precision mode of the build that
 327 # produced the library, but cannot use config.h in that case. We also
 328 # want such variables to always have a definition, because #if is more
 329 # robust than #ifdef. So, we put this value on the compiler command
 330 # line in all cases.
 331 #
 332 # GMX_RELAXED_DOUBLE_PRECISION does not need to be handled here,
 333 # because no installed header needs it
 334 if(GMX_DOUBLE)
 335     set(GMX_DOUBLE_VALUE 1)
 336 else()
 337     set(GMX_DOUBLE_VALUE 0)
 338 endif()
 339 add_definitions(-DGMX_DOUBLE=${GMX_DOUBLE_VALUE})
 340 list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_DOUBLE=${GMX_DOUBLE_VALUE}")
 341
 342 if(WIN32)
 343     list(APPEND GMX_EXTRA_LIBRARIES "wsock32")
 344     add_definitions(-DGMX_HAVE_WINSOCK)
 345 endif()
 346
 347
 348
 349 ########################################################################
 350 # Basic system tests (standard libraries, headers, functions, types)   #
 351 ########################################################################
 352 include(CheckIncludeFiles)
 353 include(CheckIncludeFileCXX)
 354 check_include_files(unistd.h     HAVE_UNISTD_H)
 355 check_include_files(pwd.h        HAVE_PWD_H)
 356 check_include_files(dirent.h     HAVE_DIRENT_H)
 357 check_include_files(time.h       HAVE_TIME_H)
 358 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 359 check_include_files(io.h         HAVE_IO_H)
 360 check_include_files(sched.h      HAVE_SCHED_H)
 361
 362 include(CheckCXXSymbolExists)
 363 check_cxx_symbol_exists(gettimeofday      sys/time.h   HAVE_GETTIMEOFDAY)
 364 check_cxx_symbol_exists(sysconf           unistd.h     HAVE_SYSCONF)
 365 check_cxx_symbol_exists(nice              unistd.h     HAVE_NICE)
 366 check_cxx_symbol_exists(fsync             unistd.h     HAVE_FSYNC)
 367 check_cxx_symbol_exists(_fileno           stdio.h      HAVE__FILENO)
 368 check_cxx_symbol_exists(fileno            stdio.h      HAVE_FILENO)
 369 check_cxx_symbol_exists(_commit           io.h         HAVE__COMMIT)
 370 check_cxx_symbol_exists(sigaction         signal.h     HAVE_SIGACTION)
 371
 372 # We cannot check for the __builtins as symbols, but check if code compiles
 373 check_cxx_source_compiles("int main(){ return __builtin_clz(1);}"   HAVE_BUILTIN_CLZ)
 374 check_cxx_source_compiles("int main(){ return __builtin_clzll(1);}" HAVE_BUILTIN_CLZLL)
 375 if(MSVC)
 376     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned long i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE)
 377     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned __int64 i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE64)
 378 elseif(CMAKE_CXX_COMPILER_ID MATCHES "XL")
 379     check_cxx_source_compiles("int main(){ return __cntlz4(1);}" HAVE_CNTLZ4)
 380     check_cxx_source_compiles("int main(){ return __cntlz8(1);}" HAVE_CNTLZ8)
 381 endif()
 382
 383 include(CheckLibraryExists)
 384 find_library(HAVE_LIBM m)
 385 mark_as_advanced(HAVE_LIBM)
 386 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 387 check_library_exists(m feenableexcept "" HAVE_FEENABLEEXCEPT)
 388 check_library_exists(m fedisableexcept "" HAVE_FEDISABLEEXCEPT)
 389
 390 include(TestSchedAffinity)
 391 test_sched_affinity(HAVE_SCHED_AFFINITY)
 392
 393 # Aligned memory allocation. We need to check for both mm_malloc(),
 394 # posix_memalign(), memalign(), and on windows also _aligned_malloc()
 395 include(gmxTestMMMalloc)
 396 gmx_test_mm_malloc(HAVE__MM_MALLOC)
 397 check_cxx_symbol_exists(posix_memalign    stdlib.h     HAVE_POSIX_MEMALIGN)
 398 check_cxx_symbol_exists(memalign          stdlib.h     HAVE_MEMALIGN)
 399 if(MSVC)
 400     # No need to waste time on this test on platforms where it will never be true
 401     check_cxx_symbol_exists(_aligned_malloc   stdlib.h     HAVE__ALIGNED_MALLOC)
 402 endif()
 403
 404 include(TestBigEndian)
 405 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 406
 407 gmx_set_boolean(GMX_USE_NICE "HAVE_UNISTD_H AND HAVE_NICE")
 408
 409 # Management of GROMACS options for specific toolchains should go
 410 # here. Because the initial settings for some of the main options have
 411 # already happened, but things like library detection and MPI compiler
 412 # feature detection have not, the docstrings for any over-rides of
 413 # GROMACS defaults or user settings will make sense. Also, any
 414 # toolchain-related reasons for choosing whether to detect various
 415 # things can be sorted out now, before the detection takes place.
 416 if(GMX_TARGET_FUJITSU_SPARC64)
 417     include(gmxManageFujitsuSparc64)
 418 endif()
 419
 420 ########################################################################
 421 #Process MPI settings
 422 ########################################################################
 423 include(gmxManageMPI)
 424
 425 ########################################################################
 426 #Process MiMiC settings
 427 ########################################################################
 428 include(gmxManageMimic)
 429
 430 ########################################################################
 431 #Process shared/static library settings
 432 ########################################################################
 433 include(gmxManageSharedLibraries)
 434
 435
 436 ########################################################################
 437 # Find external packages                                               #
 438 ########################################################################
 439
 440 # Unconditionally find the package, as it is also required for unit
 441 # tests. This exports LIBXML2_FOUND, which we should not use because
 442 # it does not tell us that linking will succeed. Instead, we test that
 443 # next.
 444 #if(DEFINED LIBXML2_LIBRARIES)
 445 #  set(LibXml2_FIND_QUIETLY TRUE)
 446 #endif()
 447 #find_package(LibXml2)
 448 #include(gmxTestLibXml2)
 449 #gmx_test_libxml2(HAVE_LIBXML2)
 450 #option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 451 #set(PKG_XML "")
 452 #mark_as_advanced(GMX_XML)
 453 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 454 #if(GMX_XML AND NOT HAVE_LIBXML2)
 455 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 456 #endif()
 457 #if(GMX_XML)
 458 #    include_directories(${LIBXML2_INCLUDE_DIR})
 459 #    set(PKG_XML libxml-2.0)
 460 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 461 #endif()
 462
 463 gmx_option_trivalue(
 464     GMX_HWLOC
 465     "Use hwloc portable hardware locality library"
 466     "AUTO")
 467
 468 if (GMX_HWLOC)
 469     # Find quietly the second time.
 470     if(DEFINED HWLOC_LIBRARIES)
 471         set(Hwloc_FIND_QUIETLY TRUE)
 472     endif()
 473     find_package(Hwloc 1.5)
 474
 475     if (HWLOC_FOUND)
 476         if (HWLOC_LIBRARIES MATCHES ".a$")
 477             set(_STATIC_HWLOC TRUE)
 478         endif()
 479
 480         gmx_check_if_changed(HWLOC_FOUND_CHANGED HWLOC_FOUND)
 481         if (_STATIC_HWLOC AND HWLOC_FOUND_CHANGED)
 482             message(STATUS "Static hwloc library found, will not attempt using it as it could lead to link-time errors. To use the detected library, manually set GMX_HWLOC=ON and you will likely have to pass appropriate linker flags too to satisfy the link-time dependencies of your hwloc library. Try \"pkg-config --libs --static hwloc\" for suggestions on what you will need.")
 483             set(GMX_USE_HWLOC OFF)
 484         else()
 485             set(GMX_USE_HWLOC ON)
 486         endif()
 487
 488         if (GMX_USE_HWLOC)
 489             include_directories(SYSTEM ${HWLOC_INCLUDE_DIRS})
 490             list(APPEND GMX_EXTRA_LIBRARIES ${HWLOC_LIBRARIES})
 491         endif()
 492     elseif(GMX_HWLOC_FORCE)
 493         message(FATAL_ERROR "Hwloc package support required, but not found.")
 494     endif()
 495 endif()
 496
 497 option(GMX_EXTERNAL_TINYXML2 "Use external TinyXML-2 instead of compiling the version bundled with GROMACS." OFF)
 498 mark_as_advanced(GMX_EXTERNAL_TINYXML2)
 499 if(GMX_EXTERNAL_TINYXML2)
 500     # Find an external TinyXML-2 library.
 501     find_package(TinyXML-2 3.0.0)
 502     set(HAVE_TINYXML2 ${TinyXML2_FOUND})
 503     if(NOT HAVE_TINYXML2)
 504         message(FATAL_ERROR "External TinyXML-2 could not be found, please adjust your search paths")
 505     endif()
 506 endif()
 507
 508 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 509 mark_as_advanced(GMX_EXTRAE)
 510
 511 if (GMX_EXTRAE)
 512   find_package(EXTRAE)
 513   if(EXTRAE_FOUND)
 514     include_directories(SYSTEM ${EXTRAE_INCLUDE_DIR})
 515     set(HAVE_EXTRAE 1)
 516   else()
 517     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 518   endif()
 519 endif()
 520
 521 option(GMX_X11 "Use X window system" OFF)
 522 if (GMX_X11)
 523     find_package(X11)
 524     # X11 includes/libraries are only set in the ngmx subdirectory!
 525     if(NOT X11_FOUND)
 526         message(FATAL_ERROR
 527                 "X11 include files and/or libraries were not found. "
 528                 "Set GMX_X11=OFF to compile without X11 support. "
 529                 "gmx view will not be available.")
 530     endif()
 531     include_directories(SYSTEM ${X11_INCLUDE_DIR})
 532 endif()
 533
 534 include(ThreadMPI)
 535 # Enable core threading facilities
 536 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 537 if(GMX_THREAD_MPI)
 538     # enable MPI functions
 539     tmpi_enable()
 540     set(MPI_IN_PLACE_EXISTS 1)
 541 endif()
 542 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 543 if (TMPI_ATOMICS_DISABLED)
 544    add_definitions(-DTMPI_ATOMICS_DISABLED)
 545 endif()
 546
 547 include(gmxManageTNG)
 548
 549 include(gmxManageLmfit)
 550
 551 if(GMX_GPU)
 552     # now that we have detected the dependencies, do the second configure pass
 553     gmx_gpu_setup()
 554     if (GMX_CLANG_CUDA)
 555         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_CUDA_CLANG_LINK_LIBS})
 556         link_directories("${GMX_CUDA_CLANG_LINK_DIRS}")
 557     endif()
 558 endif()
 559
 560 if(CYGWIN)
 561     set(GMX_CYGWIN 1)
 562 endif()
 563
 564 if(WIN32)
 565     set(GMX_NATIVE_WINDOWS 1)
 566     # This makes windows.h not declare min/max as macros that would break
 567     # C++ code using std::min/std::max.
 568     add_definitions(-DNOMINMAX)
 569 endif()
 570
 571 if(CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Work-around for cmake bug #10837
 572     if (CMAKE_COMPILER_IS_GNUCC OR CMAKE_C_COMPILER_ID MATCHES "Intel" OR CMAKE_C_COMPILER_ID MATCHES "Clang")
 573         set(CMAKE_INCLUDE_SYSTEM_FLAG_C "-isystem ")
 574     endif()
 575     if (CMAKE_COMPILER_IS_GNUCXX OR CMAKE_CXX_COMPILER_ID MATCHES "Intel" OR CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 576         set(CMAKE_INCLUDE_SYSTEM_FLAG_CXX "-isystem ")
 577     endif()
 578 endif()
 579
 580 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING" ON)
 581 mark_as_advanced(GMX_BUILD_UNITTESTS)
 582 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 583
 584 ########################################################################
 585 # Our own GROMACS tests
 586 ########################################################################
 587
 588 add_definitions( -DHAVE_CONFIG_H )
 589 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src)
 590 # TODO required at high level because both libgromacs and progs/mdrun
 591 # require it, both for thread-MPI and its atomics and mutexes.
 592 include_directories(BEFORE SYSTEM ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include)
 593 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 594 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src)
 595
 596 include(gmxTestInlineASM)
 597 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 598
 599 include(gmxSetBuildInformation)
 600 gmx_set_build_information()
 601
 602 gmx_option_multichoice(
 603     GMX_USE_RDTSCP
 604     "Use low-latency RDTSCP instruction for CPU-based timers for mdrun execution; might need to be off when compiling for heterogeneous environments)"
 605     "AUTO"
 606     OFF ON AUTO DETECT)
 607 mark_as_advanced(GMX_USE_RDTSCP)
 608
 609 macro(gmx_check_rdtscp)
 610     if (CPU_DETECTION_FEATURES MATCHES "rdtscp")
 611         set(HAVE_RDTSCP 1)
 612         set(RDTSCP_DETECTION_MESSAGE " - detected on the build host")
 613     else()
 614         set(RDTSCP_DETECTION_MESSAGE " - not detected on the build host")
 615     endif()
 616 endmacro()
 617
 618 set(HAVE_RDTSCP 0)
 619 if (GMX_USE_RDTSCP STREQUAL "ON")
 620     set(HAVE_RDTSCP 1)
 621 elseif(GMX_USE_RDTSCP STREQUAL "DETECT")
 622     gmx_check_rdtscp()
 623 elseif(GMX_USE_RDTSCP STREQUAL "AUTO")
 624     # If the user specified automated SIMD selection, that the choice
 625     # is made based on detection on the build host. If so, then RDTSCP
 626     # should be chosen the same way.
 627     #
 628     # If the user specified an AVX SIMD level (e.g. when
 629     # cross-compiling GROMACS) then they will get our best guess, ie
 630     # that in practice AVX mostly correlates with rdtscp (and anyway
 631     # is only relevant in rather old x86 hardware).
 632     if (GMX_SIMD STREQUAL "AUTO")
 633         gmx_check_rdtscp()
 634     elseif (GMX_SIMD MATCHES "AVX")
 635         set(HAVE_RDTSCP 1)
 636     endif()
 637 endif()
 638 gmx_check_if_changed(HAVE_RDTSCP_CHANGED HAVE_RDTSCP)
 639 if (HAVE_RDTSCP_CHANGED)
 640     if (HAVE_RDTSCP)
 641         message(STATUS "Enabling RDTSCP support${RDTSCP_DETECTION_MESSAGE}")
 642     else()
 643         message(STATUS "Disabling RDTSCP support${RDTSCP_DETECTION_MESSAGE}")
 644     endif()
 645 endif()
 646
 647 include(gmxTestLargeFiles)
 648 gmx_test_large_files(GMX_LARGEFILES)
 649
 650 include(gmxTestSignal)
 651 gmx_test_sigusr1(HAVE_SIGUSR1)
 652
 653 include(gmxTestPipes)
 654 gmx_test_pipes(HAVE_PIPES)
 655
 656 include(gmxTestXDR)
 657 gmx_test_xdr(GMX_SYSTEM_XDR)
 658 # Darwin has system XDR, but it uses a three-argument flavour of
 659 # xdrproc_t that it guarantees will still work if you pass the normal
 660 # two-argument xdr filters, but gcc 8 warns about the cast necessary
 661 # to do that, so it's simpler to just use our own XDR library.
 662 #
 663 # TODO It would be better to craft a cmake test which fails if such
 664 # XDR operations cause warnings, and succeeds otherwise, because it is
 665 # generally preferable to use system libraries where possible.
 666 if(NOT GMX_SYSTEM_XDR OR CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 667     set(GMX_INTERNAL_XDR 1)
 668 endif()
 669
 670
 671 ##################################################
 672 # Process SIMD instruction settings
 673 ##################################################
 674 # This checks what flags to add in order to
 675 # support the SIMD instructions we need, it sets
 676 # correct defines for the SIMD instructions supported,
 677 # and adds advanced options to control accuracy
 678 # for SIMD math operations.
 679 include(gmxManageSimd)
 680 gmx_manage_simd()
 681
 682 include(gmxManageCycleCounters)
 683 gmx_manage_cycle_counters()
 684
 685 # Process QM/MM Settings
 686 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 687     set(GMX_QMMM_GAUSSIAN 1)
 688 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 689     set(GMX_QMMM_MOPAC 1)
 690 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 691     set(GMX_QMMM_GAMESS 1)
 692 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 693     set(GMX_QMMM_ORCA 1)
 694 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 695     # nothing to do
 696 else()
 697     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 698 endif()
 699
 700
 701 ##################################################
 702 # Process FFT library settings
 703 ##################################################
 704 include(gmxManageFFTLibraries)
 705
 706
 707 include(gmxManageLinearAlgebraLibraries)
 708
 709 include(gmxManagePluginSupport)
 710
 711 if (GMX_USE_PLUGINS)
 712     if(NOT GMX_VMD_PLUGIN_PATH)
 713         find_package(VMD)
 714     endif()
 715 endif()
 716
 717 # Link real-time library for POSIX timers. The check for clock_gettime
 718 # confirms the linkability of rt.
 719 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 720     list(APPEND GMX_EXTRA_LIBRARIES rt)
 721 endif()
 722
 723 # Math and thread libraries must often come after all others when linking...
 724 if (HAVE_LIBM)
 725     list(APPEND GMX_PUBLIC_LIBRARIES m)
 726 endif()
 727
 728 option(GMX_NACL "Configure for Native Client builds" OFF)
 729 if (GMX_NACL)
 730   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 731   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 732   # TODO: Is this still necessary with the check for its presence?
 733   set(GMX_USE_NICE 0)
 734   set(GMX_NO_RENAME 1)
 735 endif()
 736 mark_as_advanced(GMX_NACL)
 737
 738 if(GMX_FAHCORE)
 739   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 740       "Path to swindirect.h")
 741   include_directories(${COREWRAP_INCLUDE_DIR})
 742 endif()
 743
 744 # Value of GMX_BUILD_HELP=AUTO tries to generate things, but will only
 745 # produce warnings if that fails.
 746 set(build_help_default AUTO)
 747 if (SOURCE_IS_SOURCE_DISTRIBUTION OR CMAKE_CROSSCOMPILING)
 748     set(build_help_default OFF)
 749 endif()
 750 gmx_option_trivalue(GMX_BUILD_HELP "Build completions automatically (requires that compiled binaries can be executed on the build host) and install man pages if built (requires building the 'man' target manually)" ${build_help_default})
 751 mark_as_advanced(GMX_BUILD_HELP)
 752 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND BUILD_IS_INSOURCE)
 753     message(FATAL_ERROR
 754         "Rebuilding shell completions or man pages is not supported for "
 755         "in-source builds from a source distribution. "
 756         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 757 endif()
 758
 759 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 760 # these are set after everything else
 761 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 762     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 763     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 764     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 765     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 766 else()
 767     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 768     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 769     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 770     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 771     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 772     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 773     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 774     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 775     message("CMAKE_SHARED_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 776 endif()
 777
 778 ########################################################################
 779 # Specify install locations
 780 ########################################################################
 781 # Use GNUInstallDirs to set paths on multiarch systems.
 782 include(GNUInstallDirs)
 783
 784 set(GMX_INSTALL_DATASUBDIR "gromacs" CACHE STRING "Subdirectory for GROMACS data under CMAKE_INSTALL_DATADIR")
 785 mark_as_advanced(GMX_INSTALL_DATASUBDIR)
 786
 787 # Internal convenience so we do not have to join two path segments in the code
 788 set(GMX_INSTALL_GMXDATADIR ${CMAKE_INSTALL_DATADIR}/${GMX_INSTALL_DATASUBDIR})
 789
 790 # If the nesting level wrt. the installation root is changed,
 791 # gromacs-config.cmake.cmakein needs to be adapted.
 792 set(GMX_INSTALL_CMAKEDIR  ${CMAKE_INSTALL_DATAROOTDIR}/cmake)
 793
 794 # TODO: Make GMXRC adapt if this is changed
 795 set(GMX_INSTALL_PKGCONFIGDIR ${CMAKE_INSTALL_LIBDIR}/pkgconfig)
 796 set(GMX_INSTALL_OCLDIR       ${GMX_INSTALL_GMXDATADIR}/opencl)
 797
 798 list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${CMAKE_INSTALL_INCLUDEDIR})
 799
 800 # Binary and library suffix options
 801 include(gmxManageSuffixes)
 802
 803 ################################################################
 804 # Shared library load path settings
 805 ################################################################
 806 if(NOT GMX_BUILD_SHARED_EXE)
 807     # No rpath
 808     set(CMAKE_SKIP_RPATH TRUE)
 809     set(CMAKE_EXE_LINK_DYNAMIC_C_FLAGS) # remove -Wl,-Bdynamic
 810     set(CMAKE_EXE_LINK_DYNAMIC_CXX_FLAGS)
 811 else()
 812     # The build folder always has bin/ and lib/; if we are also going to
 813     # install to lib/, then the installation RPATH works also in the build
 814     # tree.  This makes installation slightly faster (no need to rewrite the
 815     # RPATHs), and makes the binaries in the build tree relocatable.
 816     if(CMAKE_INSTALL_LIBDIR STREQUAL "lib")
 817         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 818         if(POLICY CMP0068)
 819             cmake_policy(SET CMP0068 NEW) # From CMake-3.9
 820             set(CMAKE_BUILD_WITH_INSTALL_NAME_DIR TRUE)
 821         endif()
 822     endif()
 823     # Set the RPATH as relative to the executable location to make the
 824     # binaries relocatable.
 825     if(CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Assume OS X >=10.5
 826         set(CMAKE_INSTALL_RPATH "@loader_path/../${CMAKE_INSTALL_LIBDIR}")
 827         set(CMAKE_INSTALL_NAME_DIR ${CMAKE_INSTALL_RPATH})
 828     else()
 829         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${CMAKE_INSTALL_LIBDIR}")
 830     endif()
 831     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 832     set(CMAKE_MACOSX_RPATH 1)
 833 endif()
 834
 835 #COPYING file: Only necessary for binary distributions.
 836 #Simpler to always install.
 837 install(FILES COPYING DESTINATION ${GMX_INSTALL_GMXDATADIR} COMPONENT data)
 838
 839 if (GMX_BUILD_FOR_COVERAGE)
 840     # Code heavy with asserts makes conditional coverage close to useless metric,
 841     # as by design most of the false branches are impossible to trigger in
 842     # correctly functioning code.  And the benefit of testing those that could
 843     # be triggered by using an API against its specification isn't usually
 844     # worth the effort.
 845     add_definitions(-DNDEBUG -DGMX_DISABLE_ASSERTS)
 846 endif()
 847
 848 if (BUILD_TESTING)
 849     include(tests/CheckTarget.cmake)
 850 endif()
 851
 852 if (NOT GMX_BUILD_MDRUN_ONLY)
 853     find_package(ImageMagick QUIET COMPONENTS convert)
 854     include(gmxTestImageMagick)
 855     GMX_TEST_IMAGEMAGICK(IMAGE_CONVERT_POSSIBLE)
 856     add_subdirectory(docs)
 857     add_subdirectory(share)
 858     add_subdirectory(scripts)
 859 endif()
 860 add_subdirectory(src)
 861
 862 if (BUILD_TESTING)
 863     add_subdirectory(tests)
 864 endif()
 865
 866 gmx_cpack_write_config()
 867
 868 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 869 # Don't bother the user after the first configure pass.
 870 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 871     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 872 endif()
 873 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 874
 875 #######################
 876 ## uninstall target
 877 #######################
 878 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 879                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 880                   IMMEDIATE @ONLY)
 881 ###########################
 882 ADD_CUSTOM_TARGET(uninstall
 883                   "${CMAKE_COMMAND}" -P
 884                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 885 ###########################
 886 set_directory_properties(PROPERTIES
 887             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")