CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014,2015, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 2.8.8)
  36 # When we require cmake >= 2.8.12, it will provide
  37 # CMAKE_MINIMUM_REQUIRED_VERSION automatically, but in the meantime we
  38 # need to set a variable, and it must have a different name.
  39 set(GMX_CMAKE_MINIMUM_REQUIRED_VERSION "2.8.8")
  40
  41 # CMake modules/macros are in a subdirectory to keep this file cleaner
  42 # This needs to be set before project() in order to pick up toolchain files
  43 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  44
  45 project(Gromacs)
  46
  47 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  48 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  49 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  50
  51 # Set up common version variables, as well as general information about
  52 # the build tree (whether the build is from a source package or from a git
  53 # repository).  Also declares a few functions that will be used for generating
  54 # version info files later.
  55 include(gmxVersionInfo)
  56
  57 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  58     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  59 endif()
  60
  61 include(gmxBuildTypeReference)
  62 include(gmxBuildTypeProfile)
  63 include(gmxBuildTypeTSAN)
  64 include(gmxBuildTypeASAN)
  65 include(gmxBuildTypeReleaseWithAssert)
  66
  67 if(NOT CMAKE_BUILD_TYPE)
  68     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert Profile." FORCE)
  69     # There's no need to offer a user the choice of ThreadSanitizer
  70     # Set the possible values of build type for cmake-gui
  71     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
  72         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert" "Profile")
  73 endif()
  74 if(CMAKE_CONFIGURATION_TYPES)
  75     # Add appropriate GROMACS-specific build types for the Visual
  76     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
  77     # are already present by default).
  78     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
  79     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
  80     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
  81         "List of configuration types"
  82         FORCE)
  83 endif()
  84 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
  85
  86 set_property(GLOBAL PROPERTY FIND_LIBRARY_USE_LIB64_PATHS ON)
  87
  88 # Set a default valgrind suppression file.
  89 # This unfortunately needs to duplicate information from CTest to work as
  90 # expected...
  91 set(MEMORYCHECK_SUPPRESSIONS_FILE
  92     "${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp"
  93     CACHE FILEPATH
  94     "File that contains suppressions for the memory checker")
  95 include(CTest)
  96
  97 include(gmxCPackUtilities)
  98 gmx_cpack_init()
  99
 100 # Variables that accumulate stuff influencing the installed headers
 101 set(INSTALLED_HEADER_INCLUDE_DIRS "")
 102 set(INSTALLED_HEADER_DEFINITIONS "")
 103
 104 ########################################################################
 105 # Check and warn if cache generated on a different host is being reused
 106 ########################################################################
 107 if(CMAKE_HOST_UNIX)
 108     execute_process(COMMAND hostname
 109                     OUTPUT_VARIABLE TMP_HOSTNAME
 110                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 111     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 112         message(WARNING "
 113             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 114             is being reused! This could lead to inconsistencies; therefore, it is
 115             recommended to regenerate the cache!")
 116     endif()
 117     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 118             "Hostname of the machine where the cache was generated.")
 119 endif()
 120
 121 ########################################################################
 122 # Detect architecture before setting options so we can alter defaults
 123 ########################################################################
 124 # Detect the architecture the compiler is targetting, detect
 125 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 126 # to use if none is specified, and populate the cache option for CPU
 127 # SIMD.
 128 include(gmxDetectTargetArchitecture)
 129 gmx_detect_target_architecture()
 130
 131 ########################################################################
 132 # User input options                                                   #
 133 ########################################################################
 134 include(gmxOptionUtilities)
 135
 136 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 137
 138 if(GMX_TARGET_FUJITSU_SPARC64)
 139     # Fujitsu only has SIMD in double precision, so this will be faster
 140     set(GMX_DOUBLE_DEFAULT ON)
 141 else()
 142     set(GMX_DOUBLE_DEFAULT OFF)
 143 endif()
 144 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" ${GMX_DOUBLE_DEFAULT})
 145 option(GMX_RELAXED_DOUBLE_PRECISION "Accept single precision 1/sqrt(x) when using Fujitsu HPC-ACE SIMD" OFF)
 146 mark_as_advanced(GMX_RELAXED_DOUBLE_PRECISION)
 147
 148 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 149 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 150 gmx_dependent_option(
 151     GMX_MPI_IN_PLACE
 152     "Enable MPI_IN_PLACE for MPIs that have it defined"
 153     ON
 154     GMX_MPI)
 155 mark_as_advanced(GMX_MPI_IN_PLACE)
 156 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 157 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 158 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 159 mark_as_advanced(GMX_FAHCORE)
 160
 161 option(GMX_COOL_QUOTES "Enable Gromacs cool quotes" ON)
 162 mark_as_advanced(GMX_COOL_QUOTES)
 163 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 164
 165 # Decide on GPU settings based on user-settings and GPU/CUDA detection.
 166 # We support CUDA >=v4.0 on *nix, but <= v4.1 doesn't work with MSVC
 167 if(MSVC)
 168     set(REQUIRED_CUDA_VERSION 4.1)
 169 else()
 170     set(REQUIRED_CUDA_VERSION 4.0)
 171 endif()
 172 set(REQUIRED_CUDA_COMPUTE_CAPABILITY 2.0)
 173 include(gmxManageGPU)
 174
 175 include(gmxDetectSimd)
 176 gmx_detect_simd(GMX_SUGGESTED_SIMD)
 177
 178 gmx_option_multichoice(
 179     GMX_SIMD
 180     "SIMD instruction set for CPU kernels and compiler optimization"
 181     "${GMX_SUGGESTED_SIMD}"
 182     None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 MIC ARM_NEON ARM_NEON_ASIMD IBM_QPX IBM_VMX IBM_VSX Sparc64_HPC_ACE Reference)
 183
 184 gmx_option_multichoice(
 185     GMX_FFT_LIBRARY
 186     "FFT library"
 187     "fftw3"
 188     fftw3 mkl "fftpack[built-in]")
 189 gmx_dependent_option(
 190     GMX_BUILD_OWN_FFTW
 191     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 192     OFF
 193     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 194 gmx_dependent_option(
 195     GMX_DISABLE_FFTW_MEASURE
 196     "Do not optimize FFTW setups (not needed with SSE)"
 197     OFF
 198     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 199 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 200 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 201
 202 gmx_option_multichoice(
 203     GMX_QMMM_PROGRAM
 204     "QM package for QM/MM"
 205     None
 206     none gaussian mopac gamess orca)
 207
 208 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 209 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 210
 211 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 212
 213 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 214 mark_as_advanced(GMX_BROKEN_CALLOC)
 215 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 216 mark_as_advanced(GMX_LOAD_PLUGINS)
 217
 218 option(GMX_GPU  "Enable GPU acceleration" ON)
 219 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 220
 221 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 222
 223 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 224
 225 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 226 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 227
 228 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 229 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 230
 231 option(GMX_BUILD_FOR_COVERAGE
 232        "Tune build for better code coverage metrics (e.g., disable asserts)"
 233        OFF)
 234 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 235
 236 option(GMX_DEVELOPER_BUILD
 237     "Enable Developer convenience features: always build unit-tests"
 238     OFF)
 239 mark_as_advanced(GMX_DEVELOPER_BUILD)
 240
 241 ######################################################################
 242 # Detect OpenMP support
 243 ######################################################################
 244 # The OpenMP detection _must_ come before tests for other CFLAGS.
 245 include(gmxManageOpenMP)
 246
 247
 248
 249 ######################################################################
 250 # Compiler tests
 251 # These need to be done early (before further tests).
 252 #####################################################################
 253
 254 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 255 # are used with permission from CMake v3.0.0 so that GROMACS can detect
 256 # invalid options with the Intel Compilers, and we have added a line
 257 # to detect warnings with the Fujitsu compilers on K computer and ICC.
 258 # CMake-3.0 also has a bug where the FAIL_REGEX pattern for AIX contains
 259 # a semicolon. Since this is also used as a separator in lists inside CMake,
 260 # that string ends up being split into two separate patterns, and the last
 261 # part is just a single word that also matches other messages. We solved this
 262 # by replacing the semicolon with a period that matches any character.
 263 #
 264 # These files should be removed from the source tree when a CMake version that
 265 # includes the features in question becomes required for building GROMACS.
 266 include(CheckCCompilerFlag)
 267 include(CheckCXXCompilerFlag)
 268
 269 include(gmxCFlags)
 270 gmx_c_flags()
 271
 272 # This variable should be used for additional compiler flags which are not
 273 # generated in gmxCFlags nor are SIMD or MPI related.
 274 set(EXTRA_C_FLAGS "")
 275 set(EXTRA_CXX_FLAGS "")
 276
 277 # Run through a number of tests for buggy compilers and other issues
 278 include(gmxTestCompilerProblems)
 279 gmx_test_compiler_problems()
 280 # GMX_SIMD will not be set automatically until the second
 281 # pass (which is not strictly guaranteed to occur), so putting this
 282 # check here among logically-related tests is inefficient, but the
 283 # potential loss is likely zero.
 284 if(GMX_SIMD STREQUAL "AVX_256"
 285         AND CMAKE_COMPILER_IS_GNUCC
 286         AND (C_COMPILER_VERSION VERSION_EQUAL "4.6.1"
 287             OR CXX_COMPILER_VERSION VERSION_EQUAL "4.6.1"))
 288     message(FATAL_ERROR "gcc 4.6.1 has buggy support for AVX, and GROMACS mdrun will not work. If you want simulation performance, use a more recent compiler. Otherwise, use GMX_SIMD=SSE4.1")
 289     # See http://gcc.gnu.org/bugzilla/show_bug.cgi?id=49002
 290 endif()
 291
 292
 293 if(GMX_DOUBLE)
 294     add_definitions(-DGMX_DOUBLE)
 295     list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_DOUBLE")
 296     if(GMX_RELAXED_DOUBLE_PRECISION)
 297         add_definitions(-DGMX_RELAXED_DOUBLE_PRECISION)
 298     endif()
 299 endif()
 300 if(GMX_SOFTWARE_INVSQRT)
 301     list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_SOFTWARE_INVSQRT")
 302 endif()
 303
 304 if(WIN32)
 305     list(APPEND GMX_EXTRA_LIBRARIES "wsock32")
 306     add_definitions(-DGMX_HAVE_WINSOCK)
 307 endif()
 308
 309
 310
 311 ########################################################################
 312 # Basic system tests (standard libraries, headers, functions, types)   #
 313 ########################################################################
 314 include(CheckIncludeFiles)
 315 include(CheckIncludeFileCXX)
 316 check_include_files(unistd.h     HAVE_UNISTD_H)
 317 check_include_files(pwd.h        HAVE_PWD_H)
 318 check_include_files(dirent.h     HAVE_DIRENT_H)
 319 check_include_files(time.h       HAVE_TIME_H)
 320 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 321 check_include_files(io.h         HAVE_IO_H)
 322 check_include_files(sched.h      HAVE_SCHED_H)
 323
 324 check_include_files(regex.h      HAVE_POSIX_REGEX)
 325 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 326 # TODO: It could be nice to inform the user if no regex support is found,
 327 # as selections won't be fully functional.
 328
 329 include(CheckFunctionExists)
 330 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 331 check_function_exists(memalign          HAVE_MEMALIGN)
 332 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 333 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 334 check_function_exists(fsync             HAVE_FSYNC)
 335 check_function_exists(_fileno           HAVE__FILENO)
 336 check_function_exists(fileno            HAVE_FILENO)
 337 check_function_exists(_commit           HAVE__COMMIT)
 338 check_function_exists(sigaction         HAVE_SIGACTION)
 339 check_function_exists(sysconf           HAVE_SYSCONF)
 340 check_function_exists(rsqrt             HAVE_RSQRT)
 341 check_function_exists(rsqrtf            HAVE_RSQRTF)
 342 check_function_exists(sqrtf             HAVE_SQRTF)
 343 check_function_exists(nice              HAVE_NICE)
 344
 345 include(CheckLibraryExists)
 346 check_library_exists(m sqrt "" HAVE_LIBM)
 347 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 348 check_library_exists(m feenableexcept "" HAVE_FEENABLEEXCEPT)
 349
 350 include(TestSchedAffinity)
 351 test_sched_affinity(HAVE_SCHED_AFFINITY)
 352
 353 include(TestBigEndian)
 354 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 355
 356 set(GMX_USE_NICE 0)
 357 if (HAVE_UNISTD_H AND HAVE_NICE)
 358     set(GMX_USE_NICE 1)
 359 endif()
 360
 361 # Management of GROMACS options for specific toolchains should go
 362 # here. Because the initial settings for some of the main options have
 363 # already happened, but things like library detection and MPI compiler
 364 # feature detection have not, the docstrings for any over-rides of
 365 # GROMACS defaults or user settings will make sense. Also, any
 366 # toolchain-related reasons for choosing whether to detect various
 367 # things can be sorted out now, before the detection takes place.
 368 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 369     include(gmxManageBlueGene)
 370 endif()
 371
 372 if(GMX_TARGET_FUJITSU_SPARC64)
 373     include(gmxManageFujitsuSparc64)
 374 endif()
 375
 376 ########################################################################
 377 #Process MPI settings
 378 ########################################################################
 379 include(gmxManageMPI)
 380
 381
 382 ########################################################################
 383 #Process shared/static library settings
 384 ########################################################################
 385 include(gmxManageSharedLibraries)
 386
 387
 388 ########################################################################
 389 # Find external packages                                               #
 390 ########################################################################
 391
 392 # Unconditionally find the package, as it is also required for unit
 393 # tests. This exports LIBXML2_FOUND, which we should not use because
 394 # it does not tell us that linking will succeed. Instead, we test that
 395 # next.
 396 if(DEFINED LIBXML2_LIBRARIES)
 397   set(LibXml2_FIND_QUIETLY TRUE)
 398 endif()
 399 find_package(LibXml2)
 400 include(gmxTestLibXml2)
 401 gmx_test_libxml2(HAVE_LIBXML2)
 402 option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 403 set(PKG_XML "")
 404 mark_as_advanced(GMX_XML)
 405 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 406 #if(GMX_XML AND NOT HAVE_LIBXML2)
 407 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 408 #endif()
 409 #if(GMX_XML)
 410 #    include_directories(${LIBXML2_INCLUDE_DIR})
 411 #    set(PKG_XML libxml-2.0)
 412 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 413 #endif()
 414
 415 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 416 mark_as_advanced(GMX_EXTRAE)
 417
 418 if (GMX_EXTRAE)
 419   find_package(EXTRAE)
 420   if(EXTRAE_FOUND)
 421     include_directories(${EXTRAE_INCLUDE_DIR})
 422     set(HAVE_EXTRAE 1)
 423   else()
 424     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 425   endif()
 426 endif()
 427
 428 option(GMX_X11 "Use X window system" OFF)
 429 if (GMX_X11)
 430     find_package(X11)
 431     # X11 includes/libraries are only set in the ngmx subdirectory!
 432     if(NOT X11_FOUND)
 433         message(FATAL_ERROR
 434                 "X11 include files and/or libraries were not found. "
 435                 "Set GMX_X11=OFF to compile without X11 support. "
 436                 "gmx view will not be available.")
 437     endif()
 438     include_directories(${X11_INCLUDE_DIR})
 439 endif()
 440
 441 include(ThreadMPI)
 442 # Enable core threading facilities
 443 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 444 # Enable tMPI C++ support
 445 tmpi_enable_cxx()
 446 if(GMX_THREAD_MPI)
 447     # enable MPI functions
 448     tmpi_enable()
 449     set(MPI_IN_PLACE_EXISTS 1)
 450 endif()
 451 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 452 if (TMPI_ATOMICS_DISABLED)
 453    add_definitions(-DTMPI_ATOMICS_DISABLED)
 454 endif()
 455
 456 if(GMX_GPU)
 457     # now that we have detected the dependencies, do the second configure pass
 458     gmx_gpu_setup()
 459 endif()
 460
 461 if(CYGWIN)
 462     set(GMX_CYGWIN 1)
 463 endif()
 464
 465 if(WIN32)
 466     set(GMX_NATIVE_WINDOWS 1)
 467     # This makes windows.h not declare min/max as macros that would break
 468     # C++ code using std::min/std::max.
 469     add_definitions(-DNOMINMAX)
 470 endif()
 471
 472 # Detect boost unless GMX_EXTERNAL_BOOST is explicitly OFF
 473 # Used for default if GMX_EXTERNAL_BOOST is not defined (first CMake pass)
 474 if(NOT DEFINED GMX_EXTERNAL_BOOST OR GMX_EXTERNAL_BOOST)
 475     find_package(Boost 1.44.0)
 476     if(Boost_FOUND AND Boost_VERSION VERSION_LESS "104400")
 477         set(Boost_FOUND FALSE)
 478     endif()
 479     # Print the notification only on first run, when determining the default
 480     if(NOT DEFINED GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 481         message("Boost >= 1.44 not found. Using minimal internal version. "
 482                 "This may cause trouble if you plan on compiling/linking other "
 483                 "software that uses Boost against Gromacs.")
 484     endif()
 485 endif()
 486 option(GMX_EXTERNAL_BOOST "Use external Boost instead of minimal built-in version"
 487        ${Boost_FOUND})
 488 if(GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 489     message(FATAL_ERROR
 490         "Boost >= 1.44 not found. "
 491         "You can set GMX_EXTERNAL_BOOST=OFF to compile against minimal "
 492         "version of Boost included with Gromacs.")
 493 endif()
 494
 495 if(NOT DEFINED GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 496     message(WARNING "libxml2 not found. Will build GROMACS without unit-tests. This is not recommended, because the unit-tests help to verify that GROMACS functions correctly. Most likely you are missing the libxml2-dev(el) package. After you installed it, set GMX_BUILD_UNITTESTS=ON.")
 497 endif()
 498 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ${HAVE_LIBXML2})
 499 mark_as_advanced(GMX_BUILD_UNITTESTS)
 500 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 501 if (GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 502     message(FATAL_ERROR
 503         "Cannot build unit tests without libxml2. "
 504         "Either set GMX_BUILD_UNITTESTS=OFF or tell CMake how to find a working version of libxml2.")
 505 endif()
 506
 507 if(GMX_USE_TNG AND NOT GMX_EXTERNAL_TNG)
 508     # TNG wants zlib if it is available
 509     find_package(ZLIB QUIET)
 510     include(gmxTestZLib)
 511     gmx_test_zlib(HAVE_ZLIB)
 512 endif()
 513
 514 ########################################################################
 515 # Our own GROMACS tests
 516 ########################################################################
 517
 518 add_definitions( -DHAVE_CONFIG_H )
 519 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src)
 520 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include)
 521 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 522 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src)
 523
 524 include(gmxTestInlineASM)
 525 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 526
 527 include(gmxSetBuildInformation)
 528 gmx_set_build_information()
 529 # Turn on RDTSCP if:
 530 # - the build system's CPU supports it
 531 # - the acceleration is set to AVX as all AVX-capable CPUs support AVX (which
 532 #   at this point means that the user set it).
 533 # Note: it's better to not use the later set value of GMX_SIMD because
 534 # it reflects the system's capability of both compiling and running AVX code.
 535 # TODO: After merge with 5.0 one could implement a cache variable dependency
 536 # such that GMX_USE_RDTSCP can change if GMX_SIMD is changed to AVX
 537 # after the first cmake pass.
 538 if (BUILD_CPU_FEATURES MATCHES "rdtscp" OR GMX_SIMD MATCHES "AVX")
 539     set(GMX_USE_RDTSCP_DEFAULT_VALUE ON)
 540 else()
 541     set(GMX_USE_RDTSCP_DEFAULT_VALUE OFF)
 542 endif()
 543 option(GMX_USE_RDTSCP "Use RDTSCP for better CPU-based timers (available on recent x86 CPUs; might need to be off when compiling for heterogeneous environments)" ${GMX_USE_RDTSCP_DEFAULT_VALUE})
 544 mark_as_advanced(GMX_USE_RDTSCP)
 545 if(GMX_USE_RDTSCP)
 546     set(HAVE_RDTSCP 1)
 547 endif()
 548
 549 include(gmxTestFloatFormat)
 550 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 551                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 552                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 553
 554 include(gmxTestLargeFiles)
 555 gmx_test_large_files(GMX_LARGEFILES)
 556
 557 include(gmxTestSignal)
 558 gmx_test_sigusr1(HAVE_SIGUSR1)
 559
 560 include(gmxTestPipes)
 561 gmx_test_pipes(HAVE_PIPES)
 562
 563 include(gmxTestIsfinite)
 564 gmx_test_isfinite(HAVE_ISFINITE)
 565 gmx_test__isfinite(HAVE__ISFINITE)
 566 gmx_test__finite(HAVE__FINITE)
 567
 568 include(gmxTestCXX11)
 569 gmx_test_cxx11(GMX_CXX11_SUPPORTED GMX_CXX11_FLAGS)
 570 include(CMakeDependentOption)
 571 # clang with some older versions of boost fail to work with C++11
 572 if(CMAKE_CXX_COMPILER_ID MATCHES Clang AND
 573     (Boost_VERSION VERSION_EQUAL 104601 OR Boost_VERSION VERSION_EQUAL 104700))
 574     set(CLANG_AND_OLD_EXTERNAL_BOOST TRUE)
 575 endif()
 576 # nvcc does not support C++11 flags, so with GPUs we prefer to skip C++11 flags
 577 # entirely to keep the compilation environment uniform.
 578 cmake_dependent_option(GMX_CXX11
 579     "Use C++11 features"
 580     ON "GMX_CXX11_SUPPORTED AND NOT GMX_GPU AND NOT CLANG_AND_OLD_EXTERNAL_BOOST" OFF)
 581 mark_as_advanced(GMX_CXX11)
 582 if(GMX_CXX11)
 583     set(EXTRA_CXX_FLAGS "${EXTRA_CXX_FLAGS} ${GMX_CXX11_FLAGS}")
 584 endif()
 585
 586
 587 include(gmxTestXDR)
 588 gmx_test_xdr(GMX_SYSTEM_XDR)
 589 if(NOT GMX_SYSTEM_XDR)
 590     set(GMX_INTERNAL_XDR 1)
 591 endif()
 592
 593
 594 ##################################################
 595 # Process SIMD instruction settings
 596 ##################################################
 597 # This checks what flags to add in order to
 598 # support the SIMD instructions we need, and sets
 599 # correct defines for the SIMD instructions supported.
 600 include(gmxTestSimd)
 601 gmx_test_simd()
 602
 603
 604 # Process QM/MM Settings
 605 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 606     set(GMX_QMMM_GAUSSIAN 1)
 607 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 608     set(GMX_QMMM_MOPAC 1)
 609 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 610     set(GMX_QMMM_GAMESS 1)
 611 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 612     set(GMX_QMMM_ORCA 1)
 613 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 614     # nothing to do
 615 else()
 616     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 617 endif()
 618
 619
 620 ##################################################
 621 # Process FFT library settings
 622 ##################################################
 623 include(gmxManageFFTLibraries)
 624
 625
 626 include(gmxManageLinearAlgebraLibraries)
 627
 628 # Whether GROMACS will really try to compile support for VMD plugins
 629 set(GMX_USE_PLUGINS OFF)
 630
 631 if(GMX_LOAD_PLUGINS)
 632   if(NOT WIN32)
 633     # Native Windows does not have, nor need dlopen
 634     include(gmxTestdlopen)
 635     gmx_test_dlopen(HAVE_DLOPEN)
 636   endif()
 637
 638   # so, should we use plug-ins?
 639   if(WIN32 OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 640     if(NOT VMD_QUIETLY)
 641       MESSAGE(STATUS "Using dynamic plugins (e.g VMD-supported file formats)")
 642     endif()
 643     if(NOT GMX_VMD_PLUGIN_PATH)
 644       find_package(VMD)
 645     endif()
 646     set(GMX_USE_PLUGINS ON)
 647     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 648     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 649   else()
 650     set(PKG_DL_LIBS)
 651   endif()
 652 endif()
 653 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 654
 655 # Link real-time library for POSIX timers. The check for clock_gettime
 656 # confirms the linkability of rt.
 657 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 658     list(APPEND GMX_EXTRA_LIBRARIES rt)
 659 endif()
 660
 661 # Math and thread libraries must often come after all others when linking...
 662 if(HAVE_LIBM)
 663     list(APPEND GMX_EXTRA_LIBRARIES m)
 664 endif()
 665
 666 option(GMX_NACL "Configure for Native Client builds" OFF)
 667 if (GMX_NACL)
 668   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 669   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 670   # TODO: Is this still necessary with the check for its presence?
 671   set(GMX_USE_NICE 0)
 672   set(GMX_NO_RENAME 1)
 673 endif()
 674 mark_as_advanced(GMX_NACL)
 675
 676 if(GMX_FAHCORE)
 677   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 678       "Path to swindirect.h")
 679   include_directories(${COREWRAP_INCLUDE_DIR})
 680 endif()
 681
 682 # Value of AUTO tries to generate things, but will only produce warnings if
 683 # that fails.
 684 set(build_help_default AUTO)
 685 if (SOURCE_IS_SOURCE_DISTRIBUTION)
 686     set(build_help_default OFF)
 687 endif()
 688 gmx_option_trivalue(GMX_BUILD_HELP "Build man pages, HTML help, and completions automatically (requires that compiled binaries can be executed on the build host)" ${build_help_default})
 689 mark_as_advanced(GMX_BUILD_HELP)
 690 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND BUILD_IS_INSOURCE)
 691     message(FATAL_ERROR
 692         "Rebuilding HTML and man pages or shell completions is not supported "
 693         "for in-source builds from a source distribution. "
 694         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 695 endif()
 696
 697 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 698 # these are set after everything else
 699 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 700     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 701     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 702     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 703     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 704 else()
 705     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 706     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 707     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 708     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 709     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 710     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 711     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 712     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 713     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
 714 endif()
 715
 716 if(NOT GMX_OPENMP)
 717     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 718     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 719     unset(OpenMP_C_FLAGS CACHE)
 720     unset(OpenMP_CXX_FLAGS CACHE)
 721 else()
 722     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 723     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 724 endif()
 725
 726 ########################################################################
 727 # Specify install locations
 728 ########################################################################
 729 # Use GNUInstallDirs to set paths on multiarch systems.
 730 include(GNUInstallDirs)
 731
 732 # Customization for the installation tree paths.
 733 set(GMX_LIB_INSTALL_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING
 734     "Library installation directory (default: ${CMAKE_INSTALL_LIBDIR})")
 735 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 736     "Data installation directory under share/ (default: gromacs)")
 737 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 738
 739 # These variables are used internally to provide a central location for
 740 # customizing the install locations.
 741 set(LIB_INSTALL_DIR       ${GMX_LIB_INSTALL_DIR})
 742 set(BIN_INSTALL_DIR       bin)
 743 set(DATA_INSTALL_DIR      share/${GMX_DATA_INSTALL_DIR})
 744 set(MAN_INSTALL_DIR       share/man)
 745 # If the nesting level wrt. the installation root is changed,
 746 # gromacs-config.cmake.cmakein needs to be adapted.
 747 set(CMAKE_INSTALL_DIR     share/cmake)
 748 # TODO: Make GMXRC adapt if this is changed
 749 set(PKGCONFIG_INSTALL_DIR ${LIB_INSTALL_DIR}/pkgconfig)
 750 set(INCL_INSTALL_DIR      include)
 751
 752 # These variables get written into config.h for use in finding the data
 753 # directories.
 754 set(GMXLIB_SEARCH_DIR share/${GMX_DATA_INSTALL_DIR}/top)
 755 set(GMXLIB_FALLBACK   ${CMAKE_INSTALL_PREFIX}/${DATA_INSTALL_DIR}/top)
 756
 757 list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${INCL_INSTALL_DIR})
 758
 759 # Binary and library suffix options
 760 include(gmxManageSuffixes)
 761
 762 ################################################################
 763 # Shared library load path settings
 764 ################################################################
 765 # CMake supports RPATH on OS X only from 2.8.12 upwards.
 766 # CMAKE_SYSTEM_VERSION > 8.0 matches OS X 10.5 and above, where RPATH support
 767 # was added.
 768 if((NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin") OR
 769    ((CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) AND (NOT CMAKE_VERSION VERSION_LESS 2.8.12)))
 770     # The build folder always has bin/ and lib/; if we are also going to
 771     # install to lib/, then the installation RPATH works also in the build
 772     # tree.  This makes installation slightly faster (no need to rewrite the
 773     # RPATHs), and makes the binaries in the build tree relocatable.
 774     if(GMX_LIB_INSTALL_DIR STREQUAL "lib")
 775         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 776     endif()
 777     # Set the RPATH as relative to the executable location to make the
 778     # binaries relocatable.
 779     if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 780         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${GMX_LIB_INSTALL_DIR}")
 781     else()
 782         set(CMAKE_INSTALL_RPATH "@executable_path/../${GMX_LIB_INSTALL_DIR}")
 783     endif()
 784     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 785     set(CMAKE_MACOSX_RPATH 1)
 786 else()
 787     # We are on Darwin/OSX, and CMake cannot handle RPATHs automatically.
 788     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0)
 789         # Set the RPATH options manually.
 790         set(CMAKE_INSTALL_NAME_DIR "@rpath")
 791         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../${GMX_LIB_INSTALL_DIR}")
 792     else()
 793         # Use the old INSTALL_NAME_DIR mechanism if RPATH is not supported.
 794         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
 795     endif()
 796 endif()
 797
 798 #COPYING file: Only necessary for binary distributions.
 799 #Simpler to always install.
 800 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 801
 802 if(GMX_EXTERNAL_BOOST)
 803     include_directories(${Boost_INCLUDE_DIRS})
 804     list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${Boost_INCLUDE_DIRS})
 805 else()
 806     include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/boost)
 807     list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${INCL_INSTALL_DIR}/gromacs/external/boost)
 808     list(APPEND INSTALLED_HEADED_DEFINITIONS "-DBOOST_NO_TYPEID")
 809     # typeid not supported for minimal internal version
 810     # (would add significant amount of code)
 811     add_definitions(-DBOOST_NO_TYPEID)
 812     if (NOT GMX_BUILD_MDRUN_ONLY)
 813         install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
 814                 DESTINATION ${INCL_INSTALL_DIR}/gromacs/external/boost
 815                 COMPONENT development)
 816     endif()
 817 endif()
 818
 819 if (GMX_BUILD_FOR_COVERAGE)
 820     # Code heavy with asserts makes conditional coverage close to useless metric,
 821     # as by design most of the false branches are impossible to trigger in
 822     # correctly functioning code.  And the benefit of testing those that could
 823     # be triggered by using an API against its specification isn't usually
 824     # worth the effort.
 825     add_definitions(-DNDEBUG -DBOOST_DISABLE_ASSERTS -DGMX_DISABLE_ASSERTS)
 826 endif()
 827
 828 if (BUILD_TESTING)
 829     # "tests" target builds all the separate test binaries.
 830     add_custom_target(tests)
 831     # "run-ctest" is an internal target that actually runs the tests.
 832     # This is necessary to be able to add separate targets that execute as part
 833     # of 'make check', but are ensured to be executed after the actual tests.
 834     add_custom_target(run-ctest
 835                       COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure
 836                       COMMENT "Running all tests"
 837                       VERBATIM)
 838     add_dependencies(run-ctest tests)
 839     # "check" target builds and runs all tests.
 840     add_custom_target(check DEPENDS run-ctest)
 841 endif()
 842
 843 if (NOT GMX_BUILD_MDRUN_ONLY)
 844     add_subdirectory(docs)
 845     add_subdirectory(share)
 846     add_subdirectory(scripts)
 847 endif()
 848 add_subdirectory(src)
 849
 850 if (BUILD_TESTING)
 851     add_subdirectory(tests)
 852 endif()
 853
 854 gmx_cpack_write_config()
 855
 856 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 857 # Don't bother the user after the first configure pass.
 858 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 859     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 860 endif()
 861 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 862
 863 #######################
 864 ## uninstall target
 865 #######################
 866 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 867                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 868                   IMMEDIATE @ONLY)
 869 ###########################
 870 ADD_CUSTOM_TARGET(uninstall
 871                   "${CMAKE_COMMAND}" -P
 872                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 873 ###########################
 874 set_directory_properties(PROPERTIES
 875             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")