CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.6)
   2
   3 project(Gromacs)
   4 include(Dart)
   5 # PROJECT_VERSION should have the following structure:
   6 # VERSION[-dev-SUFFIX] where the VERSION can have any form and the suffix
   7 set(PROJECT_VERSION "4.5"
   8     CACHE STRING "Gromacs version string")
   9 set(SOVERSION 6)
  10 # It is a bit irritating, but this has to be set separately for now!
  11 SET(CPACK_PACKAGE_VERSION_MAJOR "4")
  12 SET(CPACK_PACKAGE_VERSION_MINOR "5")
  13 SET(CPACK_PACKAGE_VERSION_PATCH "0")
  14
  15
  16 # Cmake modules/macros are in a subdirectory to keep this file cleaner
  17 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  18
  19 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  20 set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "" FORCE)
  21 endif()
  22
  23 if(NOT CMAKE_BUILD_TYPE)
  24     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
  25 endif(NOT CMAKE_BUILD_TYPE)
  26
  27 enable_language(C)
  28
  29 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
  30 set(CPACK_PACKAGE_VENDOR "gromacs.org")
  31 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
  32 set(CPACK_SET_DESTDIR "ON")
  33 set(CPACK_INCLUDE_TOPLEVEL_DIRECTORY 0)
  34 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
  35 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
  36 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/admin/InstallLicense.txt")
  37 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
  38
  39 #must come after all cpack settings!
  40 include(CPack)
  41
  42
  43 ########################################################################
  44 # Fix stupid flags on MSVC
  45 ########################################################################
  46 SET(SHARED_LIBS_DEFAULT ON)
  47 IF(CMAKE_GENERATOR MATCHES "Visual Studio")
  48     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
  49     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
  50     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
  51     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
  52     SET(SHARED_LIBS_DEFAULT OFF)
  53 ENDIF(CMAKE_GENERATOR MATCHES "Visual Studio")
  54
  55 set(GMX_EXTRA_LIBRARIES)
  56
  57
  58
  59 ######################################################################
  60 # compiler tests
  61 # these need ot be done early (before further tests).
  62 #####################################################################
  63
  64 include(CheckCCompilerFlag)
  65 include(CheckCXXCompilerFlag)
  66
  67 include(gmxCFlags)
  68 gmx_c_flags()
  69
  70 ########################################################################
  71 # User input options                                                   #
  72 ########################################################################
  73 option(GMX_DOUBLE "Use double precision" OFF)
  74 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
  75 option(GMX_THREADS    "Build a parallel (thread-based) version of GROMACS)" ON)
  76 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
  77 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
  78 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library" OFF)
  79 set(GMX_ACCELERATION "auto"
  80     CACHE STRING "Accelerated kernels. Pick one of: none, SSE, BlueGene, Power6, ia64, altivec")
  81
  82 set(GMX_FFT_LIBRARY "fftw3"
  83     CACHE STRING "FFT library choices: fftw3,fftw2,mkl,fftpack[built-in]")
  84 option(GMX_DISABLE_FFTW_MEASURE
  85        "Do not optimize FFTW setups (not needed with SSE)" OFF)
  86 set(GMX_QMMM_PROGRAM "none"
  87     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
  88 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
  89 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI, Windows)" ${SHARED_LIBS_DEFAULT})
  90 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
  91 option(GMX_DLOPEN "Compile with dlopen, needed to read VMD supported file formats" ON)
  92 mark_as_advanced(GMX_MPI_IN_PLACE)
  93
  94
  95 option(GMX_IA32_ASM "Add SSE assembly files for IA32" OFF)
  96 option(GMX_X86_64_ASM "Add SSE assembly files for X86_64" OFF)
  97
  98 option(USE_VERSION_H "Generate development version string/information" ON)
  99
 100 option(GMX_DEFAULT_SUFFIX "Use default GROMACS suffixes" ON)
 101 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for double).")
 102 set(GMX_LIBS_SUFFIX ""
 103   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for mpi, _mpi_d for mpi and double).")
 104 if (GMX_DEFAULT_SUFFIX)
 105   if (GMX_MPI)
 106     set(GMX_LIBS_SUFFIX "_mpi")
 107   endif(GMX_MPI)
 108   if (GMX_DOUBLE)
 109     set (GMX_BINARY_SUFFIX "_d")
 110     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
 111   endif(GMX_DOUBLE)
 112 endif(GMX_DEFAULT_SUFFIX)
 113
 114 set(PKG_CFLAGS "")
 115 if(GMX_DOUBLE)
 116   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 117 endif(GMX_DOUBLE)
 118 if(GMX_SOFTWARE_INVSQRT)
 119   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 120 endif(GMX_SOFTWARE_INVSQRT)
 121
 122 ########################################################################
 123 #Process MPI settings
 124 ########################################################################
 125 if(GMX_MPI)
 126         MESSAGE(WARNING "
 127             There are known problems with some MPI implementations:
 128                      OpenMPI version < 1.4.1
 129                      MVAPICH2 version <= 1.4.1                               *")
 130     if(GMX_THREADS)
 131         #message(FATAL_ERROR "Thread-based parallelization conflicts with MPI.")
 132         set(GMX_THREADS OFF CACHE BOOL
 133             "Thread-based parallelization conflicts with MPI." FORCE)
 134     endif(GMX_THREADS)
 135     find_package(MPI)
 136     if(MPI_FOUND)
 137         set(GROMACS_C_FLAGS ${GROMACS_FLAGS} ${MPI_COMPILE_FLAGS})
 138         set(GROMACS_LINKER_FLAGS ${GROMACS_LINKER_FLAGS} ${MPI_LINK_FLAGS})
 139
 140         include_directories(${MPI_INCLUDE_PATH})
 141         list(APPEND GMX_EXTRA_LIBRARIES ${MPI_LIBRARIES})
 142         add_definitions( -DMPI ) #for FAHCORE
 143         include(gmxTestMPI_IN_PLACE)
 144         if (GMX_MPI_IN_PLACE)
 145             gmx_test_mpi_in_place(MPI_IN_PLACE_EXISTS)
 146         endif (GMX_MPI_IN_PLACE)
 147     else(MPI_FOUND)
 148         message(FATAL_ERROR "MPI support requested, but no MPI compiler found.")
 149     endif(MPI_FOUND)
 150     include(gmxTestCatamount)
 151     gmx_test_catamount(GMX_CRAY_XT3)
 152     if(GMX_CRAY_XT3)
 153         set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_CRAY_XT3")
 154         set(GMX_NO_SYSTEM 1)
 155         set(GMX_NO_NICE 1)
 156     endif(GMX_CRAY_XT3)
 157     set(GMX_LIB_MPI 1)
 158     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_LIB_MPI")
 159 endif(GMX_MPI)
 160
 161
 162 #######################################################################
 163 # Check for options incompatible with OpenMM build                    #
 164 #######################################################################
 165 if(GMX_OPENMM)
 166     cmake_minimum_required(VERSION 2.6.4)
 167     # we'll use the built-in fft to avoid unnecessary dependencies
 168     message(STATUS "No external FFT libraries needed for the OpenMM build, using fftpack!")
 169     set (GMX_FFT_LIBRARY "fftpack" CACHE STRING
 170                 "No external FFT libraries needed for the OpenMM build, using fftpack!" FORCE)
 171     if(GMX_MPI)
 172         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
 173     endif(GMX_MPI)
 174     if(GMX_THREADS)
 175         message(STATUS "Threads not compatible with OpenMM build, disabled!")
 176         set(GMX_THREADS OFF CACHE BOOL
 177                 "Threads not compatible with OpenMM build, disabled!" FORCE)
 178     endif(GMX_THREADS)
 179     if(GMX_SOFTWARE_INVSQRT)
 180         set(GMX_SOFTWARE_INVSQRT OFF FORCE)
 181     endif(GMX_SOFTWARE_INVSQRT)
 182     if(NOT GMX_ACCELERATION MATCHES "^(none|None|NONE)")
 183         message(WARNING "CPU-based acceleration turned off, OpenMM does not support/need any!")
 184         unset(GMX_ACCELERATION CACHE)
 185         set(GMX_ACCELERATION "none" CACHE STRING
 186                 "CPU-based acceleration turned off, OpenMM does not support/need any!" FORCE)
 187     endif()
 188     if(GMX_FAHCORE)
 189         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
 190     endif(GMX_FAHCORE)
 191 endif(GMX_OPENMM)
 192
 193
 194 ########################################################################
 195 # Basic system tests (standard libraries, headers, functions, types)   #
 196 ########################################################################
 197 include(CheckIncludeFiles)
 198 check_include_files(string.h     HAVE_STRING_H)
 199 check_include_files(math.h       HAVE_MATH_H)
 200 check_include_files(limits.h     HAVE_LIMITS_H)
 201 check_include_files(memory.h     HAVE_MEMORY_H)
 202 check_include_files(unistd.h     HAVE_UNISTD_H)
 203 check_include_files(pwd.h        HAVE_PWD_H)
 204 check_include_files(stdint.h     HAVE_STDINT_H)
 205 check_include_files(stdlib.h     HAVE_STDLIB_H)
 206 check_include_files(pthread.h    HAVE_PTHREAD_H)
 207 check_include_files(dirent.h     HAVE_DIRENT_H)
 208 check_include_files(inttypes.h   HAVE_INTTYPES_H)
 209 check_include_files(regex.h      HAVE_REGEX_H)
 210 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 211 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
 212 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 213 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
 214 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
 215 # SSE support
 216 check_include_files(xmmintrin.h  HAVE_XMMINTRIN_H)
 217 check_include_files(emmintrin.h  HAVE_EMMINTRIN_H)
 218 check_include_files(pmmintrin.h  HAVE_PMMINTRIN_H)
 219 check_include_files(smmintrin.h  HAVE_SMMINTRIN_H)
 220 check_include_files(io.h                 HAVE_IO_H)
 221
 222
 223 include(CheckFunctionExists)
 224 check_function_exists(strcasecmp        HAVE_STRCASECMP)
 225 check_function_exists(strdup            HAVE_STRDUP)
 226 check_function_exists(vprintf           HAVE_VPRINTF)
 227 check_function_exists(memcmp            HAVE_MEMCMP)
 228 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 229 check_function_exists(memalign          HAVE_MEMALIGN)
 230 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 231 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 232 check_function_exists(isnan             HAVE_ISNAN)
 233 check_function_exists(_isnan            HAVE__ISNAN)
 234 check_function_exists(isfinite          HAVE_ISFINITE)
 235 check_function_exists(_isfinite         HAVE__ISFINITE)
 236 check_function_exists(fsync             HAVE_FSYNC)
 237 check_function_exists(_fileno           HAVE__FILENO)
 238 check_function_exists(fileno            HAVE_FILENO)
 239 check_function_exists(_commit           HAVE__COMMIT)
 240
 241 include(CheckLibraryExists)
 242 check_library_exists(m sqrt "" HAVE_LIBM)
 243 check_library_exists(m cbrt "" HAVE_CBRT)
 244
 245
 246 include(CheckTypeSize)
 247
 248 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 249 check_type_size("int"           SIZEOF_INT)
 250 check_type_size("long int"      SIZEOF_LONG_INT)
 251 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 252 check_type_size("off_t"         SIZEOF_OFF_T)
 253 check_type_size("void *"        SIZEOF_VOIDP)
 254
 255 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 256     set(GMX_64_BIT TRUE)
 257 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 258     set(GMX_64_BIT FALSE)
 259 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 260
 261 # Check for some basic types that we *need*, so set these to int if they are not present
 262 check_type_size(uid_t uid_t)
 263 if(NOT uid_t)
 264   set(uid_t int)
 265 else(NOT uid_t)
 266   set(uid_t 0)
 267 endif(NOT uid_t)
 268
 269 check_type_size(gid_t gid_t)
 270 if(NOT gid_t)
 271   set(gid_t 1)
 272 else(NOT gid_t)
 273   set(gid_t 0)
 274 endif(NOT gid_t)
 275
 276 check_type_size(size_t size_t)
 277 if(NOT size_t)
 278   set(size_t int)
 279 else(NOT size_t)
 280   set(size_t 0)
 281 endif(NOT size_t)
 282
 283 check_type_size(off_t off_t)
 284 if(NOT off_t)
 285   set(off_t int)
 286 else(NOT off_t)
 287   set(off_t 0)
 288 endif(NOT off_t)
 289
 290 include(TestBigEndian)
 291 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 292
 293
 294
 295
 296 ########################################################################
 297 # Find external packages                                               #
 298 ########################################################################
 299
 300 find_package(LibXml2)
 301 set(PKG_XML "")
 302 if(LIBXML2_FOUND)
 303     include_directories(${LIBXML2_INCLUDE_DIR})
 304     set(PKG_XML libxml-2.0)
 305     set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 306     set(HAVE_LIBXML2 1)
 307 endif(LIBXML2_FOUND)
 308
 309 option(GMX_X11 "Use X window system" OFF)
 310 if (GMX_X11)
 311         find_package(X11)
 312         # X11 includes/libraries are only set in the ngmx subdirectory!
 313         if(X11_FOUND)
 314         set(HAVE_X11 1)
 315         endif(X11_FOUND)
 316 endif(GMX_X11)
 317
 318 if(GMX_THREADS)
 319     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREADS")
 320     include(ThreadMPI)
 321     set(THREAD_MPI_LIB thread_mpi)
 322     set(GMX_MPI 1)
 323     string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 324     if(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 325         message(FATAL_ERROR "FFTW2 can't be used with threads. Try fftw3 or mkl.")
 326     endif()
 327 endif(GMX_THREADS)
 328
 329 if(GMX_OPENMM)
 330     set(CUDA_BUILD_EMULATION OFF)
 331     find_package(CUDA 3.1 REQUIRED)
 332     add_definitions(-DGMX_OPENMM)
 333     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 334         set(CUDA_VERBOSE_BUILD ON)
 335     endif()
 336     find_package(OpenMM)
 337 endif(GMX_OPENMM)
 338
 339 if(APPLE)
 340    find_library(ACCELERATE_FRAMEWORK Accelerate)
 341    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 342 endif(APPLE)
 343
 344 # only bother with finding git and using version.h if the source is a git repo
 345 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 346     if(USE_VERSION_H)
 347         # We need at least git v1.5.1 be able to parse git's date output. If not
 348         # fund or the version is too small, we can't generate version information.
 349         find_package(Git 1.5.1)
 350         # this should at some point become VERSION_LESS
 351         if(NOT Git_FOUND OR Git_VERSION STRLESS "1.5.1")
 352             message("No compatible git version found, won't be able to generate proper development version information.")
 353         endif()
 354     endif()
 355 else()
 356     set(USE_VERSION_H OFF)
 357 endif()
 358
 359 if (GMX_DLOPEN)
 360     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS})
 361 endif (GMX_DLOPEN)
 362
 363 ########################################################################
 364 # Generate development version info for cache
 365 ########################################################################
 366 # set(GEN_VERSION_INFO_INTERNAL "ON")
 367 # include(gmxGenerateVersionString)
 368
 369 ########################################################################
 370 # Our own GROMACS tests
 371 ########################################################################
 372
 373 add_definitions( -DHAVE_CONFIG_H )
 374 include_directories(${CMAKE_BINARY_DIR}/src)
 375 include_directories(${CMAKE_SOURCE_DIR}/include)
 376
 377 include(gmxCheckBuildUserTime)
 378 gmx_check_build_user_time(BUILD_TIME BUILD_USER BUILD_MACHINE)
 379
 380 include(gmxTestFloatFormat)
 381 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 382                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 383                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 384
 385 include(gmxTestLargeFiles)
 386 gmx_test_large_files(GMX_LARGEFILES)
 387 check_function_exists(fseeko     HAVE_FSEEKO)
 388
 389 include(gmxTestSignal)
 390 gmx_test_retsigtype(RETSIGTYPE)
 391 gmx_test_sigusr1(HAVE_SIGUSR1)
 392
 393 include(gmxTestInline)
 394 gmx_test_inline(INLINE_KEYWORD)
 395
 396 include(gmxTestRestrict)
 397 gmx_test_inline(RESTRICT_KEYWORD)
 398
 399 include(gmxTestPipes)
 400 gmx_test_pipes(HAVE_PIPES)
 401
 402 include(gmxTestInlineASM)
 403 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 404 gmx_test_inline_asm_msvc_x86(GMX_X86_MSVC_INLINE_ASM)
 405
 406 # turn on SSE if supported with reasonable defaults.
 407 if (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 408   if(CMAKE_SYSTEM_PROCESSOR MATCHES "^(i.86|x86|x64|x86_64|AMD64|amd64)")
 409
 410     set(GMX_ACCELERATION "SSE" CACHE STRING "Accelerated kernels. Pick one of: none, SSE, BlueGene, Power6, ia64, altivec" FORCE)
 411
 412     if (GMX_64_BIT)
 413       set(GMX_X86_64_ASM ON CACHE BOOL "Add SSE assembly files for x86_64" FORCE)
 414     else (GMX_64_BIT)
 415       set(GMX_IA32_ASM ON CACHE BOOL "Add SSE assembly files for i386" FORCE)
 416     endif (GMX_64_BIT)
 417
 418     # Determine the assembler/compiler to use
 419   else()
 420     set(GMX_ACCELERATION "none" CACHE STRING "Accelerated kernels. Pick one of: none, SSE, BlueGene, Power6, ia64, altivec" FORCE)
 421   endif()
 422 endif (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 423
 424
 425 include(gmxTestXDR)
 426 gmx_test_xdr(GMX_SYSTEM_XDR)
 427 if(NOT GMX_SYSTEM_XDR)
 428     set(GMX_INTERNAL_XDR 1)
 429     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 430 endif(NOT GMX_SYSTEM_XDR)
 431
 432 if(GMX_FORTRAN OR GMX_POWER6)
 433     enable_language(Fortran)
 434     include(FortranCInterface)
 435     discover_fortran_mangling(prefix isupper suffix extra_under_score found)
 436     if(extra_under_score)
 437         set(extrasuffix "_")
 438     endif(extra_under_score)
 439
 440     if(isupper)
 441         set(F77_FUNCDEF   "${prefix} ## NAME ## ${suffix}")
 442         set(F77_FUNCDEF_  "${prefix} ## NAME ## ${suffix}${extrasuffix}")
 443     else(isupper)
 444         set(F77_FUNCDEF   "${prefix} ## name ## ${suffix}")
 445         set(F77_FUNCDEF_  "${prefix} ## name ## ${suffix}${extrasuffix}")
 446     endif(isupper)
 447 else(GMX_FORTRAN OR GMX_POWER6)
 448         set(F77_FUNCDEF   "name ## _")
 449         set(F77_FUNCDEF_  "name ## _")
 450 endif(GMX_FORTRAN OR GMX_POWER6)
 451
 452
 453 # Process nonbonded accelerated kernels settings
 454 string(TOUPPER ${GMX_ACCELERATION} ${GMX_ACCELERATION})
 455 if(${GMX_ACCELERATION} STREQUAL "NONE")
 456   # nothing to do
 457 elseif(${GMX_ACCELERATION} STREQUAL "SSE")
 458
 459     if(CMAKE_GENERATOR MATCHES "Visual Studio")
 460       option(GMX_ASM_USEASM-NASM "Use Nasm for assembly instead of compiler (necessary on windows)" ON)
 461     else(CMAKE_GENERATOR MATCHES "Visual Studio")
 462       option(GMX_ASM_USEASM-NASM "Use Nasm for assembly instead of compiler (necessary on windows)" OFF)
 463     endif(CMAKE_GENERATOR MATCHES "Visual Studio")
 464     if (NOT GMX_64_BIT)
 465         # for 32-bit compiles, we might need to turn on sse
 466         CHECK_C_COMPILER_FLAG("-msse2" XFLAGS_SSE)
 467         if (XFLAGS_SSE)
 468             set(GROMACS_C_FLAGS "-msse2 ${GROMACS_C_FLAGS}")
 469         endif (XFLAGS_SSE)
 470         CHECK_CXX_COMPILER_FLAG("-msse2" XXFLAGS_SSE)
 471         if (XXFLAGS_SSE)
 472             set(GROMACS_CXX_FLAGS "-msse2 ${GROMACS_CXX_FLAGS}")
 473         endif (XXFLAGS_SSE)
 474     endif (NOT GMX_64_BIT)
 475
 476     if(GMX_IA32_ASM)
 477       if(GMX_DOUBLE)
 478         set(GMX_IA32_SSE2 1)
 479       else()
 480         set(GMX_IA32_SSE 1)
 481       endif()
 482     elseif(GMX_X86_64_ASM)
 483       if(GMX_DOUBLE)
 484         set(GMX_X86_64_SSE2 1)
 485       else()
 486         set(GMX_X86_64_SSE 1)
 487       endif()
 488     endif()
 489
 490 #    if(HAVE_PMMINTRIN_H)
 491 #        set(GMX_SSE3 1)
 492 #    endif(HAVE_PMMINTRIN_H)
 493 #    if(HAVE_SMMINTRIN_H)
 494 #        set(GMX_SSE4_1 1)
 495 #    endif(HAVE_SMMINTRIN_H)
 496
 497 elseif(${GMX_ACCELERATION} STREQUAL "FORTRAN")
 498     set(GMX_FORTRAN 1)
 499 elseif(${GMX_ACCELERATION} STREQUAL "BLUEGENE")
 500     set(GMX_BLUEGENE 1)
 501 elseif(${GMX_ACCELERATION} STREQUAL "POWER6")
 502     set(GMX_POWER6 1)
 503 elseif(${GMX_ACCELERATION} STREQUAL "IA64")
 504     set(GMX_IA64_ASM 1)
 505     set(DISABLE_WATERWATER_NLIST 1)
 506     set(DISABLE_WATER_NLIST 1)
 507 elseif(${GMX_ACCELERATION} STREQUAL "ALTIVEC")
 508     check_include_files(altivec.h HAVE_ALTIVEC_H)
 509     if(HAVE_ALTIVEC_H)
 510         set(GMX_PPC_ALTIVEC 1)
 511     endif(HAVE_ALTIVEC_H)
 512 else(${GMX_ACCELERATION} STREQUAL "NONE")
 513     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_ACCELERATION}. Pick one of none, SSE, Fortran, BlueGene, Power6, ia64, altivec")
 514 endif(${GMX_ACCELERATION} STREQUAL "NONE")
 515
 516
 517
 518
 519
 520
 521
 522 # Process QM/MM Settings
 523 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 524 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 525     set(GMX_QMMM_GAUSSIAN 1)
 526 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 527     set(GMX_QMMM_MOPAC 1)
 528 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 529     set(GMX_QMMM_GAMESS 1)
 530 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 531     set(GMX_QMMM_ORCA 1)
 532 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 533     # nothing to do
 534 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 535     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 536 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 537
 538 # Process FFT library settings - if not OpenMM build
 539 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 540 set(PKG_FFT "")
 541 set(PKG_FFT_LIBS "")
 542 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 543 #    MESSAGE(STATUS "Using external FFT library - fftw3")
 544     if(GMX_DOUBLE)
 545         find_package(FFTW3 REQUIRED)
 546                 include_directories(${FFTW3_INCLUDE_DIR})
 547         set(FFT_LIBRARIES ${FFTW3_LIBRARIES})
 548         set(PKG_FFT "fftw3")
 549     else(GMX_DOUBLE)
 550         find_package(FFTW3F REQUIRED)
 551         include_directories(${FFTW3F_INCLUDE_DIR})
 552         set(FFT_LIBRARIES ${FFTW3F_LIBRARIES})
 553         set(PKG_FFT "fftw3f")
 554     endif(GMX_DOUBLE)
 555
 556     if(NOT FFTW3_FOUND AND NOT FFTW3F_FOUND)
 557         MESSAGE(FATAL_ERROR "Cannot find fftw3 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 558     endif(NOT FFTW3_FOUND AND NOT FFTW3F_FOUND)
 559
 560     set(GMX_FFT_FFTW3 1)
 561
 562 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 563 #    MESSAGE(STATUS "Using external FFT library - fftw2")
 564     if(GMX_DOUBLE)
 565         find_package(FFTW2 REQUIRED)
 566     else(GMX_DOUBLE)
 567         find_package(FFTW2F REQUIRED)
 568     endif(GMX_DOUBLE)
 569
 570     if(NOT FFTW2_FOUND)
 571            MESSAGE(FATAL_ERROR "Cannot find fftw2 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 572     endif(NOT FFTW2_FOUND)
 573     include_directories(${FFTW2_INCLUDE_DIR})
 574     set(FFT_LIBRARIES ${FFTW2_LIBRARIES})
 575     set(PKG_FFT_LIBS ${FFTW2_LIBRARIES})
 576
 577     if("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 578         set(FFTW2_NAME_DFFTW 1)
 579     elseif("${FFTW2_LIBRARIES}" MATCHES "sfftw")
 580         set(FFTW2_NAME_SFFTW 1)
 581     else("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 582         set(FFTW2_NAME_FFTW 1)
 583     endif("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 584
 585     set(GMX_FFT_FFTW2 1)
 586 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 587 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 588     find_package(MKL REQUIRED)
 589     include_directories(${MKL_INCLUDE_DIR})
 590     set(FFT_LIBRARIES ${MKL_LIBRARIES})
 591     set(PKG_FFT_LIBS ${MKL_LIBRARIES})
 592
 593     set(GMX_FFT_MKL 1)
 594     set(HAVE_MKL 1)
 595
 596 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 597 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 598 #    set(GMX_FFT_ACML 1)
 599 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 600     MESSAGE(STATUS "Using internal FFT library - fftpack")
 601     set(GMX_FFT_FFTPACK 1)
 602 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 603     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, fftw2, mkl, acml, fftpack")
 604 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 605
 606 # MKL has BLAS/LAPACK routines
 607 if(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 608   set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 609   set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 610 else(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 611   set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 612   set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 613 endif(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 614
 615 # Math and thread libraries must often come after all others when linking...
 616 if(HAVE_LIBM)
 617     list(APPEND GMX_EXTRA_LIBRARIES m)
 618 endif(HAVE_LIBM)
 619
 620
 621
 622 if(GMX_FAHCORE)
 623   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 624       "Path to swindirect.h")
 625   include_directories(${COREWRAP_INCLUDE_DIR})
 626 endif(GMX_FAHCORE)
 627
 628 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 629 # these are set after everything else
 630 if (NOT DEFINED GROMACS_C_FLAGS_SET)
 631     set(GROMACS_C_FLAGS_SET true CACHE INTERNAL "Whether to reset the C flags"
 632         FORCE)
 633     set(CMAKE_C_FLAGS "${GROMACS_C_FLAGS} ${CMAKE_C_FLAGS}" CACHE STRING
 634         "Flags used by the compiler during all build types" FORCE)
 635     set(CMAKE_CXX_FLAGS "${GROMACS_CXX_FLAGS} ${CMAKE_CXX_FLAGS}" CACHE STRING
 636         "Flags used by the compiler during all build types" FORCE)
 637     set(CMAKE_EXE_LINKER_FLAGS
 638         "${GROMACS_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}"
 639         CACHE STRING "Linker flags" FORCE)
 640 endif (NOT DEFINED GROMACS_C_FLAGS_SET)
 641
 642 ########################################################################
 643 # Specify install locations and which subdirectories to process        #
 644 ########################################################################
 645 set(LIB_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/lib)
 646 set(BIN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/bin)
 647 set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/gromacs)
 648 set(MAN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/share/man)
 649 set(INCL_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/include)
 650
 651 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
 652
 653 ##################################################################
 654 # Shared library settings - Darwin uses INSTALL_NAME_DIR instead!
 655 ##################################################################
 656 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 657     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
 658     set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 659     set(CMAKE_INSTALL_RPATH "${LIB_INSTALL_DIR}")
 660     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 661 endif()
 662
 663 add_subdirectory(share)
 664 add_subdirectory(include)
 665 add_subdirectory(man)
 666 add_subdirectory(src)
 667 add_subdirectory(scripts)
 668
 669 #######################
 670 ## uninstall target
 671 #######################
 672     CONFIGURE_FILE(
 673                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 674                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 675                    IMMEDIATE @ONLY)
 676 ###########################
 677 ADD_CUSTOM_TARGET(uninstall
 678                   "${CMAKE_COMMAND}" -P
 679                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 680 ###########################
 681
 682
 683 ########################################################################
 684 # Tests                                                                #
 685 ########################################################################
 686
 687 enable_testing()
 688 add_test(TestBuildAll make)
 689
 690 add_subdirectory(tests)