CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8)
   2 # Keep CMake suitably quiet on Cygwin
   3 set(CMAKE_LEGACY_CYGWIN_WIN32 0) # Remove when CMake >= 2.8.4 is required
   4
   5 # override bugs on OS X where Cmake picks gcc (GNU) for C instead of system default cc (Clang).
   6 if(APPLE)
   7     set(CMAKE_C_COMPILER_INIT "cc")
   8 endif(APPLE)
   9
  10 project(Gromacs)
  11 include(Dart)
  12 mark_as_advanced(DART_ROOT)
  13
  14 # PROJECT_VERSION should have the following structure:
  15 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  16 #
  17 # The "-dev" suffix is important to keep because it makes possible to distinguish
  18 # between a build from official release and a build from git release branch on a
  19 # machine with no git.
  20 #
  21 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  22 set(PROJECT_VERSION "4.6-dev")
  23 set(CUSTOM_VERSION_STRING ""
  24     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  25 mark_as_advanced(CUSTOM_VERSION_STRING)
  26 if (CUSTOM_VERSION_STRING)
  27     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  28 endif (CUSTOM_VERSION_STRING)
  29 set(SOVERSION 6)
  30 # It is a bit irritating, but this has to be set separately for now!
  31 SET(CPACK_PACKAGE_VERSION_MAJOR "4")
  32 SET(CPACK_PACKAGE_VERSION_MINOR "6")
  33 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  34
  35
  36 # Cmake modules/macros are in a subdirectory to keep this file cleaner
  37 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  38
  39 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  40 set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  41 endif()
  42
  43 if(NOT CMAKE_BUILD_TYPE)
  44     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
  45 endif(NOT CMAKE_BUILD_TYPE)
  46
  47 enable_language(C)
  48
  49 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
  50 set(CPACK_PACKAGE_VENDOR "gromacs.org")
  51 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
  52 set(CPACK_SET_DESTDIR "ON")
  53 set(CPACK_INCLUDE_TOPLEVEL_DIRECTORY 0)
  54 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
  55 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
  56 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/admin/InstallLicense.txt")
  57 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
  58 set(CPACK_SOURCE_IGNORE_FILES ".isreposource;.git;.gitignore")
  59 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
  60 SET(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/man;man")
  61
  62 #must come after all cpack settings!
  63 include(CPack)
  64
  65 ########################################################################
  66 # Check and warn if cache generated on a different host is being reused
  67 ########################################################################
  68 if(CMAKE_HOST_UNIX)
  69     execute_process(COMMAND hostname
  70                     OUTPUT_VARIABLE TMP_HOSTNAME
  71                     OUTPUT_STRIP_TRAILING_WHITESPACE)
  72     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
  73         message(WARNING "
  74             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
  75             is being reused! This could lead to inconsitencies; therefore, it is
  76             recommended to regenerate the cache!")
  77     endif()
  78     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
  79             "Hostname of the machine where the cache was generated.")
  80 endif()
  81
  82 ########################################################################
  83 # Fix stupid flags on Windows
  84 ########################################################################
  85 SET(SHARED_LIBS_DEFAULT ON)
  86 IF( WIN32 AND NOT CYGWIN)
  87   option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static system libraries (MT instead of MD)!" ON)
  88   mark_as_advanced(GMX_PREFER_STATIC_LIBS)
  89   SET(SHARED_LIBS_DEFAULT OFF)  #is currently not working on Windows
  90
  91   IF (GMX_PREFER_STATIC_LIBS)
  92     #Only setting Debug and Release flags. Others configurations current not used.
  93     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
  94     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
  95     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
  96     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
  97     STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE})
  98     SET(CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE} CACHE STRING "" FORCE)
  99     STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 100     SET(CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG} CACHE STRING "" FORCE)
 101   ENDIF()
 102
 103   #Workaround for cmake bug 13174. Replace deprecated options.
 104   IF( CMAKE_C_COMPILER_ID MATCHES "Intel" )
 105     STRING(REPLACE /GZ /RTC1 CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
 106     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
 107   ENDIF()
 108   IF( CMAKE_CXX_COMPILER_ID MATCHES "Intel" )
 109     STRING(REPLACE /GZ /RTC1 CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 110     STRING(REPLACE /GX /EHsc CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 111     SET(CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG} CACHE STRING "" FORCE)
 112
 113     STRING(REPLACE /GX /EHsc CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE})
 114     SET(CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE} CACHE STRING "" FORCE)
 115   ENDIF()
 116 ENDIF()
 117
 118 ########################################################################
 119 # User input options                                                   #
 120 ########################################################################
 121 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 122 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 123 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 124 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 125 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 126 option(GMX_POWERPC_INVSQRT "Use PowerPC hardware 1/sqrt" OFF)
 127 mark_as_advanced(GMX_POWERPC_INVSQRT)
 128 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 129 mark_as_advanced(GMX_FAHCORE)
 130 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library (rerun cmake after changing to see relevant options)" OFF)
 131
 132 include(gmxDetectAcceleration)
 133 if(NOT DEFINED GMX_ACCELERATION)
 134     if(CMAKE_CROSSCOMPILING)
 135         set(GMX_SUGGESTED_ACCELERATION "None")
 136     else(CMAKE_CROSSCOMPILING)
 137         gmx_detect_acceleration(GMX_SUGGESTED_ACCELERATION)
 138     endif(CMAKE_CROSSCOMPILING)
 139 endif(NOT DEFINED GMX_ACCELERATION)
 140
 141 set(GMX_ACCELERATION "@GMX_SUGGESTED_ACCELERATION@"
 142     CACHE STRING "Accelerated kernels. Pick one of: None, SSE2, SSE4.1, AVX_128_FMA, AVX_256, BlueGene, Power6, Fortran")
 143
 144 set(GMX_FFT_LIBRARY "fftw3"
 145     CACHE STRING "FFT library choices: fftw3,mkl,fftpack[built-in]")
 146 option(GMX_DISABLE_FFTW_MEASURE
 147        "Do not optimize FFTW setups (not needed with SSE)" OFF)
 148 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 149 set(GMX_QMMM_PROGRAM "none"
 150     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
 151 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 152 mark_as_advanced(GMX_BROKEN_CALLOC)
 153 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
 154 mark_as_advanced(GMX_MPI_IN_PLACE)
 155 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 156 mark_as_advanced(GMX_LOAD_PLUGINS)
 157
 158 option(GMX_OPENMP "Enable OpenMP-based mutithreading. " ON)
 159
 160 option(USE_VERSION_H "Generate development version string/information" ON)
 161 mark_as_advanced(USE_VERSION_H)
 162
 163 option(GMX_DEFAULT_SUFFIX "Use default suffixes for GROMACS binaries and libs (_d for double, _mpi for MPI; rerun cmake after changing to see relevant options)" ON)
 164
 165 if(UNIX AND NOT APPLE)
 166     option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer \".a\" static archives (NOTE: this is enabled only for UNIX (excluding APPLE) platforms but it might not always work!" OFF)
 167     mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 168 endif()
 169
 170
 171 ######################################################################
 172 # compiler tests
 173 # these need ot be done early (before further tests).
 174 #####################################################################
 175
 176 # cmake/Check{C,CXX}CompilerFlag.cmake are lifted from CMake git next
 177 # branch (proposed for v2.8.9) to be able to detect invalid options
 178 # with the Intel Compilers.
 179 # Remove these files from the source tree when a CMake version that
 180 # includes the features in question becomes required.
 181 include(CheckCCompilerFlag)
 182 include(CheckCXXCompilerFlag)
 183
 184 # OpenMP check must come before other CFLAGS!
 185 if(GMX_OPENMP)
 186     find_package(OpenMP)
 187     if(OPENMP_FOUND)
 188         set(GROMACS_C_FLAGS "${OpenMP_C_FLAGS} ${GROMACS_C_FLAGS}")
 189         set(GROMACS_CXX_FLAGS "${OpenMP_CXX_FLAGS} ${GROMACS_CXX_FLAGS}")
 190     else(OPENMP_FOUND)
 191         message(WARNING
 192                 "Compiler not supporting OpenMP. This might hurt your performance a lot, "
 193                 "in particular with GPUs. Try using a different compiler (Intel is good on x86) "
 194                 "if you can - for now we are proceeding by turning off OpenMP.")
 195         set(GMX_OPENMP OFF CACHE STRING "Compiler does not support OpenMP." FORCE)
 196     endif(OPENMP_FOUND)
 197 endif()
 198
 199
 200 include(gmxCFlags)
 201 gmx_c_flags()
 202
 203 ########################################################################
 204 # Set up binary and library suffixing
 205 ########################################################################
 206 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 207 set(GMX_LIBS_SUFFIX ""
 208   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 209 if (GMX_DEFAULT_SUFFIX)
 210   set(GMX_BINARY_SUFFIX "")
 211   set(GMX_LIBS_SUFFIX "")
 212   if (GMX_MPI)
 213     set(GMX_BINARY_SUFFIX "_mpi")
 214     set(GMX_LIBS_SUFFIX "_mpi")
 215   endif(GMX_MPI)
 216   if (GMX_DOUBLE)
 217     set (GMX_BINARY_SUFFIX "${GMX_BINARY_SUFFIX}_d")
 218     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
 219   endif(GMX_DOUBLE)
 220   if (GMX_OPENMM)
 221     set (GMX_BINARY_SUFFIX "-openmm")
 222     set (GMX_LIBS_SUFFIX "_openmm")
 223   endif(GMX_OPENMM)
 224   mark_as_advanced(FORCE GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 225   if (NOT SUFFIX_QUIETLY)
 226     message(STATUS "Using default binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 227     message(STATUS "Using default library suffix: \"${GMX_LIBS_SUFFIX}\"")
 228   endif (NOT SUFFIX_QUIETLY)
 229 else(GMX_DEFAULT_SUFFIX)
 230   mark_as_advanced(CLEAR GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 231   if (NOT SUFFIX_QUIETLY)
 232     message(STATUS "Using manually set binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 233     message(STATUS "Using manually set library suffix: \"${GMX_LIBS_SUFFIX}\"")
 234   endif (NOT SUFFIX_QUIETLY)
 235 endif(GMX_DEFAULT_SUFFIX)
 236 set(SUFFIX_QUIETLY TRUE CACHE INTERNAL "")
 237
 238 set(PKG_CFLAGS "")
 239 if(GMX_DOUBLE)
 240     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 241 endif(GMX_DOUBLE)
 242 if(GMX_SOFTWARE_INVSQRT)
 243   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 244 endif(GMX_SOFTWARE_INVSQRT)
 245 if(GMX_POWERPC_INVSQRT)
 246   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_POWERPC_INVSQRT")
 247 endif(GMX_POWERPC_INVSQRT)
 248
 249 ########################################################################
 250 #Process MPI settings
 251 ########################################################################
 252 include(gmxManageMPI)
 253
 254 #######################################################################
 255 # Check for options incompatible with OpenMM build                    #
 256 #######################################################################
 257 if(GMX_OPENMM)
 258     # we'll use the built-in fft to avoid unnecessary dependencies
 259     string(TOUPPER ${GMX_FFT_LIBRARY} GMX_FFT_LIBRARY)
 260     if(NOT ${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 261         message(STATUS "No external FFT libraries needed for the OpenMM build, switching to fftpack!")
 262         set(GMX_FFT_LIBRARY "fftpack" CACHE STRING
 263                 "No external FFT libraries needed for the OpenMM build, switching to  fftpack!" FORCE)
 264     endif()
 265     if(GMX_MPI)
 266         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
 267     endif(GMX_MPI)
 268     if(GMX_THREAD_MPI)
 269         message(STATUS "Thread-MPI not compatible with OpenMM, disabled!")
 270         set(GMX_THREAD_MPI OFF CACHE BOOL
 271                 "Thread-MPI not compatible with OpenMM build, disabled!" FORCE)
 272     endif(GMX_THREAD_MPI)
 273     if(GMX_OPENMP)
 274         message(STATUS "OpenMP multithreading not compatible with OpenMM, disabled")
 275         set(GMX_OPENMP OFF CACHE BOOL
 276             "OpenMP multithreading not compatible with OpenMM, disabled!" FORCE)
 277     endif()
 278     if(GMX_SOFTWARE_INVSQRT)
 279         set(GMX_SOFTWARE_INVSQRT OFF CACHE STRING
 280                 "The OpenMM build does not need GROMACS software 1/sqrt!" FORCE)
 281     endif(GMX_SOFTWARE_INVSQRT)
 282     string(TOUPPER ${GMX_ACCELERATION} GMX_ACCELERATION)
 283     if(NOT GMX_ACCELERATION STREQUAL "NONE")
 284         message(STATUS "Switching off CPU-based acceleration, the OpenMM build does not support/need any!")
 285         set(GMX_ACCELERATION "none" CACHE STRING
 286                 "Switching off CPU-based acceleration, the OpenMM build does not support/need any!" FORCE)
 287     endif()
 288     if(GMX_FAHCORE)
 289         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
 290     endif(GMX_FAHCORE)
 291     if(GMX_DOUBLE)
 292         message(FATAL_ERROR  "The OpenMM-build does not support double precision calculations!")
 293     endif()
 294     # mark as advanced the unused variables
 295     mark_as_advanced(FORCE GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 296         GMX_QMMM_PROGRAM GMX_THREAD_MPI GMX_DOUBLE)
 297 else(GMX_OPENMM)
 298      mark_as_advanced(CLEAR GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 299         GMX_QMMM_PROGRAM GMX_THREAD_MPI GMX_DOUBLE)
 300 endif(GMX_OPENMM)
 301
 302
 303
 304
 305 ########################################################################
 306 # Basic system tests (standard libraries, headers, functions, types)   #
 307 ########################################################################
 308 include(CheckIncludeFiles)
 309 check_include_files(string.h     HAVE_STRING_H)
 310 check_include_files(math.h       HAVE_MATH_H)
 311 check_include_files(limits.h     HAVE_LIMITS_H)
 312 check_include_files(memory.h     HAVE_MEMORY_H)
 313 check_include_files(unistd.h     HAVE_UNISTD_H)
 314 check_include_files(direct.h     HAVE_DIRECT_H)
 315 check_include_files(pwd.h        HAVE_PWD_H)
 316 check_include_files(stdint.h     HAVE_STDINT_H)
 317 check_include_files(stdlib.h     HAVE_STDLIB_H)
 318 check_include_files(pthread.h    HAVE_PTHREAD_H)
 319 check_include_files(dirent.h     HAVE_DIRENT_H)
 320 check_include_files(inttypes.h   HAVE_INTTYPES_H)
 321 check_include_files(regex.h      HAVE_REGEX_H)
 322 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 323 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
 324 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 325 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
 326 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
 327 check_include_files(io.h                 HAVE_IO_H)
 328
 329
 330 include(CheckFunctionExists)
 331 check_function_exists(strcasecmp        HAVE_STRCASECMP)
 332 check_function_exists(strdup            HAVE_STRDUP)
 333 check_function_exists(vprintf           HAVE_VPRINTF)
 334 check_function_exists(memcmp            HAVE_MEMCMP)
 335 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 336 check_function_exists(memalign          HAVE_MEMALIGN)
 337 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 338 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 339 check_function_exists(isnan             HAVE_ISNAN)
 340 check_function_exists(_isnan            HAVE__ISNAN)
 341 check_function_exists(fsync             HAVE_FSYNC)
 342 check_function_exists(_fileno           HAVE__FILENO)
 343 check_function_exists(fileno            HAVE_FILENO)
 344 check_function_exists(_commit           HAVE__COMMIT)
 345 check_function_exists(lstat             HAVE_LSTAT)
 346 check_function_exists(sigaction         HAVE_SIGACTION)
 347
 348 include(CheckLibraryExists)
 349 check_library_exists(m sqrt "" HAVE_LIBM)
 350 check_library_exists(m cbrt "" HAVE_CBRT)
 351
 352
 353 include(CheckTypeSize)
 354
 355 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 356 check_type_size("int"           SIZEOF_INT)
 357 check_type_size("long int"      SIZEOF_LONG_INT)
 358 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 359 check_type_size("off_t"         SIZEOF_OFF_T)
 360 check_type_size("void *"        SIZEOF_VOIDP)
 361
 362 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 363     set(GMX_64_BIT TRUE)
 364 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 365     set(GMX_64_BIT FALSE)
 366 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 367
 368 # Check for some basic types that we *need*, so set these to int if they are not present
 369 check_type_size(uid_t uid_t)
 370 if(NOT uid_t)
 371   set(uid_t int)
 372 else(NOT uid_t)
 373   set(uid_t 0)
 374 endif(NOT uid_t)
 375
 376 check_type_size(gid_t gid_t)
 377 if(NOT gid_t)
 378   set(gid_t 1)
 379 else(NOT gid_t)
 380   set(gid_t 0)
 381 endif(NOT gid_t)
 382
 383 check_type_size(size_t size_t)
 384 if(NOT size_t)
 385   set(size_t int)
 386 else(NOT size_t)
 387   set(size_t 0)
 388 endif(NOT size_t)
 389
 390 check_type_size(off_t off_t)
 391 if(NOT off_t)
 392   set(off_t int)
 393 else(NOT off_t)
 394   set(off_t 0)
 395 endif(NOT off_t)
 396
 397 include(TestBigEndian)
 398 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 399
 400
 401
 402
 403 ########################################################################
 404 # Find external packages                                               #
 405 ########################################################################
 406 if(UNIX AND NOT APPLE)
 407     if(GMX_PREFER_STATIC_LIBS)
 408         SET(CMAKE_FIND_LIBRARY_SUFFIXES .a ${CMAKE_FIND_LIBRARY_SUFFIXES})
 409         if(SHARED_LIBS_DEFAULT)
 410             if(BUILD_SHARED_LIBS) #Warn the user about the combination. But don't overwrite the request.
 411                 message(WARNING "Static libraries requested, and shared Gromacs libraries requested.")
 412             elseif(NOT DEFINED BUILD_SHARED_LIBS) #Change default to OFF. Don't warn if it's already off.
 413                 message(WARNING "Static libraries requested, the GROMACS libraries will also be build static (BUILD_SHARED_LIBS=OFF)")
 414                 set(SHARED_LIBS_DEFAULT OFF)
 415             endif()
 416         endif()
 417     endif()
 418 endif()
 419 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI, Windows)" ${SHARED_LIBS_DEFAULT})
 420
 421 option(GMX_XML "Use libxml2 to parse xml files" ON)
 422 if (GMX_XML)
 423   find_package(LibXml2)
 424   set(PKG_XML "")
 425   if(LIBXML2_FOUND)
 426     include_directories(${LIBXML2_INCLUDE_DIR})
 427     set(PKG_XML libxml-2.0)
 428     set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 429     set(HAVE_LIBXML2 1)
 430   endif(LIBXML2_FOUND)
 431 endif(GMX_XML)
 432
 433 option(GMX_GSL "Add support for gsl" OFF)
 434 if (GMX_GSL)
 435   find_package(gsl)
 436   set(PKG_GSL "")
 437   if(GSL_FOUND)
 438     include_directories(${GSL_INCLUDE_DIR})
 439     set(PKG_GSL gsl)
 440     set(HAVE_LIBGSL 1)
 441   endif(GSL_FOUND)
 442 endif (GMX_GSL)
 443
 444 option(GMX_X11 "Use X window system" OFF)
 445 if (GMX_X11)
 446         find_package(X11)
 447         # X11 includes/libraries are only set in the ngmx subdirectory!
 448         if(X11_FOUND)
 449         set(HAVE_X11 1)
 450         endif(X11_FOUND)
 451 endif(GMX_X11)
 452
 453 if(GMX_THREAD_MPI)
 454     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREAD_MPI")
 455     include(ThreadMPI)
 456     set(THREAD_MPI_LIB thread_mpi)
 457     set(GMX_MPI 1)
 458     string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 459 endif(GMX_THREAD_MPI)
 460
 461 if(GMX_OPENMM)
 462     set(CUDA_BUILD_EMULATION OFF)
 463     find_package(CUDA 3.1 REQUIRED)
 464     add_definitions(-DGMX_OPENMM)
 465     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 466         set(CUDA_VERBOSE_BUILD ON)
 467     endif()
 468     find_package(OpenMM)
 469 endif(GMX_OPENMM)
 470
 471
 472 if(APPLE)
 473    find_library(ACCELERATE_FRAMEWORK Accelerate)
 474    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 475 endif(APPLE)
 476
 477 if(CYGWIN)
 478     set(GMX_CYGWIN 1)
 479 endif(CYGWIN)
 480
 481 if(WIN32 AND NOT CYGWIN)
 482     set(GMX_NATIVE_WINDOWS 1)
 483 endif()
 484
 485 # only bother with finding git and using version.h if the source is a git repo
 486 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 487     if(USE_VERSION_H)
 488         # We need at least git v1.5.3 be able to parse git's date output. If not
 489         # found or the version is too small, we can't generate version information.
 490         find_package(Git)
 491
 492         # Find out the git version
 493         if(GIT_FOUND AND NOT GIT_VERSION)
 494           execute_process(COMMAND ${GIT_EXECUTABLE} "--version"
 495             OUTPUT_VARIABLE _exec_out
 496             OUTPUT_STRIP_TRAILING_WHITESPACE)
 497           string(REGEX REPLACE "git version (.*)" "\\1" GIT_VERSION ${_exec_out})
 498           set(GIT_VERSION ${GIT_VERSION} CACHE STRING "Git version")
 499           mark_as_advanced(GIT_VERSION)
 500         endif()
 501
 502         if(NOT GIT_FOUND OR GIT_VERSION VERSION_LESS "1.5.3")
 503           message("No compatible git version found, won't be able to generate proper development version information.")
 504           set(USE_VERSION_H OFF)
 505         endif()
 506     endif()
 507 else()
 508     set(USE_VERSION_H OFF)
 509 endif()
 510
 511 ########################################################################
 512 # Generate development version info for cache
 513 ########################################################################
 514 # set(GEN_VERSION_INFO_INTERNAL "ON")
 515 # include(gmxGenerateVersionString)
 516
 517 ########################################################################
 518 # Our own GROMACS tests
 519 ########################################################################
 520
 521 add_definitions( -DHAVE_CONFIG_H )
 522 include_directories(${CMAKE_BINARY_DIR}/src)
 523 include_directories(${CMAKE_BINARY_DIR}/include)
 524 include_directories(${CMAKE_SOURCE_DIR}/include)
 525
 526 include(gmxTestInlineASM)
 527 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 528
 529 include(gmxSetBuildInformation)
 530 gmx_set_build_information()
 531 if(BUILD_CPU_FEATURES MATCHES "rdtscp")
 532     # The timestep counter headers do not include config.h
 533     add_definitions(-DHAVE_RDTSCP)
 534 endif(BUILD_CPU_FEATURES MATCHES "rdtscp")
 535
 536 include(gmxTestFloatFormat)
 537 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 538                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 539                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 540
 541 include(gmxTestLargeFiles)
 542 gmx_test_large_files(GMX_LARGEFILES)
 543 check_function_exists(fseeko     HAVE_FSEEKO)
 544
 545 include(gmxTestSignal)
 546 gmx_test_sigusr1(HAVE_SIGUSR1)
 547
 548 include(gmxTestInline)
 549 gmx_test_inline(INLINE_KEYWORD)
 550
 551 include(gmxTestRestrict)
 552 gmx_test_inline(RESTRICT_KEYWORD)
 553
 554 include(gmxTestPipes)
 555 gmx_test_pipes(HAVE_PIPES)
 556
 557 include(gmxTestIsfinite)
 558 gmx_test_isfinite(HAVE_ISFINITE)
 559 gmx_test__isfinite(HAVE__ISFINITE)
 560 gmx_test__finite(HAVE__FINITE)
 561
 562 include(gmxTestXDR)
 563 gmx_test_xdr(GMX_SYSTEM_XDR)
 564 if(NOT GMX_SYSTEM_XDR)
 565     set(GMX_INTERNAL_XDR 1)
 566     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 567 endif(NOT GMX_SYSTEM_XDR)
 568
 569 # Process nonbonded accelerated kernels settings
 570 string(TOUPPER ${GMX_ACCELERATION} ${GMX_ACCELERATION})
 571 if(${GMX_ACCELERATION} STREQUAL "NONE")
 572     # nothing to do
 573 elseif(${GMX_ACCELERATION} STREQUAL "SSE2")
 574
 575     GMX_TEST_CFLAG(GNU_SSE2_CFLAG "-msse2" GROMACS_C_FLAGS)
 576     if(NOT GNU_SSE2_CFLAG)
 577         GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" GROMACS_C_FLAGS)
 578     endif(NOT GNU_SSE2_CFLAG)
 579
 580     GMX_TEST_CXXFLAG(GNU_SSE2_CXXFLAG "-msse2" GROMACS_CXX_FLAGS)
 581     if(NOT GNU_SSE2_CXXFLAG)
 582         GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" GROMACS_CXX_FLAGS)
 583     endif(NOT GNU_SSE2_CXXFLAG)
 584
 585     # We dont warn for lacking SSE2 flag support, since that is probably standard today.
 586
 587     # Only test the include after we have tried to add the correct flag for SSE2 support
 588     check_include_file(emmintrin.h  HAVE_EMMINTRIN_H ${GROMACS_C_FLAGS})
 589
 590     if(NOT HAVE_EMMINTRIN_H)
 591         message(FATAL_ERROR "Cannot find emmintrin.h, which is required for SSE2 intrinsics support.")
 592     endif(NOT HAVE_EMMINTRIN_H)
 593
 594     # The user should not be able to set this orthogonally to the acceleration
 595     set(GMX_X86_SSE2 1)
 596     if (NOT ACCELERATION_QUIETLY)
 597       message(STATUS "Enabling SSE2 Gromacs acceleration, and it will help compiler optimization.")
 598     endif()
 599
 600 elseif(${GMX_ACCELERATION} STREQUAL "SSE4.1")
 601
 602     GMX_TEST_CFLAG(GNU_SSE4_CFLAG "-msse4.1" GROMACS_C_FLAGS)
 603     if (NOT GNU_SSE4_CFLAG)
 604         GMX_TEST_CFLAG(MSVC_SSE4_CFLAG "/arch:SSE4.1" GROMACS_C_FLAGS)
 605     endif(NOT GNU_SSE4_CFLAG)
 606     if (NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 607         message(WARNING "No C SSE4.1 flag found. Consider a newer compiler, or disable SSE4.1 for slightly lower performance.")
 608         # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 609         # intrinsics when SSE2 support is enabled, so we try that instead.
 610         GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" GROMACS_C_FLAGS)
 611     endif(NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 612
 613     GMX_TEST_CXXFLAG(GNU_SSE4_CXXFLAG "-msse4.1" GROMACS_CXX_FLAG)
 614     if (NOT GNU_SSE4_CXXFLAG)
 615        GMX_TEST_CXXFLAG(MSVC_SSE4_CXXFLAG "/arch:SSE4.1" GROMACS_CXX_FLAGS)
 616     endif(NOT GNU_SSE4_CXXFLAG)
 617     if (NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 618         message(WARNING "No C++ SSE4.1 flag found. Consider a newer compiler, or disable SSE4.1 for slightly lower performance.")
 619         # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 620         # intrinsics when SSE2 support is enabled, so we try that instead.
 621         GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" GROMACS_CXX_FLAGS)
 622     endif(NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 623
 624     # This must come after we have added the -msse4.1 flag on some platforms.
 625     check_include_file(smmintrin.h  HAVE_SMMINTRIN_H ${GROMACS_C_FLAGS})
 626
 627     if(NOT HAVE_SMMINTRIN_H)
 628         message(FATAL_ERROR "Cannot find smmintrin.h, which is required for SSE4.1 intrinsics support.")
 629     endif(NOT HAVE_SMMINTRIN_H)
 630
 631     # The user should not be able to set this orthogonally to the acceleration
 632     set(GMX_X86_SSE4_1 1)
 633     set(GMX_X86_SSE2   1)
 634     if (NOT ACCELERATION_QUIETLY)
 635       message(STATUS "Enabling SSE4.1 Gromacs acceleration, and it will help compiler optimization.")
 636     endif()
 637
 638 elseif(${GMX_ACCELERATION} STREQUAL "AVX_128_FMA" OR ${GMX_ACCELERATION} STREQUAL "AVX_256")
 639
 640     # Set the AVX compiler flag for both these choices!
 641
 642     GMX_TEST_CFLAG(GNU_AVX_CFLAG "-mavx" GROMACS_C_FLAGS)
 643     if (NOT GNU_AVX_CFLAG)
 644         GMX_TEST_CFLAG(MSVC_AVX_CFLAG "/arch:AVX" GROMACS_C_FLAGS)
 645     endif (NOT GNU_AVX_CFLAG)
 646     if (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 647         message(WARNING "No C AVX flag found. Consider a newer compiler, or disable AVX for much lower performance.")
 648     endif (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 649
 650     GMX_TEST_CXXFLAG(GNU_AVX_CXXFLAG "-mavx" GROMACS_CXX_FLAGS)
 651     if (NOT GNU_AVX_CXXFLAG)
 652        GMX_TEST_CXXFLAG(MSVC_AVX_CXXFLAG "/arch:AVX" GROMACS_CXX_FLAGS)
 653     endif (NOT GNU_AVX_CXXFLAG)
 654     if (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 655        message(WARNING "No C++ AVX flag found. Consider a newer compiler, or disable AVX for much lower performance.")
 656     endif (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 657
 658     # Only test the header after we have tried to add the flag for AVX support
 659     check_include_file(immintrin.h  HAVE_IMMINTRIN_H ${GROMACS_C_FLAGS})
 660
 661     if(NOT HAVE_IMMINTRIN_H)
 662         message(FATAL_ERROR "Cannot find immintrin.h, which is required for AVX intrinsics support. Consider switching compiler.")
 663     endif(NOT HAVE_IMMINTRIN_H)
 664
 665     # AMD says we should include x86intrin.h for FMA support, but MSVC seems to do fine without it, so don't require it.
 666     check_include_file(x86intrin.h HAVE_X86INTRIN_H ${GROMACS_C_FLAGS})
 667
 668     # The user should not be able to set this orthogonally to the acceleration
 669     set(GMX_X86_SSE4_1 1)
 670     set(GMX_X86_SSE2   1)
 671
 672     # But just enable one of the choices internally...
 673     if(${GMX_ACCELERATION} STREQUAL "AVX_128_FMA")
 674         set(GMX_X86_AVX_128_FMA 1)
 675         if (NOT ACCELERATION_QUIETLY)
 676           message(STATUS "Enabling 128-bit AVX Gromacs acceleration (with fused-multiply add), and it will help compiler optimization.")
 677         endif()
 678     else()
 679         # If we are not doing AVX_128, it must be AVX_256...
 680         set(GMX_X86_AVX_256 1)
 681         if (NOT ACCELERATION_QUIETLY)
 682           message(STATUS "Enabling 256-bit AVX Gromacs acceleration, and it will help compiler optimization.")
 683         endif()
 684     endif()
 685
 686 elseif(${GMX_ACCELERATION} STREQUAL "FORTRAN")
 687
 688 #    Fortran is temporarily disabled while we push in nbNxN kernels.
 689 #    We need to fake it a bit here to avoid jenkins build errors!
 690 #    add_definitions(-DGMX_FORTRAN)
 691
 692 elseif(${GMX_ACCELERATION} STREQUAL "BLUEGENE")
 693 # GMX_ACCELERATION=BlueGene should be set in the Toolchain-BlueGene?-???.cmake file
 694     if (NOT ACCELERATION_QUIETLY)
 695       message(STATUS "Configuring for BlueGene")
 696     endif()
 697     set(GMX_BLUEGENE 1)
 698     if (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 699         set(SHARED_LIBS_DEFAULT OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 700         set(BUILD_SHARED_LIBS OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 701     endif (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 702     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on BlueGene" FORCE)
 703     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on BlueGene" FORCE)
 704     set(GMX_X11 OFF CACHE BOOL "X11 not compatible with BlueGene, disabled!" FORCE)
 705     set(GMX_THREAD_MPI OFF CACHE BOOL "Thread-MPI not compatible with BlueGene, disabled!" FORCE)
 706     set(GMX_MPI ON CACHE BOOL "Use MPI on BlueGene" FORCE)
 707 elseif(${GMX_ACCELERATION} STREQUAL "POWER6")
 708     set(GMX_POWER6 1)
 709     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on Power6" FORCE)
 710     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on Power6" FORCE)
 711 else(${GMX_ACCELERATION} STREQUAL "NONE")
 712     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_ACCELERATION}. Pick one of None, SSE2, SSE4.1, AVX_128_FMA, AVX_256, Fortran, BlueGene, Power6")
 713 endif(${GMX_ACCELERATION} STREQUAL "NONE")
 714 set(ACCELERATION_QUIETLY TRUE CACHE INTERNAL "")
 715
 716 if(GMX_FORTRAN OR GMX_POWER6)
 717     if (GMX_THREAD_MPI)
 718         message(FATAL_ERROR "FORTRAN/POWER6 is incompatible with thread-MPI and only provides a speed-up on certain IBM compilers. Disable FORTRAN (or threads if you really want to use FORTRAN kernels).")
 719     endif(GMX_THREAD_MPI)
 720     enable_language(Fortran)
 721     include(FortranCInterface)
 722     discover_fortran_mangling(prefix isupper suffix extra_under_score found)
 723     if(extra_under_score)
 724         set(extrasuffix "_")
 725     endif(extra_under_score)
 726     if(prefix)
 727       set(prefix "${prefix} ##")
 728     endif(prefix)
 729     if(suffix)
 730       set(suffix "## ${suffix}")
 731       if(extrasuffix)
 732         set(extrasuffix "${suffix}${extrasuffix}")
 733       endif(extrasuffix)
 734     else(suffix)
 735       if(extrasuffix)
 736         # Don't know if this is needed, but it can't hurt
 737         set(extrasuffix "## ${extrasuffix}")
 738       endif(extrasuffix)
 739     endif(suffix)
 740
 741     if(isupper)
 742         set(F77_FUNCDEF   "${prefix} NAME ${suffix}")
 743         set(F77_FUNCDEF_  "${prefix} NAME ${extrasuffix}")
 744     else(isupper)
 745         set(F77_FUNCDEF   "${prefix} name ${suffix}")
 746         set(F77_FUNCDEF_  "${prefix} name ${extrasuffix}")
 747     endif(isupper)
 748 else(GMX_FORTRAN OR GMX_POWER6)
 749         set(F77_FUNCDEF   "name ## _")
 750         set(F77_FUNCDEF_  "name ## _")
 751 endif(GMX_FORTRAN OR GMX_POWER6)
 752
 753 # Process QM/MM Settings
 754 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 755 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 756     set(GMX_QMMM_GAUSSIAN 1)
 757 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 758     set(GMX_QMMM_MOPAC 1)
 759 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 760     set(GMX_QMMM_GAMESS 1)
 761 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 762     set(GMX_QMMM_ORCA 1)
 763 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 764     # nothing to do
 765 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 766     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 767 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 768
 769 # Process FFT library settings - if not OpenMM build
 770 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 771 set(PKG_FFT "")
 772 set(PKG_FFT_LIBS "")
 773 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 774     if(GMX_DOUBLE)
 775         find_package(FFTW 3 COMPONENTS fftw)
 776     else(GMX_DOUBLE)
 777         find_package(FFTW 3 COMPONENTS fftwf)
 778     endif(GMX_DOUBLE)
 779     if(NOT FFTW_FOUND)
 780       MESSAGE(FATAL_ERROR "Cannot find FFTW3 (with correct precision - libfftw3f for single precision GROMACS or libfftw3 for double precision GROMACS). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 781     endif(NOT FFTW_FOUND)
 782     include_directories(${FFTW_INCLUDE_DIRS})
 783     set(FFT_LIBRARIES ${FFTW_LIBRARIES})
 784     set(PKG_FFT "${FFTW_PKG}")
 785
 786     set(GMX_FFT_FFTW3 1)
 787
 788     if (${GMX_ACCELERATION} STREQUAL "SSE" AND NOT FFTW_HAVE_SSE)
 789       message(WARNING "The fftw library found is compiled without SSE support, which makes it slow. Consider recompiling it or contact your admin")
 790     endif (${GMX_ACCELERATION} STREQUAL "SSE" AND NOT FFTW_HAVE_SSE)
 791
 792 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 793 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 794     find_package(MKL REQUIRED)
 795     include_directories(${MKL_INCLUDE_DIR})
 796     set(FFT_LIBRARIES ${MKL_LIBRARIES})
 797     set(PKG_FFT_LIBS ${MKL_LIBRARIES})
 798
 799     set(GMX_FFT_MKL 1)
 800     set(HAVE_MKL 1)
 801
 802 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 803 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 804 #    set(GMX_FFT_ACML 1)
 805 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 806     MESSAGE(STATUS "Using internal FFT library - fftpack")
 807     set(GMX_FFT_FFTPACK 1)
 808 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 809     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, mkl, fftpack")
 810 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 811
 812 set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 813 set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 814 # MKL has BLAS/LAPACK routines
 815 if(NOT HAVE_MKL AND NOT ACCELERATE_FRAMEWORK)
 816   if(GMX_EXTERNAL_BLAS)
 817     if (GMX_BLAS_USER)
 818         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_BLAS_USER})
 819     else(GMX_BLAS_USER)
 820         set(BLAS_FIND_QUIETLY ON)
 821         find_package(BLAS)
 822         if (BLAS_FOUND)
 823           list(APPEND GMX_EXTRA_LIBRARIES ${BLAS_LIBRARIES})
 824         else()
 825           MESSAGE(STATUS "Using internal BLAS library")
 826           set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external BLAS instead of built-in" FORCE)
 827         endif()
 828     endif(GMX_BLAS_USER)
 829   endif(GMX_EXTERNAL_BLAS)
 830   if(GMX_EXTERNAL_LAPACK)
 831     if (GMX_LAPACK_USER)
 832         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_LAPACK_USER})
 833     else(GMX_LAPACK_USER)
 834         set(LAPACK_FIND_QUIETLY ON)
 835         find_package(LAPACK)
 836         if (LAPACK_FOUND)
 837           list(APPEND GMX_EXTRA_LIBRARIES ${LAPACK_LIBRARIES})
 838         else()
 839           MESSAGE(STATUS "Using internal LAPACK library")
 840           set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in" FORCE)
 841         endif()
 842     endif(GMX_LAPACK_USER)
 843   endif(GMX_EXTERNAL_LAPACK)
 844 endif()
 845 mark_as_advanced(GMX_EXTERNAL_LAPACK)
 846 mark_as_advanced(GMX_EXTERNAL_BLAS)
 847
 848 set(GMX_USE_PLUGINS OFF CACHE INTERNAL "Whether GROMACS will really try to compile support for VMD plugins")
 849 set(GMX_VMD_PLUGIN_PATH)
 850 mark_as_advanced(GMX_VMD_PLUGIN_PATH)
 851
 852 if(GMX_LOAD_PLUGINS)
 853   if(CYGWIN OR NOT WIN32)
 854     # Native Windows does not have, nor need dlopen
 855     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 856     include(gmxTestdlopen)
 857     gmx_test_dlopen(HAVE_DLOPEN)
 858   endif()
 859
 860   find_package(VMD)
 861
 862   # Test for unsuitable versions of VMD
 863
 864   if(VMD_FOUND AND NOT GMX_VMD_PLUGIN_PATH)
 865     message(STATUS "Checking for suitable VMD version")
 866     exec_program(${VMD_EXECUTABLE}
 867       ARGS --help
 868       OUTPUT_VARIABLE VMD_HELP
 869       RETURN_VALUE VMD_EXEC_RETURN)
 870
 871     if(VMD_EXEC_RETURN EQUAL 0)
 872       # This is the accepted idiom for subexpression matching, unfortunately
 873       string(REGEX REPLACE ".*VMD for .*, version ([0-9]+\\.[0-9]*\\.?[0-9]*).*" "\\1" VMD_VERSION ${VMD_HELP})
 874       string(REGEX REPLACE ".*VMD for (.*), version .*" "\\1" VMD_ARCH ${VMD_HELP})
 875
 876       if(VMD_VERSION VERSION_LESS "1.8")
 877         MESSAGE(WARNING "Found VMD version ${VMD_VERSION}, but GROMACS needs at least 1.8")
 878         unset(VMD_EXECUTABLE)
 879         set(VMD_FOUND FALSE)
 880       else()
 881         message(STATUS "VMD version ${VMD_VERSION} is suitable")
 882         if(DEFINED ENV{VMDDIR})
 883           # This permits GROMACS to avoid hard-coding a fall-back
 884           # path that it can tell right now would be useless.
 885           set(GMX_VMD_PLUGIN_PATH "$ENV{VMDDIR}/plugins/${VMD_ARCH}/molfile" CACHE PATH "Path to VMD plugins for molfile I/O")
 886         else()
 887           set(GMX_VMD_PLUGIN_PATH "/usr/local/lib/vmd/plugins/*/molfile" CACHE PATH "Path to VMD plugins for molfile I/O")
 888         endif()
 889       endif()
 890
 891       # clean up
 892       unset(VMD_HELP)
 893       unset(VMD_VERSION)
 894       unset(VMD_ARCH)
 895     endif()
 896   endif()
 897
 898   # so, should we use plug-ins?
 899   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 900     if (NOT VMD_QUIETLY)
 901       MESSAGE(STATUS "Found the ability to use plug-ins when building shared libaries, so will compile to use plug-ins (e.g. to read VMD-supported file formats).")
 902     endif(NOT VMD_QUIETLY)
 903     set(GMX_USE_PLUGINS ON)
 904     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 905     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 906   else()
 907     set(PKG_DL_LIBS)
 908   endif()
 909 endif(GMX_LOAD_PLUGINS)
 910 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 911
 912 if(EXISTS "${CMAKE_SOURCE_DIR}/admin/.isreposource")
 913     if(NOT CMAKE_CROSSCOMPILING)
 914         option(GMX_BUILD_MANPAGES "Build man pages" ON)
 915     else()
 916         message(STATUS "Building the man pages is not available when "
 917             "cross-compiling the developer version from git")
 918     endif()
 919 else()
 920     #make sure source package contains all man pages
 921     if(NOT EXISTS "${CMAKE_SOURCE_DIR}/man/man1/ngmx.1")
 922         message(FATAL_ERROR "Man pages are missing from source package.")
 923     endif()
 924 endif()
 925 mark_as_advanced(GMX_BUILD_MANPAGES)
 926
 927 # Math and thread libraries must often come after all others when linking...
 928 if(HAVE_LIBM)
 929     list(APPEND GMX_EXTRA_LIBRARIES m)
 930 endif(HAVE_LIBM)
 931
 932 if(GMX_FAHCORE)
 933   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 934       "Path to swindirect.h")
 935   include_directories(${COREWRAP_INCLUDE_DIR})
 936 endif(GMX_FAHCORE)
 937
 938 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 939 # these are set after everything else
 940 if (NOT DEFINED GROMACS_C_FLAGS_SET)
 941     set(GROMACS_C_FLAGS_SET true CACHE INTERNAL "Whether to reset the C flags"
 942         FORCE)
 943     set(CMAKE_C_FLAGS "${GROMACS_C_FLAGS} ${CMAKE_C_FLAGS}" CACHE STRING
 944         "Flags used by the compiler during all build types" FORCE)
 945     set(CMAKE_CXX_FLAGS "${GROMACS_CXX_FLAGS} ${CMAKE_CXX_FLAGS}" CACHE STRING
 946         "Flags used by the compiler during all build types" FORCE)
 947     set(CMAKE_EXE_LINKER_FLAGS
 948         "${GROMACS_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}"
 949         CACHE STRING "Linker flags" FORCE)
 950 endif (NOT DEFINED GROMACS_C_FLAGS_SET)
 951
 952 ######################################
 953 # Output compiler and CFLAGS used
 954 ######################################
 955 execute_process(COMMAND ${CMAKE_C_COMPILER} --version RESULT_VARIABLE TMP_RESULT OUTPUT_VARIABLE CC_VERSION ERROR_VARIABLE CC_VERSION)
 956 #try executing just the compiler command if that failed...
 957 if(TMP_RESULT)
 958     execute_process(COMMAND ${CMAKE_C_COMPILER} RESULT_VARIABLE TMP_RESULT OUTPUT_VARIABLE CC_VERSION ERROR_VARIABLE CC_VERSION)
 959 endif()
 960 string(LENGTH "${CC_VERSION}" len)
 961 if(len)
 962     string(REGEX MATCH "[^\n]*" CC_VERSION "${CC_VERSION}")
 963 endif()
 964
 965 set(BUILD_COMPILER "@CMAKE_C_COMPILER@ @CMAKE_C_COMPILER_ID@ @CC_VERSION@")
 966 set(BUILD_CFLAGS "@CMAKE_C_FLAGS@")
 967 if(CMAKE_BUILD_TYPE STREQUAL "Debug")
 968     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_DEBUG@")
 969 elseif(CMAKE_BUILD_TYPE STREQUAL "Release")
 970     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_RELEASE@")
 971 elseif(CMAKE_BUILD_TYPE STREQUAL "MinSizeRel")
 972     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_MINSIZEREL@")
 973 elseif(CMAKE_BUILD_TYPE STREQUAL "RelWithDebInfo")
 974     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_RELWITHDEBINFO@")
 975 endif()
 976
 977
 978 ########################################################################
 979 # Specify install locations and which subdirectories to process        #
 980 ########################################################################
 981 if ( DEFINED GMXLIB )
 982     set(LIB_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/${GMXLIB}")
 983 else()
 984     set(LIB_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/lib)
 985 endif()
 986 set(BIN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/bin)
 987 set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/gromacs)
 988 set(MAN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/share/man)
 989 set(INCL_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/include)
 990
 991 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
 992
 993 ##################################################################
 994 # Shared library settings - Darwin uses INSTALL_NAME_DIR instead!
 995 ##################################################################
 996 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 997     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
 998     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
 999     set(CMAKE_INSTALL_RPATH "${LIB_INSTALL_DIR}")
1000     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
1001 endif()
1002
1003 add_subdirectory(share)
1004 add_subdirectory(include)
1005 add_subdirectory(man)
1006 add_subdirectory(src)
1007 add_subdirectory(scripts)
1008
1009 #######################
1010 ## uninstall target
1011 #######################
1012     CONFIGURE_FILE(
1013                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
1014                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
1015                    IMMEDIATE @ONLY)
1016 ###########################
1017 ADD_CUSTOM_TARGET(uninstall
1018                   "${CMAKE_COMMAND}" -P
1019                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
1020 ###########################
1021
1022
1023 ########################################################################
1024 # Tests                                                                #
1025 ########################################################################
1026
1027 include(CTest)
1028 mark_as_advanced(BUILD_TESTING)
1029 IF(BUILD_TESTING)
1030         enable_testing()
1031         add_subdirectory(tests)
1032 ENDIF()
1033