CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.6)
   2
   3 project(Gromacs)
   4 include(Dart)
   5 mark_as_advanced(DART_ROOT)
   6 # PROJECT_VERSION should have the following structure:
   7 # VERSION[-dev-SUFFIX] where the VERSION can have any form and the suffix
   8 set(PROJECT_VERSION "4.5.1")
   9 set(CUSTOM_VERSION_STRING ""
  10     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  11 mark_as_advanced(CUSTOM_VERSION_STRING)
  12 if (CUSTOM_VERSION_STRING)
  13     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  14 endif (CUSTOM_VERSION_STRING)
  15 set(SOVERSION 6)
  16 # It is a bit irritating, but this has to be set separately for now!
  17 SET(CPACK_PACKAGE_VERSION_MAJOR "4")
  18 SET(CPACK_PACKAGE_VERSION_MINOR "5")
  19 SET(CPACK_PACKAGE_VERSION_PATCH "1")
  20
  21
  22 # Cmake modules/macros are in a subdirectory to keep this file cleaner
  23 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  24
  25 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  26 set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  27 endif()
  28
  29 if(NOT CMAKE_BUILD_TYPE)
  30     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
  31 endif(NOT CMAKE_BUILD_TYPE)
  32
  33 enable_language(C)
  34
  35 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
  36 set(CPACK_PACKAGE_VENDOR "gromacs.org")
  37 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
  38 set(CPACK_SET_DESTDIR "ON")
  39 set(CPACK_INCLUDE_TOPLEVEL_DIRECTORY 0)
  40 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
  41 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
  42 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/admin/InstallLicense.txt")
  43 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
  44
  45 #must come after all cpack settings!
  46 include(CPack)
  47
  48
  49 ########################################################################
  50 # Fix stupid flags on MSVC
  51 ########################################################################
  52 SET(SHARED_LIBS_DEFAULT ON)
  53 IF(CMAKE_GENERATOR MATCHES "Visual Studio")
  54     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
  55     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
  56     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
  57     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
  58     SET(SHARED_LIBS_DEFAULT OFF)
  59 ENDIF(CMAKE_GENERATOR MATCHES "Visual Studio")
  60
  61 set(GMX_EXTRA_LIBRARIES)
  62
  63
  64
  65 ######################################################################
  66 # compiler tests
  67 # these need ot be done early (before further tests).
  68 #####################################################################
  69
  70 include(CheckCCompilerFlag)
  71 include(CheckCXXCompilerFlag)
  72
  73 include(gmxCFlags)
  74 gmx_c_flags()
  75
  76 ########################################################################
  77 # User input options                                                   #
  78 ########################################################################
  79 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
  80 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
  81 option(GMX_THREADS    "Build a parallel (thread-based) version of GROMACS (cannot be combined with MPI yet)" ON)
  82 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
  83 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
  84 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
  85 mark_as_advanced(GMX_FAHCORE)
  86 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library (rerun cmake after changing to see relevant options)" OFF)
  87 set(GMX_ACCELERATION "auto"
  88     CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec")
  89
  90 set(GMX_FFT_LIBRARY "fftw3"
  91     CACHE STRING "FFT library choices: fftw3,fftw2,mkl,fftpack[built-in]")
  92 option(GMX_DISABLE_FFTW_MEASURE
  93        "Do not optimize FFTW setups (not needed with SSE)" OFF)
  94 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
  95 set(GMX_QMMM_PROGRAM "none"
  96     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
  97 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
  98 mark_as_advanced(GMX_BROKEN_CALLOC)
  99 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI, Windows)" ${SHARED_LIBS_DEFAULT})
 100 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
 101 mark_as_advanced(GMX_MPI_IN_PLACE)
 102 option(GMX_DLOPEN "Compile with dlopen, needed to read VMD supported file formats" ON)
 103 mark_as_advanced(GMX_DLOPEN)
 104
 105
 106 option(GMX_IA32_ASM "Add SSE assembly files for IA32" OFF)
 107 mark_as_advanced(GMX_IA32_ASM)
 108 option(GMX_X86_64_ASM "Add SSE assembly files for X86_64" OFF)
 109 mark_as_advanced(GMX_X86_64_ASM)
 110
 111 option(USE_VERSION_H "Generate development version string/information" ON)
 112 mark_as_advanced(USE_VERSION_H)
 113
 114 option(GMX_DEFAULT_SUFFIX "Use default suffixes for GROMACS binaries and libs (_d for double, _mpi for MPI; rerun cmake after changing to see relevant options)" ON)
 115
 116 ########################################################################
 117 # Set up binary and library suffixing
 118 ########################################################################
 119 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 120 set(GMX_LIBS_SUFFIX ""
 121   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 122 if (GMX_DEFAULT_SUFFIX)
 123   set(GMX_BINARY_SUFFIX "")
 124   set(GMX_LIBS_SUFFIX "")
 125   if (GMX_MPI)
 126     set(GMX_BINARY_SUFFIX "_mpi")
 127     set(GMX_LIBS_SUFFIX "_mpi")
 128   endif(GMX_MPI)
 129   if (GMX_DOUBLE)
 130     set (GMX_BINARY_SUFFIX "${GMX_BINARY_SUFFIX}_d")
 131     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
 132   endif(GMX_DOUBLE)
 133   if (GMX_OPENMM)
 134     set (GMX_BINARY_SUFFIX "-gpu")
 135     set (GMX_LIBS_SUFFIX "_gpu")
 136   endif(GMX_OPENMM)
 137   mark_as_advanced(FORCE GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 138   message(STATUS "Using default binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 139   message(STATUS "Using default library suffix: \"${GMX_LIBS_SUFFIX}\"")
 140 else(GMX_DEFAULT_SUFFIX)
 141   mark_as_advanced(CLEAR GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 142   message(STATUS "Using manually set binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 143   message(STATUS "Using manually set library suffix: \"${GMX_LIBS_SUFFIX}\"")
 144 endif(GMX_DEFAULT_SUFFIX)
 145
 146 set(PKG_CFLAGS "")
 147 if(GMX_DOUBLE)
 148     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 149 endif(GMX_DOUBLE)
 150 if(GMX_SOFTWARE_INVSQRT)
 151   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 152 endif(GMX_SOFTWARE_INVSQRT)
 153
 154 ########################################################################
 155 #Process MPI settings
 156 ########################################################################
 157 if(GMX_MPI)
 158         MESSAGE(WARNING "
 159             There are known problems with some MPI implementations:
 160                      OpenMPI version < 1.4.1
 161                      MVAPICH2 version <= 1.4.1                               *")
 162     if(GMX_THREADS)
 163         #message(FATAL_ERROR "Thread-based parallelization conflicts with MPI.")
 164         set(GMX_THREADS OFF CACHE BOOL
 165             "Thread-based parallelization conflicts with MPI." FORCE)
 166     endif(GMX_THREADS)
 167     find_package(MPI)
 168     if(MPI_FOUND)
 169         set(GROMACS_C_FLAGS ${GROMACS_FLAGS} ${MPI_COMPILE_FLAGS})
 170         set(GROMACS_LINKER_FLAGS ${GROMACS_LINKER_FLAGS} ${MPI_LINK_FLAGS})
 171
 172         include_directories(${MPI_INCLUDE_PATH})
 173         list(APPEND GMX_EXTRA_LIBRARIES ${MPI_LIBRARIES})
 174         add_definitions( -DMPI ) #for FAHCORE
 175         include(gmxTestMPI_IN_PLACE)
 176         if (GMX_MPI_IN_PLACE)
 177             gmx_test_mpi_in_place(MPI_IN_PLACE_EXISTS)
 178         endif (GMX_MPI_IN_PLACE)
 179     else(MPI_FOUND)
 180         message(FATAL_ERROR "MPI support requested, but no MPI compiler found.")
 181     endif(MPI_FOUND)
 182     include(gmxTestCatamount)
 183     gmx_test_catamount(GMX_CRAY_XT3)
 184     if(GMX_CRAY_XT3)
 185         set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_CRAY_XT3")
 186         set(GMX_NO_SYSTEM 1)
 187         set(GMX_NO_NICE 1)
 188     endif(GMX_CRAY_XT3)
 189     set(GMX_LIB_MPI 1)
 190     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_LIB_MPI")
 191 endif(GMX_MPI)
 192
 193
 194 #######################################################################
 195 # Check for options incompatible with OpenMM build                    #
 196 #######################################################################
 197 if(GMX_OPENMM)
 198     cmake_minimum_required(VERSION 2.6.4)
 199     # we'll use the built-in fft to avoid unnecessary dependencies
 200     string(TOUPPER ${GMX_FFT_LIBRARY} GMX_FFT_LIBRARY)
 201     if(NOT ${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 202         message(STATUS "No external FFT libraries needed for the OpenMM build, switching to fftpack!")
 203         set(GMX_FFT_LIBRARY "fftpack" CACHE STRING
 204                 "No external FFT libraries needed for the OpenMM build, switching to  fftpack!" FORCE)
 205     endif()
 206     if(GMX_MPI)
 207         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
 208     endif(GMX_MPI)
 209     if(GMX_THREADS)
 210         message(STATUS "Threads are  not compatible with OpenMM build, disabled!")
 211         set(GMX_THREADS OFF CACHE BOOL
 212                 "Threads are not compatible with OpenMM build, disabled!" FORCE)
 213     endif(GMX_THREADS)
 214     if(GMX_SOFTWARE_INVSQRT)
 215         set(GMX_SOFTWARE_INVSQRT OFF CACHE STRING
 216                 "The OpenMM build does not need GROMACS software 1/sqrt!" FORCE)
 217     endif(GMX_SOFTWARE_INVSQRT)
 218     string(TOUPPER ${GMX_ACCELERATION} GMX_ACCELERATION)
 219     if(NOT GMX_ACCELERATION STREQUAL "NONE")
 220         message(STATUS "Switching off CPU-based acceleration, the OpenMM build does not support/need any!")
 221         set(GMX_ACCELERATION "none" CACHE STRING
 222                 "Switching off CPU-based acceleration, the OpenMM build does not support/need any!" FORCE)
 223     endif()
 224     if(GMX_FAHCORE)
 225         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
 226     endif(GMX_FAHCORE)
 227     if(GMX_DOUBLE)
 228         message(FATAL_ERROR  "The OpenMM-build does not support double precision calculations!")
 229     endif()
 230     # mark as advanced the unused variables
 231     mark_as_advanced(FORCE GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 232         GMX_QMMM_PROGRAM GMX_THREADS GMX_DOUBLE)
 233 else(GMX_OPENMM)
 234      mark_as_advanced(CLEAR GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 235         GMX_QMMM_PROGRAM GMX_THREADS GMX_DOUBLE)
 236 endif(GMX_OPENMM)
 237
 238
 239 ########################################################################
 240 # Basic system tests (standard libraries, headers, functions, types)   #
 241 ########################################################################
 242 include(CheckIncludeFiles)
 243 check_include_files(string.h     HAVE_STRING_H)
 244 check_include_files(math.h       HAVE_MATH_H)
 245 check_include_files(limits.h     HAVE_LIMITS_H)
 246 check_include_files(memory.h     HAVE_MEMORY_H)
 247 check_include_files(unistd.h     HAVE_UNISTD_H)
 248 check_include_files(pwd.h        HAVE_PWD_H)
 249 check_include_files(stdint.h     HAVE_STDINT_H)
 250 check_include_files(stdlib.h     HAVE_STDLIB_H)
 251 check_include_files(pthread.h    HAVE_PTHREAD_H)
 252 check_include_files(dirent.h     HAVE_DIRENT_H)
 253 check_include_files(inttypes.h   HAVE_INTTYPES_H)
 254 check_include_files(regex.h      HAVE_REGEX_H)
 255 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 256 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
 257 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 258 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
 259 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
 260 # SSE support
 261 check_include_files(xmmintrin.h  HAVE_XMMINTRIN_H)
 262 check_include_files(emmintrin.h  HAVE_EMMINTRIN_H)
 263 check_include_files(pmmintrin.h  HAVE_PMMINTRIN_H)
 264 check_include_files(smmintrin.h  HAVE_SMMINTRIN_H)
 265 check_include_files(io.h                 HAVE_IO_H)
 266
 267
 268 include(CheckFunctionExists)
 269 check_function_exists(strcasecmp        HAVE_STRCASECMP)
 270 check_function_exists(strdup            HAVE_STRDUP)
 271 check_function_exists(vprintf           HAVE_VPRINTF)
 272 check_function_exists(memcmp            HAVE_MEMCMP)
 273 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 274 check_function_exists(memalign          HAVE_MEMALIGN)
 275 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 276 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 277 check_function_exists(isnan             HAVE_ISNAN)
 278 check_function_exists(_isnan            HAVE__ISNAN)
 279 check_function_exists(isfinite          HAVE_ISFINITE)
 280 check_function_exists(_isfinite         HAVE__ISFINITE)
 281 check_function_exists(fsync             HAVE_FSYNC)
 282 check_function_exists(_fileno           HAVE__FILENO)
 283 check_function_exists(fileno            HAVE_FILENO)
 284 check_function_exists(_commit           HAVE__COMMIT)
 285
 286 include(CheckLibraryExists)
 287 check_library_exists(m sqrt "" HAVE_LIBM)
 288 check_library_exists(m cbrt "" HAVE_CBRT)
 289
 290
 291 include(CheckTypeSize)
 292
 293 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 294 check_type_size("int"           SIZEOF_INT)
 295 check_type_size("long int"      SIZEOF_LONG_INT)
 296 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 297 check_type_size("off_t"         SIZEOF_OFF_T)
 298 check_type_size("void *"        SIZEOF_VOIDP)
 299
 300 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 301     set(GMX_64_BIT TRUE)
 302 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 303     set(GMX_64_BIT FALSE)
 304 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 305
 306 # Check for some basic types that we *need*, so set these to int if they are not present
 307 check_type_size(uid_t uid_t)
 308 if(NOT uid_t)
 309   set(uid_t int)
 310 else(NOT uid_t)
 311   set(uid_t 0)
 312 endif(NOT uid_t)
 313
 314 check_type_size(gid_t gid_t)
 315 if(NOT gid_t)
 316   set(gid_t 1)
 317 else(NOT gid_t)
 318   set(gid_t 0)
 319 endif(NOT gid_t)
 320
 321 check_type_size(size_t size_t)
 322 if(NOT size_t)
 323   set(size_t int)
 324 else(NOT size_t)
 325   set(size_t 0)
 326 endif(NOT size_t)
 327
 328 check_type_size(off_t off_t)
 329 if(NOT off_t)
 330   set(off_t int)
 331 else(NOT off_t)
 332   set(off_t 0)
 333 endif(NOT off_t)
 334
 335 include(TestBigEndian)
 336 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 337
 338
 339
 340
 341 ########################################################################
 342 # Find external packages                                               #
 343 ########################################################################
 344
 345 find_package(LibXml2)
 346 set(PKG_XML "")
 347 if(LIBXML2_FOUND)
 348     include_directories(${LIBXML2_INCLUDE_DIR})
 349     set(PKG_XML libxml-2.0)
 350     set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 351     set(HAVE_LIBXML2 1)
 352 endif(LIBXML2_FOUND)
 353
 354 option(GMX_X11 "Use X window system" OFF)
 355 if (GMX_X11)
 356         find_package(X11)
 357         # X11 includes/libraries are only set in the ngmx subdirectory!
 358         if(X11_FOUND)
 359         set(HAVE_X11 1)
 360         endif(X11_FOUND)
 361 endif(GMX_X11)
 362
 363 if(GMX_THREADS)
 364     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREADS")
 365     include(ThreadMPI)
 366     set(THREAD_MPI_LIB thread_mpi)
 367     set(GMX_MPI 1)
 368     string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 369     if(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 370         message(FATAL_ERROR "FFTW2 can't be used with threads. Try fftw3 or mkl.")
 371     endif()
 372 endif(GMX_THREADS)
 373
 374 if(GMX_OPENMM)
 375     set(CUDA_BUILD_EMULATION OFF)
 376     find_package(CUDA 3.1 REQUIRED)
 377     add_definitions(-DGMX_OPENMM)
 378     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 379         set(CUDA_VERBOSE_BUILD ON)
 380     endif()
 381     find_package(OpenMM)
 382 endif(GMX_OPENMM)
 383
 384 if(APPLE)
 385    find_library(ACCELERATE_FRAMEWORK Accelerate)
 386    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 387 endif(APPLE)
 388
 389 # only bother with finding git and using version.h if the source is a git repo
 390 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 391     if(USE_VERSION_H)
 392         # We need at least git v1.5.1 be able to parse git's date output. If not
 393         # fund or the version is too small, we can't generate version information.
 394         find_package(Git 1.5.1)
 395         # this should at some point become VERSION_LESS
 396         if(NOT Git_FOUND OR Git_VERSION STRLESS "1.5.1")
 397             message("No compatible git version found, won't be able to generate proper development version information.")
 398             set(USE_VERSION_H OFF)
 399         endif()
 400     endif()
 401 else()
 402     set(USE_VERSION_H OFF)
 403 endif()
 404
 405 if (GMX_DLOPEN)
 406     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS})
 407 endif (GMX_DLOPEN)
 408
 409 ########################################################################
 410 # Generate development version info for cache
 411 ########################################################################
 412 # set(GEN_VERSION_INFO_INTERNAL "ON")
 413 # include(gmxGenerateVersionString)
 414
 415 ########################################################################
 416 # Our own GROMACS tests
 417 ########################################################################
 418
 419 add_definitions( -DHAVE_CONFIG_H )
 420 include_directories(${CMAKE_BINARY_DIR}/src)
 421 include_directories(${CMAKE_SOURCE_DIR}/include)
 422
 423 include(gmxCheckBuildUserTime)
 424 gmx_check_build_user_time(BUILD_TIME BUILD_USER BUILD_MACHINE)
 425
 426 include(gmxTestFloatFormat)
 427 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 428                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 429                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 430
 431 include(gmxTestLargeFiles)
 432 gmx_test_large_files(GMX_LARGEFILES)
 433 check_function_exists(fseeko     HAVE_FSEEKO)
 434
 435 include(gmxTestSignal)
 436 gmx_test_retsigtype(RETSIGTYPE)
 437 gmx_test_sigusr1(HAVE_SIGUSR1)
 438
 439 include(gmxTestInline)
 440 gmx_test_inline(INLINE_KEYWORD)
 441
 442 include(gmxTestRestrict)
 443 gmx_test_inline(RESTRICT_KEYWORD)
 444
 445 include(gmxTestPipes)
 446 gmx_test_pipes(HAVE_PIPES)
 447
 448 include(gmxTestInlineASM)
 449 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 450 gmx_test_inline_asm_msvc_x86(GMX_X86_MSVC_INLINE_ASM)
 451
 452 # turn on SSE if supported with reasonable defaults.
 453 if (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 454   if(CMAKE_SYSTEM_PROCESSOR MATCHES "^(i.86|x86|x64|x86_64|AMD64|amd64)")
 455
 456     set(GMX_ACCELERATION "SSE" CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec" FORCE)
 457
 458     if (GMX_64_BIT)
 459       set(GMX_X86_64_ASM ON CACHE BOOL "Add SSE assembly files for x86_64" FORCE)
 460     else (GMX_64_BIT)
 461       set(GMX_IA32_ASM ON CACHE BOOL "Add SSE assembly files for i386" FORCE)
 462     endif (GMX_64_BIT)
 463
 464     # Determine the assembler/compiler to use
 465   else()
 466     set(GMX_ACCELERATION "none" CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec" FORCE)
 467   endif()
 468 endif (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 469
 470
 471 include(gmxTestXDR)
 472 gmx_test_xdr(GMX_SYSTEM_XDR)
 473 if(NOT GMX_SYSTEM_XDR)
 474     set(GMX_INTERNAL_XDR 1)
 475     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 476 endif(NOT GMX_SYSTEM_XDR)
 477
 478 if(GMX_FORTRAN OR GMX_POWER6)
 479     enable_language(Fortran)
 480     include(FortranCInterface)
 481     discover_fortran_mangling(prefix isupper suffix extra_under_score found)
 482     if(extra_under_score)
 483         set(extrasuffix "_")
 484     endif(extra_under_score)
 485
 486     if(isupper)
 487         set(F77_FUNCDEF   "${prefix} ## NAME ## ${suffix}")
 488         set(F77_FUNCDEF_  "${prefix} ## NAME ## ${suffix}${extrasuffix}")
 489     else(isupper)
 490         set(F77_FUNCDEF   "${prefix} ## name ## ${suffix}")
 491         set(F77_FUNCDEF_  "${prefix} ## name ## ${suffix}${extrasuffix}")
 492     endif(isupper)
 493 else(GMX_FORTRAN OR GMX_POWER6)
 494         set(F77_FUNCDEF   "name ## _")
 495         set(F77_FUNCDEF_  "name ## _")
 496 endif(GMX_FORTRAN OR GMX_POWER6)
 497
 498
 499 # Process nonbonded accelerated kernels settings
 500 string(TOUPPER ${GMX_ACCELERATION} ${GMX_ACCELERATION})
 501 if(${GMX_ACCELERATION} STREQUAL "NONE")
 502   # nothing to do
 503 elseif(${GMX_ACCELERATION} STREQUAL "SSE")
 504
 505     if(CMAKE_GENERATOR MATCHES "Visual Studio")
 506       option(GMX_ASM_USEASM-NASM "Use Nasm for assembly instead of compiler (necessary on windows)" ON)
 507     else()
 508       option(GMX_ASM_USEASM-NASM "Use Nasm for assembly instead of compiler (necessary on windows)" OFF)
 509     endif()
 510         mark_as_advanced(GMX_ASM_USEASM-NASM)
 511
 512     if (NOT GMX_64_BIT)
 513         # for 32-bit compiles, we might need to turn on sse
 514         CHECK_C_COMPILER_FLAG("-msse2" XFLAGS_SSE)
 515         if (XFLAGS_SSE)
 516             set(GROMACS_C_FLAGS "-msse2 ${GROMACS_C_FLAGS}")
 517         endif (XFLAGS_SSE)
 518         CHECK_CXX_COMPILER_FLAG("-msse2" XXFLAGS_SSE)
 519         if (XXFLAGS_SSE)
 520             set(GROMACS_CXX_FLAGS "-msse2 ${GROMACS_CXX_FLAGS}")
 521         endif (XXFLAGS_SSE)
 522     endif (NOT GMX_64_BIT)
 523
 524     if(GMX_IA32_ASM)
 525       if(GMX_DOUBLE)
 526         set(GMX_IA32_SSE2 1)
 527       else()
 528         set(GMX_IA32_SSE 1)
 529       endif()
 530     elseif(GMX_X86_64_ASM)
 531       if(GMX_DOUBLE)
 532         set(GMX_X86_64_SSE2 1)
 533       else()
 534         set(GMX_X86_64_SSE 1)
 535       endif()
 536     endif()
 537
 538 #    if(HAVE_PMMINTRIN_H)
 539 #        set(GMX_SSE3 1)
 540 #    endif(HAVE_PMMINTRIN_H)
 541 #    if(HAVE_SMMINTRIN_H)
 542 #        set(GMX_SSE4_1 1)
 543 #    endif(HAVE_SMMINTRIN_H)
 544
 545 elseif(${GMX_ACCELERATION} STREQUAL "FORTRAN")
 546     set(GMX_FORTRAN 1)
 547 elseif(${GMX_ACCELERATION} STREQUAL "BLUEGENE")
 548     set(GMX_BLUEGENE 1)
 549 elseif(${GMX_ACCELERATION} STREQUAL "POWER6")
 550     set(GMX_POWER6 1)
 551 elseif(${GMX_ACCELERATION} STREQUAL "IA64")
 552     set(GMX_IA64_ASM 1)
 553     set(DISABLE_WATERWATER_NLIST 1)
 554     set(DISABLE_WATER_NLIST 1)
 555 elseif(${GMX_ACCELERATION} STREQUAL "ALTIVEC")
 556     check_include_files(altivec.h HAVE_ALTIVEC_H)
 557     if(HAVE_ALTIVEC_H)
 558         set(GMX_PPC_ALTIVEC 1)
 559     endif(HAVE_ALTIVEC_H)
 560 else(${GMX_ACCELERATION} STREQUAL "NONE")
 561     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_ACCELERATION}. Pick one of auto, none, SSE, Fortran, BlueGene, Power6, ia64, altivec")
 562 endif(${GMX_ACCELERATION} STREQUAL "NONE")
 563
 564
 565 if(GMX_FORTRAN)
 566     if (GMX_THREADS)
 567         message(WARNING "FORTRAN is incompatible with threads and only provides a speed-up on certain IBM compilers. Disable FORTRAN (or threads if you really want to use FORTRAN kernels).")
 568     endif()
 569 endif()
 570
 571
 572
 573
 574
 575 # Process QM/MM Settings
 576 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 577 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 578     set(GMX_QMMM_GAUSSIAN 1)
 579 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 580     set(GMX_QMMM_MOPAC 1)
 581 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 582     set(GMX_QMMM_GAMESS 1)
 583 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 584     set(GMX_QMMM_ORCA 1)
 585 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 586     # nothing to do
 587 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 588     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 589 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 590
 591 # Process FFT library settings - if not OpenMM build
 592 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 593 set(PKG_FFT "")
 594 set(PKG_FFT_LIBS "")
 595 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 596 #    MESSAGE(STATUS "Using external FFT library - fftw3")
 597     if(GMX_DOUBLE)
 598         find_package(FFTW3 REQUIRED)
 599                 include_directories(${FFTW3_INCLUDE_DIR})
 600         set(FFT_LIBRARIES ${FFTW3_LIBRARIES})
 601         set(PKG_FFT "fftw3")
 602     else(GMX_DOUBLE)
 603         find_package(FFTW3F REQUIRED)
 604         include_directories(${FFTW3F_INCLUDE_DIR})
 605         set(FFT_LIBRARIES ${FFTW3F_LIBRARIES})
 606         set(PKG_FFT "fftw3f")
 607     endif(GMX_DOUBLE)
 608
 609     if(NOT FFTW3_FOUND AND NOT FFTW3F_FOUND)
 610         MESSAGE(FATAL_ERROR "Cannot find fftw3 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 611     endif(NOT FFTW3_FOUND AND NOT FFTW3F_FOUND)
 612
 613     set(GMX_FFT_FFTW3 1)
 614
 615 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 616 #    MESSAGE(STATUS "Using external FFT library - fftw2")
 617     if(GMX_DOUBLE)
 618         find_package(FFTW2 REQUIRED)
 619     else(GMX_DOUBLE)
 620         find_package(FFTW2F REQUIRED)
 621     endif(GMX_DOUBLE)
 622
 623     if(NOT FFTW2_FOUND)
 624            MESSAGE(FATAL_ERROR "Cannot find fftw2 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 625     endif(NOT FFTW2_FOUND)
 626     include_directories(${FFTW2_INCLUDE_DIR})
 627     set(FFT_LIBRARIES ${FFTW2_LIBRARIES})
 628     set(PKG_FFT_LIBS ${FFTW2_LIBRARIES})
 629
 630     if("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 631         set(FFTW2_NAME_DFFTW 1)
 632     elseif("${FFTW2_LIBRARIES}" MATCHES "sfftw")
 633         set(FFTW2_NAME_SFFTW 1)
 634     else("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 635         set(FFTW2_NAME_FFTW 1)
 636     endif("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 637
 638     set(GMX_FFT_FFTW2 1)
 639 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 640 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 641     find_package(MKL REQUIRED)
 642     include_directories(${MKL_INCLUDE_DIR})
 643     set(FFT_LIBRARIES ${MKL_LIBRARIES})
 644     set(PKG_FFT_LIBS ${MKL_LIBRARIES})
 645
 646     set(GMX_FFT_MKL 1)
 647     set(HAVE_MKL 1)
 648
 649 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 650 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 651 #    set(GMX_FFT_ACML 1)
 652 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 653     MESSAGE(STATUS "Using internal FFT library - fftpack")
 654     set(GMX_FFT_FFTPACK 1)
 655 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 656     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, fftw2, mkl, acml, fftpack")
 657 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 658
 659 # MKL has BLAS/LAPACK routines
 660 if(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 661   set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 662   set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 663 else(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 664   set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 665   set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 666 endif(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 667 mark_as_advanced(GMX_EXTERNAL_LAPACK)
 668 mark_as_advanced(GMX_EXTERNAL_BLAS)
 669
 670 # Math and thread libraries must often come after all others when linking...
 671 if(HAVE_LIBM)
 672     list(APPEND GMX_EXTRA_LIBRARIES m)
 673 endif(HAVE_LIBM)
 674
 675
 676
 677 if(GMX_FAHCORE)
 678   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 679       "Path to swindirect.h")
 680   include_directories(${COREWRAP_INCLUDE_DIR})
 681 endif(GMX_FAHCORE)
 682
 683 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 684 # these are set after everything else
 685 if (NOT DEFINED GROMACS_C_FLAGS_SET)
 686     set(GROMACS_C_FLAGS_SET true CACHE INTERNAL "Whether to reset the C flags"
 687         FORCE)
 688     set(CMAKE_C_FLAGS "${GROMACS_C_FLAGS} ${CMAKE_C_FLAGS}" CACHE STRING
 689         "Flags used by the compiler during all build types" FORCE)
 690     set(CMAKE_CXX_FLAGS "${GROMACS_CXX_FLAGS} ${CMAKE_CXX_FLAGS}" CACHE STRING
 691         "Flags used by the compiler during all build types" FORCE)
 692     set(CMAKE_EXE_LINKER_FLAGS
 693         "${GROMACS_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}"
 694         CACHE STRING "Linker flags" FORCE)
 695 endif (NOT DEFINED GROMACS_C_FLAGS_SET)
 696
 697 ########################################################################
 698 # Specify install locations and which subdirectories to process        #
 699 ########################################################################
 700 set(LIB_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/lib)
 701 set(BIN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/bin)
 702 set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/gromacs)
 703 set(MAN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/share/man)
 704 set(INCL_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/include)
 705
 706 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
 707
 708 ##################################################################
 709 # Shared library settings - Darwin uses INSTALL_NAME_DIR instead!
 710 ##################################################################
 711 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 712     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
 713     set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 714     set(CMAKE_INSTALL_RPATH "${LIB_INSTALL_DIR}")
 715     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 716 endif()
 717
 718 add_subdirectory(share)
 719 add_subdirectory(include)
 720 add_subdirectory(man)
 721 add_subdirectory(src)
 722 add_subdirectory(scripts)
 723
 724 #######################
 725 ## uninstall target
 726 #######################
 727     CONFIGURE_FILE(
 728                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 729                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 730                    IMMEDIATE @ONLY)
 731 ###########################
 732 ADD_CUSTOM_TARGET(uninstall
 733                   "${CMAKE_COMMAND}" -P
 734                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 735 ###########################
 736
 737
 738 ########################################################################
 739 # Tests                                                                #
 740 ########################################################################
 741
 742 include(CTest)
 743 mark_as_advanced(BUILD_TESTING)
 744 IF(BUILD_TESTING)
 745         enable_testing()
 746         add_test(TestBuildAll make)
 747         add_subdirectory(tests)
 748 ENDIF()
 749