CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8)
   2 # Keep CMake suitably quiet on Cygwin
   3 set(CMAKE_LEGACY_CYGWIN_WIN32 0) # Remove when CMake >= 2.8.4 is required
   4
   5 # Allows CPack to act differently for normal tools and mdrun (e.g. because of MPI)
   6 set(CPACK_COMPONENT_GROUP_TOOLS_DESCRIPTION "All GROMACS executable tools")
   7 set(CPACK_COMPONENT_GROUP_MDRUN_DESCRIPTION "GROMACS executable for running simulations")
   8
   9 # override bugs on OS X where Cmake picks gcc (GNU) for C instead of system default cc (Clang).
  10 if(APPLE)
  11     set(CMAKE_C_COMPILER_INIT "cc")
  12 endif(APPLE)
  13
  14 project(Gromacs C)
  15 include(Dart)
  16 mark_as_advanced(DART_ROOT)
  17
  18 # PROJECT_VERSION should have the following structure:
  19 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  20 #
  21 # The "-dev" suffix is important to keep because it makes possible to distinguish
  22 # between a build from official release and a build from git release branch on a
  23 # machine with no git.
  24 #
  25 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  26 set(PROJECT_VERSION "4.6-dev")
  27 set(CUSTOM_VERSION_STRING ""
  28     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  29 mark_as_advanced(CUSTOM_VERSION_STRING)
  30 if (CUSTOM_VERSION_STRING)
  31     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  32 endif (CUSTOM_VERSION_STRING)
  33 set(SOVERSION 6)
  34 # It is a bit irritating, but this has to be set separately for now!
  35 SET(CPACK_PACKAGE_VERSION_MAJOR "4")
  36 SET(CPACK_PACKAGE_VERSION_MINOR "6")
  37 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  38
  39 # The numerical gromacs version. It is 40600 for 4.6.0.
  40 # The #define GMX_VERSION in gmx_header_config_h is set to this value.
  41 math(EXPR NUM_VERSION
  42     "${CPACK_PACKAGE_VERSION_MAJOR}*10000 + ${CPACK_PACKAGE_VERSION_MINOR}*100")
  43 if(CPACK_PACKAGE_VERSION_PATCH)
  44     math(EXPR NUM_VERSION
  45          "${NUM_VERSION} + ${CPACK_PACKAGE_VERSION_PATCH}")
  46 endif()
  47
  48 # The API version tracks the numerical Gromacs version (for now).
  49 # It is potentially different from the Gromacs version in the future, if
  50 # the programs/libraries diverge from the presumably more stable API.
  51 # The #define GMX_API_VERSION in version.h is set to this value to
  52 # provide backward compatibility of software written against the Gromacs API.
  53 set(API_VERSION ${NUM_VERSION})
  54
  55 # Cmake modules/macros are in a subdirectory to keep this file cleaner
  56 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  57
  58 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  59 set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  60 endif()
  61
  62 if(NOT CMAKE_BUILD_TYPE)
  63     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
  64 endif(NOT CMAKE_BUILD_TYPE)
  65
  66 enable_language(C)
  67
  68 set(GMX_USE_RELATIVE_INSTALL_PATH OFF CACHE STRING "Use relative paths not absolute paths for cmake install. Has only an effect on cpack.")
  69 mark_as_advanced(GMX_USE_RELATIVE_INSTALL_PATH)
  70
  71 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
  72 set(CPACK_PACKAGE_VENDOR "gromacs.org")
  73 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
  74 if (NOT GMX_USE_RELATIVE_INSTALL_PATH)
  75     set(CPACK_SET_DESTDIR "ON")
  76 endif()
  77 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
  78 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
  79 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/COPYING")
  80 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
  81 set(CPACK_SOURCE_IGNORE_FILES ".isreposource;.git;.gitignore")
  82 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
  83 SET(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/man;man")
  84 set(CPACK_PACKAGE_CONTACT "gmx-users@gromacs.org")
  85
  86 #must come after all cpack settings!
  87 include(CPack)
  88
  89 ########################################################################
  90 # Check and warn if cache generated on a different host is being reused
  91 ########################################################################
  92 if(CMAKE_HOST_UNIX)
  93     execute_process(COMMAND hostname
  94                     OUTPUT_VARIABLE TMP_HOSTNAME
  95                     OUTPUT_STRIP_TRAILING_WHITESPACE)
  96     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
  97         message(WARNING "
  98             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
  99             is being reused! This could lead to inconsitencies; therefore, it is
 100             recommended to regenerate the cache!")
 101     endif()
 102     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 103             "Hostname of the machine where the cache was generated.")
 104 endif()
 105
 106 ########################################################################
 107 # User input options - enable C++ - before any CXX flags are changed   #
 108 ########################################################################
 109 option(GMX_GPU  "Enable GPU acceleration" ON)
 110 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library (rerun cmake after changing to see relevant options)" OFF)
 111 option(GMX_FORCE_CXX "Enable C++ compilation even if not necessary" OFF)
 112 mark_as_advanced(GMX_FORCE_CXX)
 113 if(GMX_GPU OR GMX_OPENMM OR GMX_FORCE_CXX)
 114     enable_language(CXX)
 115 endif()
 116 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 117
 118 ########################################################################
 119 # Fix stupid flags on Windows
 120 ########################################################################
 121 SET(SHARED_LIBS_DEFAULT ON)
 122 IF( WIN32 AND NOT CYGWIN)
 123   option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static system libraries (MT instead of MD)!" ON)
 124   mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 125   SET(SHARED_LIBS_DEFAULT OFF)  #is currently not working on Windows
 126
 127   IF (GMX_PREFER_STATIC_LIBS)
 128     #Only setting Debug and Release flags. Others configurations current not used.
 129     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
 130     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
 131     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
 132     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
 133     if(CMAKE_CXX_COMPILER_LOADED)
 134         STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE})
 135         SET(CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE} CACHE STRING "" FORCE)
 136         STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 137         SET(CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG} CACHE STRING "" FORCE)
 138     endif()
 139   ENDIF()
 140
 141   #Workaround for cmake bug 13174. Replace deprecated options.
 142   IF( CMAKE_C_COMPILER_ID MATCHES "Intel" )
 143     STRING(REPLACE /GZ /RTC1 CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
 144     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
 145   ENDIF()
 146   IF( CMAKE_CXX_COMPILER_ID MATCHES "Intel" AND CMAKE_CXX_COMPILER_LOADED)
 147     STRING(REPLACE /GZ /RTC1 CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 148     STRING(REPLACE /GX /EHsc CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 149     SET(CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG} CACHE STRING "" FORCE)
 150
 151     STRING(REPLACE /GX /EHsc CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE})
 152     SET(CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE} CACHE STRING "" FORCE)
 153   ENDIF()
 154 ENDIF()
 155
 156
 157 ########################################################################
 158 # User input options                                                   #
 159 ########################################################################
 160 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 161 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 162 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 163 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 164 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 165 option(GMX_POWERPC_INVSQRT "Use PowerPC hardware 1/sqrt" OFF)
 166 mark_as_advanced(GMX_POWERPC_INVSQRT)
 167 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 168 mark_as_advanced(GMX_FAHCORE)
 169
 170 include(gmxDetectAcceleration)
 171 if(NOT DEFINED GMX_CPU_ACCELERATION)
 172     if(CMAKE_CROSSCOMPILING)
 173         set(GMX_SUGGESTED_CPU_ACCELERATION "None")
 174     else(CMAKE_CROSSCOMPILING)
 175         gmx_detect_acceleration(GMX_SUGGESTED_CPU_ACCELERATION)
 176     endif(CMAKE_CROSSCOMPILING)
 177 endif(NOT DEFINED GMX_CPU_ACCELERATION)
 178
 179 set(GMX_CPU_ACCELERATION "@GMX_SUGGESTED_CPU_ACCELERATION@"
 180     CACHE STRING "Accelerated CPU kernels. Pick one of: None, SSE2, SSE4.1, AVX_128_FMA, AVX_256, BlueGene, Power6, Fortran")
 181
 182 set(GMX_FFT_LIBRARY "fftw3"
 183     CACHE STRING "FFT library choices: fftw3,mkl,fftpack[built-in]")
 184 option(GMX_DISABLE_FFTW_MEASURE
 185        "Do not optimize FFTW setups (not needed with SSE)" OFF)
 186 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 187 set(GMX_QMMM_PROGRAM "none"
 188     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
 189 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 190 mark_as_advanced(GMX_BROKEN_CALLOC)
 191 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
 192 mark_as_advanced(GMX_MPI_IN_PLACE)
 193 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 194 mark_as_advanced(GMX_LOAD_PLUGINS)
 195
 196 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 197
 198 option(USE_VERSION_H "Generate development version string/information" ON)
 199 mark_as_advanced(USE_VERSION_H)
 200
 201 option(GMX_DEFAULT_SUFFIX "Use default suffixes for GROMACS binaries and libs (_d for double, _mpi for MPI; rerun cmake after changing to see relevant options)" ON)
 202
 203 if(UNIX)
 204     option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static archives (not available on non-*nix platforms and it will only work if static versions of external dependencies are available and found)!" OFF)
 205     mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 206 endif()
 207
 208 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 209 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 210
 211 ######################################################################
 212 # Compiler tests
 213 # These need to be done early (before further tests).
 214 #####################################################################
 215
 216 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 217 # are used with permission from CMake v2.8.9 so that GROMACS can detect
 218 # invalid options with the Intel Compilers.
 219 # These files should be removed from the source tree when a CMake version that
 220 # includes the features in question becomes required for building GROMACS.
 221 include(CheckCCompilerFlag)
 222 if(CMAKE_CXX_COMPILER_LOADED)
 223     include(CheckCXXCompilerFlag)
 224 endif()
 225
 226 # OpenMP check must come before other CFLAGS!
 227 if(GMX_OPENMP)
 228     find_package(OpenMP)
 229     if(OPENMP_FOUND)
 230         #- only set linker flag, if user didn't set them manual
 231         #- cmake on windows doesn't support linker flags passed to target_link_libraries
 232         #  (cmake treats /openmp as \openmp library file) and no openmp linker flags are needed
 233         if(NOT (WIN32 AND NOT CYGWIN))
 234             if(CMAKE_COMPILER_IS_GNUCC AND GMX_PREFER_STATIC_OPENMP)
 235                 set(OpenMP_LINKER_FLAGS "-Wl,-static -lgomp -lrt -Wl,-Bdynamic -lpthread")
 236                 set(OpenMP_SHARED_LINKER_FLAGS "")
 237             else()
 238                 if(NOT DEFINED OpenMP_LINKER_FLAGS)
 239                     set(OpenMP_LINKER_FLAGS "${OpenMP_C_FLAGS}")
 240                 endif()
 241                 if(NOT DEFINED OpenMP_SHARED_LINKER_FLAGS)
 242                     set(OpenMP_SHARED_LINKER_FLAGS "${OpenMP_C_FLAGS}")
 243                 endif()
 244             endif()
 245         endif()
 246     else(OPENMP_FOUND)
 247         message(WARNING
 248                 "Compiler not supporting OpenMP. This might hurt your performance a lot, "
 249                 "in particular with GPUs. Try using a different compiler (Intel is good on x86) "
 250                 "if you can - for now we are proceeding by turning off OpenMP.")
 251         set(GMX_OPENMP OFF CACHE STRING "Compiler does not support OpenMP." FORCE)
 252     endif(OPENMP_FOUND)
 253 endif()
 254
 255
 256 include(gmxCFlags)
 257 gmx_c_flags()
 258
 259 include(gmxGetCompilerVersion)
 260 get_compiler_version()
 261
 262 # gcc 4.4.x is buggy and crashes when compiling some files with O3 and OpenMP on.
 263 # Detect here whether applying a workaround is needed and will apply it later
 264 # on the affected files.
 265 include(gmxGCC44O3BugWorkaround)
 266 gmx_check_gcc44_bug_workaround_needed(GMX_USE_GCC44_BUG_WORKAROUND)
 267
 268 ########################################################################
 269 # Set up binary and library suffixing
 270 ########################################################################
 271 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 272 set(GMX_LIBS_SUFFIX ""
 273   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 274 if (GMX_DEFAULT_SUFFIX)
 275   set(GMX_BINARY_SUFFIX "")
 276   set(GMX_LIBS_SUFFIX "")
 277   if (GMX_MPI)
 278     set(GMX_BINARY_SUFFIX "_mpi")
 279     set(GMX_LIBS_SUFFIX "_mpi")
 280   endif(GMX_MPI)
 281   if (GMX_DOUBLE)
 282     set (GMX_BINARY_SUFFIX "${GMX_BINARY_SUFFIX}_d")
 283     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
 284   endif(GMX_DOUBLE)
 285   if (GMX_OPENMM)
 286     set (GMX_BINARY_SUFFIX "-openmm")
 287     set (GMX_LIBS_SUFFIX "_openmm")
 288   endif(GMX_OPENMM)
 289   mark_as_advanced(FORCE GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 290   if (NOT SUFFIX_QUIETLY)
 291     message(STATUS "Using default binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 292     message(STATUS "Using default library suffix: \"${GMX_LIBS_SUFFIX}\"")
 293   endif (NOT SUFFIX_QUIETLY)
 294 else(GMX_DEFAULT_SUFFIX)
 295   mark_as_advanced(CLEAR GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 296   if (NOT SUFFIX_QUIETLY)
 297     message(STATUS "Using manually set binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 298     message(STATUS "Using manually set library suffix: \"${GMX_LIBS_SUFFIX}\"")
 299   endif (NOT SUFFIX_QUIETLY)
 300 endif(GMX_DEFAULT_SUFFIX)
 301 set(SUFFIX_QUIETLY TRUE CACHE INTERNAL "")
 302
 303 set(PKG_CFLAGS "")
 304 if(GMX_DOUBLE)
 305     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 306 endif(GMX_DOUBLE)
 307 if(GMX_SOFTWARE_INVSQRT)
 308   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 309 endif(GMX_SOFTWARE_INVSQRT)
 310 if(GMX_POWERPC_INVSQRT)
 311   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_POWERPC_INVSQRT")
 312 endif(GMX_POWERPC_INVSQRT)
 313
 314 ########################################################################
 315 #Process MPI settings
 316 ########################################################################
 317 include(gmxManageMPI)
 318
 319 #######################################################################
 320 # Check for options incompatible with OpenMM build                    #
 321 #######################################################################
 322 if(GMX_OPENMM)
 323     # we'll use the built-in fft to avoid unnecessary dependencies
 324     string(TOUPPER ${GMX_FFT_LIBRARY} GMX_FFT_LIBRARY)
 325     if(NOT ${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 326         message(STATUS "No external FFT libraries needed for the OpenMM build, switching to fftpack!")
 327         set(GMX_FFT_LIBRARY "fftpack" CACHE STRING
 328                 "No external FFT libraries needed for the OpenMM build, switching to  fftpack!" FORCE)
 329     endif()
 330     if(GMX_MPI)
 331         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
 332     endif(GMX_MPI)
 333     if(GMX_THREAD_MPI)
 334         message(STATUS "Thread-MPI not compatible with OpenMM, disabled!")
 335         set(GMX_THREAD_MPI OFF CACHE BOOL
 336                 "Thread-MPI not compatible with OpenMM build, disabled!" FORCE)
 337     endif(GMX_THREAD_MPI)
 338     if(GMX_OPENMP)
 339         message(STATUS "OpenMP multithreading not compatible with OpenMM, disabled")
 340         set(GMX_OPENMP OFF CACHE BOOL
 341             "OpenMP multithreading not compatible with OpenMM, disabled!" FORCE)
 342     endif()
 343     if(GMX_SOFTWARE_INVSQRT)
 344         set(GMX_SOFTWARE_INVSQRT OFF CACHE STRING
 345                 "The OpenMM build does not need GROMACS software 1/sqrt!" FORCE)
 346     endif(GMX_SOFTWARE_INVSQRT)
 347     string(TOUPPER ${GMX_CPU_ACCELERATION} GMX_CPU_ACCELERATION)
 348     if(NOT GMX_CPU_ACCELERATION STREQUAL "NONE")
 349         message(STATUS "Switching off CPU-based acceleration, the OpenMM build does not support/need any!")
 350         set(GMX_CPU_ACCELERATION "None" CACHE STRING
 351             "Switching off CPU-based acceleration, the OpenMM build does not support/need any!" FORCE)
 352     endif()
 353     if(GMX_FAHCORE)
 354         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
 355     endif(GMX_FAHCORE)
 356     if(GMX_DOUBLE)
 357         message(FATAL_ERROR  "The OpenMM-build does not support double precision calculations!")
 358     endif()
 359     # mark as advanced the unused variables
 360     mark_as_advanced(FORCE GMX_CPU_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 361         GMX_QMMM_PROGRAM GMX_THREAD_MPI GMX_DOUBLE)
 362 else(GMX_OPENMM)
 363      mark_as_advanced(CLEAR GMX_CPU_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 364         GMX_QMMM_PROGRAM GMX_THREAD_MPI GMX_DOUBLE)
 365 endif(GMX_OPENMM)
 366
 367
 368 ########################################################################
 369 # Basic system tests (standard libraries, headers, functions, types)   #
 370 ########################################################################
 371 include(CheckIncludeFiles)
 372 check_include_files(string.h     HAVE_STRING_H)
 373 check_include_files(math.h       HAVE_MATH_H)
 374 check_include_files(limits.h     HAVE_LIMITS_H)
 375 check_include_files(memory.h     HAVE_MEMORY_H)
 376 check_include_files(unistd.h     HAVE_UNISTD_H)
 377 check_include_files(direct.h     HAVE_DIRECT_H)
 378 check_include_files(pwd.h        HAVE_PWD_H)
 379 check_include_files(stdint.h     HAVE_STDINT_H)
 380 check_include_files(stdlib.h     HAVE_STDLIB_H)
 381 check_include_files(pthread.h    HAVE_PTHREAD_H)
 382 check_include_files(dirent.h     HAVE_DIRENT_H)
 383 check_include_files(inttypes.h   HAVE_INTTYPES_H)
 384 check_include_files(regex.h      HAVE_REGEX_H)
 385 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 386 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
 387 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 388 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
 389 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
 390 check_include_files(io.h                 HAVE_IO_H)
 391 check_include_files(sched.h      HAVE_SCHED_H)
 392
 393 include(CheckFunctionExists)
 394 check_function_exists(strcasecmp        HAVE_STRCASECMP)
 395 check_function_exists(strdup            HAVE_STRDUP)
 396 check_function_exists(vprintf           HAVE_VPRINTF)
 397 check_function_exists(memcmp            HAVE_MEMCMP)
 398 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 399 check_function_exists(memalign          HAVE_MEMALIGN)
 400 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 401 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 402 check_function_exists(isnan             HAVE_ISNAN)
 403 check_function_exists(_isnan            HAVE__ISNAN)
 404 check_function_exists(fsync             HAVE_FSYNC)
 405 check_function_exists(_fileno           HAVE__FILENO)
 406 check_function_exists(fileno            HAVE_FILENO)
 407 check_function_exists(_commit           HAVE__COMMIT)
 408 check_function_exists(lstat             HAVE_LSTAT)
 409 check_function_exists(sigaction         HAVE_SIGACTION)
 410 check_function_exists(sysconf           HAVE_SYSCONF)
 411 check_function_exists(sched_setaffinity HAVE_SCHED_SETAFFINITY)
 412 check_function_exists(sched_getaffinity HAVE_SCHED_GETAFFINITY)
 413 check_function_exists(rsqrt             HAVE_RSQRT)
 414 check_function_exists(rsqrtf            HAVE_RSQRTF)
 415 check_function_exists(sqrtf             HAVE_SQRTF)
 416
 417 include(CheckLibraryExists)
 418 check_library_exists(m sqrt "" HAVE_LIBM)
 419 check_library_exists(m cbrt "" HAVE_CBRT)
 420
 421
 422 include(CheckTypeSize)
 423
 424 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 425 check_type_size("int"           SIZEOF_INT)
 426 check_type_size("long int"      SIZEOF_LONG_INT)
 427 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 428 check_type_size("off_t"         SIZEOF_OFF_T)
 429 check_type_size("void *"        SIZEOF_VOIDP)
 430
 431 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 432     set(GMX_64_BIT TRUE)
 433 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 434     set(GMX_64_BIT FALSE)
 435 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 436
 437 # Check for some basic types that we *need*, so set these to int if they are not present
 438 check_type_size(uid_t uid_t)
 439 if(NOT uid_t)
 440   set(uid_t int)
 441 else(NOT uid_t)
 442   set(uid_t 0)
 443 endif(NOT uid_t)
 444
 445 check_type_size(gid_t gid_t)
 446 if(NOT gid_t)
 447   set(gid_t 1)
 448 else(NOT gid_t)
 449   set(gid_t 0)
 450 endif(NOT gid_t)
 451
 452 check_type_size(size_t size_t)
 453 if(NOT size_t)
 454   set(size_t int)
 455 else(NOT size_t)
 456   set(size_t 0)
 457 endif(NOT size_t)
 458
 459 check_type_size(off_t off_t)
 460 if(NOT off_t)
 461   set(off_t int)
 462 else(NOT off_t)
 463   set(off_t 0)
 464 endif(NOT off_t)
 465
 466 include(TestBigEndian)
 467 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 468
 469
 470
 471
 472 ########################################################################
 473 # Find external packages                                               #
 474 ########################################################################
 475 if(UNIX)
 476     if(GMX_PREFER_STATIC_LIBS)
 477         # On Linux .a is the static library suffix, on Mac OS X .lib can also
 478         # be used, so we'll add both to the preference list.
 479         SET(CMAKE_FIND_LIBRARY_SUFFIXES ".lib;.a" ${CMAKE_FIND_LIBRARY_SUFFIXES})
 480         if(SHARED_LIBS_DEFAULT)
 481             if(BUILD_SHARED_LIBS) #Warn the user about the combination. But don't overwrite the request.
 482                 message(WARNING "Static libraries requested, and shared Gromacs libraries requested.")
 483             elseif(NOT DEFINED BUILD_SHARED_LIBS) #Change default to OFF. Don't warn if it's already off.
 484                 message(WARNING "Static libraries requested, the GROMACS libraries will also be build static (BUILD_SHARED_LIBS=OFF)")
 485                 set(SHARED_LIBS_DEFAULT OFF)
 486             endif()
 487         endif()
 488     endif()
 489 endif()
 490 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI, Windows)" ${SHARED_LIBS_DEFAULT})
 491
 492 option(GMX_GSL "Add support for gsl" OFF)
 493 if (GMX_GSL)
 494   find_package(gsl)
 495   set(PKG_GSL "")
 496   if(GSL_FOUND)
 497     include_directories(${GSL_INCLUDE_DIR})
 498     set(PKG_GSL gsl)
 499     set(HAVE_LIBGSL 1)
 500   endif(GSL_FOUND)
 501 endif (GMX_GSL)
 502
 503 option(GMX_X11 "Use X window system" OFF)
 504 if (GMX_X11)
 505         find_package(X11)
 506         # X11 includes/libraries are only set in the ngmx subdirectory!
 507         if(X11_FOUND)
 508         set(HAVE_X11 1)
 509         endif(X11_FOUND)
 510 endif(GMX_X11)
 511
 512 include(ThreadMPI)
 513 set(THREAD_MPI_LIB thread_mpi)
 514 if(GMX_THREAD_MPI)
 515     tmpi_get_source_list(THREAD_MPI_SRC)
 516     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREAD_MPI")
 517     set(GMX_MPI 1)
 518 else(GMX_THREAD_MPI)
 519     tmpi_get_source_list(THREAD_MPI_SRC NOMPI)
 520 endif(GMX_THREAD_MPI)
 521
 522 if(GMX_OPENMM)
 523     set(CUDA_BUILD_EMULATION OFF)
 524     find_package(CUDA 3.1 REQUIRED)
 525     add_definitions(-DGMX_OPENMM)
 526     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 527         set(CUDA_VERBOSE_BUILD ON)
 528     endif()
 529     find_package(OpenMM)
 530 endif(GMX_OPENMM)
 531
 532
 533 if(GMX_GPU)
 534     if(GMX_DOUBLE)
 535         message(WARNING "GPU acceleration is not available in double precision, disabled!")
 536         set(GMX_GPU OFF CACHE BOOL "Enable GPU acceleration" FORCE)
 537     endif()
 538 endif(GMX_GPU)
 539
 540 if(GMX_GPU)
 541
 542     # We support CUDA >=v3.2 on *nix, but <= v4.1 doesn't work with MSVC
 543     if(MSVC)
 544         find_package(CUDA 4.1)
 545     else()
 546         find_package(CUDA 3.2)
 547     endif()
 548
 549     if (NOT EXISTS ${CUDA_TOOLKIT_ROOT_DIR})
 550         message(FATAL_ERROR "
 551     mdrun supports native GPU acceleration on NVIDIA hardware with compute
 552     capability >=2.0. This requires the NVIDIA CUDA library, which was not
 553     found; the location can be hinted by setting CUDA_TOOLKIT_ROOT_DIR.
 554
 555     CPU or GPU acceleration can be selected at runtime, but if you are
 556     sure you can not make use of GPU acceleration, disable it by setting
 557     the CMake variable GMX_GPU=OFF.")
 558     endif()
 559
 560     if(NOT GMX_OPENMP)
 561         message(WARNING "
 562     In order to use GPU acceleration efficiently, mdrun requires OpenMP multithreding.
 563     Without OpenMP only a single CPU core per GPU can be used which is suboptimal.
 564     Note that with MPI multiple processes can be forced to use a single GPU, but this
 565     typically inefficient.")
 566     endif()
 567
 568     include(gmxManageNvccConfig)
 569
 570     # Check whether we can use atomic operations needed for polling wait for GPU
 571     # (to avoid the cudaStreamSynchronize + ECC bug).
 572     # With thread-MPI testing atomics has already been carried out, but without
 573     # thread-MPI we need to invoke the atomics test independently.
 574     if (NOT GMX_THREAD_MPI)
 575         set(TEST_TMPI_ATOMICS_ONLY ON CACHE INTERNAL
 576             "Test only the atomic operations of thread-MPI.")
 577         include(ThreadMPI)
 578     endif()
 579
 580     # we need this linker flag in case if we have ld >= 2.22 (typically with gcc 4.5+),
 581     # but it's too cumbersome to check the ld version and the flag should not hurt
 582     if(CMAKE_COMPILER_IS_GNUCC)
 583         set(GROMACS_LINKER_FLAGS "-Wl,--add-needed ${GROMACS_LINKER_FLAGS}")
 584     endif()
 585 endif()
 586 # Annoyingly enough, FindCUDA leaves a few variables behind as non-advanced.
 587 # We need to mark these advanced outside the conditional, otherwise, if the user
 588 # tuns GMX_GPU=OFF after a failed cmake pass, these variables will be left behind.
 589 mark_as_advanced(CUDA_BUILD_CUBIN CUDA_BUILD_EMULATION CUDA_SDK_ROOT_DIR CUDA_VERBOSE_BUILD)
 590
 591 if(APPLE)
 592    find_library(ACCELERATE_FRAMEWORK Accelerate)
 593    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 594 endif(APPLE)
 595
 596 if(CYGWIN)
 597     set(GMX_CYGWIN 1)
 598 endif(CYGWIN)
 599
 600 if(WIN32 AND NOT CYGWIN)
 601     set(GMX_NATIVE_WINDOWS 1)
 602 endif()
 603
 604 # only bother with finding git and using version.h if the source is a git repo
 605 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 606     if(USE_VERSION_H)
 607         # We need at least git v1.5.3 be able to parse git's date output. If not
 608         # found or the version is too small, we can't generate version information.
 609         find_package(Git)
 610
 611         # Find out the git version
 612         if(GIT_FOUND AND NOT GIT_VERSION)
 613           execute_process(COMMAND ${GIT_EXECUTABLE} "--version"
 614             OUTPUT_VARIABLE _exec_out
 615             OUTPUT_STRIP_TRAILING_WHITESPACE)
 616           string(REGEX REPLACE "git version (.*)" "\\1" GIT_VERSION ${_exec_out})
 617           set(GIT_VERSION ${GIT_VERSION} CACHE STRING "Git version")
 618           mark_as_advanced(GIT_VERSION)
 619         endif()
 620
 621         if(NOT GIT_FOUND OR GIT_VERSION VERSION_LESS "1.5.3")
 622           message("No compatible git version found, won't be able to generate proper development version information.")
 623           set(USE_VERSION_H OFF)
 624         endif()
 625     endif()
 626 else()
 627     set(USE_VERSION_H OFF)
 628 endif()
 629
 630 ########################################################################
 631 # Generate development version info for cache
 632 ########################################################################
 633 # set(GEN_VERSION_INFO_INTERNAL "ON")
 634 # include(gmxGenerateVersionString)
 635
 636 ########################################################################
 637 # Our own GROMACS tests
 638 ########################################################################
 639
 640 add_definitions( -DHAVE_CONFIG_H )
 641 include_directories(${CMAKE_BINARY_DIR}/src)
 642 include_directories(${CMAKE_BINARY_DIR}/include)
 643 include_directories(${CMAKE_SOURCE_DIR}/include)
 644
 645 include(gmxTestInlineASM)
 646 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 647
 648 include(gmxSetBuildInformation)
 649 gmx_set_build_information()
 650 if(BUILD_CPU_FEATURES MATCHES "rdtscp" AND NOT GMX_DISTRIBUTABLE_BUILD)
 651     # The timestep counter headers do not include config.h
 652     add_definitions(-DHAVE_RDTSCP)
 653 endif(BUILD_CPU_FEATURES MATCHES "rdtscp" AND NOT GMX_DISTRIBUTABLE_BUILD)
 654
 655 include(gmxTestFloatFormat)
 656 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 657                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 658                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 659
 660 include(gmxTestLargeFiles)
 661 gmx_test_large_files(GMX_LARGEFILES)
 662
 663 include(gmxTestSignal)
 664 gmx_test_sigusr1(HAVE_SIGUSR1)
 665
 666 include(gmxTestInline)
 667 gmx_test_inline(INLINE_KEYWORD)
 668
 669 include(gmxTestRestrict)
 670 gmx_test_restrict(RESTRICT_KEYWORD)
 671
 672 include(gmxTestPipes)
 673 gmx_test_pipes(HAVE_PIPES)
 674
 675 include(gmxTestIsfinite)
 676 gmx_test_isfinite(HAVE_ISFINITE)
 677 gmx_test__isfinite(HAVE__ISFINITE)
 678 gmx_test__finite(HAVE__FINITE)
 679
 680 include(gmxTestXDR)
 681 gmx_test_xdr(GMX_SYSTEM_XDR)
 682 if(NOT GMX_SYSTEM_XDR)
 683     set(GMX_INTERNAL_XDR 1)
 684     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 685 endif(NOT GMX_SYSTEM_XDR)
 686
 687 # Process nonbonded accelerated kernels settings
 688 string(TOUPPER ${GMX_CPU_ACCELERATION} ${GMX_CPU_ACCELERATION})
 689 if(${GMX_CPU_ACCELERATION} STREQUAL "NONE")
 690     # nothing to do
 691 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SSE2")
 692
 693     GMX_TEST_CFLAG(GNU_SSE2_CFLAG "-msse2" GROMACS_C_FLAGS)
 694     if(NOT GNU_SSE2_CFLAG)
 695         GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" GROMACS_C_FLAGS)
 696     endif(NOT GNU_SSE2_CFLAG)
 697
 698     if (CMAKE_CXX_COMPILER_LOADED)
 699         GMX_TEST_CXXFLAG(GNU_SSE2_CXXFLAG "-msse2" GROMACS_CXX_FLAGS)
 700         if(NOT GNU_SSE2_CXXFLAG)
 701             GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" GROMACS_CXX_FLAGS)
 702         endif(NOT GNU_SSE2_CXXFLAG)
 703     endif()
 704
 705     # We dont warn for lacking SSE2 flag support, since that is probably standard today.
 706
 707     # Only test the include after we have tried to add the correct flag for SSE2 support
 708     check_include_file(emmintrin.h  HAVE_EMMINTRIN_H ${GROMACS_C_FLAGS})
 709
 710     if(NOT HAVE_EMMINTRIN_H)
 711         message(FATAL_ERROR "Cannot find emmintrin.h, which is required for SSE2 intrinsics support.")
 712     endif(NOT HAVE_EMMINTRIN_H)
 713
 714     set(GMX_CPU_ACCELERATION_X86_SSE2 1)
 715     # The user should not be able to set this orthogonally to the acceleration
 716     set(GMX_X86_SSE2 1)
 717     if (NOT ACCELERATION_QUIETLY)
 718       message(STATUS "Enabling SSE2 Gromacs acceleration, and it will help compiler optimization.")
 719     endif()
 720
 721 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SSE4.1")
 722
 723     GMX_TEST_CFLAG(GNU_SSE4_CFLAG "-msse4.1" GROMACS_C_FLAGS)
 724     if (NOT GNU_SSE4_CFLAG)
 725         GMX_TEST_CFLAG(MSVC_SSE4_CFLAG "/arch:SSE4.1" GROMACS_C_FLAGS)
 726     endif(NOT GNU_SSE4_CFLAG)
 727     if (NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 728         message(WARNING "No C SSE4.1 flag found. Consider a newer compiler, or disable SSE4.1 for slightly lower performance.")
 729         # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 730         # intrinsics when SSE2 support is enabled, so we try that instead.
 731         GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" GROMACS_C_FLAGS)
 732     endif(NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 733
 734     if (CMAKE_CXX_COMPILER_LOADED)
 735         GMX_TEST_CXXFLAG(GNU_SSE4_CXXFLAG "-msse4.1" GROMACS_CXX_FLAG)
 736         if (NOT GNU_SSE4_CXXFLAG)
 737             GMX_TEST_CXXFLAG(MSVC_SSE4_CXXFLAG "/arch:SSE4.1" GROMACS_CXX_FLAGS)
 738         endif(NOT GNU_SSE4_CXXFLAG)
 739         if (NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 740             message(WARNING "No C++ SSE4.1 flag found. Consider a newer compiler, or disable SSE4.1 for slightly lower performance.")
 741             # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 742             # intrinsics when SSE2 support is enabled, so we try that instead.
 743             GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" GROMACS_CXX_FLAGS)
 744         endif(NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 745     endif()
 746
 747     # This must come after we have added the -msse4.1 flag on some platforms.
 748     check_include_file(smmintrin.h  HAVE_SMMINTRIN_H ${GROMACS_C_FLAGS})
 749
 750     if(NOT HAVE_SMMINTRIN_H)
 751         message(FATAL_ERROR "Cannot find smmintrin.h, which is required for SSE4.1 intrinsics support.")
 752     endif(NOT HAVE_SMMINTRIN_H)
 753
 754     set(GMX_CPU_ACCELERATION_X86_SSE4_1 1)
 755     # The user should not be able to set this orthogonally to the acceleration
 756     set(GMX_X86_SSE4_1 1)
 757     set(GMX_X86_SSE2   1)
 758     if (NOT ACCELERATION_QUIETLY)
 759       message(STATUS "Enabling SSE4.1 Gromacs acceleration, and it will help compiler optimization.")
 760     endif()
 761
 762 elseif(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA" OR ${GMX_CPU_ACCELERATION} STREQUAL "AVX_256")
 763
 764     # Set the AVX compiler flag for both these choices!
 765
 766     GMX_TEST_CFLAG(GNU_AVX_CFLAG "-mavx" GROMACS_C_FLAGS)
 767     if (NOT GNU_AVX_CFLAG)
 768         GMX_TEST_CFLAG(MSVC_AVX_CFLAG "/arch:AVX" GROMACS_C_FLAGS)
 769     endif (NOT GNU_AVX_CFLAG)
 770     if (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 771         message(WARNING "No C AVX flag found. Consider a newer compiler, or disable AVX for much lower performance.")
 772     endif (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 773
 774     if (CMAKE_CXX_COMPILER_LOADED)
 775         GMX_TEST_CXXFLAG(GNU_AVX_CXXFLAG "-mavx" GROMACS_CXX_FLAGS)
 776         if (NOT GNU_AVX_CXXFLAG)
 777             GMX_TEST_CXXFLAG(MSVC_AVX_CXXFLAG "/arch:AVX" GROMACS_CXX_FLAGS)
 778         endif (NOT GNU_AVX_CXXFLAG)
 779         if (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 780             message(WARNING "No C++ AVX flag found. Consider a newer compiler, or disable AVX for much lower performance.")
 781         endif (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 782     endif()
 783
 784     # Set the FMA4 flags (MSVC doesn't require any)
 785     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA" AND NOT MSVC)
 786         GMX_TEST_CFLAG(GNU_FMA_CFLAG "-mfma4" GROMACS_C_FLAGS)
 787         if (NOT GNU_FMA_CFLAG)
 788             message(WARNING "No C FMA4 flag found. Consider a newer compiler, or disable AVX_128_FMA for much lower performance.")
 789         endif(NOT GNU_FMA_CFLAG)
 790         if (CMAKE_CXX_COMPILER_LOADED)
 791             GMX_TEST_CXXFLAG(GNU_FMA_CXXFLAG "-mfma4" GROMACS_CXX_FLAGS)
 792             if (NOT GNU_FMA_CXXFLAG)
 793                 message(WARNING "No C++ FMA flag found. Consider a newer compiler, or disable AVX_128_FMA for much lower performance.")
 794             endif (NOT GNU_FMA_CXXFLAG)
 795         endif()
 796     endif()
 797
 798     # Only test the header after we have tried to add the flag for AVX support
 799     check_include_file(immintrin.h  HAVE_IMMINTRIN_H ${GROMACS_C_FLAGS})
 800
 801     if(NOT HAVE_IMMINTRIN_H)
 802         message(FATAL_ERROR "Cannot find immintrin.h, which is required for AVX intrinsics support. Consider switching compiler.")
 803     endif(NOT HAVE_IMMINTRIN_H)
 804
 805     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_256")
 806         try_compile(TEST_AVX ${CMAKE_BINARY_DIR}
 807             "${CMAKE_SOURCE_DIR}/cmake/TestAVX.c"
 808             COMPILE_DEFINITIONS "${GROMACS_C_FLAGS}")
 809         if(NOT TEST_AVX)
 810             message(FATAL_ERROR "Cannot compile AVX intrinsics. Consider switching compiler.")
 811         endif()
 812     endif()
 813
 814     # GCC requires x86intrin.h for FMA support. MSVC 2010 requires intrin.h for FMA support.
 815     check_include_file(x86intrin.h HAVE_X86INTRIN_H ${GROMACS_C_FLAGS})
 816     check_include_file(intrin.h HAVE_INTRIN_H ${GROMACS_C_FLAGS})
 817
 818     # The user should not be able to set this orthogonally to the acceleration
 819     set(GMX_X86_SSE4_1 1)
 820     set(GMX_X86_SSE2   1)
 821
 822     # But just enable one of the choices internally...
 823     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA")
 824         set(GMX_CPU_ACCELERATION_X86_AVX_128_FMA 1)
 825         set(GMX_X86_AVX_128_FMA 1)
 826         if (NOT ACCELERATION_QUIETLY)
 827           message(STATUS "Enabling 128-bit AVX Gromacs acceleration (with fused-multiply add), and it will help compiler optimization.")
 828         endif()
 829     else()
 830         # If we are not doing AVX_128, it must be AVX_256...
 831         set(GMX_CPU_ACCELERATION_X86_AVX_256 1)
 832         set(GMX_X86_AVX_256 1)
 833         if (NOT ACCELERATION_QUIETLY)
 834           message(STATUS "Enabling 256-bit AVX Gromacs acceleration, and it will help compiler optimization.")
 835         endif()
 836     endif()
 837
 838 elseif(${GMX_CPU_ACCELERATION} STREQUAL "FORTRAN")
 839
 840 #    Fortran is temporarily disabled while we push in nbNxN kernels.
 841 #    We need to fake it a bit here to avoid jenkins build errors!
 842 #    add_definitions(-DGMX_FORTRAN)
 843
 844 elseif(${GMX_CPU_ACCELERATION} STREQUAL "BLUEGENE")
 845 # GMX_CPU_ACCELERATION=BlueGene should be set in the Toolchain-BlueGene?-???.cmake file
 846     if (NOT ACCELERATION_QUIETLY)
 847       message(STATUS "Configuring for BlueGene")
 848     endif()
 849     set(GMX_BLUEGENE 1)
 850     if (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 851         set(SHARED_LIBS_DEFAULT OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 852         set(BUILD_SHARED_LIBS OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 853     endif (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 854     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on BlueGene" FORCE)
 855     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on BlueGene" FORCE)
 856     set(GMX_X11 OFF CACHE BOOL "X11 not compatible with BlueGene, disabled!" FORCE)
 857     set(GMX_THREAD_MPI OFF CACHE BOOL "Thread-MPI not compatible with BlueGene, disabled!" FORCE)
 858     set(GMX_MPI ON CACHE BOOL "Use MPI on BlueGene" FORCE)
 859 # Access to /etc/passwd is not available on the back end of BlueGene,
 860 # despite being detected by CMake. This can cause linker warnings
 861 # about harmless things in src/gmxlib/string2.h.
 862     set(HAVE_PWD_H OFF)
 863 # The automatic testing for endianness does not work for the BlueGene cross-compiler
 864     set(GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER 1 CACHE INTERNAL "BlueGene has big endian FP byte order (by default)" FORCE)
 865     set(GMX_IEEE754_BIG_ENDIAN_WORD_ORDER 1 CACHE INTERNAL "BlueGene has big endian FP word order (by default)" FORCE)
 866 elseif(${GMX_CPU_ACCELERATION} STREQUAL "POWER6")
 867     set(GMX_POWER6 1)
 868     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on Power6" FORCE)
 869     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on Power6" FORCE)
 870 else(${GMX_CPU_ACCELERATION} STREQUAL "NONE")
 871     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_CPU_ACCELERATION}. Pick one of None, SSE2, SSE4.1, AVX_128_FMA, AVX_256, Fortran, BlueGene, Power6")
 872 endif(${GMX_CPU_ACCELERATION} STREQUAL "NONE")
 873 set(ACCELERATION_QUIETLY TRUE CACHE INTERNAL "")
 874
 875 if(GMX_FORTRAN OR GMX_POWER6)
 876     if (GMX_THREAD_MPI)
 877         message(FATAL_ERROR "FORTRAN/POWER6 is incompatible with thread-MPI and only provides a speed-up on certain IBM compilers. Disable FORTRAN (or threads if you really want to use FORTRAN kernels).")
 878     endif(GMX_THREAD_MPI)
 879     enable_language(Fortran)
 880     include(FortranCInterface)
 881     discover_fortran_mangling(prefix isupper suffix extra_under_score found)
 882     if(extra_under_score)
 883         set(extrasuffix "_")
 884     endif(extra_under_score)
 885     if(prefix)
 886       set(prefix "${prefix} ##")
 887     endif(prefix)
 888     if(suffix)
 889       set(suffix "## ${suffix}")
 890       if(extrasuffix)
 891         set(extrasuffix "${suffix}${extrasuffix}")
 892       endif(extrasuffix)
 893     else(suffix)
 894       if(extrasuffix)
 895         # Don't know if this is needed, but it can't hurt
 896         set(extrasuffix "## ${extrasuffix}")
 897       endif(extrasuffix)
 898     endif(suffix)
 899
 900     if(isupper)
 901         set(F77_FUNCDEF   "${prefix} NAME ${suffix}")
 902         set(F77_FUNCDEF_  "${prefix} NAME ${extrasuffix}")
 903     else(isupper)
 904         set(F77_FUNCDEF   "${prefix} name ${suffix}")
 905         set(F77_FUNCDEF_  "${prefix} name ${extrasuffix}")
 906     endif(isupper)
 907 else(GMX_FORTRAN OR GMX_POWER6)
 908         set(F77_FUNCDEF   "name ## _")
 909         set(F77_FUNCDEF_  "name ## _")
 910 endif(GMX_FORTRAN OR GMX_POWER6)
 911
 912 # Process QM/MM Settings
 913 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 914 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 915     set(GMX_QMMM_GAUSSIAN 1)
 916 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 917     set(GMX_QMMM_MOPAC 1)
 918 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 919     set(GMX_QMMM_GAMESS 1)
 920 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 921     set(GMX_QMMM_ORCA 1)
 922 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 923     # nothing to do
 924 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 925     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 926 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 927
 928 # Process FFT library settings - if not OpenMM build
 929 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 930 set(PKG_FFT "")
 931 set(PKG_FFT_LIBS "")
 932 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 933     if(GMX_DOUBLE)
 934         set(FFTW fftw)
 935     else(GMX_DOUBLE)
 936         set(FFTW fftwf)
 937     endif(GMX_DOUBLE)
 938     find_package(FFTW COMPONENTS ${FFTW})
 939     string(TOUPPER "${FFTW}" FFTW)
 940     set(PKG_FFT "${${FFTW}_PKG}")
 941     include_directories(${${FFTW}_INCLUDE_DIRS})
 942     set(FFT_LIBRARIES ${${FFTW}_LIBRARIES})
 943     if(NOT ${FFTW}_FOUND)
 944       MESSAGE(FATAL_ERROR "Cannot find FFTW3 (with correct precision - libfftw3f for single precision GROMACS or libfftw3 for double precision GROMACS). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 945     endif(NOT ${FFTW}_FOUND)
 946
 947     set(GMX_FFT_FFTW3 1)
 948
 949     if (NOT ${GMX_CPU_ACCELERATION} STREQUAL "NONE" AND NOT ${FFTW}_HAVE_SIMD)
 950       message(WARNING "The fftw library found is compiled without SIMD support, which makes it slow. Consider recompiling it or contact your admin")
 951     endif (NOT ${GMX_CPU_ACCELERATION} STREQUAL "NONE" AND NOT ${FFTW}_HAVE_SIMD)
 952
 953 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 954 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 955     find_package(MKL REQUIRED)
 956     include_directories(${MKL_INCLUDE_DIR})
 957     set(FFT_LIBRARIES ${MKL_LIBRARIES})
 958     set(PKG_FFT_LIBS ${MKL_LIBRARIES})
 959
 960     set(GMX_FFT_MKL 1)
 961     set(HAVE_MKL 1)
 962
 963 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 964 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 965 #    set(GMX_FFT_ACML 1)
 966 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 967     MESSAGE(STATUS "Using internal FFT library - fftpack")
 968     set(GMX_FFT_FFTPACK 1)
 969 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 970     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, mkl, fftpack")
 971 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 972
 973 # enable threaded fftw3 if we've found it
 974 if(FFTW3_THREADS OR FFTW3F_THREADS)
 975     add_definitions(-DFFT5D_FFTW_THREADS)
 976 endif()
 977
 978 set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 979 set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 980 # MKL has BLAS/LAPACK routines
 981 if(NOT HAVE_MKL AND NOT ACCELERATE_FRAMEWORK)
 982   if(GMX_EXTERNAL_BLAS)
 983     if (GMX_BLAS_USER)
 984         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_BLAS_USER})
 985     else(GMX_BLAS_USER)
 986         set(BLAS_FIND_QUIETLY ON)
 987         find_package(BLAS)
 988         if (BLAS_FOUND)
 989           list(APPEND GMX_EXTRA_LIBRARIES ${BLAS_LIBRARIES})
 990         else()
 991           MESSAGE(STATUS "Using internal BLAS library")
 992           set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external BLAS instead of built-in" FORCE)
 993         endif()
 994     endif(GMX_BLAS_USER)
 995   endif(GMX_EXTERNAL_BLAS)
 996   if(GMX_EXTERNAL_LAPACK)
 997     if (GMX_LAPACK_USER)
 998         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_LAPACK_USER})
 999     else(GMX_LAPACK_USER)
1000         set(LAPACK_FIND_QUIETLY ON)
1001         find_package(LAPACK)
1002         if (LAPACK_FOUND)
1003           list(APPEND GMX_EXTRA_LIBRARIES ${LAPACK_LIBRARIES})
1004         else()
1005           MESSAGE(STATUS "Using internal LAPACK library")
1006           set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in" FORCE)
1007         endif()
1008     endif(GMX_LAPACK_USER)
1009   endif(GMX_EXTERNAL_LAPACK)
1010 endif()
1011 mark_as_advanced(GMX_EXTERNAL_LAPACK)
1012 mark_as_advanced(GMX_EXTERNAL_BLAS)
1013
1014 set(GMX_USE_PLUGINS OFF CACHE INTERNAL "Whether GROMACS will really try to compile support for VMD plugins")
1015
1016 if(GMX_LOAD_PLUGINS)
1017   if(CYGWIN OR NOT WIN32)
1018     # Native Windows does not have, nor need dlopen
1019     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
1020     include(gmxTestdlopen)
1021     gmx_test_dlopen(HAVE_DLOPEN)
1022   endif()
1023
1024   # so, should we use plug-ins?
1025   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
1026     if(NOT VMD_QUIETLY)
1027       MESSAGE(STATUS
1028           "Found the ability to use plug-ins when building shared libaries, "
1029           "so will compile to use plug-ins (e.g. to read VMD-supported file "
1030           "formats).")
1031     endif()
1032     if(NOT GMX_VMD_PLUGIN_PATH)
1033       find_package(VMD)
1034     endif()
1035     set(GMX_USE_PLUGINS ON)
1036     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
1037     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
1038   else()
1039     set(PKG_DL_LIBS)
1040   endif()
1041 endif(GMX_LOAD_PLUGINS)
1042 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
1043
1044 if(EXISTS "${CMAKE_SOURCE_DIR}/admin/.isreposource")
1045     if(NOT CMAKE_CROSSCOMPILING)
1046         option(GMX_BUILD_MANPAGES "Build man pages" ON)
1047     else()
1048         message(STATUS "Building the man pages is not available when "
1049             "cross-compiling the developer version from git")
1050     endif()
1051 else()
1052     #make sure source package contains all man pages
1053     if(NOT EXISTS "${CMAKE_SOURCE_DIR}/man/man1/ngmx.1")
1054         message(FATAL_ERROR "Man pages are missing from source package.")
1055     endif()
1056 endif()
1057 mark_as_advanced(GMX_BUILD_MANPAGES)
1058
1059 # Math and thread libraries must often come after all others when linking...
1060 if(HAVE_LIBM)
1061     list(APPEND GMX_EXTRA_LIBRARIES m)
1062 endif(HAVE_LIBM)
1063
1064 if(GMX_FAHCORE)
1065   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
1066       "Path to swindirect.h")
1067   include_directories(${COREWRAP_INCLUDE_DIR})
1068 endif(GMX_FAHCORE)
1069
1070 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
1071 # these are set after everything else
1072 if (NOT DEFINED GROMACS_C_FLAGS_SET)
1073     set(GROMACS_C_FLAGS_SET true CACHE INTERNAL "Whether to reset the C flags"
1074         FORCE)
1075     set(CMAKE_C_FLAGS "${GROMACS_C_FLAGS} ${CMAKE_C_FLAGS}" CACHE STRING
1076         "Flags used by the compiler during all build types" FORCE)
1077     if (CMAKE_CXX_COMPILER_LOADED)
1078         set(CMAKE_CXX_FLAGS "${GROMACS_CXX_FLAGS} ${CMAKE_CXX_FLAGS}" CACHE STRING
1079             "Flags used by the compiler during all build types" FORCE)
1080     endif()
1081     set(CMAKE_EXE_LINKER_FLAGS
1082         "${GROMACS_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}"
1083         CACHE STRING "Linker flags for creating executables" FORCE)
1084     set(CMAKE_SHARED_LINKER_FLAGS
1085         "${GROMACS_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}"
1086         CACHE STRING "Linker flags for creating shared libraries" FORCE)
1087 endif (NOT DEFINED GROMACS_C_FLAGS_SET)
1088
1089 if(NOT GMX_OPENMP)
1090     #Unset all OpenMP flags in case OpenMP was disabled either by the user
1091     #or because it was only partially detected (e.g. only for C but not C++ compiler)
1092     unset(OpenMP_C_FLAGS CACHE)
1093     unset(OpenMP_CXX_FLAGS CACHE)
1094     unset(OpenMP_LINKER_FLAGS CACHE)
1095     unset(OpenMP_SHARED_LINKER_FLAGS)
1096 endif()
1097 ######################################
1098 # Output compiler and CFLAGS used
1099 ######################################
1100 execute_process(COMMAND ${CMAKE_C_COMPILER} --version RESULT_VARIABLE TMP_RESULT OUTPUT_VARIABLE CC_VERSION ERROR_VARIABLE CC_VERSION)
1101 #try executing just the compiler command if that failed...
1102 if(TMP_RESULT)
1103     execute_process(COMMAND ${CMAKE_C_COMPILER} RESULT_VARIABLE TMP_RESULT OUTPUT_VARIABLE CC_VERSION ERROR_VARIABLE CC_VERSION)
1104 endif()
1105 string(LENGTH "${CC_VERSION}" len)
1106 if(len)
1107     string(REGEX MATCH "[^\n]+" CC_VERSION "${CC_VERSION}")
1108 endif()
1109
1110 set(BUILD_COMPILER "@CMAKE_C_COMPILER@ @CMAKE_C_COMPILER_ID@ @CC_VERSION@")
1111 set(BUILD_CFLAGS "@CMAKE_C_FLAGS@")
1112 if(CMAKE_BUILD_TYPE STREQUAL "Debug")
1113     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_DEBUG@")
1114 elseif(CMAKE_BUILD_TYPE STREQUAL "Release")
1115     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_RELEASE@")
1116 elseif(CMAKE_BUILD_TYPE STREQUAL "MinSizeRel")
1117     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_MINSIZEREL@")
1118 elseif(CMAKE_BUILD_TYPE STREQUAL "RelWithDebInfo")
1119     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_RELWITHDEBINFO@")
1120 endif()
1121
1122
1123 ########################################################################
1124 # Specify install locations and which subdirectories to process        #
1125 ########################################################################
1126 if (GMX_USE_RELATIVE_INSTALL_PATH)
1127     set(GMX_INSTALL_PREFIX "" CACHE STRING "Prefix gets appended to CMAKE_INSTALL_PREFIX. For cpack it sets the root folder of the archive.")
1128     mark_as_advanced(GMX_INSTALL_PREFIX)
1129 else()
1130     set(GMX_INSTALL_PREFIX "${CMAKE_INSTALL_PREFIX}/")
1131 endif()
1132
1133 if ( NOT DEFINED GMXLIB )
1134     set(GMXLIB lib)
1135 endif()
1136 set(LIB_INSTALL_DIR "${GMX_INSTALL_PREFIX}${GMXLIB}")
1137 set(BIN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}bin)
1138 set(DATA_INSTALL_DIR ${GMX_INSTALL_PREFIX}share/gromacs)
1139 set(MAN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}share/man)
1140 set(INCL_INSTALL_DIR ${GMX_INSTALL_PREFIX}include)
1141
1142 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
1143
1144 ##################################################################
1145 # Shared library settings - Darwin uses INSTALL_NAME_DIR instead!
1146 ##################################################################
1147 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
1148     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
1149     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
1150     set(CMAKE_INSTALL_RPATH "\\\$ORIGIN/../${GMXLIB}")
1151     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
1152 endif()
1153
1154 #COPYING file: Only necessary for binary distributions.
1155 #Simpler to always install.
1156 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
1157
1158 add_subdirectory(share)
1159 add_subdirectory(include)
1160 add_subdirectory(src)
1161 add_subdirectory(scripts)
1162
1163 #######################
1164 ## uninstall target
1165 #######################
1166     CONFIGURE_FILE(
1167                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
1168                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
1169                    IMMEDIATE @ONLY)
1170 ###########################
1171 ADD_CUSTOM_TARGET(uninstall
1172                   "${CMAKE_COMMAND}" -P
1173                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
1174 ###########################
1175
1176
1177 ########################################################################
1178 # Tests                                                                #
1179 ########################################################################
1180
1181 include(CTest)
1182 mark_as_advanced(BUILD_TESTING)
1183 IF(BUILD_TESTING)
1184         enable_testing()
1185         add_subdirectory(tests)
1186 ENDIF()
1187