CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.6)
   2
   3 project(Gromacs)
   4 include(Dart)
   5 mark_as_advanced(DART_ROOT)
   6 # PROJECT_VERSION should have the following structure:
   7 # VERSION[-dev-SUFFIX] where the VERSION can have any form and the suffix
   8 set(PROJECT_VERSION "4.5.1")
   9 set(CUSTOM_VERSION_STRING ""
  10     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  11 mark_as_advanced(CUSTOM_VERSION_STRING)
  12 if (CUSTOM_VERSION_STRING)
  13     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  14 endif (CUSTOM_VERSION_STRING)
  15 set(SOVERSION 6)
  16 # It is a bit irritating, but this has to be set separately for now!
  17 SET(CPACK_PACKAGE_VERSION_MAJOR "4")
  18 SET(CPACK_PACKAGE_VERSION_MINOR "5")
  19 SET(CPACK_PACKAGE_VERSION_PATCH "1")
  20
  21
  22 # Cmake modules/macros are in a subdirectory to keep this file cleaner
  23 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  24
  25 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  26 set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "" FORCE)
  27 endif()
  28
  29 if(NOT CMAKE_BUILD_TYPE)
  30     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
  31 endif(NOT CMAKE_BUILD_TYPE)
  32
  33 enable_language(C)
  34
  35 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
  36 set(CPACK_PACKAGE_VENDOR "gromacs.org")
  37 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
  38 set(CPACK_SET_DESTDIR "ON")
  39 set(CPACK_INCLUDE_TOPLEVEL_DIRECTORY 0)
  40 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
  41 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
  42 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/admin/InstallLicense.txt")
  43 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
  44
  45 #must come after all cpack settings!
  46 include(CPack)
  47
  48
  49 ########################################################################
  50 # Fix stupid flags on MSVC
  51 ########################################################################
  52 SET(SHARED_LIBS_DEFAULT ON)
  53 IF(CMAKE_GENERATOR MATCHES "Visual Studio")
  54     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
  55     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
  56     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
  57     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
  58     SET(SHARED_LIBS_DEFAULT OFF)
  59 ENDIF(CMAKE_GENERATOR MATCHES "Visual Studio")
  60
  61 set(GMX_EXTRA_LIBRARIES)
  62
  63
  64
  65 ######################################################################
  66 # compiler tests
  67 # these need ot be done early (before further tests).
  68 #####################################################################
  69
  70 include(CheckCCompilerFlag)
  71 include(CheckCXXCompilerFlag)
  72
  73 include(gmxCFlags)
  74 gmx_c_flags()
  75
  76 ########################################################################
  77 # User input options                                                   #
  78 ########################################################################
  79 option(GMX_DOUBLE "Use double precision. Much slower, use only if needed!)" OFF)
  80 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
  81 option(GMX_THREADS    "Build a parallel (thread-based) version of GROMACS)" ON)
  82 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
  83 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
  84 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
  85 mark_as_advanced(GMX_FAHCORE)
  86 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library" OFF)
  87 set(GMX_ACCELERATION "auto"
  88     CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec")
  89
  90 set(GMX_FFT_LIBRARY "fftw3"
  91     CACHE STRING "FFT library choices: fftw3,fftw2,mkl,fftpack[built-in]")
  92 option(GMX_DISABLE_FFTW_MEASURE
  93        "Do not optimize FFTW setups (not needed with SSE)" OFF)
  94 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
  95 set(GMX_QMMM_PROGRAM "none"
  96     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
  97 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
  98 mark_as_advanced(GMX_BROKEN_CALLOC)
  99 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI, Windows)" ${SHARED_LIBS_DEFAULT})
 100 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
 101 mark_as_advanced(GMX_MPI_IN_PLACE)
 102 option(GMX_DLOPEN "Compile with dlopen, needed to read VMD supported file formats" ON)
 103 mark_as_advanced(GMX_DLOPEN)
 104
 105
 106 option(GMX_IA32_ASM "Add SSE assembly files for IA32" OFF)
 107 mark_as_advanced(GMX_IA32_ASM)
 108 option(GMX_X86_64_ASM "Add SSE assembly files for X86_64" OFF)
 109 mark_as_advanced(GMX_X86_64_ASM)
 110
 111 option(USE_VERSION_H "Generate development version string/information" ON)
 112 mark_as_advanced(USE_VERSION_H)
 113
 114 option(GMX_DEFAULT_SUFFIX "Use default GROMACS suffixes" ON)
 115 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for double).")
 116 set(GMX_LIBS_SUFFIX ""
 117   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for mpi, _mpi_d for mpi and double).")
 118 if (GMX_DEFAULT_SUFFIX)
 119   if (GMX_MPI)
 120     set(GMX_LIBS_SUFFIX "_mpi")
 121   endif(GMX_MPI)
 122   if (GMX_DOUBLE)
 123     set (GMX_BINARY_SUFFIX "_d")
 124     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
 125   endif(GMX_DOUBLE)
 126 endif(GMX_DEFAULT_SUFFIX)
 127
 128 set(PKG_CFLAGS "")
 129 if(GMX_DOUBLE)
 130   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 131 endif(GMX_DOUBLE)
 132 if(GMX_SOFTWARE_INVSQRT)
 133   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 134 endif(GMX_SOFTWARE_INVSQRT)
 135
 136 ########################################################################
 137 #Process MPI settings
 138 ########################################################################
 139 if(GMX_MPI)
 140         MESSAGE(WARNING "
 141             There are known problems with some MPI implementations:
 142                      OpenMPI version < 1.4.1
 143                      MVAPICH2 version <= 1.4.1                               *")
 144     if(GMX_THREADS)
 145         #message(FATAL_ERROR "Thread-based parallelization conflicts with MPI.")
 146         set(GMX_THREADS OFF CACHE BOOL
 147             "Thread-based parallelization conflicts with MPI." FORCE)
 148     endif(GMX_THREADS)
 149     find_package(MPI)
 150     if(MPI_FOUND)
 151         set(GROMACS_C_FLAGS ${GROMACS_FLAGS} ${MPI_COMPILE_FLAGS})
 152         set(GROMACS_LINKER_FLAGS ${GROMACS_LINKER_FLAGS} ${MPI_LINK_FLAGS})
 153
 154         include_directories(${MPI_INCLUDE_PATH})
 155         list(APPEND GMX_EXTRA_LIBRARIES ${MPI_LIBRARIES})
 156         add_definitions( -DMPI ) #for FAHCORE
 157         include(gmxTestMPI_IN_PLACE)
 158         if (GMX_MPI_IN_PLACE)
 159             gmx_test_mpi_in_place(MPI_IN_PLACE_EXISTS)
 160         endif (GMX_MPI_IN_PLACE)
 161     else(MPI_FOUND)
 162         message(FATAL_ERROR "MPI support requested, but no MPI compiler found.")
 163     endif(MPI_FOUND)
 164     include(gmxTestCatamount)
 165     gmx_test_catamount(GMX_CRAY_XT3)
 166     if(GMX_CRAY_XT3)
 167         set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_CRAY_XT3")
 168         set(GMX_NO_SYSTEM 1)
 169         set(GMX_NO_NICE 1)
 170     endif(GMX_CRAY_XT3)
 171     set(GMX_LIB_MPI 1)
 172     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_LIB_MPI")
 173 endif(GMX_MPI)
 174
 175
 176 #######################################################################
 177 # Check for options incompatible with OpenMM build                    #
 178 #######################################################################
 179 if(GMX_OPENMM)
 180     cmake_minimum_required(VERSION 2.6.4)
 181     # we'll use the built-in fft to avoid unnecessary dependencies
 182     message(STATUS "No external FFT libraries needed for the OpenMM build, using fftpack!")
 183     set (GMX_FFT_LIBRARY "fftpack" CACHE STRING
 184                 "No external FFT libraries needed for the OpenMM build, using fftpack!" FORCE)
 185     if(GMX_MPI)
 186         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
 187     endif(GMX_MPI)
 188     if(GMX_THREADS)
 189         message(STATUS "Threads not compatible with OpenMM build, disabled!")
 190         set(GMX_THREADS OFF CACHE BOOL
 191                 "Threads not compatible with OpenMM build, disabled!" FORCE)
 192     endif(GMX_THREADS)
 193     if(GMX_SOFTWARE_INVSQRT)
 194         set(GMX_SOFTWARE_INVSQRT OFF FORCE)
 195     endif(GMX_SOFTWARE_INVSQRT)
 196     if(NOT GMX_ACCELERATION MATCHES "^(none|None|NONE)")
 197         message(WARNING "CPU-based acceleration turned off, OpenMM does not support/need any!")
 198         unset(GMX_ACCELERATION CACHE)
 199         set(GMX_ACCELERATION "none" CACHE STRING
 200                 "CPU-based acceleration turned off, OpenMM does not support/need any!" FORCE)
 201     endif()
 202     if(GMX_FAHCORE)
 203         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
 204     endif(GMX_FAHCORE)
 205 endif(GMX_OPENMM)
 206
 207
 208 ########################################################################
 209 # Basic system tests (standard libraries, headers, functions, types)   #
 210 ########################################################################
 211 include(CheckIncludeFiles)
 212 check_include_files(string.h     HAVE_STRING_H)
 213 check_include_files(math.h       HAVE_MATH_H)
 214 check_include_files(limits.h     HAVE_LIMITS_H)
 215 check_include_files(memory.h     HAVE_MEMORY_H)
 216 check_include_files(unistd.h     HAVE_UNISTD_H)
 217 check_include_files(pwd.h        HAVE_PWD_H)
 218 check_include_files(stdint.h     HAVE_STDINT_H)
 219 check_include_files(stdlib.h     HAVE_STDLIB_H)
 220 check_include_files(pthread.h    HAVE_PTHREAD_H)
 221 check_include_files(dirent.h     HAVE_DIRENT_H)
 222 check_include_files(inttypes.h   HAVE_INTTYPES_H)
 223 check_include_files(regex.h      HAVE_REGEX_H)
 224 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 225 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
 226 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 227 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
 228 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
 229 # SSE support
 230 check_include_files(xmmintrin.h  HAVE_XMMINTRIN_H)
 231 check_include_files(emmintrin.h  HAVE_EMMINTRIN_H)
 232 check_include_files(pmmintrin.h  HAVE_PMMINTRIN_H)
 233 check_include_files(smmintrin.h  HAVE_SMMINTRIN_H)
 234 check_include_files(io.h                 HAVE_IO_H)
 235
 236
 237 include(CheckFunctionExists)
 238 check_function_exists(strcasecmp        HAVE_STRCASECMP)
 239 check_function_exists(strdup            HAVE_STRDUP)
 240 check_function_exists(vprintf           HAVE_VPRINTF)
 241 check_function_exists(memcmp            HAVE_MEMCMP)
 242 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 243 check_function_exists(memalign          HAVE_MEMALIGN)
 244 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 245 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 246 check_function_exists(isnan             HAVE_ISNAN)
 247 check_function_exists(_isnan            HAVE__ISNAN)
 248 check_function_exists(isfinite          HAVE_ISFINITE)
 249 check_function_exists(_isfinite         HAVE__ISFINITE)
 250 check_function_exists(fsync             HAVE_FSYNC)
 251 check_function_exists(_fileno           HAVE__FILENO)
 252 check_function_exists(fileno            HAVE_FILENO)
 253 check_function_exists(_commit           HAVE__COMMIT)
 254
 255 include(CheckLibraryExists)
 256 check_library_exists(m sqrt "" HAVE_LIBM)
 257 check_library_exists(m cbrt "" HAVE_CBRT)
 258
 259
 260 include(CheckTypeSize)
 261
 262 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 263 check_type_size("int"           SIZEOF_INT)
 264 check_type_size("long int"      SIZEOF_LONG_INT)
 265 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 266 check_type_size("off_t"         SIZEOF_OFF_T)
 267 check_type_size("void *"        SIZEOF_VOIDP)
 268
 269 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 270     set(GMX_64_BIT TRUE)
 271 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 272     set(GMX_64_BIT FALSE)
 273 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 274
 275 # Check for some basic types that we *need*, so set these to int if they are not present
 276 check_type_size(uid_t uid_t)
 277 if(NOT uid_t)
 278   set(uid_t int)
 279 else(NOT uid_t)
 280   set(uid_t 0)
 281 endif(NOT uid_t)
 282
 283 check_type_size(gid_t gid_t)
 284 if(NOT gid_t)
 285   set(gid_t 1)
 286 else(NOT gid_t)
 287   set(gid_t 0)
 288 endif(NOT gid_t)
 289
 290 check_type_size(size_t size_t)
 291 if(NOT size_t)
 292   set(size_t int)
 293 else(NOT size_t)
 294   set(size_t 0)
 295 endif(NOT size_t)
 296
 297 check_type_size(off_t off_t)
 298 if(NOT off_t)
 299   set(off_t int)
 300 else(NOT off_t)
 301   set(off_t 0)
 302 endif(NOT off_t)
 303
 304 include(TestBigEndian)
 305 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 306
 307
 308
 309
 310 ########################################################################
 311 # Find external packages                                               #
 312 ########################################################################
 313
 314 find_package(LibXml2)
 315 set(PKG_XML "")
 316 if(LIBXML2_FOUND)
 317     include_directories(${LIBXML2_INCLUDE_DIR})
 318     set(PKG_XML libxml-2.0)
 319     set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 320     set(HAVE_LIBXML2 1)
 321 endif(LIBXML2_FOUND)
 322
 323 option(GMX_X11 "Use X window system" OFF)
 324 if (GMX_X11)
 325         find_package(X11)
 326         # X11 includes/libraries are only set in the ngmx subdirectory!
 327         if(X11_FOUND)
 328         set(HAVE_X11 1)
 329         endif(X11_FOUND)
 330 endif(GMX_X11)
 331
 332 if(GMX_THREADS)
 333     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREADS")
 334     include(ThreadMPI)
 335     set(THREAD_MPI_LIB thread_mpi)
 336     set(GMX_MPI 1)
 337     string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 338     if(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 339         message(FATAL_ERROR "FFTW2 can't be used with threads. Try fftw3 or mkl.")
 340     endif()
 341 endif(GMX_THREADS)
 342
 343 if(GMX_OPENMM)
 344     set(CUDA_BUILD_EMULATION OFF)
 345     find_package(CUDA 3.1 REQUIRED)
 346     add_definitions(-DGMX_OPENMM)
 347     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 348         set(CUDA_VERBOSE_BUILD ON)
 349     endif()
 350     find_package(OpenMM)
 351 endif(GMX_OPENMM)
 352
 353 if(APPLE)
 354    find_library(ACCELERATE_FRAMEWORK Accelerate)
 355    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 356 endif(APPLE)
 357
 358 # only bother with finding git and using version.h if the source is a git repo
 359 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 360     if(USE_VERSION_H)
 361         # We need at least git v1.5.1 be able to parse git's date output. If not
 362         # fund or the version is too small, we can't generate version information.
 363         find_package(Git 1.5.1)
 364         # this should at some point become VERSION_LESS
 365         if(NOT Git_FOUND OR Git_VERSION STRLESS "1.5.1")
 366             message("No compatible git version found, won't be able to generate proper development version information.")
 367         endif()
 368     endif()
 369 else()
 370     set(USE_VERSION_H OFF)
 371 endif()
 372
 373 if (GMX_DLOPEN)
 374     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS})
 375 endif (GMX_DLOPEN)
 376
 377 ########################################################################
 378 # Generate development version info for cache
 379 ########################################################################
 380 # set(GEN_VERSION_INFO_INTERNAL "ON")
 381 # include(gmxGenerateVersionString)
 382
 383 ########################################################################
 384 # Our own GROMACS tests
 385 ########################################################################
 386
 387 add_definitions( -DHAVE_CONFIG_H )
 388 include_directories(${CMAKE_BINARY_DIR}/src)
 389 include_directories(${CMAKE_SOURCE_DIR}/include)
 390
 391 include(gmxCheckBuildUserTime)
 392 gmx_check_build_user_time(BUILD_TIME BUILD_USER BUILD_MACHINE)
 393
 394 include(gmxTestFloatFormat)
 395 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 396                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 397                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 398
 399 include(gmxTestLargeFiles)
 400 gmx_test_large_files(GMX_LARGEFILES)
 401 check_function_exists(fseeko     HAVE_FSEEKO)
 402
 403 include(gmxTestSignal)
 404 gmx_test_retsigtype(RETSIGTYPE)
 405 gmx_test_sigusr1(HAVE_SIGUSR1)
 406
 407 include(gmxTestInline)
 408 gmx_test_inline(INLINE_KEYWORD)
 409
 410 include(gmxTestRestrict)
 411 gmx_test_inline(RESTRICT_KEYWORD)
 412
 413 include(gmxTestPipes)
 414 gmx_test_pipes(HAVE_PIPES)
 415
 416 include(gmxTestInlineASM)
 417 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 418 gmx_test_inline_asm_msvc_x86(GMX_X86_MSVC_INLINE_ASM)
 419
 420 # turn on SSE if supported with reasonable defaults.
 421 if (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 422   if(CMAKE_SYSTEM_PROCESSOR MATCHES "^(i.86|x86|x64|x86_64|AMD64|amd64)")
 423
 424     set(GMX_ACCELERATION "SSE" CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec" FORCE)
 425
 426     if (GMX_64_BIT)
 427       set(GMX_X86_64_ASM ON CACHE BOOL "Add SSE assembly files for x86_64" FORCE)
 428     else (GMX_64_BIT)
 429       set(GMX_IA32_ASM ON CACHE BOOL "Add SSE assembly files for i386" FORCE)
 430     endif (GMX_64_BIT)
 431
 432     # Determine the assembler/compiler to use
 433   else()
 434     set(GMX_ACCELERATION "none" CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec" FORCE)
 435   endif()
 436 endif (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 437
 438
 439 include(gmxTestXDR)
 440 gmx_test_xdr(GMX_SYSTEM_XDR)
 441 if(NOT GMX_SYSTEM_XDR)
 442     set(GMX_INTERNAL_XDR 1)
 443     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 444 endif(NOT GMX_SYSTEM_XDR)
 445
 446 if(GMX_FORTRAN OR GMX_POWER6)
 447     enable_language(Fortran)
 448     include(FortranCInterface)
 449     discover_fortran_mangling(prefix isupper suffix extra_under_score found)
 450     if(extra_under_score)
 451         set(extrasuffix "_")
 452     endif(extra_under_score)
 453
 454     if(isupper)
 455         set(F77_FUNCDEF   "${prefix} ## NAME ## ${suffix}")
 456         set(F77_FUNCDEF_  "${prefix} ## NAME ## ${suffix}${extrasuffix}")
 457     else(isupper)
 458         set(F77_FUNCDEF   "${prefix} ## name ## ${suffix}")
 459         set(F77_FUNCDEF_  "${prefix} ## name ## ${suffix}${extrasuffix}")
 460     endif(isupper)
 461 else(GMX_FORTRAN OR GMX_POWER6)
 462         set(F77_FUNCDEF   "name ## _")
 463         set(F77_FUNCDEF_  "name ## _")
 464 endif(GMX_FORTRAN OR GMX_POWER6)
 465
 466
 467 # Process nonbonded accelerated kernels settings
 468 string(TOUPPER ${GMX_ACCELERATION} ${GMX_ACCELERATION})
 469 if(${GMX_ACCELERATION} STREQUAL "NONE")
 470   # nothing to do
 471 elseif(${GMX_ACCELERATION} STREQUAL "SSE")
 472
 473     if(CMAKE_GENERATOR MATCHES "Visual Studio")
 474       option(GMX_ASM_USEASM-NASM "Use Nasm for assembly instead of compiler (necessary on windows)" ON)
 475     else()
 476       option(GMX_ASM_USEASM-NASM "Use Nasm for assembly instead of compiler (necessary on windows)" OFF)
 477     endif()
 478         mark_as_advanced(GMX_ASM_USEASM-NASM)
 479
 480     if (NOT GMX_64_BIT)
 481         # for 32-bit compiles, we might need to turn on sse
 482         CHECK_C_COMPILER_FLAG("-msse2" XFLAGS_SSE)
 483         if (XFLAGS_SSE)
 484             set(GROMACS_C_FLAGS "-msse2 ${GROMACS_C_FLAGS}")
 485         endif (XFLAGS_SSE)
 486         CHECK_CXX_COMPILER_FLAG("-msse2" XXFLAGS_SSE)
 487         if (XXFLAGS_SSE)
 488             set(GROMACS_CXX_FLAGS "-msse2 ${GROMACS_CXX_FLAGS}")
 489         endif (XXFLAGS_SSE)
 490     endif (NOT GMX_64_BIT)
 491
 492     if(GMX_IA32_ASM)
 493       if(GMX_DOUBLE)
 494         set(GMX_IA32_SSE2 1)
 495       else()
 496         set(GMX_IA32_SSE 1)
 497       endif()
 498     elseif(GMX_X86_64_ASM)
 499       if(GMX_DOUBLE)
 500         set(GMX_X86_64_SSE2 1)
 501       else()
 502         set(GMX_X86_64_SSE 1)
 503       endif()
 504     endif()
 505
 506 #    if(HAVE_PMMINTRIN_H)
 507 #        set(GMX_SSE3 1)
 508 #    endif(HAVE_PMMINTRIN_H)
 509 #    if(HAVE_SMMINTRIN_H)
 510 #        set(GMX_SSE4_1 1)
 511 #    endif(HAVE_SMMINTRIN_H)
 512
 513 elseif(${GMX_ACCELERATION} STREQUAL "FORTRAN")
 514     set(GMX_FORTRAN 1)
 515 elseif(${GMX_ACCELERATION} STREQUAL "BLUEGENE")
 516     set(GMX_BLUEGENE 1)
 517 elseif(${GMX_ACCELERATION} STREQUAL "POWER6")
 518     set(GMX_POWER6 1)
 519 elseif(${GMX_ACCELERATION} STREQUAL "IA64")
 520     set(GMX_IA64_ASM 1)
 521     set(DISABLE_WATERWATER_NLIST 1)
 522     set(DISABLE_WATER_NLIST 1)
 523 elseif(${GMX_ACCELERATION} STREQUAL "ALTIVEC")
 524     check_include_files(altivec.h HAVE_ALTIVEC_H)
 525     if(HAVE_ALTIVEC_H)
 526         set(GMX_PPC_ALTIVEC 1)
 527     endif(HAVE_ALTIVEC_H)
 528 else(${GMX_ACCELERATION} STREQUAL "NONE")
 529     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_ACCELERATION}. Pick one of auto, none, SSE, Fortran, BlueGene, Power6, ia64, altivec")
 530 endif(${GMX_ACCELERATION} STREQUAL "NONE")
 531
 532
 533
 534
 535
 536
 537
 538 # Process QM/MM Settings
 539 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 540 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 541     set(GMX_QMMM_GAUSSIAN 1)
 542 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 543     set(GMX_QMMM_MOPAC 1)
 544 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 545     set(GMX_QMMM_GAMESS 1)
 546 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 547     set(GMX_QMMM_ORCA 1)
 548 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 549     # nothing to do
 550 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 551     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 552 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 553
 554 # Process FFT library settings - if not OpenMM build
 555 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 556 set(PKG_FFT "")
 557 set(PKG_FFT_LIBS "")
 558 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 559 #    MESSAGE(STATUS "Using external FFT library - fftw3")
 560     if(GMX_DOUBLE)
 561         find_package(FFTW3 REQUIRED)
 562                 include_directories(${FFTW3_INCLUDE_DIR})
 563         set(FFT_LIBRARIES ${FFTW3_LIBRARIES})
 564         set(PKG_FFT "fftw3")
 565     else(GMX_DOUBLE)
 566         find_package(FFTW3F REQUIRED)
 567         include_directories(${FFTW3F_INCLUDE_DIR})
 568         set(FFT_LIBRARIES ${FFTW3F_LIBRARIES})
 569         set(PKG_FFT "fftw3f")
 570     endif(GMX_DOUBLE)
 571
 572     if(NOT FFTW3_FOUND AND NOT FFTW3F_FOUND)
 573         MESSAGE(FATAL_ERROR "Cannot find fftw3 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 574     endif(NOT FFTW3_FOUND AND NOT FFTW3F_FOUND)
 575
 576     set(GMX_FFT_FFTW3 1)
 577
 578 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 579 #    MESSAGE(STATUS "Using external FFT library - fftw2")
 580     if(GMX_DOUBLE)
 581         find_package(FFTW2 REQUIRED)
 582     else(GMX_DOUBLE)
 583         find_package(FFTW2F REQUIRED)
 584     endif(GMX_DOUBLE)
 585
 586     if(NOT FFTW2_FOUND)
 587            MESSAGE(FATAL_ERROR "Cannot find fftw2 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 588     endif(NOT FFTW2_FOUND)
 589     include_directories(${FFTW2_INCLUDE_DIR})
 590     set(FFT_LIBRARIES ${FFTW2_LIBRARIES})
 591     set(PKG_FFT_LIBS ${FFTW2_LIBRARIES})
 592
 593     if("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 594         set(FFTW2_NAME_DFFTW 1)
 595     elseif("${FFTW2_LIBRARIES}" MATCHES "sfftw")
 596         set(FFTW2_NAME_SFFTW 1)
 597     else("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 598         set(FFTW2_NAME_FFTW 1)
 599     endif("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 600
 601     set(GMX_FFT_FFTW2 1)
 602 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 603 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 604     find_package(MKL REQUIRED)
 605     include_directories(${MKL_INCLUDE_DIR})
 606     set(FFT_LIBRARIES ${MKL_LIBRARIES})
 607     set(PKG_FFT_LIBS ${MKL_LIBRARIES})
 608
 609     set(GMX_FFT_MKL 1)
 610     set(HAVE_MKL 1)
 611
 612 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 613 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 614 #    set(GMX_FFT_ACML 1)
 615 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 616     MESSAGE(STATUS "Using internal FFT library - fftpack")
 617     set(GMX_FFT_FFTPACK 1)
 618 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 619     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, fftw2, mkl, acml, fftpack")
 620 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 621
 622 # MKL has BLAS/LAPACK routines
 623 if(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 624   set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 625   set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 626 else(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 627   set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 628   set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 629 endif(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 630 mark_as_advanced(GMX_EXTERNAL_LAPACK)
 631 mark_as_advanced(GMX_EXTERNAL_BLAS)
 632
 633 # Math and thread libraries must often come after all others when linking...
 634 if(HAVE_LIBM)
 635     list(APPEND GMX_EXTRA_LIBRARIES m)
 636 endif(HAVE_LIBM)
 637
 638
 639
 640 if(GMX_FAHCORE)
 641   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 642       "Path to swindirect.h")
 643   include_directories(${COREWRAP_INCLUDE_DIR})
 644 endif(GMX_FAHCORE)
 645
 646 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 647 # these are set after everything else
 648 if (NOT DEFINED GROMACS_C_FLAGS_SET)
 649     set(GROMACS_C_FLAGS_SET true CACHE INTERNAL "Whether to reset the C flags"
 650         FORCE)
 651     set(CMAKE_C_FLAGS "${GROMACS_C_FLAGS} ${CMAKE_C_FLAGS}" CACHE STRING
 652         "Flags used by the compiler during all build types" FORCE)
 653     set(CMAKE_CXX_FLAGS "${GROMACS_CXX_FLAGS} ${CMAKE_CXX_FLAGS}" CACHE STRING
 654         "Flags used by the compiler during all build types" FORCE)
 655     set(CMAKE_EXE_LINKER_FLAGS
 656         "${GROMACS_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}"
 657         CACHE STRING "Linker flags" FORCE)
 658 endif (NOT DEFINED GROMACS_C_FLAGS_SET)
 659
 660 ########################################################################
 661 # Specify install locations and which subdirectories to process        #
 662 ########################################################################
 663 set(LIB_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/lib)
 664 set(BIN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/bin)
 665 set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/gromacs)
 666 set(MAN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/share/man)
 667 set(INCL_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/include)
 668
 669 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
 670
 671 ##################################################################
 672 # Shared library settings - Darwin uses INSTALL_NAME_DIR instead!
 673 ##################################################################
 674 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 675     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
 676     set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 677     set(CMAKE_INSTALL_RPATH "${LIB_INSTALL_DIR}")
 678     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 679 endif()
 680
 681 add_subdirectory(share)
 682 add_subdirectory(include)
 683 add_subdirectory(man)
 684 add_subdirectory(src)
 685 add_subdirectory(scripts)
 686
 687 #######################
 688 ## uninstall target
 689 #######################
 690     CONFIGURE_FILE(
 691                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 692                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 693                    IMMEDIATE @ONLY)
 694 ###########################
 695 ADD_CUSTOM_TARGET(uninstall
 696                   "${CMAKE_COMMAND}" -P
 697                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 698 ###########################
 699
 700
 701 ########################################################################
 702 # Tests                                                                #
 703 ########################################################################
 704
 705 include(CTest)
 706 mark_as_advanced(BUILD_TESTING)
 707 IF(BUILD_TESTING)
 708         enable_testing()
 709         add_test(TestBuildAll make)
 710         add_subdirectory(tests)
 711 ENDIF()
 712