CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8)
   2 # Keep CMake suitably quiet on Cygwin
   3 set(CMAKE_LEGACY_CYGWIN_WIN32 0) # Remove when CMake >= 2.8.4 is required
   4
   5 # override bugs on OS X where Cmake picks gcc (GNU) for C instead of system default cc (Clang).
   6 if(APPLE)
   7     set(CMAKE_C_COMPILER_INIT "cc")
   8 endif(APPLE)
   9
  10 project(Gromacs)
  11 include(Dart)
  12 mark_as_advanced(DART_ROOT)
  13
  14 # PROJECT_VERSION should have the following structure:
  15 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  16 #
  17 # The "-dev" suffix is important to keep because it makes possible to distinguish
  18 # between a build from official release and a build from git release branch on a
  19 # machine with no git.
  20 #
  21 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  22 set(PROJECT_VERSION "4.6-dev")
  23 set(CUSTOM_VERSION_STRING ""
  24     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  25 mark_as_advanced(CUSTOM_VERSION_STRING)
  26 if (CUSTOM_VERSION_STRING)
  27     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  28 endif (CUSTOM_VERSION_STRING)
  29 set(SOVERSION 6)
  30 # It is a bit irritating, but this has to be set separately for now!
  31 SET(CPACK_PACKAGE_VERSION_MAJOR "4")
  32 SET(CPACK_PACKAGE_VERSION_MINOR "6")
  33 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  34
  35
  36 # Cmake modules/macros are in a subdirectory to keep this file cleaner
  37 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  38
  39 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  40 set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  41 endif()
  42
  43 if(NOT CMAKE_BUILD_TYPE)
  44     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
  45 endif(NOT CMAKE_BUILD_TYPE)
  46
  47 enable_language(C)
  48
  49 set(GMX_USE_RELATIVE_INSTALL_PATH OFF CACHE STRING "Use relative paths not absolute paths for cmake install. Has only an effect on cpack.")
  50 mark_as_advanced(GMX_USE_RELATIVE_INSTALL_PATH)
  51
  52 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
  53 set(CPACK_PACKAGE_VENDOR "gromacs.org")
  54 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
  55 if (NOT GMX_USE_RELATIVE_INSTALL_PATH)
  56     set(CPACK_SET_DESTDIR "ON")
  57 endif()
  58 set(CPACK_INCLUDE_TOPLEVEL_DIRECTORY 0)
  59 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
  60 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
  61 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/admin/InstallLicense.txt")
  62 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
  63 set(CPACK_SOURCE_IGNORE_FILES ".isreposource;.git;.gitignore")
  64 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
  65 SET(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/man;man")
  66
  67 #must come after all cpack settings!
  68 include(CPack)
  69
  70 ########################################################################
  71 # Check and warn if cache generated on a different host is being reused
  72 ########################################################################
  73 if(CMAKE_HOST_UNIX)
  74     execute_process(COMMAND hostname
  75                     OUTPUT_VARIABLE TMP_HOSTNAME
  76                     OUTPUT_STRIP_TRAILING_WHITESPACE)
  77     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
  78         message(WARNING "
  79             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
  80             is being reused! This could lead to inconsitencies; therefore, it is
  81             recommended to regenerate the cache!")
  82     endif()
  83     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
  84             "Hostname of the machine where the cache was generated.")
  85 endif()
  86
  87 ########################################################################
  88 # Fix stupid flags on Windows
  89 ########################################################################
  90 SET(SHARED_LIBS_DEFAULT ON)
  91 IF( WIN32 AND NOT CYGWIN)
  92   option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static system libraries (MT instead of MD)!" ON)
  93   mark_as_advanced(GMX_PREFER_STATIC_LIBS)
  94   SET(SHARED_LIBS_DEFAULT OFF)  #is currently not working on Windows
  95
  96   IF (GMX_PREFER_STATIC_LIBS)
  97     #Only setting Debug and Release flags. Others configurations current not used.
  98     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
  99     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
 100     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
 101     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
 102     STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE})
 103     SET(CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE} CACHE STRING "" FORCE)
 104     STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 105     SET(CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG} CACHE STRING "" FORCE)
 106   ENDIF()
 107
 108   #Workaround for cmake bug 13174. Replace deprecated options.
 109   IF( CMAKE_C_COMPILER_ID MATCHES "Intel" )
 110     STRING(REPLACE /GZ /RTC1 CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
 111     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
 112   ENDIF()
 113   IF( CMAKE_CXX_COMPILER_ID MATCHES "Intel" )
 114     STRING(REPLACE /GZ /RTC1 CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 115     STRING(REPLACE /GX /EHsc CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 116     SET(CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG} CACHE STRING "" FORCE)
 117
 118     STRING(REPLACE /GX /EHsc CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE})
 119     SET(CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE} CACHE STRING "" FORCE)
 120   ENDIF()
 121 ENDIF()
 122
 123 ########################################################################
 124 # User input options                                                   #
 125 ########################################################################
 126 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 127 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 128 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 129 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 130 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 131 option(GMX_POWERPC_INVSQRT "Use PowerPC hardware 1/sqrt" OFF)
 132 mark_as_advanced(GMX_POWERPC_INVSQRT)
 133 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 134 mark_as_advanced(GMX_FAHCORE)
 135 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library (rerun cmake after changing to see relevant options)" OFF)
 136
 137 include(gmxDetectAcceleration)
 138 if(NOT DEFINED GMX_ACCELERATION)
 139     if(CMAKE_CROSSCOMPILING)
 140         set(GMX_SUGGESTED_ACCELERATION "None")
 141     else(CMAKE_CROSSCOMPILING)
 142         gmx_detect_acceleration(GMX_SUGGESTED_ACCELERATION)
 143     endif(CMAKE_CROSSCOMPILING)
 144 endif(NOT DEFINED GMX_ACCELERATION)
 145
 146 set(GMX_ACCELERATION "@GMX_SUGGESTED_ACCELERATION@"
 147     CACHE STRING "Accelerated kernels. Pick one of: None, SSE2, SSE4.1, AVX_128_FMA, AVX_256, BlueGene, Power6, Fortran")
 148
 149 set(GMX_FFT_LIBRARY "fftw3"
 150     CACHE STRING "FFT library choices: fftw3,mkl,fftpack[built-in]")
 151 option(GMX_DISABLE_FFTW_MEASURE
 152        "Do not optimize FFTW setups (not needed with SSE)" OFF)
 153 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 154 set(GMX_QMMM_PROGRAM "none"
 155     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
 156 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 157 mark_as_advanced(GMX_BROKEN_CALLOC)
 158 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
 159 mark_as_advanced(GMX_MPI_IN_PLACE)
 160 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 161 mark_as_advanced(GMX_LOAD_PLUGINS)
 162
 163 option(GMX_OPENMP "Enable OpenMP-based mutithreading. " ON)
 164
 165 option(USE_VERSION_H "Generate development version string/information" ON)
 166 mark_as_advanced(USE_VERSION_H)
 167
 168 option(GMX_DEFAULT_SUFFIX "Use default suffixes for GROMACS binaries and libs (_d for double, _mpi for MPI; rerun cmake after changing to see relevant options)" ON)
 169
 170 if(UNIX AND NOT APPLE)
 171     option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer \".a\" static archives (NOTE: this is enabled only for UNIX (excluding APPLE) platforms but it might not always work!" OFF)
 172     mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 173 endif()
 174
 175
 176 ######################################################################
 177 # compiler tests
 178 # these need ot be done early (before further tests).
 179 #####################################################################
 180
 181 # cmake/Check{C,CXX}CompilerFlag.cmake are lifted from CMake git next
 182 # branch (proposed for v2.8.9) to be able to detect invalid options
 183 # with the Intel Compilers.
 184 # Remove these files from the source tree when a CMake version that
 185 # includes the features in question becomes required.
 186 include(CheckCCompilerFlag)
 187 include(CheckCXXCompilerFlag)
 188
 189 # OpenMP check must come before other CFLAGS!
 190 if(GMX_OPENMP)
 191     find_package(OpenMP)
 192     if(OPENMP_FOUND)
 193         set(GROMACS_C_FLAGS "${OpenMP_C_FLAGS} ${GROMACS_C_FLAGS}")
 194         set(GROMACS_CXX_FLAGS "${OpenMP_CXX_FLAGS} ${GROMACS_CXX_FLAGS}")
 195     else(OPENMP_FOUND)
 196         message(WARNING
 197                 "Compiler not supporting OpenMP. This might hurt your performance a lot, "
 198                 "in particular with GPUs. Try using a different compiler (Intel is good on x86) "
 199                 "if you can - for now we are proceeding by turning off OpenMP.")
 200         set(GMX_OPENMP OFF CACHE STRING "Compiler does not support OpenMP." FORCE)
 201     endif(OPENMP_FOUND)
 202 endif()
 203
 204
 205 include(gmxCFlags)
 206 gmx_c_flags()
 207
 208 ########################################################################
 209 # Set up binary and library suffixing
 210 ########################################################################
 211 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 212 set(GMX_LIBS_SUFFIX ""
 213   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 214 if (GMX_DEFAULT_SUFFIX)
 215   set(GMX_BINARY_SUFFIX "")
 216   set(GMX_LIBS_SUFFIX "")
 217   if (GMX_MPI)
 218     set(GMX_BINARY_SUFFIX "_mpi")
 219     set(GMX_LIBS_SUFFIX "_mpi")
 220   endif(GMX_MPI)
 221   if (GMX_DOUBLE)
 222     set (GMX_BINARY_SUFFIX "${GMX_BINARY_SUFFIX}_d")
 223     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
 224   endif(GMX_DOUBLE)
 225   if (GMX_OPENMM)
 226     set (GMX_BINARY_SUFFIX "-openmm")
 227     set (GMX_LIBS_SUFFIX "_openmm")
 228   endif(GMX_OPENMM)
 229   mark_as_advanced(FORCE GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 230   if (NOT SUFFIX_QUIETLY)
 231     message(STATUS "Using default binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 232     message(STATUS "Using default library suffix: \"${GMX_LIBS_SUFFIX}\"")
 233   endif (NOT SUFFIX_QUIETLY)
 234 else(GMX_DEFAULT_SUFFIX)
 235   mark_as_advanced(CLEAR GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 236   if (NOT SUFFIX_QUIETLY)
 237     message(STATUS "Using manually set binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 238     message(STATUS "Using manually set library suffix: \"${GMX_LIBS_SUFFIX}\"")
 239   endif (NOT SUFFIX_QUIETLY)
 240 endif(GMX_DEFAULT_SUFFIX)
 241 set(SUFFIX_QUIETLY TRUE CACHE INTERNAL "")
 242
 243 set(PKG_CFLAGS "")
 244 if(GMX_DOUBLE)
 245     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 246 endif(GMX_DOUBLE)
 247 if(GMX_SOFTWARE_INVSQRT)
 248   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 249 endif(GMX_SOFTWARE_INVSQRT)
 250 if(GMX_POWERPC_INVSQRT)
 251   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_POWERPC_INVSQRT")
 252 endif(GMX_POWERPC_INVSQRT)
 253
 254 ########################################################################
 255 #Process MPI settings
 256 ########################################################################
 257 include(gmxManageMPI)
 258
 259 #######################################################################
 260 # Check for options incompatible with OpenMM build                    #
 261 #######################################################################
 262 if(GMX_OPENMM)
 263     # we'll use the built-in fft to avoid unnecessary dependencies
 264     string(TOUPPER ${GMX_FFT_LIBRARY} GMX_FFT_LIBRARY)
 265     if(NOT ${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 266         message(STATUS "No external FFT libraries needed for the OpenMM build, switching to fftpack!")
 267         set(GMX_FFT_LIBRARY "fftpack" CACHE STRING
 268                 "No external FFT libraries needed for the OpenMM build, switching to  fftpack!" FORCE)
 269     endif()
 270     if(GMX_MPI)
 271         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
 272     endif(GMX_MPI)
 273     if(GMX_THREAD_MPI)
 274         message(STATUS "Thread-MPI not compatible with OpenMM, disabled!")
 275         set(GMX_THREAD_MPI OFF CACHE BOOL
 276                 "Thread-MPI not compatible with OpenMM build, disabled!" FORCE)
 277     endif(GMX_THREAD_MPI)
 278     if(GMX_OPENMP)
 279         message(STATUS "OpenMP multithreading not compatible with OpenMM, disabled")
 280         set(GMX_OPENMP OFF CACHE BOOL
 281             "OpenMP multithreading not compatible with OpenMM, disabled!" FORCE)
 282     endif()
 283     if(GMX_SOFTWARE_INVSQRT)
 284         set(GMX_SOFTWARE_INVSQRT OFF CACHE STRING
 285                 "The OpenMM build does not need GROMACS software 1/sqrt!" FORCE)
 286     endif(GMX_SOFTWARE_INVSQRT)
 287     string(TOUPPER ${GMX_ACCELERATION} GMX_ACCELERATION)
 288     if(NOT GMX_ACCELERATION STREQUAL "NONE")
 289         message(STATUS "Switching off CPU-based acceleration, the OpenMM build does not support/need any!")
 290         set(GMX_ACCELERATION "none" CACHE STRING
 291                 "Switching off CPU-based acceleration, the OpenMM build does not support/need any!" FORCE)
 292     endif()
 293     if(GMX_FAHCORE)
 294         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
 295     endif(GMX_FAHCORE)
 296     if(GMX_DOUBLE)
 297         message(FATAL_ERROR  "The OpenMM-build does not support double precision calculations!")
 298     endif()
 299     # mark as advanced the unused variables
 300     mark_as_advanced(FORCE GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 301         GMX_QMMM_PROGRAM GMX_THREAD_MPI GMX_DOUBLE)
 302 else(GMX_OPENMM)
 303      mark_as_advanced(CLEAR GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 304         GMX_QMMM_PROGRAM GMX_THREAD_MPI GMX_DOUBLE)
 305 endif(GMX_OPENMM)
 306
 307
 308
 309
 310 ########################################################################
 311 # Basic system tests (standard libraries, headers, functions, types)   #
 312 ########################################################################
 313 include(CheckIncludeFiles)
 314 check_include_files(string.h     HAVE_STRING_H)
 315 check_include_files(math.h       HAVE_MATH_H)
 316 check_include_files(limits.h     HAVE_LIMITS_H)
 317 check_include_files(memory.h     HAVE_MEMORY_H)
 318 check_include_files(unistd.h     HAVE_UNISTD_H)
 319 check_include_files(direct.h     HAVE_DIRECT_H)
 320 check_include_files(pwd.h        HAVE_PWD_H)
 321 check_include_files(stdint.h     HAVE_STDINT_H)
 322 check_include_files(stdlib.h     HAVE_STDLIB_H)
 323 check_include_files(pthread.h    HAVE_PTHREAD_H)
 324 check_include_files(dirent.h     HAVE_DIRENT_H)
 325 check_include_files(inttypes.h   HAVE_INTTYPES_H)
 326 check_include_files(regex.h      HAVE_REGEX_H)
 327 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 328 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
 329 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 330 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
 331 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
 332 check_include_files(io.h                 HAVE_IO_H)
 333
 334
 335 include(CheckFunctionExists)
 336 check_function_exists(strcasecmp        HAVE_STRCASECMP)
 337 check_function_exists(strdup            HAVE_STRDUP)
 338 check_function_exists(vprintf           HAVE_VPRINTF)
 339 check_function_exists(memcmp            HAVE_MEMCMP)
 340 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 341 check_function_exists(memalign          HAVE_MEMALIGN)
 342 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 343 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 344 check_function_exists(isnan             HAVE_ISNAN)
 345 check_function_exists(_isnan            HAVE__ISNAN)
 346 check_function_exists(fsync             HAVE_FSYNC)
 347 check_function_exists(_fileno           HAVE__FILENO)
 348 check_function_exists(fileno            HAVE_FILENO)
 349 check_function_exists(_commit           HAVE__COMMIT)
 350 check_function_exists(lstat             HAVE_LSTAT)
 351 check_function_exists(sigaction         HAVE_SIGACTION)
 352
 353 include(CheckLibraryExists)
 354 check_library_exists(m sqrt "" HAVE_LIBM)
 355 check_library_exists(m cbrt "" HAVE_CBRT)
 356
 357
 358 include(CheckTypeSize)
 359
 360 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 361 check_type_size("int"           SIZEOF_INT)
 362 check_type_size("long int"      SIZEOF_LONG_INT)
 363 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 364 check_type_size("off_t"         SIZEOF_OFF_T)
 365 check_type_size("void *"        SIZEOF_VOIDP)
 366
 367 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 368     set(GMX_64_BIT TRUE)
 369 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 370     set(GMX_64_BIT FALSE)
 371 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 372
 373 # Check for some basic types that we *need*, so set these to int if they are not present
 374 check_type_size(uid_t uid_t)
 375 if(NOT uid_t)
 376   set(uid_t int)
 377 else(NOT uid_t)
 378   set(uid_t 0)
 379 endif(NOT uid_t)
 380
 381 check_type_size(gid_t gid_t)
 382 if(NOT gid_t)
 383   set(gid_t 1)
 384 else(NOT gid_t)
 385   set(gid_t 0)
 386 endif(NOT gid_t)
 387
 388 check_type_size(size_t size_t)
 389 if(NOT size_t)
 390   set(size_t int)
 391 else(NOT size_t)
 392   set(size_t 0)
 393 endif(NOT size_t)
 394
 395 check_type_size(off_t off_t)
 396 if(NOT off_t)
 397   set(off_t int)
 398 else(NOT off_t)
 399   set(off_t 0)
 400 endif(NOT off_t)
 401
 402 include(TestBigEndian)
 403 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 404
 405
 406
 407
 408 ########################################################################
 409 # Find external packages                                               #
 410 ########################################################################
 411 if(UNIX AND NOT APPLE)
 412     if(GMX_PREFER_STATIC_LIBS)
 413         SET(CMAKE_FIND_LIBRARY_SUFFIXES .a ${CMAKE_FIND_LIBRARY_SUFFIXES})
 414         if(SHARED_LIBS_DEFAULT)
 415             if(BUILD_SHARED_LIBS) #Warn the user about the combination. But don't overwrite the request.
 416                 message(WARNING "Static libraries requested, and shared Gromacs libraries requested.")
 417             elseif(NOT DEFINED BUILD_SHARED_LIBS) #Change default to OFF. Don't warn if it's already off.
 418                 message(WARNING "Static libraries requested, the GROMACS libraries will also be build static (BUILD_SHARED_LIBS=OFF)")
 419                 set(SHARED_LIBS_DEFAULT OFF)
 420             endif()
 421         endif()
 422     endif()
 423 endif()
 424 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI, Windows)" ${SHARED_LIBS_DEFAULT})
 425
 426 option(GMX_XML "Use libxml2 to parse xml files" ON)
 427 if (GMX_XML)
 428   find_package(LibXml2)
 429   set(PKG_XML "")
 430   if(LIBXML2_FOUND)
 431     include_directories(${LIBXML2_INCLUDE_DIR})
 432     set(PKG_XML libxml-2.0)
 433     set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 434     set(HAVE_LIBXML2 1)
 435   endif(LIBXML2_FOUND)
 436 endif(GMX_XML)
 437
 438 option(GMX_GSL "Add support for gsl" OFF)
 439 if (GMX_GSL)
 440   find_package(gsl)
 441   set(PKG_GSL "")
 442   if(GSL_FOUND)
 443     include_directories(${GSL_INCLUDE_DIR})
 444     set(PKG_GSL gsl)
 445     set(HAVE_LIBGSL 1)
 446   endif(GSL_FOUND)
 447 endif (GMX_GSL)
 448
 449 option(GMX_X11 "Use X window system" OFF)
 450 if (GMX_X11)
 451         find_package(X11)
 452         # X11 includes/libraries are only set in the ngmx subdirectory!
 453         if(X11_FOUND)
 454         set(HAVE_X11 1)
 455         endif(X11_FOUND)
 456 endif(GMX_X11)
 457
 458 if(GMX_THREAD_MPI)
 459     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREAD_MPI")
 460     include(ThreadMPI)
 461     set(THREAD_MPI_LIB thread_mpi)
 462     set(GMX_MPI 1)
 463     string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 464 endif(GMX_THREAD_MPI)
 465
 466 if(GMX_OPENMM)
 467     set(CUDA_BUILD_EMULATION OFF)
 468     find_package(CUDA 3.1 REQUIRED)
 469     add_definitions(-DGMX_OPENMM)
 470     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 471         set(CUDA_VERBOSE_BUILD ON)
 472     endif()
 473     find_package(OpenMM)
 474 endif(GMX_OPENMM)
 475
 476
 477 if(APPLE)
 478    find_library(ACCELERATE_FRAMEWORK Accelerate)
 479    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 480 endif(APPLE)
 481
 482 if(CYGWIN)
 483     set(GMX_CYGWIN 1)
 484 endif(CYGWIN)
 485
 486 if(WIN32 AND NOT CYGWIN)
 487     set(GMX_NATIVE_WINDOWS 1)
 488 endif()
 489
 490 # only bother with finding git and using version.h if the source is a git repo
 491 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 492     if(USE_VERSION_H)
 493         # We need at least git v1.5.3 be able to parse git's date output. If not
 494         # found or the version is too small, we can't generate version information.
 495         find_package(Git)
 496
 497         # Find out the git version
 498         if(GIT_FOUND AND NOT GIT_VERSION)
 499           execute_process(COMMAND ${GIT_EXECUTABLE} "--version"
 500             OUTPUT_VARIABLE _exec_out
 501             OUTPUT_STRIP_TRAILING_WHITESPACE)
 502           string(REGEX REPLACE "git version (.*)" "\\1" GIT_VERSION ${_exec_out})
 503           set(GIT_VERSION ${GIT_VERSION} CACHE STRING "Git version")
 504           mark_as_advanced(GIT_VERSION)
 505         endif()
 506
 507         if(NOT GIT_FOUND OR GIT_VERSION VERSION_LESS "1.5.3")
 508           message("No compatible git version found, won't be able to generate proper development version information.")
 509           set(USE_VERSION_H OFF)
 510         endif()
 511     endif()
 512 else()
 513     set(USE_VERSION_H OFF)
 514 endif()
 515
 516 ########################################################################
 517 # Generate development version info for cache
 518 ########################################################################
 519 # set(GEN_VERSION_INFO_INTERNAL "ON")
 520 # include(gmxGenerateVersionString)
 521
 522 ########################################################################
 523 # Our own GROMACS tests
 524 ########################################################################
 525
 526 add_definitions( -DHAVE_CONFIG_H )
 527 include_directories(${CMAKE_BINARY_DIR}/src)
 528 include_directories(${CMAKE_BINARY_DIR}/include)
 529 include_directories(${CMAKE_SOURCE_DIR}/include)
 530
 531 include(gmxTestInlineASM)
 532 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 533
 534 include(gmxSetBuildInformation)
 535 gmx_set_build_information()
 536 if(BUILD_CPU_FEATURES MATCHES "rdtscp")
 537     # The timestep counter headers do not include config.h
 538     add_definitions(-DHAVE_RDTSCP)
 539 endif(BUILD_CPU_FEATURES MATCHES "rdtscp")
 540
 541 include(gmxTestFloatFormat)
 542 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 543                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 544                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 545
 546 include(gmxTestLargeFiles)
 547 gmx_test_large_files(GMX_LARGEFILES)
 548 check_function_exists(fseeko     HAVE_FSEEKO)
 549
 550 include(gmxTestSignal)
 551 gmx_test_sigusr1(HAVE_SIGUSR1)
 552
 553 include(gmxTestInline)
 554 gmx_test_inline(INLINE_KEYWORD)
 555
 556 include(gmxTestRestrict)
 557 gmx_test_inline(RESTRICT_KEYWORD)
 558
 559 include(gmxTestPipes)
 560 gmx_test_pipes(HAVE_PIPES)
 561
 562 include(gmxTestIsfinite)
 563 gmx_test_isfinite(HAVE_ISFINITE)
 564 gmx_test__isfinite(HAVE__ISFINITE)
 565 gmx_test__finite(HAVE__FINITE)
 566
 567 include(gmxTestXDR)
 568 gmx_test_xdr(GMX_SYSTEM_XDR)
 569 if(NOT GMX_SYSTEM_XDR)
 570     set(GMX_INTERNAL_XDR 1)
 571     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 572 endif(NOT GMX_SYSTEM_XDR)
 573
 574 # Process nonbonded accelerated kernels settings
 575 string(TOUPPER ${GMX_ACCELERATION} ${GMX_ACCELERATION})
 576 if(${GMX_ACCELERATION} STREQUAL "NONE")
 577     # nothing to do
 578 elseif(${GMX_ACCELERATION} STREQUAL "SSE2")
 579
 580     GMX_TEST_CFLAG(GNU_SSE2_CFLAG "-msse2" GROMACS_C_FLAGS)
 581     if(NOT GNU_SSE2_CFLAG)
 582         GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" GROMACS_C_FLAGS)
 583     endif(NOT GNU_SSE2_CFLAG)
 584
 585     GMX_TEST_CXXFLAG(GNU_SSE2_CXXFLAG "-msse2" GROMACS_CXX_FLAGS)
 586     if(NOT GNU_SSE2_CXXFLAG)
 587         GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" GROMACS_CXX_FLAGS)
 588     endif(NOT GNU_SSE2_CXXFLAG)
 589
 590     # We dont warn for lacking SSE2 flag support, since that is probably standard today.
 591
 592     # Only test the include after we have tried to add the correct flag for SSE2 support
 593     check_include_file(emmintrin.h  HAVE_EMMINTRIN_H ${GROMACS_C_FLAGS})
 594
 595     if(NOT HAVE_EMMINTRIN_H)
 596         message(FATAL_ERROR "Cannot find emmintrin.h, which is required for SSE2 intrinsics support.")
 597     endif(NOT HAVE_EMMINTRIN_H)
 598
 599     # The user should not be able to set this orthogonally to the acceleration
 600     set(GMX_X86_SSE2 1)
 601     if (NOT ACCELERATION_QUIETLY)
 602       message(STATUS "Enabling SSE2 Gromacs acceleration, and it will help compiler optimization.")
 603     endif()
 604
 605 elseif(${GMX_ACCELERATION} STREQUAL "SSE4.1")
 606
 607     GMX_TEST_CFLAG(GNU_SSE4_CFLAG "-msse4.1" GROMACS_C_FLAGS)
 608     if (NOT GNU_SSE4_CFLAG)
 609         GMX_TEST_CFLAG(MSVC_SSE4_CFLAG "/arch:SSE4.1" GROMACS_C_FLAGS)
 610     endif(NOT GNU_SSE4_CFLAG)
 611     if (NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 612         message(WARNING "No C SSE4.1 flag found. Consider a newer compiler, or disable SSE4.1 for slightly lower performance.")
 613         # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 614         # intrinsics when SSE2 support is enabled, so we try that instead.
 615         GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" GROMACS_C_FLAGS)
 616     endif(NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 617
 618     GMX_TEST_CXXFLAG(GNU_SSE4_CXXFLAG "-msse4.1" GROMACS_CXX_FLAG)
 619     if (NOT GNU_SSE4_CXXFLAG)
 620        GMX_TEST_CXXFLAG(MSVC_SSE4_CXXFLAG "/arch:SSE4.1" GROMACS_CXX_FLAGS)
 621     endif(NOT GNU_SSE4_CXXFLAG)
 622     if (NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 623         message(WARNING "No C++ SSE4.1 flag found. Consider a newer compiler, or disable SSE4.1 for slightly lower performance.")
 624         # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 625         # intrinsics when SSE2 support is enabled, so we try that instead.
 626         GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" GROMACS_CXX_FLAGS)
 627     endif(NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 628
 629     # This must come after we have added the -msse4.1 flag on some platforms.
 630     check_include_file(smmintrin.h  HAVE_SMMINTRIN_H ${GROMACS_C_FLAGS})
 631
 632     if(NOT HAVE_SMMINTRIN_H)
 633         message(FATAL_ERROR "Cannot find smmintrin.h, which is required for SSE4.1 intrinsics support.")
 634     endif(NOT HAVE_SMMINTRIN_H)
 635
 636     # The user should not be able to set this orthogonally to the acceleration
 637     set(GMX_X86_SSE4_1 1)
 638     set(GMX_X86_SSE2   1)
 639     if (NOT ACCELERATION_QUIETLY)
 640       message(STATUS "Enabling SSE4.1 Gromacs acceleration, and it will help compiler optimization.")
 641     endif()
 642
 643 elseif(${GMX_ACCELERATION} STREQUAL "AVX_128_FMA" OR ${GMX_ACCELERATION} STREQUAL "AVX_256")
 644
 645     # Set the AVX compiler flag for both these choices!
 646
 647     GMX_TEST_CFLAG(GNU_AVX_CFLAG "-mavx" GROMACS_C_FLAGS)
 648     if (NOT GNU_AVX_CFLAG)
 649         GMX_TEST_CFLAG(MSVC_AVX_CFLAG "/arch:AVX" GROMACS_C_FLAGS)
 650     endif (NOT GNU_AVX_CFLAG)
 651     if (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 652         message(WARNING "No C AVX flag found. Consider a newer compiler, or disable AVX for much lower performance.")
 653     endif (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 654
 655     GMX_TEST_CXXFLAG(GNU_AVX_CXXFLAG "-mavx" GROMACS_CXX_FLAGS)
 656     if (NOT GNU_AVX_CXXFLAG)
 657        GMX_TEST_CXXFLAG(MSVC_AVX_CXXFLAG "/arch:AVX" GROMACS_CXX_FLAGS)
 658     endif (NOT GNU_AVX_CXXFLAG)
 659     if (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 660        message(WARNING "No C++ AVX flag found. Consider a newer compiler, or disable AVX for much lower performance.")
 661     endif (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 662
 663     # Only test the header after we have tried to add the flag for AVX support
 664     check_include_file(immintrin.h  HAVE_IMMINTRIN_H ${GROMACS_C_FLAGS})
 665
 666     if(NOT HAVE_IMMINTRIN_H)
 667         message(FATAL_ERROR "Cannot find immintrin.h, which is required for AVX intrinsics support. Consider switching compiler.")
 668     endif(NOT HAVE_IMMINTRIN_H)
 669
 670     # AMD says we should include x86intrin.h for FMA support, but MSVC seems to do fine without it, so don't require it.
 671     check_include_file(x86intrin.h HAVE_X86INTRIN_H ${GROMACS_C_FLAGS})
 672
 673     # The user should not be able to set this orthogonally to the acceleration
 674     set(GMX_X86_SSE4_1 1)
 675     set(GMX_X86_SSE2   1)
 676
 677     # But just enable one of the choices internally...
 678     if(${GMX_ACCELERATION} STREQUAL "AVX_128_FMA")
 679         set(GMX_X86_AVX_128_FMA 1)
 680         if (NOT ACCELERATION_QUIETLY)
 681           message(STATUS "Enabling 128-bit AVX Gromacs acceleration (with fused-multiply add), and it will help compiler optimization.")
 682         endif()
 683     else()
 684         # If we are not doing AVX_128, it must be AVX_256...
 685         set(GMX_X86_AVX_256 1)
 686         if (NOT ACCELERATION_QUIETLY)
 687           message(STATUS "Enabling 256-bit AVX Gromacs acceleration, and it will help compiler optimization.")
 688         endif()
 689     endif()
 690
 691 elseif(${GMX_ACCELERATION} STREQUAL "FORTRAN")
 692
 693 #    Fortran is temporarily disabled while we push in nbNxN kernels.
 694 #    We need to fake it a bit here to avoid jenkins build errors!
 695 #    add_definitions(-DGMX_FORTRAN)
 696
 697 elseif(${GMX_ACCELERATION} STREQUAL "BLUEGENE")
 698 # GMX_ACCELERATION=BlueGene should be set in the Toolchain-BlueGene?-???.cmake file
 699     if (NOT ACCELERATION_QUIETLY)
 700       message(STATUS "Configuring for BlueGene")
 701     endif()
 702     set(GMX_BLUEGENE 1)
 703     if (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 704         set(SHARED_LIBS_DEFAULT OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 705         set(BUILD_SHARED_LIBS OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 706     endif (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 707     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on BlueGene" FORCE)
 708     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on BlueGene" FORCE)
 709     set(GMX_X11 OFF CACHE BOOL "X11 not compatible with BlueGene, disabled!" FORCE)
 710     set(GMX_THREAD_MPI OFF CACHE BOOL "Thread-MPI not compatible with BlueGene, disabled!" FORCE)
 711     set(GMX_MPI ON CACHE BOOL "Use MPI on BlueGene" FORCE)
 712 # Access to /etc/passwd is not available on the back end of BlueGene,
 713 # despite being detected by CMake. This can cause linker warnings
 714 # about harmless things in src/gmxlib/string2.h.
 715     set(HAVE_PWD_H OFF)
 716 # The automatic testing for endianness does not work for the BlueGene cross-compiler
 717     set(GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER 1 CACHE INTERNAL "BlueGene has big endian FP byte order (by default)" FORCE)
 718     set(GMX_IEEE754_BIG_ENDIAN_WORD_ORDER 1 CACHE INTERNAL "BlueGene has big endian FP word order (by default)" FORCE)
 719 elseif(${GMX_ACCELERATION} STREQUAL "POWER6")
 720     set(GMX_POWER6 1)
 721     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on Power6" FORCE)
 722     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on Power6" FORCE)
 723 else(${GMX_ACCELERATION} STREQUAL "NONE")
 724     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_ACCELERATION}. Pick one of None, SSE2, SSE4.1, AVX_128_FMA, AVX_256, Fortran, BlueGene, Power6")
 725 endif(${GMX_ACCELERATION} STREQUAL "NONE")
 726 set(ACCELERATION_QUIETLY TRUE CACHE INTERNAL "")
 727
 728 if(GMX_FORTRAN OR GMX_POWER6)
 729     if (GMX_THREAD_MPI)
 730         message(FATAL_ERROR "FORTRAN/POWER6 is incompatible with thread-MPI and only provides a speed-up on certain IBM compilers. Disable FORTRAN (or threads if you really want to use FORTRAN kernels).")
 731     endif(GMX_THREAD_MPI)
 732     enable_language(Fortran)
 733     include(FortranCInterface)
 734     discover_fortran_mangling(prefix isupper suffix extra_under_score found)
 735     if(extra_under_score)
 736         set(extrasuffix "_")
 737     endif(extra_under_score)
 738     if(prefix)
 739       set(prefix "${prefix} ##")
 740     endif(prefix)
 741     if(suffix)
 742       set(suffix "## ${suffix}")
 743       if(extrasuffix)
 744         set(extrasuffix "${suffix}${extrasuffix}")
 745       endif(extrasuffix)
 746     else(suffix)
 747       if(extrasuffix)
 748         # Don't know if this is needed, but it can't hurt
 749         set(extrasuffix "## ${extrasuffix}")
 750       endif(extrasuffix)
 751     endif(suffix)
 752
 753     if(isupper)
 754         set(F77_FUNCDEF   "${prefix} NAME ${suffix}")
 755         set(F77_FUNCDEF_  "${prefix} NAME ${extrasuffix}")
 756     else(isupper)
 757         set(F77_FUNCDEF   "${prefix} name ${suffix}")
 758         set(F77_FUNCDEF_  "${prefix} name ${extrasuffix}")
 759     endif(isupper)
 760 else(GMX_FORTRAN OR GMX_POWER6)
 761         set(F77_FUNCDEF   "name ## _")
 762         set(F77_FUNCDEF_  "name ## _")
 763 endif(GMX_FORTRAN OR GMX_POWER6)
 764
 765 # Process QM/MM Settings
 766 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 767 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 768     set(GMX_QMMM_GAUSSIAN 1)
 769 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 770     set(GMX_QMMM_MOPAC 1)
 771 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 772     set(GMX_QMMM_GAMESS 1)
 773 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 774     set(GMX_QMMM_ORCA 1)
 775 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 776     # nothing to do
 777 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 778     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 779 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 780
 781 # Process FFT library settings - if not OpenMM build
 782 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 783 set(PKG_FFT "")
 784 set(PKG_FFT_LIBS "")
 785 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 786     if(GMX_DOUBLE)
 787         find_package(FFTW 3 COMPONENTS fftw)
 788     else(GMX_DOUBLE)
 789         find_package(FFTW 3 COMPONENTS fftwf)
 790     endif(GMX_DOUBLE)
 791     if(NOT FFTW_FOUND)
 792       MESSAGE(FATAL_ERROR "Cannot find FFTW3 (with correct precision - libfftw3f for single precision GROMACS or libfftw3 for double precision GROMACS). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 793     endif(NOT FFTW_FOUND)
 794     include_directories(${FFTW_INCLUDE_DIRS})
 795     set(FFT_LIBRARIES ${FFTW_LIBRARIES})
 796     set(PKG_FFT "${FFTW_PKG}")
 797
 798     set(GMX_FFT_FFTW3 1)
 799
 800     if (${GMX_ACCELERATION} STREQUAL "SSE" AND NOT FFTW_HAVE_SSE)
 801       message(WARNING "The fftw library found is compiled without SSE support, which makes it slow. Consider recompiling it or contact your admin")
 802     endif (${GMX_ACCELERATION} STREQUAL "SSE" AND NOT FFTW_HAVE_SSE)
 803
 804 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 805 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 806     find_package(MKL REQUIRED)
 807     include_directories(${MKL_INCLUDE_DIR})
 808     set(FFT_LIBRARIES ${MKL_LIBRARIES})
 809     set(PKG_FFT_LIBS ${MKL_LIBRARIES})
 810
 811     set(GMX_FFT_MKL 1)
 812     set(HAVE_MKL 1)
 813
 814 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 815 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 816 #    set(GMX_FFT_ACML 1)
 817 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 818     MESSAGE(STATUS "Using internal FFT library - fftpack")
 819     set(GMX_FFT_FFTPACK 1)
 820 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 821     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, mkl, fftpack")
 822 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 823
 824 set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 825 set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 826 # MKL has BLAS/LAPACK routines
 827 if(NOT HAVE_MKL AND NOT ACCELERATE_FRAMEWORK)
 828   if(GMX_EXTERNAL_BLAS)
 829     if (GMX_BLAS_USER)
 830         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_BLAS_USER})
 831     else(GMX_BLAS_USER)
 832         set(BLAS_FIND_QUIETLY ON)
 833         find_package(BLAS)
 834         if (BLAS_FOUND)
 835           list(APPEND GMX_EXTRA_LIBRARIES ${BLAS_LIBRARIES})
 836         else()
 837           MESSAGE(STATUS "Using internal BLAS library")
 838           set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external BLAS instead of built-in" FORCE)
 839         endif()
 840     endif(GMX_BLAS_USER)
 841   endif(GMX_EXTERNAL_BLAS)
 842   if(GMX_EXTERNAL_LAPACK)
 843     if (GMX_LAPACK_USER)
 844         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_LAPACK_USER})
 845     else(GMX_LAPACK_USER)
 846         set(LAPACK_FIND_QUIETLY ON)
 847         find_package(LAPACK)
 848         if (LAPACK_FOUND)
 849           list(APPEND GMX_EXTRA_LIBRARIES ${LAPACK_LIBRARIES})
 850         else()
 851           MESSAGE(STATUS "Using internal LAPACK library")
 852           set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in" FORCE)
 853         endif()
 854     endif(GMX_LAPACK_USER)
 855   endif(GMX_EXTERNAL_LAPACK)
 856 endif()
 857 mark_as_advanced(GMX_EXTERNAL_LAPACK)
 858 mark_as_advanced(GMX_EXTERNAL_BLAS)
 859
 860 set(GMX_USE_PLUGINS OFF CACHE INTERNAL "Whether GROMACS will really try to compile support for VMD plugins")
 861 set(GMX_VMD_PLUGIN_PATH)
 862 mark_as_advanced(GMX_VMD_PLUGIN_PATH)
 863
 864 if(GMX_LOAD_PLUGINS)
 865   if(CYGWIN OR NOT WIN32)
 866     # Native Windows does not have, nor need dlopen
 867     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 868     include(gmxTestdlopen)
 869     gmx_test_dlopen(HAVE_DLOPEN)
 870   endif()
 871
 872   find_package(VMD)
 873
 874   # Test for unsuitable versions of VMD
 875
 876   if(VMD_FOUND AND NOT GMX_VMD_PLUGIN_PATH)
 877     message(STATUS "Checking for suitable VMD version")
 878     exec_program(${VMD_EXECUTABLE}
 879       ARGS --help
 880       OUTPUT_VARIABLE VMD_HELP
 881       RETURN_VALUE VMD_EXEC_RETURN)
 882
 883     if(VMD_EXEC_RETURN EQUAL 0)
 884       # This is the accepted idiom for subexpression matching, unfortunately
 885       string(REGEX REPLACE ".*VMD for .*, version ([0-9]+\\.[0-9]*\\.?[0-9]*).*" "\\1" VMD_VERSION ${VMD_HELP})
 886       string(REGEX REPLACE ".*VMD for (.*), version .*" "\\1" VMD_ARCH ${VMD_HELP})
 887
 888       if(VMD_VERSION VERSION_LESS "1.8")
 889         MESSAGE(WARNING "Found VMD version ${VMD_VERSION}, but GROMACS needs at least 1.8")
 890         unset(VMD_EXECUTABLE)
 891         set(VMD_FOUND FALSE)
 892       else()
 893         message(STATUS "VMD version ${VMD_VERSION} is suitable")
 894         if(DEFINED ENV{VMDDIR})
 895           # This permits GROMACS to avoid hard-coding a fall-back
 896           # path that it can tell right now would be useless.
 897           set(GMX_VMD_PLUGIN_PATH "$ENV{VMDDIR}/plugins/${VMD_ARCH}/molfile" CACHE PATH "Path to VMD plugins for molfile I/O")
 898         else()
 899           set(GMX_VMD_PLUGIN_PATH "/usr/local/lib/vmd/plugins/*/molfile" CACHE PATH "Path to VMD plugins for molfile I/O")
 900         endif()
 901       endif()
 902
 903       # clean up
 904       unset(VMD_HELP)
 905       unset(VMD_VERSION)
 906       unset(VMD_ARCH)
 907     endif()
 908   endif()
 909
 910   # so, should we use plug-ins?
 911   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 912     if (NOT VMD_QUIETLY)
 913       MESSAGE(STATUS "Found the ability to use plug-ins when building shared libaries, so will compile to use plug-ins (e.g. to read VMD-supported file formats).")
 914     endif(NOT VMD_QUIETLY)
 915     set(GMX_USE_PLUGINS ON)
 916     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 917     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 918   else()
 919     set(PKG_DL_LIBS)
 920   endif()
 921 endif(GMX_LOAD_PLUGINS)
 922 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 923
 924 if(EXISTS "${CMAKE_SOURCE_DIR}/admin/.isreposource")
 925     if(NOT CMAKE_CROSSCOMPILING)
 926         option(GMX_BUILD_MANPAGES "Build man pages" ON)
 927     else()
 928         message(STATUS "Building the man pages is not available when "
 929             "cross-compiling the developer version from git")
 930     endif()
 931 else()
 932     #make sure source package contains all man pages
 933     if(NOT EXISTS "${CMAKE_SOURCE_DIR}/man/man1/ngmx.1")
 934         message(FATAL_ERROR "Man pages are missing from source package.")
 935     endif()
 936 endif()
 937 mark_as_advanced(GMX_BUILD_MANPAGES)
 938
 939 # Math and thread libraries must often come after all others when linking...
 940 if(HAVE_LIBM)
 941     list(APPEND GMX_EXTRA_LIBRARIES m)
 942 endif(HAVE_LIBM)
 943
 944 if(GMX_FAHCORE)
 945   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 946       "Path to swindirect.h")
 947   include_directories(${COREWRAP_INCLUDE_DIR})
 948 endif(GMX_FAHCORE)
 949
 950 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 951 # these are set after everything else
 952 if (NOT DEFINED GROMACS_C_FLAGS_SET)
 953     set(GROMACS_C_FLAGS_SET true CACHE INTERNAL "Whether to reset the C flags"
 954         FORCE)
 955     set(CMAKE_C_FLAGS "${GROMACS_C_FLAGS} ${CMAKE_C_FLAGS}" CACHE STRING
 956         "Flags used by the compiler during all build types" FORCE)
 957     set(CMAKE_CXX_FLAGS "${GROMACS_CXX_FLAGS} ${CMAKE_CXX_FLAGS}" CACHE STRING
 958         "Flags used by the compiler during all build types" FORCE)
 959     set(CMAKE_EXE_LINKER_FLAGS
 960         "${GROMACS_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}"
 961         CACHE STRING "Linker flags" FORCE)
 962 endif (NOT DEFINED GROMACS_C_FLAGS_SET)
 963
 964 ######################################
 965 # Output compiler and CFLAGS used
 966 ######################################
 967 execute_process(COMMAND ${CMAKE_C_COMPILER} --version RESULT_VARIABLE TMP_RESULT OUTPUT_VARIABLE CC_VERSION ERROR_VARIABLE CC_VERSION)
 968 #try executing just the compiler command if that failed...
 969 if(TMP_RESULT)
 970     execute_process(COMMAND ${CMAKE_C_COMPILER} RESULT_VARIABLE TMP_RESULT OUTPUT_VARIABLE CC_VERSION ERROR_VARIABLE CC_VERSION)
 971 endif()
 972 string(LENGTH "${CC_VERSION}" len)
 973 if(len)
 974     string(REGEX MATCH "[^\n]*" CC_VERSION "${CC_VERSION}")
 975 endif()
 976
 977 set(BUILD_COMPILER "@CMAKE_C_COMPILER@ @CMAKE_C_COMPILER_ID@ @CC_VERSION@")
 978 set(BUILD_CFLAGS "@CMAKE_C_FLAGS@")
 979 if(CMAKE_BUILD_TYPE STREQUAL "Debug")
 980     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_DEBUG@")
 981 elseif(CMAKE_BUILD_TYPE STREQUAL "Release")
 982     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_RELEASE@")
 983 elseif(CMAKE_BUILD_TYPE STREQUAL "MinSizeRel")
 984     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_MINSIZEREL@")
 985 elseif(CMAKE_BUILD_TYPE STREQUAL "RelWithDebInfo")
 986     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_RELWITHDEBINFO@")
 987 endif()
 988
 989
 990 ########################################################################
 991 # Specify install locations and which subdirectories to process        #
 992 ########################################################################
 993 if (GMX_USE_RELATIVE_INSTALL_PATH)
 994     set(GMX_INSTALL_PREFIX "" CACHE STRING "Prefix gets appended to CMAKE_INSTALL_PREFIX. For cpack it sets the root folder of the archive.")
 995     mark_as_advanced(GMX_INSTALL_PREFIX)
 996 else()
 997     set(GMX_INSTALL_PREFIX "${CMAKE_INSTALL_PREFIX}/")
 998 endif()
 999
1000 if ( NOT DEFINED GMXLIB )
1001     set(GMXLIB lib)
1002 endif()
1003 set(LIB_INSTALL_DIR "${GMX_INSTALL_PREFIX}${GMXLIB}")
1004 set(BIN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}bin)
1005 set(DATA_INSTALL_DIR ${GMX_INSTALL_PREFIX}share/gromacs)
1006 set(MAN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}share/man)
1007 set(INCL_INSTALL_DIR ${GMX_INSTALL_PREFIX}include)
1008
1009 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
1010
1011 ##################################################################
1012 # Shared library settings - Darwin uses INSTALL_NAME_DIR instead!
1013 ##################################################################
1014 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
1015     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
1016     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
1017     set(CMAKE_INSTALL_RPATH "\\\$ORIGIN/../${GMXLIB}")
1018     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
1019 endif()
1020
1021 add_subdirectory(share)
1022 add_subdirectory(include)
1023 add_subdirectory(man)
1024 add_subdirectory(src)
1025 add_subdirectory(scripts)
1026
1027 #######################
1028 ## uninstall target
1029 #######################
1030     CONFIGURE_FILE(
1031                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
1032                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
1033                    IMMEDIATE @ONLY)
1034 ###########################
1035 ADD_CUSTOM_TARGET(uninstall
1036                   "${CMAKE_COMMAND}" -P
1037                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
1038 ###########################
1039
1040
1041 ########################################################################
1042 # Tests                                                                #
1043 ########################################################################
1044
1045 include(CTest)
1046 mark_as_advanced(BUILD_TESTING)
1047 IF(BUILD_TESTING)
1048         enable_testing()
1049         add_subdirectory(tests)
1050 ENDIF()
1051