CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013 by the GROMACS development team.
   5 # Copyright (c) 2014,2015,2016,2017,2018 by the GROMACS development team.
   6 # Copyright (c) 2019,2020,2021, by the GROMACS development team, led by
   7 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   8 # and including many others, as listed in the AUTHORS file in the
   9 # top-level source directory and at http://www.gromacs.org.
  10 #
  11 # GROMACS is free software; you can redistribute it and/or
  12 # modify it under the terms of the GNU Lesser General Public License
  13 # as published by the Free Software Foundation; either version 2.1
  14 # of the License, or (at your option) any later version.
  15 #
  16 # GROMACS is distributed in the hope that it will be useful,
  17 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  19 # Lesser General Public License for more details.
  20 #
  21 # You should have received a copy of the GNU Lesser General Public
  22 # License along with GROMACS; if not, see
  23 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  24 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  25 #
  26 # If you want to redistribute modifications to GROMACS, please
  27 # consider that scientific software is very special. Version
  28 # control is crucial - bugs must be traceable. We will be happy to
  29 # consider code for inclusion in the official distribution, but
  30 # derived work must not be called official GROMACS. Details are found
  31 # in the README & COPYING files - if they are missing, get the
  32 # official version at http://www.gromacs.org.
  33 #
  34 # To help us fund GROMACS development, we humbly ask that you cite
  35 # the research papers on the package. Check out http://www.gromacs.org.
  36
  37 cmake_minimum_required(VERSION 3.16.3)
  38 cmake_policy(SET CMP0074 NEW) # From CMake 3.12
  39 cmake_policy(SET CMP0068 NEW) # From CMake-3.9
  40
  41 # CMake modules/macros are in a subdirectory to keep this file cleaner
  42 # This needs to be set before project() in order to pick up toolchain files
  43 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  44
  45 if(CMAKE_SYSTEM_NAME STREQUAL "Darwin")
  46     # Providing a default value >=10.14 helps to find modern C++ compatibility,
  47     # such as by defaulting to the Clang libc++ instead of libstdc++.
  48     set(CMAKE_OSX_DEPLOYMENT_TARGET 10.14 CACHE STRING
  49         "OS X deployment target affects default SDK version and compiler flags.")
  50     # By default, limit the binary architecture to a single 64-bit build.
  51     set(CMAKE_OSX_ARCHITECTURES x86_64 CACHE STRING
  52         "OS X architecture affects the compatibility of the (potentially fat) binaries produced."
  53         FORCE)
  54 endif()
  55
  56 project(Gromacs)
  57
  58 set(CMAKE_CXX_STANDARD 17)
  59 set(CMAKE_CXX_STANDARD_REQUIRED ON)
  60 set(CMAKE_CXX_EXTENSIONS OFF)
  61
  62 include(gmxManageCcache)
  63
  64 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  65 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  66 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  67
  68 find_package(LibStdCpp)
  69
  70 # Python is first referenced in gmxVersionInfo, so we perform the search early
  71 # to find a suitable installation for all components.
  72 include(gmxPythonDiscovery)
  73 # Set up common version variables, as well as general information about
  74 # the build tree (whether the build is from a source package or from a git
  75 # repository).  Also declares a few functions that will be used for generating
  76 # version info files later.
  77 include(gmxBuildTreeInfo)
  78 include(gmxVersionInfo)
  79
  80 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  81     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  82 endif()
  83 if("${CMAKE_INSTALL_PREFIX}" STREQUAL "${CMAKE_BINARY_DIR}")
  84     message(FATAL_ERROR "GROMACS cannot be installed into the build tree, choose a different location for CMAKE_INSTALL_PREFIX")
  85 endif()
  86
  87 include(gmxBuildTypeReference)
  88 include(gmxBuildTypeProfile)
  89 include(gmxBuildTypeTSAN)
  90 include(gmxBuildTypeASAN)
  91 include(gmxBuildTypeMSAN)
  92 include(gmxBuildTypeUBSAN)
  93 include(gmxBuildTypeReleaseWithAssert)
  94
  95 if(NOT CMAKE_BUILD_TYPE)
  96     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert Profile TSAN ASAN MSAN UBSAN." FORCE)
  97     # Set the possible values of build type for cmake-gui
  98     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
  99         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert" "Profile" "TSAN" "ASAN" "MSAN" "UBSAN")
 100 endif()
 101 if(CMAKE_CONFIGURATION_TYPES)
 102     # Add appropriate GROMACS-specific build types for the Visual
 103     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
 104     # are already present by default).
 105     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
 106     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
 107     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
 108         "List of configuration types"
 109         FORCE)
 110 endif()
 111 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
 112
 113 set_property(GLOBAL PROPERTY FIND_LIBRARY_USE_LIB64_PATHS ON)
 114
 115 include(gmxCTestUtilities)
 116 gmx_ctest_init()
 117
 118 include(gmxCPackUtilities)
 119 gmx_cpack_init()
 120
 121 # Variables that accumulate stuff influencing the installed headers
 122 set(INSTALLED_HEADER_INCLUDE_DIRS "")
 123 set(INSTALLED_HEADER_DEFINITIONS "")
 124
 125 ########################################################################
 126 # Global non-cache variables for implementing the build system
 127 ########################################################################
 128
 129 # These variables collect libraries that GROMACS requires for
 130 # linking. They should be appended to with list(APPEND ${name}
 131 # new-library) calls. They are:
 132 #  - Libraries that are required for libgromacs (only)
 133 set(GMX_EXTRA_LIBRARIES "")
 134 #  - Libraries that are required for all code in the repository
 135 set(GMX_COMMON_LIBRARIES "")
 136 #  - Libraries that all code linked against libgromacs needs
 137 #    (i.e., something that is exposed in installed headers).
 138 set(GMX_PUBLIC_LIBRARIES "")
 139
 140 ########################################################################
 141 # Check and warn if cache generated on a different host is being reused
 142 ########################################################################
 143 if(CMAKE_HOST_UNIX)
 144     execute_process(COMMAND hostname
 145                     OUTPUT_VARIABLE TMP_HOSTNAME
 146                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 147     # Only check for host name if not running in a CI environment, as the cache might
 148     # be reused there between different machines in different stages
 149     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}"
 150             AND NOT DEFINED ENV{CI_JOB_ID})
 151         message(WARNING "
 152             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 153             is being reused! This could lead to inconsistencies; therefore, it is
 154             recommended to regenerate the cache!")
 155     endif()
 156     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 157             "Hostname of the machine where the cache was generated.")
 158 endif()
 159
 160 ########################################################################
 161 # Detect architecture before setting options so we can alter defaults
 162 ########################################################################
 163 # Detect the architecture the compiler is targetting, detect
 164 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 165 # to use if none is specified, and populate the cache option for CPU
 166 # SIMD.
 167 include(gmxDetectTargetArchitecture)
 168 gmx_detect_target_architecture()
 169
 170 ########################################################################
 171 # User input options                                                   #
 172 ########################################################################
 173 include(gmxOptionUtilities)
 174
 175 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 176
 177 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 178
 179 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 180 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 181
 182 option(GMX_MIMIC "Enable MiMiC QM/MM interface (CPMD is required)" OFF)
 183
 184 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 185 mark_as_advanced(GMX_FAHCORE)
 186
 187 option(GMX_COOL_QUOTES "Enable GROMACS cool quotes" ON)
 188 mark_as_advanced(GMX_COOL_QUOTES)
 189 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 190
 191 option(GMX_INSTALL_LEGACY_API "Install legacy headers" OFF)
 192
 193 gmx_option_multichoice(
 194     GMX_GPU
 195     "Framework for GPU acceleration"
 196     OFF
 197     OFF CUDA OpenCL SYCL)
 198
 199 gmx_option_multichoice(
 200     GMX_SIMD
 201     "SIMD instruction set for CPU kernels and compiler optimization"
 202     "AUTO"
 203     AUTO None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 AVX2_128 AVX_512 AVX_512_KNL ARM_NEON_ASIMD ARM_SVE IBM_VSX Reference)
 204
 205 set(GMX_FFT_LIBRARY_DEFAULT "fftw3")
 206
 207 gmx_option_multichoice(
 208     GMX_FFT_LIBRARY
 209     "FFT library"
 210     "${GMX_FFT_LIBRARY_DEFAULT}"
 211     fftw3 mkl "fftpack[built-in]")
 212 gmx_dependent_option(
 213     GMX_BUILD_OWN_FFTW
 214     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 215     OFF
 216     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 217 gmx_dependent_option(
 218     GMX_DISABLE_FFTW_MEASURE
 219     "Do not optimize FFTW setups (not needed with SSE)"
 220     OFF
 221     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 222 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 223 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 224
 225 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 226 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 227
 228 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 229
 230 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 231 mark_as_advanced(GMX_BROKEN_CALLOC)
 232
 233 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 234
 235 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 236
 237 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 238 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 239
 240 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 241 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 242
 243 option(GMX_BUILD_FOR_COVERAGE
 244        "Tune build for better code coverage metrics (e.g., disable asserts)"
 245        OFF)
 246 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 247
 248 option(GMX_DEVELOPER_BUILD
 249     "Enable Developer convenience features: always build unit-tests"
 250     OFF)
 251 mark_as_advanced(GMX_DEVELOPER_BUILD)
 252
 253 gmx_set_boolean(GMX_COMPILER_WARNINGS_DEFAULT "NOT SOURCE_IS_SOURCE_DISTRIBUTION")
 254 option(GMX_COMPILER_WARNINGS
 255     "Enable a default set of compiler warnings"
 256     ${GMX_COMPILER_WARNINGS_DEFAULT})
 257 mark_as_advanced(GMX_COMPILER_WARNINGS)
 258 # Always turn on compiler warnings with a developer build.
 259 gmx_add_cache_dependency(GMX_COMPILER_WARNINGS BOOL "NOT GMX_DEVELOPER_BUILD" ON)
 260
 261 option(GMX_BUILD_SHARED_EXE
 262     "Build exectuables as shared binaries. If not set, this disables rpath and dynamic linker flags in an attempt to build a static binary, but this may require setting up the toolchain properly and making appropriate libraries available."
 263     ON)
 264 mark_as_advanced(GMX_BUILD_SHARED_EXE)
 265
 266 option(GMX_PHYSICAL_VALIDATION
 267        "Include physical validation tests in ctest environment. These can then be called using 'make check-phys' or
 268        'make check-all'. Warning: Running the physical validation tests takes significantly more time than other tests!"
 269        OFF)
 270 mark_as_advanced(GMX_PHYSICAL_VALIDATION)
 271
 272 ######################################################################
 273 # Detect OpenMP support
 274 ######################################################################
 275 # The OpenMP detection _must_ come before tests for other CFLAGS.
 276 include(gmxManageOpenMP)
 277
 278
 279
 280 ######################################################################
 281 # Compiler tests
 282 # These need to be done early (before further tests).
 283 #####################################################################
 284
 285 include(gmxTestIntelLLVM)
 286 include(gmxCFlags)
 287 gmx_c_flags()
 288
 289 # These variables should be used for CMake-style lists (ie. separated
 290 # by semicolons) of additional compiler flags which are not generated
 291 # in gmxCFlags nor are SIMD or MPI related.
 292 #
 293 # TODO These variables should be consolidated into
 294 # EXTRA_COMPILER_FLAGS so that we we don't perpetrate bugs where
 295 # things that work in C compilation (e.g. merging from old branches)
 296 # might not also work for C++ compilation.
 297 set(EXTRA_C_FLAGS "")
 298 set(EXTRA_CXX_FLAGS "")
 299
 300 # Run through a number of tests for buggy compilers and other issues
 301 include(gmxTestCompilerProblems)
 302 gmx_test_compiler_problems()
 303
 304 # Implement double-precision option. This is complicated because we
 305 # need installed headers to use the precision mode of the build that
 306 # produced the library, but cannot use config.h in that case. We also
 307 # want such variables to always have a definition, because #if is more
 308 # robust than #ifdef. So, we put this value on the compiler command
 309 # line in all cases.
 310 if(GMX_DOUBLE)
 311     set(GMX_DOUBLE_VALUE 1)
 312 else()
 313     set(GMX_DOUBLE_VALUE 0)
 314 endif()
 315 add_definitions(-DGMX_DOUBLE=${GMX_DOUBLE_VALUE})
 316 list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_DOUBLE=${GMX_DOUBLE_VALUE}")
 317
 318 option(GMX_IMD "Enable Interactive Molecular Dynamics (IMD) sessions, e.g. with VMD" ON)
 319 if(GMX_IMD AND WIN32)
 320     list(APPEND GMX_EXTRA_LIBRARIES "wsock32")
 321 endif()
 322
 323
 324
 325 ########################################################################
 326 # Basic system tests (standard libraries, headers, functions, types)   #
 327 ########################################################################
 328 include(CheckIncludeFiles)
 329 include(CheckIncludeFileCXX)
 330 check_include_files(unistd.h     HAVE_UNISTD_H)
 331 check_include_files(pwd.h        HAVE_PWD_H)
 332 check_include_files(dirent.h     HAVE_DIRENT_H)
 333 check_include_files(time.h       HAVE_TIME_H)
 334 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 335 check_include_files(io.h         HAVE_IO_H)
 336 check_include_files(sched.h      HAVE_SCHED_H)
 337 check_include_files(xmmintrin.h  HAVE_XMMINTRIN_H)
 338
 339 include(CheckCXXSymbolExists)
 340 check_cxx_symbol_exists(gettimeofday      sys/time.h   HAVE_GETTIMEOFDAY)
 341 check_cxx_symbol_exists(sysconf           unistd.h     HAVE_SYSCONF)
 342 check_cxx_symbol_exists(nice              unistd.h     HAVE_NICE)
 343 check_cxx_symbol_exists(fsync             unistd.h     HAVE_FSYNC)
 344 check_cxx_symbol_exists(_fileno           stdio.h      HAVE__FILENO)
 345 check_cxx_symbol_exists(fileno            stdio.h      HAVE_FILENO)
 346 check_cxx_symbol_exists(_commit           io.h         HAVE__COMMIT)
 347 check_cxx_symbol_exists(sigaction         signal.h     HAVE_SIGACTION)
 348
 349 # We cannot check for the __builtins as symbols, but check if code compiles
 350 check_cxx_source_compiles("int main(){ return __builtin_clz(1);}"   HAVE_BUILTIN_CLZ)
 351 check_cxx_source_compiles("int main(){ return __builtin_clzll(1);}" HAVE_BUILTIN_CLZLL)
 352 if(MSVC)
 353     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned long i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE)
 354     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned __int64 i=1;_BitScanReverse64(&r,i);return r;}" HAVE_BITSCANREVERSE64)
 355 elseif(CMAKE_CXX_COMPILER_ID MATCHES "XL")
 356     check_cxx_source_compiles("int main(){ return __cntlz4(1);}" HAVE_CNTLZ4)
 357     check_cxx_source_compiles("int main(){ return __cntlz8(1);}" HAVE_CNTLZ8)
 358 endif()
 359
 360 include(CheckLibraryExists)
 361 find_library(HAVE_LIBM m)
 362 mark_as_advanced(HAVE_LIBM)
 363 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 364 check_library_exists(m feenableexcept "" HAVE_FEENABLEEXCEPT)
 365 check_library_exists(m fedisableexcept "" HAVE_FEDISABLEEXCEPT)
 366
 367 include(TestSchedAffinity)
 368 test_sched_affinity(HAVE_SCHED_AFFINITY)
 369
 370 # Aligned memory allocation. We need to check for both mm_malloc(),
 371 # posix_memalign(), memalign(), and on windows also _aligned_malloc()
 372 include(gmxTestMMMalloc)
 373 gmx_test_mm_malloc(HAVE__MM_MALLOC)
 374 check_cxx_symbol_exists(posix_memalign    stdlib.h     HAVE_POSIX_MEMALIGN)
 375 check_cxx_symbol_exists(memalign          stdlib.h     HAVE_MEMALIGN)
 376 if(MSVC)
 377     # No need to waste time on this test on platforms where it will never be true
 378     check_cxx_symbol_exists(_aligned_malloc   stdlib.h     HAVE__ALIGNED_MALLOC)
 379 endif()
 380
 381 include(TestBigEndian)
 382 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 383
 384 gmx_set_boolean(GMX_USE_NICE "HAVE_UNISTD_H AND HAVE_NICE")
 385
 386 ########################################################################
 387 #Process MPI settings
 388 ########################################################################
 389 include(gmxManageMPI)
 390
 391 ########################################################################
 392 #Process MiMiC settings
 393 ########################################################################
 394 include(gmxManageMimic)
 395
 396 ########################################################################
 397 #Process shared/static library settings
 398 ########################################################################
 399 include(gmxManageSharedLibraries)
 400
 401
 402 ########################################################################
 403 # Specify install locations
 404 ########################################################################
 405 # Use GNUInstallDirs to set paths on multiarch systems.
 406 include(GNUInstallDirs)
 407
 408 set(GMX_INSTALL_DATASUBDIR "gromacs" CACHE STRING "Subdirectory for GROMACS data under CMAKE_INSTALL_DATADIR")
 409 mark_as_advanced(GMX_INSTALL_DATASUBDIR)
 410
 411 # Internal convenience so we do not have to join two path segments in the code
 412 set(GMX_INSTALL_GMXDATADIR ${CMAKE_INSTALL_DATADIR}/${GMX_INSTALL_DATASUBDIR})
 413
 414 # If the nesting level wrt. the installation root is changed,
 415 # gromacs-config.cmake.cmakein needs to be adapted.
 416 set(GMX_INSTALL_CMAKEDIR  ${CMAKE_INSTALL_DATAROOTDIR}/cmake)
 417
 418 # TODO: Make GMXRC adapt if this is changed
 419 set(GMX_INSTALL_PKGCONFIGDIR ${CMAKE_INSTALL_LIBDIR}/pkgconfig)
 420
 421 list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${CMAKE_INSTALL_INCLUDEDIR})
 422
 423 # Binary and library suffix options
 424 include(gmxManageSuffixes)
 425
 426
 427 ########################################################################
 428 # Find external packages                                               #
 429 ########################################################################
 430
 431 # Unconditionally find the package, as it is also required for unit
 432 # tests. This exports LIBXML2_FOUND, which we should not use because
 433 # it does not tell us that linking will succeed. Instead, we test that
 434 # next.
 435 #if(DEFINED LIBXML2_LIBRARIES)
 436 #  set(LibXml2_FIND_QUIETLY TRUE)
 437 #endif()
 438 #find_package(LibXml2)
 439 #include(gmxTestLibXml2)
 440 #gmx_test_libxml2(HAVE_LIBXML2)
 441 #option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 442 #set(PKG_XML "")
 443 #mark_as_advanced(GMX_XML)
 444 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 445 #if(GMX_XML AND NOT HAVE_LIBXML2)
 446 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 447 #endif()
 448 #if(GMX_XML)
 449 #    include_directories(${LIBXML2_INCLUDE_DIR})
 450 #    set(PKG_XML libxml-2.0)
 451 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 452 #endif()
 453
 454 option(GMX_HWLOC "Use hwloc portable hardware locality library" OFF)
 455
 456 if (GMX_HWLOC)
 457     # Find quietly the second time.
 458     if (HWLOC_FIND_QUIETLY_AFTER_FIRST_RUN)
 459         set(HWLOC_FIND_QUIETLY TRUE)
 460     endif()
 461     find_package(HWLOC 1.5)
 462
 463     if (HWLOC_FOUND)
 464         if (HWLOC_LIBRARIES MATCHES ".a$")
 465             set(_STATIC_HWLOC TRUE)
 466         endif()
 467
 468         gmx_check_if_changed(HWLOC_FOUND_CHANGED HWLOC_FOUND)
 469         if (_STATIC_HWLOC AND HWLOC_FOUND_CHANGED AND NOT GMX_HWLOC_FORCE)
 470             message(STATUS "Static hwloc library found, will not attempt using it as it could lead to link-time errors. To use the detected library, manually set GMX_HWLOC=ON and you will likely have to pass appropriate linker flags too to satisfy the link-time dependencies of your hwloc library. Try \"pkg-config --libs --static hwloc\" for suggestions on what you will need.")
 471             set(GMX_USE_HWLOC OFF)
 472         else()
 473             set(GMX_USE_HWLOC ON)
 474         endif()
 475
 476         if (GMX_USE_HWLOC)
 477             include_directories(SYSTEM ${HWLOC_INCLUDE_DIRS})
 478             list(APPEND GMX_EXTRA_LIBRARIES ${HWLOC_LIBRARIES})
 479         endif()
 480     elseif(GMX_HWLOC_FORCE)
 481         message(FATAL_ERROR "HWLOC package support required, but not found.")
 482     endif()
 483
 484     if (HWLOC_FOUND AND HWLOC_VERSION VERSION_LESS "2")
 485         message(STATUS "Support for hwloc versions 1.x is deprecated")
 486     endif()
 487
 488     set(HWLOC_FIND_QUIETLY_AFTER_FIRST_RUN TRUE CACHE INTERNAL "Be quiet during future attempts to find HWLOC")
 489 endif()
 490
 491 option(GMX_EXTERNAL_TINYXML2 "Use external TinyXML-2 instead of compiling the version bundled with GROMACS." OFF)
 492 mark_as_advanced(GMX_EXTERNAL_TINYXML2)
 493 if(GMX_EXTERNAL_TINYXML2)
 494     # Find an external TinyXML-2 library.
 495     find_package(TinyXML-2 3.0.0)
 496     set(HAVE_TINYXML2 ${TinyXML2_FOUND})
 497     if(NOT HAVE_TINYXML2)
 498         message(FATAL_ERROR "External TinyXML-2 could not be found, please adjust your search paths")
 499     endif()
 500 endif()
 501
 502 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 503 mark_as_advanced(GMX_EXTRAE)
 504
 505 if (GMX_EXTRAE)
 506   find_package(EXTRAE)
 507   if(EXTRAE_FOUND)
 508     include_directories(SYSTEM ${EXTRAE_INCLUDE_DIR})
 509     set(HAVE_EXTRAE 1)
 510   else()
 511     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 512   endif()
 513 endif()
 514
 515 option(GMX_X11 "Use X window system" OFF)
 516 if (GMX_X11)
 517     find_package(X11)
 518     # X11 includes/libraries are only set in the ngmx subdirectory!
 519     if(NOT X11_FOUND)
 520         message(FATAL_ERROR
 521                 "X11 include files and/or libraries were not found. "
 522                 "Set GMX_X11=OFF to compile without X11 support. "
 523                 "gmx view will not be available.")
 524     endif()
 525     include_directories(SYSTEM ${X11_INCLUDE_DIR})
 526 endif()
 527
 528 include(ThreadMPI)
 529 # Enable core threading facilities
 530 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 531 if(GMX_THREAD_MPI)
 532     # enable MPI functions
 533     tmpi_enable()
 534 endif()
 535 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 536 if (TMPI_ATOMICS_DISABLED)
 537    add_definitions(-DTMPI_ATOMICS_DISABLED)
 538 endif()
 539
 540 include(gmxManageTNG)
 541
 542 include(gmxManageLmfit)
 543
 544 include(gmxManageMuparser)
 545
 546 if(GMX_GPU)
 547
 548     string(TOUPPER "${GMX_GPU}" _gmx_gpu_uppercase)
 549     if(${_gmx_gpu_uppercase} STREQUAL "CUDA")
 550         include(gmxManageCuda)
 551     elseif(${_gmx_gpu_uppercase} STREQUAL "OPENCL")
 552         message(STATUS "GPU support with OpenCL is deprecated. It is still fully supported (and "
 553             "recommended for AMD and Intel GPUs). It may be replaced by different approaches in "
 554             "future releases of GROMACS.")
 555         include(gmxManageOpenCL)
 556     elseif(${_gmx_gpu_uppercase} STREQUAL "SYCL")
 557         include(gmxManageSYCL)
 558     endif()
 559     if(NOT GMX_OPENMP)
 560         message(WARNING "To use GPU acceleration efficiently, mdrun requires OpenMP multi-threading, which is currently not enabled.")
 561     endif()
 562
 563     if (GMX_OPENCL_NB_CLUSTER_SIZE)
 564         message(WARNING "GMX_OPENCL_NB_CLUSTER_SIZE is deprecated, use GMX_GPU_NB_CLUSTER_SIZE instead")
 565     endif()
 566     if (GMX_OPENCL_NB_CLUSTER_SIZE AND GMX_GPU_NB_CLUSTER_SIZE)
 567         if (NOT ${GMX_OPENCL_NB_CLUSTER_SIZE} EQUAL ${GMX_GPU_NB_CLUSTER_SIZE})
 568             message(FATAL_ERROR "Mismatching values passed to GMX_OPENCL_NB_CLUSTER_SIZE and GMX_GPU_NB_CLUSTER_SIZE; the former is deprecated, use only the latter!")
 569         endif()
 570     endif()
 571     # Only OpenCL and SYCL support changing the default cluster size
 572     if (${_gmx_gpu_uppercase} STREQUAL "CUDA")
 573         if (GMX_GPU_NB_CLUSTER_SIZE AND NOT "${GMX_GPU_NB_CLUSTER_SIZE}" EQUAL 8)
 574             message(FATAL_ERROR "Setting GMX_GPU_NB_CLUSTER_SIZE is not supported in CUDA (the default GMX_GPU_NB_CLUSTER_SIZE=8 is used)")
 575         endif()
 576     else()
 577         # use the legacy GMX_OPENCL_NB_CLUSTER_SIZE variable if set, otherwise set the defaults
 578         if (GMX_OPENCL_NB_CLUSTER_SIZE)
 579             set(_gmx_gpu_nb_cluster_size_value ${GMX_OPENCL_NB_CLUSTER_SIZE})
 580         else()
 581             # default cluster size is 8 with OpenCL and 4 with SYCL for now
 582             if(${_gmx_gpu_uppercase} STREQUAL "OPENCL")
 583                 set(_gmx_gpu_nb_cluster_size_value 8)
 584             elseif(GMX_GPU_SYCL)
 585                 if (GMX_SYCL_HIPSYCL AND NOT GMX_HIPSYCL_HAVE_LEVELZERO_TARGET)
 586                     set(_gmx_gpu_nb_cluster_size_value 8)
 587                 else()
 588                     # Either DPCPP or hipSYCL targeting Intel Level0
 589                     set(_gmx_gpu_nb_cluster_size_value 4)
 590                 endif()
 591             endif()
 592         endif()
 593         set(GMX_GPU_NB_CLUSTER_SIZE ${_gmx_gpu_nb_cluster_size_value} CACHE STRING "Cluster size used by the nonbonded kernel. Set to 4 for Intel GPUs.")
 594         mark_as_advanced(GMX_GPU_NB_CLUSTER_SIZE)
 595     endif()
 596
 597 endif()
 598
 599 # For build with CUDA and Lib-MPI, check if underlying MPI implementation is CUDA-aware
 600 # CUDA-aware MPI allows direct GPU communication without staging data through host
 601 if(GMX_GPU_CUDA AND GMX_LIB_MPI)
 602     include(gmxManageCudaAwareMPI)
 603 else()
 604     set(HAVE_CUDA_AWARE_MPI 0)
 605 endif()
 606
 607 if(CYGWIN)
 608     set(GMX_CYGWIN 1)
 609 endif()
 610
 611 if(WIN32)
 612     set(GMX_NATIVE_WINDOWS 1)
 613     # This makes windows.h not declare min/max as macros that would break
 614     # C++ code using std::min/std::max.
 615     add_definitions(-DNOMINMAX)
 616 endif()
 617
 618 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING" ON)
 619 mark_as_advanced(GMX_BUILD_UNITTESTS)
 620 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 621
 622 ########################################################################
 623 # Our own GROMACS tests
 624 ########################################################################
 625
 626 include_directories(SYSTEM ${CMAKE_SOURCE_DIR}/src/external)
 627
 628 include(gmxTestInlineASM)
 629 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 630
 631 include(gmxSetBuildInformation)
 632 gmx_set_build_information()
 633
 634 # Anything but truly ancient x86 hardware should support rdtscp, so we enable it by default.
 635 # The inline assembly calling it is only ever compiled on x86, so defaulting to ON is OK.
 636 option(GMX_USE_RDTSCP "Use low-latency RDTSCP instruction for x86 CPU-based timers for mdrun execution; might need to be off when compiling for heterogeneous environments" ON)
 637 mark_as_advanced(GMX_USE_RDTSCP)
 638
 639 include(gmxTestLargeFiles)
 640 gmx_test_large_files(GMX_LARGEFILES)
 641
 642 include(gmxTestSignal)
 643 gmx_test_sigusr1(HAVE_SIGUSR1)
 644
 645 include(gmxTestPipes)
 646 gmx_test_pipes(HAVE_PIPES)
 647
 648 include(gmxTestXDR)
 649 gmx_test_xdr(GMX_SYSTEM_XDR)
 650 # Darwin has system XDR, but it uses a three-argument flavour of
 651 # xdrproc_t that it guarantees will still work if you pass the normal
 652 # two-argument xdr filters, but gcc 8 warns about the cast necessary
 653 # to do that, so it's simpler to just use our own XDR library.
 654 #
 655 # TODO It would be better to craft a cmake test which fails if such
 656 # XDR operations cause warnings, and succeeds otherwise, because it is
 657 # generally preferable to use system libraries where possible.
 658 if(NOT GMX_SYSTEM_XDR OR CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 659     set(GMX_INTERNAL_XDR 1)
 660 endif()
 661
 662
 663 ##################################################
 664 # Process SIMD instruction settings
 665 ##################################################
 666 # This checks what flags to add in order to
 667 # support the SIMD instructions we need, it sets
 668 # correct defines for the SIMD instructions supported,
 669 # and adds advanced options to control accuracy
 670 # for SIMD math operations.
 671 include(gmxManageSimd)
 672 gmx_manage_simd()
 673
 674 ##################################################
 675 # Process FFT library settings
 676 ##################################################
 677 include(gmxManageFFTLibraries)
 678
 679
 680 include(gmxManageLinearAlgebraLibraries)
 681
 682 include(gmxManagePluginSupport)
 683 gmx_manage_plugin_support()
 684
 685 if(GMX_USE_PLUGINS)
 686     if(NOT GMX_VMD_PLUGIN_PATH)
 687         find_package(VMD)
 688     endif()
 689 endif()
 690
 691 # People might want to customize the default location for the DSSP binary
 692 set(GMX_DSSP_PROGRAM_PATH "/usr/local/bin/dssp"
 693     CACHE PATH
 694     "The default location to use for the DSSP binary")
 695 mark_as_advanced(GMX_DSSP_PROGRAM_PATH)
 696
 697 # Link real-time library for POSIX timers. The check for clock_gettime
 698 # confirms the linkability of rt.
 699 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 700     list(APPEND GMX_EXTRA_LIBRARIES rt)
 701 endif()
 702
 703 # Math and thread libraries must often come after all others when linking...
 704 if (HAVE_LIBM)
 705     list(APPEND GMX_PUBLIC_LIBRARIES m)
 706 endif()
 707
 708 option(GMX_NACL "Configure for Native Client builds" OFF)
 709 if (GMX_NACL)
 710   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 711   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 712   # TODO: Is this still necessary with the check for its presence?
 713   set(GMX_USE_NICE 0)
 714   set(GMX_NO_RENAME 1)
 715 endif()
 716 mark_as_advanced(GMX_NACL)
 717
 718 if(GMX_FAHCORE)
 719   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 720       "Path to swindirect.h")
 721   include_directories(${COREWRAP_INCLUDE_DIR})
 722 endif()
 723
 724 option(GMX_BUILD_HELP "Build completions (requires that compiled binaries can be executed on build host) and install man pages if built (requires building the 'man' target manually)" OFF)
 725 mark_as_advanced(GMX_BUILD_HELP)
 726 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND BUILD_IS_INSOURCE)
 727     message(FATAL_ERROR
 728         "Rebuilding shell completions or man pages is not supported for "
 729         "in-source builds from a source distribution. "
 730         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 731 endif()
 732
 733 if (GMX_BUILD_FOR_COVERAGE)
 734     # Set flags for coverage build here instead having to do so manually
 735     set(CMAKE_C_FLAGS "-g --coverage")
 736     set(CMAKE_CXX_FLAGS "-g --coverage")
 737 endif()
 738
 739 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 740 # these are set after everything else
 741 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 742     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS} ${DISABLE_SYCL_CXX_FLAGS}")
 743     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS} ${DISABLE_SYCL_CXX_FLAGS}")
 744 else()
 745     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 746     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS};${MPI_COMPILE_FLAGS};${EXTRA_C_FLAGS};${GMXC_CFLAGS}")
 747     foreach(build_type ${build_types_with_explicit_flags})
 748         message("CMAKE_C_FLAGS_${build_type}: ${GMXC_CFLAGS_${build_type}}")
 749     endforeach()
 750     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS};${MPI_COMPILE_FLAGS};${EXTRA_CXX_FLAGS};${GMXC_CXXFLAGS}")
 751     foreach(build_type ${build_types_with_explicit_flags})
 752         message("CMAKE_CXX_FLAGS_${build_type}: ${GMXC_CXXFLAGS_${build_type}}")
 753     endforeach()
 754     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 755     message("CMAKE_SHARED_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 756 endif()
 757 # Allow `admin` directory to be easily conveyed to nested CMake commands.
 758 set(GMX_ADMIN_DIR ${CMAKE_SOURCE_DIR}/admin)
 759
 760 ################################################################
 761 # Shared library load path settings
 762 ################################################################
 763 if(NOT GMX_BUILD_SHARED_EXE)
 764     # No rpath
 765     set(CMAKE_SKIP_RPATH TRUE)
 766     set(CMAKE_EXE_LINK_DYNAMIC_C_FLAGS) # remove -Wl,-Bdynamic
 767     set(CMAKE_EXE_LINK_DYNAMIC_CXX_FLAGS)
 768 else()
 769     # The build folder always has bin/ and lib/; if we are also going to
 770     # install to lib/, then the installation RPATH works also in the build
 771     # tree.  This makes installation slightly faster (no need to rewrite the
 772     # RPATHs), and makes the binaries in the build tree relocatable.
 773     if(CMAKE_INSTALL_LIBDIR STREQUAL "lib")
 774         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 775         set(CMAKE_BUILD_WITH_INSTALL_NAME_DIR TRUE)
 776     endif()
 777     # Set the RPATH as relative to the executable location to make the
 778     # binaries relocatable.
 779     if(CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Assume OS X >=10.5
 780         set(CMAKE_INSTALL_RPATH "@loader_path/../${CMAKE_INSTALL_LIBDIR}")
 781         set(CMAKE_INSTALL_NAME_DIR ${CMAKE_INSTALL_RPATH})
 782     else()
 783         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${CMAKE_INSTALL_LIBDIR}")
 784     endif()
 785     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 786     set(CMAKE_MACOSX_RPATH 1)
 787 endif()
 788
 789 #COPYING file: Only necessary for binary distributions.
 790 #Simpler to always install.
 791 install(FILES COPYING DESTINATION ${GMX_INSTALL_GMXDATADIR} COMPONENT data)
 792
 793 if (BUILD_TESTING)
 794     include(tests/CheckTarget.cmake)
 795 endif()
 796
 797 # TODO: Determine control flow and defaults for package installation and testing use cases.
 798 # Ref: https://gitlab.com/gromacs/gromacs/-/issues/2896
 799 option(GMX_PYTHON_PACKAGE "Configure gmxapi Python package" OFF)
 800 mark_as_advanced(GMX_PYTHON_PACKAGE)
 801
 802 find_package(ImageMagick QUIET COMPONENTS convert)
 803 include(gmxTestImageMagick)
 804 GMX_TEST_IMAGEMAGICK(IMAGE_CONVERT_POSSIBLE)
 805 # TODO: Resolve circular dependency between docs, gromacs, and python_packaging
 806 add_subdirectory(docs)
 807 add_subdirectory(share)
 808 add_subdirectory(scripts)
 809 add_subdirectory(api)
 810 add_subdirectory(src)
 811
 812 if (BUILD_TESTING)
 813     add_subdirectory(tests)
 814 endif()
 815
 816 if(GMX_PYTHON_PACKAGE)
 817     add_subdirectory(python_packaging)
 818 endif()
 819
 820 gmx_cpack_write_config()
 821
 822 #######################
 823 ## uninstall target
 824 #######################
 825 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 826                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 827                   IMMEDIATE @ONLY)
 828 ###########################
 829 ADD_CUSTOM_TARGET(uninstall
 830                   "${CMAKE_COMMAND}" -P
 831                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 832 ###########################
 833 set_directory_properties(PROPERTIES
 834             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")