CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2012,2013, by the GROMACS development team, led by
   5 # David van der Spoel, Berk Hess, Erik Lindahl, and including many
   6 # others, as listed in the AUTHORS file in the top-level source
   7 # directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34 #
  35 cmake_minimum_required(VERSION 2.8)
  36 # Keep CMake suitably quiet on Cygwin
  37 set(CMAKE_LEGACY_CYGWIN_WIN32 0) # Remove when CMake >= 2.8.4 is required
  38
  39 # Allows CPack to act differently for normal tools and mdrun (e.g. because of MPI)
  40 set(CPACK_COMPONENT_GROUP_TOOLS_DESCRIPTION "All GROMACS executable tools")
  41 set(CPACK_COMPONENT_GROUP_MDRUN_DESCRIPTION "GROMACS executable for running simulations")
  42
  43 # CMake modules/macros are in a subdirectory to keep this file cleaner
  44 # This needs to be set before project() in order to pick up toolchain files
  45 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  46
  47 project(Gromacs C)
  48 include(Dart)
  49 mark_as_advanced(DART_ROOT)
  50
  51 # PROJECT_VERSION should have the following structure:
  52 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  53 #
  54 # The "-dev" suffix is important to keep because it makes possible to distinguish
  55 # between a build from official release and a build from git release branch on a
  56 # machine with no git.
  57 #
  58 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  59 set(PROJECT_VERSION "4.6.1-dev")
  60 set(CUSTOM_VERSION_STRING ""
  61     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  62 mark_as_advanced(CUSTOM_VERSION_STRING)
  63 if (CUSTOM_VERSION_STRING)
  64     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  65 endif (CUSTOM_VERSION_STRING)
  66 set(SOVERSION 8)
  67 # It is a bit irritating, but this has to be set separately for now!
  68 SET(CPACK_PACKAGE_VERSION_MAJOR "4")
  69 SET(CPACK_PACKAGE_VERSION_MINOR "6")
  70 SET(CPACK_PACKAGE_VERSION_PATCH "1")
  71
  72 # The numerical gromacs version. It is 40600 for 4.6.0.
  73 # The #define GMX_VERSION in gmx_header_config_h is set to this value.
  74 math(EXPR NUM_VERSION
  75     "${CPACK_PACKAGE_VERSION_MAJOR}*10000 + ${CPACK_PACKAGE_VERSION_MINOR}*100")
  76 if(CPACK_PACKAGE_VERSION_PATCH)
  77     math(EXPR NUM_VERSION
  78          "${NUM_VERSION} + ${CPACK_PACKAGE_VERSION_PATCH}")
  79 endif()
  80
  81 # The API version tracks the numerical Gromacs version (for now).
  82 # It is potentially different from the Gromacs version in the future, if
  83 # the programs/libraries diverge from the presumably more stable API.
  84 # The #define GMX_API_VERSION in version.h is set to this value to
  85 # provide backward compatibility of software written against the Gromacs API.
  86 set(API_VERSION ${NUM_VERSION})
  87
  88 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  89 set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  90 endif()
  91
  92 include(gmxBuildTypeReference)
  93
  94 if(NOT CMAKE_BUILD_TYPE)
  95     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference." FORCE)
  96 endif(NOT CMAKE_BUILD_TYPE)
  97
  98 enable_language(C)
  99
 100 set(GMX_USE_RELATIVE_INSTALL_PATH OFF CACHE STRING "Use relative paths not absolute paths for cmake install. Has only an effect on cpack.")
 101 mark_as_advanced(GMX_USE_RELATIVE_INSTALL_PATH)
 102
 103 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
 104 set(CPACK_PACKAGE_VENDOR "gromacs.org")
 105 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
 106 if (NOT GMX_USE_RELATIVE_INSTALL_PATH)
 107     set(CPACK_SET_DESTDIR "ON")
 108 endif()
 109 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
 110 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
 111 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/COPYING")
 112 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
 113 set(CPACK_SOURCE_IGNORE_FILES "\\\\.isreposource$;\\\\.git/;\\\\.gitignore$")
 114 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
 115 SET(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/man;man")
 116 set(CPACK_PACKAGE_CONTACT "gmx-users@gromacs.org")
 117
 118 #must come after all cpack settings!
 119 include(CPack)
 120
 121 ########################################################################
 122 # Check and warn if cache generated on a different host is being reused
 123 ########################################################################
 124 if(CMAKE_HOST_UNIX)
 125     execute_process(COMMAND hostname
 126                     OUTPUT_VARIABLE TMP_HOSTNAME
 127                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 128     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 129         message(WARNING "
 130             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 131             is being reused! This could lead to inconsitencies; therefore, it is
 132             recommended to regenerate the cache!")
 133     endif()
 134     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 135             "Hostname of the machine where the cache was generated.")
 136 endif()
 137
 138 ########################################################################
 139 # User input options - enable C++ - before any CXX flags are changed   #
 140 ########################################################################
 141
 142 # decide on GPU settings based on user-settings and GPU/CUDA detection
 143 include(gmxManageGPU)
 144
 145 option(GMX_FORCE_CXX "Enable C++ compilation even if not necessary" OFF)
 146 mark_as_advanced(GMX_FORCE_CXX)
 147
 148 option(GMX_COOL_QUOTES "Enable Gromacs cool quotes" ON)
 149 mark_as_advanced(GMX_COOL_QUOTES)
 150
 151 if(GMX_GPU OR GMX_FORCE_CXX)
 152     enable_language(CXX)
 153 endif()
 154 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 155
 156 ########################################################################
 157 # User input options                                                   #
 158 ########################################################################
 159 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 160 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 161 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 162 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 163 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 164 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 165 mark_as_advanced(GMX_FAHCORE)
 166
 167 include(gmxDetectAcceleration)
 168 if(NOT DEFINED GMX_CPU_ACCELERATION)
 169     if(CMAKE_CROSSCOMPILING)
 170         if("${CMAKE_SYSTEM_NAME}" MATCHES "BlueGeneQ")
 171             set(GMX_SUGGESTED_CPU_ACCELERATION "IBM_QPX")
 172         else()
 173             set(GMX_SUGGESTED_CPU_ACCELERATION "None")
 174         endif()
 175     else(CMAKE_CROSSCOMPILING)
 176         gmx_detect_acceleration(GMX_SUGGESTED_CPU_ACCELERATION)
 177     endif(CMAKE_CROSSCOMPILING)
 178 endif(NOT DEFINED GMX_CPU_ACCELERATION)
 179
 180 set(GMX_CPU_ACCELERATION "@GMX_SUGGESTED_CPU_ACCELERATION@"
 181     CACHE STRING "Accelerated CPU kernels. Pick one of: None, SSE2, SSE4.1, AVX_128_FMA, AVX_256, IBM_QPX")
 182
 183 set(GMX_FFT_LIBRARY "fftw3"
 184     CACHE STRING "FFT library choices: fftw3,mkl,fftpack[built-in]")
 185 option(GMX_BUILD_OWN_FFTW "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack." OFF)
 186 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 187 option(GMX_DISABLE_FFTW_MEASURE
 188        "Do not optimize FFTW setups (not needed with SSE)" OFF)
 189 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 190 set(GMX_QMMM_PROGRAM "none"
 191     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
 192 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 193 mark_as_advanced(GMX_BROKEN_CALLOC)
 194 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
 195 mark_as_advanced(GMX_MPI_IN_PLACE)
 196 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 197 mark_as_advanced(GMX_LOAD_PLUGINS)
 198
 199 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 200
 201 option(USE_VERSION_H "Generate development version string/information" ON)
 202 mark_as_advanced(USE_VERSION_H)
 203
 204 option(GMX_DEFAULT_SUFFIX "Use default suffixes for GROMACS binaries and libs (_d for double, _mpi for MPI; rerun cmake after changing to see relevant options)" ON)
 205
 206 if(UNIX)
 207     option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static archives (not available on non-*nix platforms and it will only work if static versions of external dependencies are available and found)!" OFF)
 208     mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 209 endif()
 210
 211 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 212 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 213
 214 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 215 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 216
 217 ######################################################################
 218 # Compiler tests
 219 # These need to be done early (before further tests).
 220 #####################################################################
 221
 222 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 223 # are used with permission from CMake v2.8.9 so that GROMACS can detect
 224 # invalid options with the Intel Compilers.
 225 # These files should be removed from the source tree when a CMake version that
 226 # includes the features in question becomes required for building GROMACS.
 227 include(CheckCCompilerFlag)
 228 if(CMAKE_CXX_COMPILER_LOADED)
 229     include(CheckCXXCompilerFlag)
 230 endif()
 231
 232 # Get compiler version information, needs to be done early as check that depend
 233 # on compiler verison follow below.
 234 include(gmxGetCompilerInfo)
 235 get_compiler_version()
 236
 237 # First exclude compilers known to not work with OpenMP although claim to support it:
 238 # gcc 4.2.1 and gcc-llvm 4.2.1 (also claims to be 4.2.1) on Mac OS X
 239 # This fixes redmine 900 and needs to run before OpenMP flags are set below.
 240 if (CMAKE_SYSTEM_NAME STREQUAL "Darwin" AND
 241     (CMAKE_COMPILER_IS_GNUCC AND C_COMPILER_VERSION AND C_COMPILER_VERSION VERSION_LESS 4.3))
 242     message(STATUS "OpenMP multithreading not supported with gcc/llvm-gcc 4.2 on Mac OS X, disabled")
 243     set(GMX_OPENMP OFF CACHE BOOL
 244         "OpenMP multithreading not not supported with gcc/llvm-gcc 4.2 on Mac OS X, disabled!" FORCE)
 245 endif()
 246
 247 # OpenMP check must come before other CFLAGS!
 248 if(GMX_OPENMP)
 249     find_package(OpenMP)
 250     if(OPENMP_FOUND)
 251         # CMake on Windows doesn't support linker flags passed to target_link_libraries
 252         # (i.e. it treats /openmp as \openmp library file). Also, no OpenMP linker flags are needed.
 253         if(NOT (WIN32 AND NOT CYGWIN))
 254             if(CMAKE_COMPILER_IS_GNUCC AND GMX_PREFER_STATIC_OPENMP)
 255                 set(OpenMP_LINKER_FLAGS "-Wl,-static -lgomp -lrt -Wl,-Bdynamic -lpthread")
 256                 set(OpenMP_SHARED_LINKER_FLAGS "")
 257             else()
 258                 # Only set a linker flag if the user didn't set them manually
 259                 if(NOT DEFINED OpenMP_LINKER_FLAGS)
 260                     set(OpenMP_LINKER_FLAGS "${OpenMP_C_FLAGS}")
 261                 endif()
 262                 if(NOT DEFINED OpenMP_SHARED_LINKER_FLAGS)
 263                     set(OpenMP_SHARED_LINKER_FLAGS "${OpenMP_C_FLAGS}")
 264                 endif()
 265             endif()
 266         endif()
 267     else(OPENMP_FOUND)
 268         message(WARNING
 269                 "The compiler you are using does not support OpenMP parallelism. This might hurt your performance a lot, in particular with GPUs. Try using a more recent version, or a different compiler. For now, we are proceeding by turning off OpenMP.")
 270         set(GMX_OPENMP OFF CACHE STRING "Whether GROMACS will use OpenMP parallelism." FORCE)
 271     endif(OPENMP_FOUND)
 272 endif()
 273
 274
 275 include(gmxCFlags)
 276 gmx_c_flags()
 277
 278 # gcc 4.4.x is buggy and crashes when compiling some files with O3 and OpenMP on.
 279 # Detect here whether applying a workaround is needed and will apply it later
 280 # on the affected files.
 281 include(gmxGCC44O3BugWorkaround)
 282 gmx_check_gcc44_bug_workaround_needed(GMX_USE_GCC44_BUG_WORKAROUND)
 283
 284 # clang 3.0 is buggy for some unknown reason detected during adding
 285 # the SSE2 group kernels for GROMACS 4.6. If we ever work out what
 286 # that is, we should replace these tests with a compiler feature test,
 287 # update GROMACS Redmine task #1039 and perhaps report a clang bug.
 288 #
 289 # In the meantime, until we require CMake 2.8.10 we cannot rely on it to detect
 290 # the compiler version for us. So we need a manual check for clang 3.0.
 291 include(gmxDetectClang30)
 292 gmx_detect_clang_3_0(COMPILER_IS_CLANG_3_0)
 293 if(COMPILER_IS_CLANG_3_0)
 294     message(FATAL_ERROR "Your compiler is clang version 3.0, which is known to be buggy for GROMACS. Use a different compiler.")
 295 endif()
 296
 297 if (CMAKE_C_COMPILER_ID STREQUAL "PGI")
 298     message(WARNING "All tested PGI compiler versions (up to 12.9.0) generate binaries which produce incorrect results, or even fail to compile Gromacs. Highly recommended to use a different compiler. If you choose to use PGI, make sure to run the regressiontests.")
 299 endif()
 300
 301 if(CMAKE_C_COMPILER_ID MATCHES "Intel" AND C_COMPILER_VERSION VERSION_LESS "12.0.0")
 302     message(WARNING "Intel compilers before 12.0.0 are not routinely tested, so there may be problems. Version 11.1 with SSE4.1 is known to produce incorrect results. It is highly recommended to use a more up-to-date compiler. If you choose to use this version, make sure you run the regressiontests.")
 303 endif()
 304
 305 ########################################################################
 306 # Set up binary and library suffixing
 307 ########################################################################
 308 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 309 set(GMX_LIBS_SUFFIX ""
 310   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 311 if (GMX_DEFAULT_SUFFIX)
 312   set(GMX_BINARY_SUFFIX "")
 313   set(GMX_LIBS_SUFFIX "")
 314   if (GMX_MPI)
 315     set(GMX_BINARY_SUFFIX "_mpi")
 316     set(GMX_LIBS_SUFFIX "_mpi")
 317   endif(GMX_MPI)
 318   if (GMX_DOUBLE)
 319     set (GMX_BINARY_SUFFIX "${GMX_BINARY_SUFFIX}_d")
 320     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
 321   endif(GMX_DOUBLE)
 322   mark_as_advanced(FORCE GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 323   if (NOT SUFFIX_QUIETLY)
 324     message(STATUS "Using default binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 325     message(STATUS "Using default library suffix: \"${GMX_LIBS_SUFFIX}\"")
 326   endif (NOT SUFFIX_QUIETLY)
 327 else(GMX_DEFAULT_SUFFIX)
 328   mark_as_advanced(CLEAR GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 329   if (NOT SUFFIX_QUIETLY)
 330     message(STATUS "Using manually set binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 331     message(STATUS "Using manually set library suffix: \"${GMX_LIBS_SUFFIX}\"")
 332   endif (NOT SUFFIX_QUIETLY)
 333 endif(GMX_DEFAULT_SUFFIX)
 334 set(SUFFIX_QUIETLY TRUE CACHE INTERNAL "")
 335
 336 set(PKG_CFLAGS "")
 337 if(GMX_DOUBLE)
 338     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 339 endif(GMX_DOUBLE)
 340 if(GMX_SOFTWARE_INVSQRT)
 341   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 342 endif(GMX_SOFTWARE_INVSQRT)
 343
 344
 345
 346 ########################################################################
 347 # Basic system tests (standard libraries, headers, functions, types)   #
 348 ########################################################################
 349 include(CheckIncludeFiles)
 350 check_include_files(string.h     HAVE_STRING_H)
 351 check_include_files(math.h       HAVE_MATH_H)
 352 check_include_files(limits.h     HAVE_LIMITS_H)
 353 check_include_files(memory.h     HAVE_MEMORY_H)
 354 check_include_files(unistd.h     HAVE_UNISTD_H)
 355 check_include_files(direct.h     HAVE_DIRECT_H)
 356 check_include_files(pwd.h        HAVE_PWD_H)
 357 check_include_files(stdint.h     HAVE_STDINT_H)
 358 check_include_files(stdlib.h     HAVE_STDLIB_H)
 359 check_include_files(pthread.h    HAVE_PTHREAD_H)
 360 check_include_files(dirent.h     HAVE_DIRENT_H)
 361 check_include_files(inttypes.h   HAVE_INTTYPES_H)
 362 check_include_files(regex.h      HAVE_REGEX_H)
 363 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 364 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
 365 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 366 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
 367 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
 368 check_include_files(io.h                 HAVE_IO_H)
 369 check_include_files(sched.h      HAVE_SCHED_H)
 370
 371 include(CheckFunctionExists)
 372 check_function_exists(strcasecmp        HAVE_STRCASECMP)
 373 check_function_exists(strdup            HAVE_STRDUP)
 374 check_function_exists(vprintf           HAVE_VPRINTF)
 375 check_function_exists(memcmp            HAVE_MEMCMP)
 376 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 377 check_function_exists(memalign          HAVE_MEMALIGN)
 378 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 379 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 380 check_function_exists(isnan             HAVE_ISNAN)
 381 check_function_exists(_isnan            HAVE__ISNAN)
 382 check_function_exists(fsync             HAVE_FSYNC)
 383 check_function_exists(_fileno           HAVE__FILENO)
 384 check_function_exists(fileno            HAVE_FILENO)
 385 check_function_exists(_commit           HAVE__COMMIT)
 386 check_function_exists(sigaction         HAVE_SIGACTION)
 387 check_function_exists(sysconf           HAVE_SYSCONF)
 388 check_function_exists(sched_setaffinity HAVE_SCHED_SETAFFINITY)
 389 check_function_exists(sched_getaffinity HAVE_SCHED_GETAFFINITY)
 390 check_function_exists(rsqrt             HAVE_RSQRT)
 391 check_function_exists(rsqrtf            HAVE_RSQRTF)
 392 check_function_exists(sqrtf             HAVE_SQRTF)
 393
 394 include(CheckLibraryExists)
 395 check_library_exists(m sqrt "" HAVE_LIBM)
 396 check_library_exists(m cbrt "" HAVE_CBRT)
 397
 398
 399 include(CheckTypeSize)
 400
 401 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 402 check_type_size("int"           SIZEOF_INT)
 403 check_type_size("long int"      SIZEOF_LONG_INT)
 404 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 405 check_type_size("off_t"         SIZEOF_OFF_T)
 406 check_type_size("void *"        SIZEOF_VOIDP)
 407
 408 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 409     set(GMX_64_BIT TRUE)
 410 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 411     set(GMX_64_BIT FALSE)
 412 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 413
 414 # Check for some basic types that we *need*, so set these to int if they are not present
 415 check_type_size(uid_t uid_t)
 416 if(NOT uid_t)
 417   set(uid_t int)
 418 else(NOT uid_t)
 419   set(uid_t 0)
 420 endif(NOT uid_t)
 421
 422 check_type_size(gid_t gid_t)
 423 if(NOT gid_t)
 424   set(gid_t 1)
 425 else(NOT gid_t)
 426   set(gid_t 0)
 427 endif(NOT gid_t)
 428
 429 check_type_size(size_t size_t)
 430 if(NOT size_t)
 431   set(size_t int)
 432 else(NOT size_t)
 433   set(size_t 0)
 434 endif(NOT size_t)
 435
 436 check_type_size(off_t off_t)
 437 if(NOT off_t)
 438   set(off_t int)
 439 else(NOT off_t)
 440   set(off_t 0)
 441 endif(NOT off_t)
 442
 443 include(TestBigEndian)
 444 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 445
 446
 447 if(APPLE OR CYGWIN OR ${CMAKE_SYSTEM_NAME} MATCHES "Linux|.*BSD")
 448     # Maybe Solaris should be here? Patch this if you know!
 449     SET(SHARED_LIBS_DEFAULT ON)
 450 elseif(WIN32 OR ${CMAKE_SYSTEM_NAME} MATCHES "BlueGene")
 451     # Support for shared libs on native Windows is a bit new. Its
 452     # default might change later if/when we sort things out. Also,
 453     # Cray should go here. What variable value can detect it?
 454     SET(SHARED_LIBS_DEFAULT OFF)
 455 else()
 456     message(STATUS "Defaulting to building static libraries")
 457     SET(SHARED_LIBS_DEFAULT OFF)
 458 endif()
 459
 460 # Management of GROMACS options for specific toolchains should go
 461 # here. Because the initial settings for some of the main options have
 462 # already happened, but things like library detection and MPI compiler
 463 # feature detection have not, the docstrings for any over-rides of
 464 # GROMACS defaults or user settings will make sense. Also, any
 465 # toolchain-related reasons for choosing whether to detect various
 466 # things can be sorted out now, before the detection takes place.
 467 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 468     include(gmxManageBlueGene)
 469 endif()
 470
 471 if(UNIX AND GMX_PREFER_STATIC_LIBS AND SHARED_LIBS_DEFAULT)
 472     if(BUILD_SHARED_LIBS)
 473         # Warn the user about the combination. But don't overwrite the request.
 474         message(WARNING "Searching for static libraries requested, and building shared Gromacs libraries requested. This might cause problems linking later.")
 475     elseif(NOT DEFINED BUILD_SHARED_LIBS)
 476         # Change default to OFF. Don't warn if it's already off.
 477         message(WARNING "Searching for static libraries requested, so the GROMACS libraries will also be built statically (BUILD_SHARED_LIBS=OFF)")
 478         set(SHARED_LIBS_DEFAULT OFF)
 479     endif()
 480 endif()
 481
 482 # By now, all tool chains should have spoken up if they care about
 483 # the setting of SHARED_LIBS_DEFAULT.
 484 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic e.g. with MPI, or on some HPC systems)" ${SHARED_LIBS_DEFAULT})
 485
 486 ########################################################################
 487 #Process MPI settings
 488 ########################################################################
 489 include(gmxManageMPI)
 490
 491 ########################################################################
 492 # Find external packages                                               #
 493 ########################################################################
 494 if(UNIX AND GMX_PREFER_STATIC_LIBS)
 495     # On Linux .a is the static library suffix, on Mac OS X .lib can also
 496     # be used, so we'll add both to the preference list.
 497     SET(CMAKE_FIND_LIBRARY_SUFFIXES ".lib;.a" ${CMAKE_FIND_LIBRARY_SUFFIXES})
 498 endif()
 499
 500 IF( WIN32 AND NOT CYGWIN)
 501   if (NOT BUILD_SHARED_LIBS)
 502       option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static system libraries (MT instead of MD)!" ON)
 503       if(NOT GMX_PREFER_STATIC_LIBS)
 504           message(WARNING "Shared system libraries requested, and static Gromacs libraries requested.")
 505       endif()
 506   else()
 507       option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static system libraries (MT instead of MD)!" OFF)
 508       if(GMX_PREFER_STATIC_LIBS)
 509           #this combination segfaults (illigal passing of file handles)
 510           message(FATAL_ERROR "Static system libraries requested, and shared Gromacs libraries requested.")
 511       endif()
 512       add_definitions(-DUSE_VISIBILITY -DTMPI_USE_VISIBILITY)
 513       set(PKG_CFLAGS "$PKG_CFLAGS -DUSE_VISIBILITY -DTMPI_USE_VISIBILITY")
 514   endif()
 515   mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 516
 517   IF (GMX_PREFER_STATIC_LIBS)
 518       #Only setting Debug and Release flags. Others configurations are current not used.
 519       STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
 520       STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
 521       if(CMAKE_CXX_COMPILER_LOADED)
 522           STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE})
 523           STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 524       endif()
 525   ENDIF()
 526   IF( CMAKE_C_COMPILER_ID MATCHES "Intel" )
 527     if(BUILD_SHARED_LIBS) #not sure why incremental building with shared libs doesn't work
 528         STRING(REPLACE "/INCREMENTAL:YES" "" CMAKE_SHARED_LINKER_FLAGS ${CMAKE_SHARED_LINKER_FLAGS})
 529     endif()
 530   ENDIF()
 531 ENDIF()
 532
 533 option(GMX_GSL "Add support for gsl" OFF)
 534 if (GMX_GSL)
 535   find_package(GSL)
 536   set(PKG_GSL "")
 537   if(GSL_FOUND)
 538     include_directories(${GSL_INCLUDE_DIR})
 539     set(PKG_GSL gsl)
 540     set(HAVE_LIBGSL 1)
 541   endif(GSL_FOUND)
 542 endif (GMX_GSL)
 543
 544 option(GMX_X11 "Use X window system" OFF)
 545 if (GMX_X11)
 546     find_package(X11)
 547     # X11 includes/libraries are only set in the ngmx subdirectory!
 548     if(NOT X11_FOUND)
 549         message(WARNING "X11 include files and/or libraries were not found. Will not build the GROMACS X11-binaries, such as ngmx")
 550     endif()
 551 endif(GMX_X11)
 552
 553 include(ThreadMPI)
 554 set(THREAD_MPI_LIB thread_mpi)
 555 if(GMX_THREAD_MPI)
 556     tmpi_get_source_list(THREAD_MPI_SRC)
 557     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREAD_MPI")
 558     set(GMX_MPI 1)
 559 else(GMX_THREAD_MPI)
 560     tmpi_get_source_list(THREAD_MPI_SRC NOMPI)
 561 endif(GMX_THREAD_MPI)
 562
 563 if(GMX_GPU)
 564     # now that we have detected the dependencies, do the second configure pass
 565     gmx_gpu_setup()
 566 endif(GMX_GPU)
 567
 568 if(APPLE)
 569    find_library(ACCELERATE_FRAMEWORK Accelerate)
 570    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 571 endif(APPLE)
 572
 573 if(CYGWIN)
 574     set(GMX_CYGWIN 1)
 575 endif(CYGWIN)
 576
 577 if(WIN32 AND NOT CYGWIN)
 578     set(GMX_NATIVE_WINDOWS 1)
 579 endif()
 580
 581 # only bother with finding git and using version.h if the source is a git repo
 582 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 583     if(USE_VERSION_H)
 584         # We need at least git v1.5.3 be able to parse git's date output. If not
 585         # found or the version is too small, we can't generate version information.
 586         find_package(Git)
 587
 588         # Find out the git version
 589         if(GIT_FOUND AND NOT GIT_VERSION)
 590           execute_process(COMMAND ${GIT_EXECUTABLE} "--version"
 591             OUTPUT_VARIABLE _exec_out
 592             OUTPUT_STRIP_TRAILING_WHITESPACE)
 593           string(REGEX REPLACE "git version (.*)" "\\1" GIT_VERSION ${_exec_out})
 594           set(GIT_VERSION ${GIT_VERSION} CACHE STRING "Git version")
 595           mark_as_advanced(GIT_VERSION)
 596         endif()
 597
 598         if(NOT GIT_FOUND OR GIT_VERSION VERSION_LESS "1.5.3")
 599           message("No compatible git version found, won't be able to generate proper development version information.")
 600           set(USE_VERSION_H OFF)
 601         endif()
 602     endif()
 603 else()
 604     set(USE_VERSION_H OFF)
 605 endif()
 606
 607 ########################################################################
 608 # Generate development version info for cache
 609 ########################################################################
 610 # set(GEN_VERSION_INFO_INTERNAL "ON")
 611 # include(gmxGenerateVersionString)
 612
 613 ########################################################################
 614 # Our own GROMACS tests
 615 ########################################################################
 616
 617 add_definitions( -DHAVE_CONFIG_H )
 618 include_directories(${CMAKE_BINARY_DIR}/src)
 619 include_directories(${CMAKE_BINARY_DIR}/include)
 620 include_directories(${CMAKE_SOURCE_DIR}/include)
 621
 622 include(gmxTestInlineASM)
 623 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 624
 625 include(gmxSetBuildInformation)
 626 gmx_set_build_information()
 627 if(BUILD_CPU_FEATURES MATCHES "rdtscp" AND NOT GMX_DISTRIBUTABLE_BUILD)
 628     # The timestep counter headers do not include config.h
 629     add_definitions(-DHAVE_RDTSCP)
 630 endif(BUILD_CPU_FEATURES MATCHES "rdtscp" AND NOT GMX_DISTRIBUTABLE_BUILD)
 631
 632 include(gmxTestFloatFormat)
 633 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 634                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 635                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 636
 637 include(gmxTestLargeFiles)
 638 gmx_test_large_files(GMX_LARGEFILES)
 639
 640 include(gmxTestSignal)
 641 gmx_test_sigusr1(HAVE_SIGUSR1)
 642
 643 include(gmxTestInline)
 644 gmx_test_inline(INLINE_KEYWORD)
 645
 646 include(gmxTestRestrict)
 647 gmx_test_restrict(RESTRICT_KEYWORD)
 648
 649 include(gmxTestPipes)
 650 gmx_test_pipes(HAVE_PIPES)
 651
 652 include(gmxTestIsfinite)
 653 gmx_test_isfinite(HAVE_ISFINITE)
 654 gmx_test__isfinite(HAVE__ISFINITE)
 655 gmx_test__finite(HAVE__FINITE)
 656
 657 include(gmxTestXDR)
 658 gmx_test_xdr(GMX_SYSTEM_XDR)
 659 if(NOT GMX_SYSTEM_XDR)
 660     set(GMX_INTERNAL_XDR 1)
 661     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 662 endif(NOT GMX_SYSTEM_XDR)
 663
 664 # include avx test source, used if the AVX flags are set below
 665 include(gmxTestAVXMaskload)
 666
 667 # Process nonbonded accelerated kernels settings
 668 #
 669 # Note that for the backward-compatible x86 SIMD architectures, the
 670 # GMX_CPU_ACCELERATION determines the maximum level of the instruction
 671 # set used (e.g. GMX_CPU_ACCLERATION=SSE4.1 implies
 672 # SSE2). Accordingly, there are a set of CMake variables
 673 # GMX_<arch>_<feature-set> that are exported to the C code to specify
 674 # CPU features that should be used. This means that the logic for
 675 # requiring such backward compatibility is all located here.
 676 string(TOUPPER ${GMX_CPU_ACCELERATION} GMX_CPU_ACCELERATION)
 677 if(${GMX_CPU_ACCELERATION} STREQUAL "NONE")
 678     # nothing to do
 679 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SSE2")
 680
 681     GMX_TEST_CFLAG(GNU_SSE2_CFLAG "-msse2" ACCELERATION_C_FLAGS)
 682     if(NOT GNU_SSE2_CFLAG AND GMX_NATIVE_WINDOWS)
 683         GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" ACCELERATION_C_FLAGS)
 684     endif(NOT GNU_SSE2_CFLAG AND GMX_NATIVE_WINDOWS)
 685
 686     if (CMAKE_CXX_COMPILER_LOADED)
 687         GMX_TEST_CXXFLAG(GNU_SSE2_CXXFLAG "-msse2" ACCELERATION_CXX_FLAGS)
 688         if(NOT GNU_SSE2_CXXFLAG AND GMX_NATIVE_WINDOWS)
 689             GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" ACCELERATION_CXX_FLAGS)
 690         endif(NOT GNU_SSE2_CXXFLAG AND GMX_NATIVE_WINDOWS)
 691     endif()
 692
 693     # We dont warn for lacking SSE2 flag support, since that is probably standard today.
 694
 695     # Only test the include after we have tried to add the correct flag for SSE2 support
 696     check_include_file(emmintrin.h  HAVE_EMMINTRIN_H ${ACCELERATION_C_FLAGS})
 697
 698     if(NOT HAVE_EMMINTRIN_H)
 699         message(FATAL_ERROR "Cannot find emmintrin.h, which is required for SSE2 intrinsics support.")
 700     endif(NOT HAVE_EMMINTRIN_H)
 701
 702     set(GMX_CPU_ACCELERATION_X86_SSE2 1)
 703     # The user should not be able to set this orthogonally to the acceleration
 704     set(GMX_X86_SSE2 1)
 705     if (NOT ACCELERATION_QUIETLY)
 706       message(STATUS "Enabling SSE2 Gromacs acceleration, and it will help compiler optimization.")
 707     endif()
 708
 709 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SSE4.1")
 710
 711     GMX_TEST_CFLAG(GNU_SSE4_CFLAG "-msse4.1" ACCELERATION_C_FLAGS)
 712     if (NOT GNU_SSE4_CFLAG AND GMX_NATIVE_WINDOWS)
 713         GMX_TEST_CFLAG(MSVC_SSE4_CFLAG "/arch:SSE4.1" ACCELERATION_C_FLAGS)
 714     endif(NOT GNU_SSE4_CFLAG AND GMX_NATIVE_WINDOWS)
 715     if (NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 716         # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 717         # intrinsics when SSE2 support is enabled, so we try that instead first.
 718         if (GMX_NATIVE_WINDOWS)
 719             GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" ACCELERATION_C_FLAGS)
 720             message(WARNING "Neither SSE4.1 or SSE2 seems to be supported by your Windows compiler. Something is likely broken.")
 721         else()
 722             message(WARNING "No C SSE4.1 flag found. Consider a newer compiler, or use SSE2 for slightly lower performance")
 723         endif()
 724     endif(NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 725
 726     if (CMAKE_CXX_COMPILER_LOADED)
 727         GMX_TEST_CXXFLAG(GNU_SSE4_CXXFLAG "-msse4.1" ACCELERATION_CXX_FLAGS)
 728         if (NOT GNU_SSE4_CXXFLAG AND GMX_NATIVE_WINDOWS)
 729             GMX_TEST_CXXFLAG(MSVC_SSE4_CXXFLAG "/arch:SSE4.1" ACCELERATION_CXX_FLAGS)
 730         endif(NOT GNU_SSE4_CXXFLAG AND GMX_NATIVE_WINDOWS)
 731         if (NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 732             message(WARNING "No C++ SSE4.1 flag found. Consider a newer compiler, or use SSE2 for slightly lower performance.")
 733             # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 734             # intrinsics when SSE2 support is enabled, so we try that instead.
 735             if (GMX_NATIVE_WINDOWS)
 736                 GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" ACCELERATION_CXX_FLAGS)
 737             endif()
 738         endif(NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 739     endif()
 740
 741     # This must come after we have added the -msse4.1 flag on some platforms.
 742     check_include_file(smmintrin.h  HAVE_SMMINTRIN_H ${ACCELERATION_C_FLAGS})
 743
 744     if(NOT HAVE_SMMINTRIN_H)
 745         message(FATAL_ERROR "Cannot find smmintrin.h, which is required for SSE4.1 intrinsics support.")
 746     endif(NOT HAVE_SMMINTRIN_H)
 747
 748     set(GMX_CPU_ACCELERATION_X86_SSE4_1 1)
 749     # The user should not be able to set this orthogonally to the acceleration
 750     set(GMX_X86_SSE4_1 1)
 751     set(GMX_X86_SSE2   1)
 752     if (NOT ACCELERATION_QUIETLY)
 753       message(STATUS "Enabling SSE4.1 Gromacs acceleration, and it will help compiler optimization.")
 754     endif()
 755
 756     if(CMAKE_C_COMPILER_ID MATCHES "Intel" AND C_COMPILER_VERSION VERSION_EQUAL "11.1")
 757         message(FATAL_ERROR "You are using Intel compiler version 11.1, and that compiler is known to produce incorrect results with SSE4.1 acceleration. You need to use another compiler (e.g. icc 12 or newer) or different acceleration (probably slower simulations).")
 758     endif()
 759 elseif(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA" OR ${GMX_CPU_ACCELERATION} STREQUAL "AVX_256")
 760
 761     # Set the AVX compiler flag for both these choices!
 762
 763     GMX_TEST_CFLAG(GNU_AVX_CFLAG "-mavx" ACCELERATION_C_FLAGS)
 764     if (NOT GNU_AVX_CFLAG AND GMX_NATIVE_WINDOWS)
 765         GMX_TEST_CFLAG(MSVC_AVX_CFLAG "/arch:AVX" ACCELERATION_C_FLAGS)
 766     endif (NOT GNU_AVX_CFLAG AND GMX_NATIVE_WINDOWS)
 767     if (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 768         message(WARNING "No C AVX flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 769     endif (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 770
 771     if (CMAKE_CXX_COMPILER_LOADED)
 772         GMX_TEST_CXXFLAG(GNU_AVX_CXXFLAG "-mavx" ACCELERATION_CXX_FLAGS)
 773         if (NOT GNU_AVX_CXXFLAG AND GMX_NATIVE_WINDOWS)
 774             GMX_TEST_CXXFLAG(MSVC_AVX_CXXFLAG "/arch:AVX" ACCELERATION_CXX_FLAGS)
 775         endif (NOT GNU_AVX_CXXFLAG AND GMX_NATIVE_WINDOWS)
 776         if (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 777             message(WARNING "No C++ AVX flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 778         endif (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 779     endif()
 780
 781     # Set the FMA4 flags (MSVC doesn't require any)
 782     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA" AND NOT MSVC)
 783         if (${CMAKE_COMPILER_ID} MATCHES "Clang")
 784             message(FATAL_ERROR "Clang up to at least version 3.2 produces incorrect code for AVX_128_FMA. Sorry, but you will have to select a different compiler or acceleration.")
 785         endif()
 786         GMX_TEST_CFLAG(GNU_FMA_CFLAG "-mfma4" ACCELERATION_C_FLAGS)
 787         if (NOT GNU_FMA_CFLAG)
 788             message(WARNING "No C FMA4 flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 789         endif(NOT GNU_FMA_CFLAG)
 790         GMX_TEST_CFLAG(GNU_XOP_CFLAG "-mxop" ACCELERATION_C_FLAGS)
 791         # No big deal if we do not have xop, so no point yelling warnings about it.
 792         if (CMAKE_CXX_COMPILER_LOADED)
 793             GMX_TEST_CXXFLAG(GNU_FMA_CXXFLAG "-mfma4" ACCELERATION_CXX_FLAGS)
 794             if (NOT GNU_FMA_CXXFLAG)
 795                 message(WARNING "No C++ FMA flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 796             endif (NOT GNU_FMA_CXXFLAG)
 797             GMX_TEST_CXXFLAG(GNU_XOP_CXXFLAG "-mxop" ACCELERATION_CXX_FLAGS)
 798             # No big deal if we do not have xop, so no point yelling warnings about it.
 799         endif()
 800     endif()
 801
 802     # Only test the header after we have tried to add the flag for AVX support
 803     check_include_file(immintrin.h  HAVE_IMMINTRIN_H ${ACCELERATION_C_FLAGS})
 804
 805     if(NOT HAVE_IMMINTRIN_H)
 806         message(FATAL_ERROR "Cannot find immintrin.h, which is required for AVX intrinsics support. Consider switching compiler.")
 807     endif(NOT HAVE_IMMINTRIN_H)
 808
 809     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_256")
 810         try_compile(TEST_AVX ${CMAKE_BINARY_DIR}
 811             "${CMAKE_SOURCE_DIR}/cmake/TestAVX.c"
 812             COMPILE_DEFINITIONS "${ACCELERATION_C_FLAGS}")
 813         if(NOT TEST_AVX)
 814             message(FATAL_ERROR "Cannot compile AVX intrinsics. Consider switching compiler.")
 815         endif()
 816     endif()
 817
 818     # GCC requires x86intrin.h for FMA support. MSVC 2010 requires intrin.h for FMA support.
 819     check_include_file(x86intrin.h HAVE_X86INTRIN_H ${ACCELERATION_C_FLAGS})
 820     check_include_file(intrin.h HAVE_INTRIN_H ${ACCELERATION_C_FLAGS})
 821
 822     # The user should not be able to set this orthogonally to the acceleration
 823     set(GMX_X86_SSE4_1 1)
 824     set(GMX_X86_SSE2   1)
 825
 826     # But just enable one of the choices internally...
 827     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA")
 828         set(GMX_CPU_ACCELERATION_X86_AVX_128_FMA 1)
 829         set(GMX_X86_AVX_128_FMA 1)
 830         if (NOT ACCELERATION_QUIETLY)
 831           message(STATUS "Enabling 128-bit AVX Gromacs acceleration (with fused-multiply add), and it will help compiler optimization.")
 832         endif()
 833     else()
 834         # If we are not doing AVX_128, it must be AVX_256...
 835         set(GMX_CPU_ACCELERATION_X86_AVX_256 1)
 836         set(GMX_X86_AVX_256 1)
 837         if (NOT ACCELERATION_QUIETLY)
 838           message(STATUS "Enabling 256-bit AVX Gromacs acceleration, and it will help compiler optimization.")
 839         endif()
 840     endif()
 841
 842     # Unfortunately gcc-4.5.2 and gcc-4.6.0 has a bug where they use the wrong datatype for the formal
 843     # parameter of the mask for maskload/maskstore arguments. Check if this is present, since we can work around it.
 844     gmx_test_avx_gcc_maskload_bug(${ACCELERATION_C_FLAGS} GMX_X86_AVX_GCC_MASKLOAD_BUG)
 845
 846 elseif(${GMX_CPU_ACCELERATION} STREQUAL "IBM_QPX")
 847     # Used on BlueGene/Q
 848     if (CMAKE_C_COMPILER_ID MATCHES "XL")
 849         GMX_TEST_CFLAG(XLC_BLUEGENEQ_CFLAG "-qarch=qp -qtune=qp" ACCELERATION_C_FLAGS)
 850         try_compile(TEST_QPX ${CMAKE_BINARY_DIR}
 851             "${CMAKE_SOURCE_DIR}/cmake/TestQPX.c"
 852             COMPILE_DEFINITIONS "${ACCELERATION_C_FLAGS}")
 853         if(NOT TEST_QPX)
 854             message(FATAL_ERROR "Cannot compile the requested IBM QPX intrinsics.")
 855         endif()
 856     endif()
 857     if (CMAKE_CXX_COMPILER_ID MATCHES "XL" AND CMAKE_CXX_COMPILER_LOADED)
 858         GMX_TEST_CXXFLAG(XLC_BLUEGENEQ_CXXFLAG "-qarch=qp -qtune=qp" ACCELERATION_CXX_FLAGS)
 859         try_compile(TEST_QPX ${CMAKE_BINARY_DIR}
 860             "cmake/TestQPX.c"
 861             COMPILE_DEFINITIONS "${ACCELERATION_CXX_FLAGS")
 862         if(NOT TEST_QPX)
 863             message(FATAL_ERROR "Cannot compile the requested IBM QPX intrinsics.")
 864         endif()
 865     endif()
 866
 867     if (TEST_QPX)
 868         message(WARNING "IBM QPX acceleration was selected and could be compiled, but the accelerated kernels are not yet available.")
 869         set(GMX_CPU_ACCELERATION_IBM_QPX 1)
 870     else()
 871         message(FATAL_ERROR "Cannot compile IBM QPX intrinsics without the XL compiler. If you are compiling for BlueGene/Q, use 'cmake .. -DCMAKE_TOOLCHAIN_FILE=BlueGeneQ-static-XL-C' to set up the tool chain.")
 872     endif()
 873
 874 else(${GMX_CPU_ACCELERATION} STREQUAL "NONE")
 875     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_CPU_ACCELERATION}. Pick one of None, SSE2, SSE4.1, AVX_128_FMA, AVX_256, IBM_QPX")
 876 endif(${GMX_CPU_ACCELERATION} STREQUAL "NONE")
 877 set(ACCELERATION_QUIETLY TRUE CACHE INTERNAL "")
 878
 879 # Process QM/MM Settings
 880 string(TOUPPER ${GMX_QMMM_PROGRAM} GMX_QMMM_PROGRAM)
 881 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 882     set(GMX_QMMM_GAUSSIAN 1)
 883 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 884     set(GMX_QMMM_MOPAC 1)
 885 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 886     set(GMX_QMMM_GAMESS 1)
 887 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 888     set(GMX_QMMM_ORCA 1)
 889 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 890     # nothing to do
 891 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 892     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 893 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 894
 895 # Process FFT library settings
 896 string(TOUPPER ${GMX_FFT_LIBRARY} GMX_FFT_LIBRARY)
 897 set(PKG_FFT "")
 898 set(PKG_FFT_LIBS "")
 899 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 900     if(GMX_DOUBLE)
 901         set(FFTW fftw)
 902     else()
 903         set(FFTW fftwf)
 904     endif()
 905
 906     if(GMX_BUILD_OWN_FFTW)
 907       add_subdirectory(src/contrib/fftw)
 908     else()
 909       find_package(FFTW COMPONENTS ${FFTW})
 910     endif()
 911
 912     string(TOUPPER "${FFTW}" FFTW)
 913     set(PKG_FFT "${${FFTW}_PKG}")
 914     include_directories(${${FFTW}_INCLUDE_DIRS})
 915     set(FFT_LIBRARIES ${${FFTW}_LIBRARIES})
 916     if(NOT ${FFTW}_FOUND)
 917       MESSAGE(FATAL_ERROR "Cannot find FFTW 3 (with correct precision - libfftw3f for single-precision GROMACS or libfftw3 for double-precision GROMACS). Either choose the right precision, choose another FFT(W) library, enable the advanced option to let GROMACS build FFTW 3 for you, or use the really slow GROMACS built-in fftpack library.")
 918     endif()
 919
 920     set(GMX_FFT_FFTW3 1)
 921
 922     if (NOT ${GMX_CPU_ACCELERATION} STREQUAL "NONE" AND NOT ${FFTW}_HAVE_SIMD)
 923       message(WARNING "The fftw library found is compiled without SIMD support, which makes it slow. Consider recompiling it or contact your admin")
 924     endif()
 925
 926     if(NOT ${GMX_CPU_ACCELERATION} STREQUAL "NONE" AND ${FFTW}_HAVE_AVX)
 927         # If we're not doing CPU acceleration, we don't care about FFTW performance on x86 either
 928         message(WARNING "The FFTW library was compiled with --enable-avx to enable AVX SIMD instructions. That might sound like a good idea for your processor, but for FFTW versions up to 3.3.3, these are slower than the SSE/SSE2 SIMD instructions for the way GROMACS uses FFTs. Limitations in the way FFTW allows GROMACS to measure performance make it awkward for either GROMACS or FFTW to make the decision for you based on runtime performance. You should compile a different FFTW library with --enable-sse or --enable-sse2. If you have a more recent FFTW, you may like to compare the performance of GROMACS with FFTW libraries compiled with and without --enable-avx. However, the GROMACS developers do not really expect the FFTW AVX optimization to help, because the performance is limited by memory access, not computation.")
 929     endif()
 930
 931 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 932 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 933     find_package(MKL REQUIRED)
 934     include_directories(${MKL_INCLUDE_DIR})
 935     set(FFT_LIBRARIES ${MKL_LIBRARIES})
 936     set(PKG_FFT_LIBS ${MKL_LIBRARIES})
 937
 938     set(GMX_FFT_MKL 1)
 939     set(HAVE_MKL 1)
 940
 941 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 942 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 943 #    set(GMX_FFT_ACML 1)
 944 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 945     MESSAGE(STATUS "Using internal FFT library - fftpack")
 946     set(GMX_FFT_FFTPACK 1)
 947 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 948     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, mkl, fftpack")
 949 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 950
 951 # enable threaded fftw3 if we've found it
 952 if(FFTW3_THREADS OR FFTW3F_THREADS)
 953     add_definitions(-DFFT5D_FFTW_THREADS)
 954 endif()
 955
 956 set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 957 set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 958 # MKL has BLAS/LAPACK routines
 959 if(NOT HAVE_MKL AND NOT ACCELERATE_FRAMEWORK)
 960   if(GMX_EXTERNAL_BLAS)
 961     if (GMX_BLAS_USER)
 962         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_BLAS_USER})
 963     else(GMX_BLAS_USER)
 964         set(BLAS_FIND_QUIETLY ON)
 965         find_package(BLAS)
 966         if (BLAS_FOUND)
 967           list(APPEND GMX_EXTRA_LIBRARIES ${BLAS_LIBRARIES})
 968         else()
 969           MESSAGE(STATUS "Using internal BLAS library")
 970           set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external BLAS instead of built-in" FORCE)
 971         endif()
 972     endif(GMX_BLAS_USER)
 973   endif(GMX_EXTERNAL_BLAS)
 974   if(GMX_EXTERNAL_LAPACK)
 975     if (GMX_LAPACK_USER)
 976         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_LAPACK_USER})
 977     else(GMX_LAPACK_USER)
 978         set(LAPACK_FIND_QUIETLY ON)
 979         find_package(LAPACK)
 980         if (LAPACK_FOUND)
 981           list(APPEND GMX_EXTRA_LIBRARIES ${LAPACK_LIBRARIES})
 982         else()
 983           MESSAGE(STATUS "Using internal LAPACK library")
 984           set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in" FORCE)
 985         endif()
 986     endif(GMX_LAPACK_USER)
 987   endif(GMX_EXTERNAL_LAPACK)
 988 endif()
 989 mark_as_advanced(GMX_EXTERNAL_LAPACK)
 990 mark_as_advanced(GMX_EXTERNAL_BLAS)
 991
 992 set(GMX_USE_PLUGINS OFF CACHE INTERNAL "Whether GROMACS will really try to compile support for VMD plugins")
 993
 994 if(GMX_LOAD_PLUGINS)
 995   if(CYGWIN OR NOT WIN32)
 996     # Native Windows does not have, nor need dlopen
 997     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 998     include(gmxTestdlopen)
 999     gmx_test_dlopen(HAVE_DLOPEN)
1000   endif()
1001
1002   # so, should we use plug-ins?
1003   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
1004     if(NOT VMD_QUIETLY)
1005       MESSAGE(STATUS
1006           "Found the ability to use plug-ins when building shared libaries, "
1007           "so will compile to use plug-ins (e.g. to read VMD-supported file "
1008           "formats).")
1009     endif()
1010     if(NOT GMX_VMD_PLUGIN_PATH)
1011       find_package(VMD)
1012     endif()
1013     set(GMX_USE_PLUGINS ON)
1014     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
1015     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
1016   else()
1017     set(PKG_DL_LIBS)
1018   endif()
1019 endif(GMX_LOAD_PLUGINS)
1020 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
1021
1022 if(EXISTS "${CMAKE_SOURCE_DIR}/admin/.isreposource")
1023     if(NOT CMAKE_CROSSCOMPILING)
1024         option(GMX_BUILD_MANPAGES "Build man pages" ON)
1025     else()
1026         message(STATUS "Building the man pages is not available when "
1027             "cross-compiling the developer version from git")
1028     endif()
1029 else()
1030     #make sure source package contains all man pages
1031     if(NOT EXISTS "${CMAKE_SOURCE_DIR}/man/man1/ngmx.1")
1032         message(FATAL_ERROR "Man pages are missing from source package.")
1033     endif()
1034 endif()
1035 mark_as_advanced(GMX_BUILD_MANPAGES)
1036
1037 # Math and thread libraries must often come after all others when linking...
1038 if(HAVE_LIBM)
1039     list(APPEND GMX_EXTRA_LIBRARIES m)
1040 endif(HAVE_LIBM)
1041
1042 if(GMX_FAHCORE)
1043   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
1044       "Path to swindirect.h")
1045   include_directories(${COREWRAP_INCLUDE_DIR})
1046   set_property(CACHE GMX_COOL_QUOTES VALUE OFF)
1047 endif(GMX_FAHCORE)
1048
1049 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
1050 # these are set after everything else
1051 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
1052     set(CMAKE_C_FLAGS "${ACCELERATION_C_FLAGS} ${MPI_COMPILE_FLAGS} ${CMAKE_C_FLAGS}")
1053     set(CMAKE_CXX_FLAGS "${ACCELERATION_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${CMAKE_CXX_FLAGS}")
1054     set(CMAKE_EXE_LINKER_FLAGS "${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
1055     set(CMAKE_SHARED_LINKER_FLAGS "${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
1056 else()
1057     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
1058     message("CMAKE_C_FLAGS: ${ACCELERATION_C_FLAGS} ${MPI_COMPILE_FLAGS} ${GMXC_CFLAGS}")
1059     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
1060     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
1061     if(CMAKE_CXX_COMPILER_LOADED)
1062         message("CMAKE_CXX_FLAGS: ${ACCELERATION_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${GMXC_CXXFLAGS}")
1063         message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
1064         message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
1065     endif()
1066     message("CMAKE_EXE_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
1067     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
1068 endif()
1069
1070 if(NOT GMX_OPENMP)
1071     #Unset all OpenMP flags in case OpenMP was disabled either by the user
1072     #or because it was only partially detected (e.g. only for C but not C++ compiler)
1073     unset(OpenMP_C_FLAGS CACHE)
1074     unset(OpenMP_CXX_FLAGS CACHE)
1075     unset(OpenMP_LINKER_FLAGS CACHE)
1076     unset(OpenMP_SHARED_LINKER_FLAGS)
1077 endif()
1078 set(PKG_CFLAGS "${PKG_CFLAGS} ${OpenMP_C_FLAGS}")
1079
1080 ######################################
1081 # Output compiler and CFLAGS used
1082 ######################################
1083 get_compiler_info(C BUILD_C_COMPILER BUILD_CFLAGS)
1084 if (CMAKE_CXX_COMPILER_LOADED)
1085     get_compiler_info(CXX BUILD_CXX_COMPILER BUILD_CXXFLAGS)
1086 endif ()
1087
1088 ########################################################################
1089 # Specify install locations and which subdirectories to process        #
1090 ########################################################################
1091 if (GMX_USE_RELATIVE_INSTALL_PATH)
1092     set(GMX_INSTALL_PREFIX "" CACHE STRING "Prefix gets appended to CMAKE_INSTALL_PREFIX. For cpack it sets the root folder of the archive.")
1093     mark_as_advanced(GMX_INSTALL_PREFIX)
1094 else()
1095     set(GMX_INSTALL_PREFIX "${CMAKE_INSTALL_PREFIX}/")
1096 endif()
1097
1098 if ( NOT DEFINED GMXLIB )
1099     set(GMXLIB lib)
1100 endif()
1101 set(LIB_INSTALL_DIR "${GMX_INSTALL_PREFIX}${GMXLIB}")
1102 set(BIN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}bin)
1103 set(DATA_INSTALL_DIR ${GMX_INSTALL_PREFIX}share/gromacs)
1104 set(MAN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}share/man)
1105 set(INCL_INSTALL_DIR ${GMX_INSTALL_PREFIX}include)
1106
1107 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
1108
1109 ##################################################################
1110 # Shared library settings - Darwin uses INSTALL_NAME_DIR instead!
1111 ##################################################################
1112 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
1113     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
1114     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
1115     set(CMAKE_INSTALL_RPATH "\\\$ORIGIN/../${GMXLIB}")
1116     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
1117 endif()
1118
1119 #COPYING file: Only necessary for binary distributions.
1120 #Simpler to always install.
1121 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
1122
1123 add_subdirectory(share)
1124 add_subdirectory(include)
1125 add_subdirectory(src)
1126 add_subdirectory(scripts)
1127
1128 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
1129 # Don't bother the user after the first configure pass.
1130 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
1131     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
1132     unset(CUDA_NOTFOUND_AUTO)
1133     unset(CUDA_NOTFOUND_MESSAGE)
1134 endif()
1135 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
1136
1137 #######################
1138 ## uninstall target
1139 #######################
1140     CONFIGURE_FILE(
1141                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
1142                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
1143                    IMMEDIATE @ONLY)
1144 ###########################
1145 ADD_CUSTOM_TARGET(uninstall
1146                   "${CMAKE_COMMAND}" -P
1147                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
1148 ###########################
1149
1150 ########################################################################
1151 # Tests                                                                #
1152 ########################################################################
1153
1154 include(CTest)
1155 mark_as_advanced(BUILD_TESTING)
1156 #gmxtests target builds all binaries required for running gmxtest
1157 add_custom_target(gmxtests DEPENDS grompp mdrun pdb2gmx gmxcheck editconf)
1158 IF(BUILD_TESTING)
1159     enable_testing()
1160     add_subdirectory(tests)
1161     if(REGRESSIONTEST_PATH)
1162         #check target builds all to run tests and the runs tests
1163         add_custom_target(check COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure)
1164         add_dependencies(check gmxtests)
1165     else()
1166         add_custom_target(check COMMAND ${CMAKE_COMMAND} -E echo "WARNING: No tests are run. Running the tests requires either of the cmake variables REGRESSIONTEST_PATH or REGRESSIONTEST_DOWNLOAD to be set.")
1167     endif()
1168 ENDIF()
1169