CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.6)
   2
   3 project(Gromacs)
   4 include(Dart)
   5 mark_as_advanced(DART_ROOT)
   6
   7 # PROJECT_VERSION should have the following structure:
   8 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
   9 #
  10 # The "-dev" suffix is important to keep because it makes possible to distinguish
  11 # between a build from official release and a build from git release branch on a
  12 # machine with no git.
  13 #
  14 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  15 set(PROJECT_VERSION "4.5.3-dev")
  16 set(CUSTOM_VERSION_STRING ""
  17     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  18 mark_as_advanced(CUSTOM_VERSION_STRING)
  19 if (CUSTOM_VERSION_STRING)
  20     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  21 endif (CUSTOM_VERSION_STRING)
  22 set(SOVERSION 6)
  23 # It is a bit irritating, but this has to be set separately for now!
  24 SET(CPACK_PACKAGE_VERSION_MAJOR "4")
  25 SET(CPACK_PACKAGE_VERSION_MINOR "5")
  26 SET(CPACK_PACKAGE_VERSION_PATCH "3")
  27
  28
  29 # Cmake modules/macros are in a subdirectory to keep this file cleaner
  30 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  31
  32 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  33 set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  34 endif()
  35
  36 if(NOT CMAKE_BUILD_TYPE)
  37     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
  38 endif(NOT CMAKE_BUILD_TYPE)
  39
  40 enable_language(C)
  41
  42 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
  43 set(CPACK_PACKAGE_VENDOR "gromacs.org")
  44 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
  45 set(CPACK_SET_DESTDIR "ON")
  46 set(CPACK_INCLUDE_TOPLEVEL_DIRECTORY 0)
  47 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
  48 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
  49 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/admin/InstallLicense.txt")
  50 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
  51
  52 #must come after all cpack settings!
  53 include(CPack)
  54
  55
  56 ########################################################################
  57 # Fix stupid flags on MSVC
  58 ########################################################################
  59 SET(SHARED_LIBS_DEFAULT ON)
  60 IF(CMAKE_GENERATOR MATCHES "Visual Studio")
  61     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
  62     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
  63     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
  64     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
  65     SET(SHARED_LIBS_DEFAULT OFF)
  66 ENDIF(CMAKE_GENERATOR MATCHES "Visual Studio")
  67
  68 set(GMX_EXTRA_LIBRARIES)
  69
  70
  71
  72 ######################################################################
  73 # compiler tests
  74 # these need ot be done early (before further tests).
  75 #####################################################################
  76
  77 include(CheckCCompilerFlag)
  78 include(CheckCXXCompilerFlag)
  79
  80 include(gmxCFlags)
  81 gmx_c_flags()
  82
  83 ########################################################################
  84 # User input options                                                   #
  85 ########################################################################
  86 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
  87 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
  88 option(GMX_THREADS    "Build a parallel (thread-based) version of GROMACS (cannot be combined with MPI yet)" ON)
  89 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
  90 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
  91 option(GMX_POWERPC_INVSQRT "Use PowerPC hardware 1/sqrt" OFF)
  92 mark_as_advanced(GMX_POWERPC_INVSQRT)
  93 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
  94 mark_as_advanced(GMX_FAHCORE)
  95 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library (rerun cmake after changing to see relevant options)" OFF)
  96 set(GMX_ACCELERATION "auto"
  97     CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran")
  98
  99 set(GMX_FFT_LIBRARY "fftw3"
 100     CACHE STRING "FFT library choices: fftw3,fftw2,mkl,fftpack[built-in]")
 101 option(GMX_DISABLE_FFTW_MEASURE
 102        "Do not optimize FFTW setups (not needed with SSE)" OFF)
 103 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 104 set(GMX_QMMM_PROGRAM "none"
 105     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
 106 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 107 mark_as_advanced(GMX_BROKEN_CALLOC)
 108 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI, Windows)" ${SHARED_LIBS_DEFAULT})
 109 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
 110 mark_as_advanced(GMX_MPI_IN_PLACE)
 111 option(GMX_DLOPEN "Compile with dlopen, needed to read VMD supported file formats" ON)
 112 mark_as_advanced(GMX_DLOPEN)
 113
 114
 115 option(GMX_IA32_ASM "Add SSE assembly files for IA32" OFF)
 116 mark_as_advanced(GMX_IA32_ASM)
 117 option(GMX_X86_64_ASM "Add SSE assembly files for X86_64" OFF)
 118 mark_as_advanced(GMX_X86_64_ASM)
 119
 120 option(USE_VERSION_H "Generate development version string/information" ON)
 121 mark_as_advanced(USE_VERSION_H)
 122
 123 option(GMX_DEFAULT_SUFFIX "Use default suffixes for GROMACS binaries and libs (_d for double, _mpi for MPI; rerun cmake after changing to see relevant options)" ON)
 124
 125 if(UNIX AND NOT APPLE)
 126     option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer \".a\" static archives (NOTE: this is enabled only for UNIX (excluding APPLE) platforms but it might not always work!" OFF)
 127     mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 128 endif()
 129
 130 ########################################################################
 131 # Set up binary and library suffixing
 132 ########################################################################
 133 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 134 set(GMX_LIBS_SUFFIX ""
 135   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 136 if (GMX_DEFAULT_SUFFIX)
 137   set(GMX_BINARY_SUFFIX "")
 138   set(GMX_LIBS_SUFFIX "")
 139   if (GMX_MPI)
 140     set(GMX_BINARY_SUFFIX "_mpi")
 141     set(GMX_LIBS_SUFFIX "_mpi")
 142   endif(GMX_MPI)
 143   if (GMX_DOUBLE)
 144     set (GMX_BINARY_SUFFIX "${GMX_BINARY_SUFFIX}_d")
 145     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
 146   endif(GMX_DOUBLE)
 147   if (GMX_OPENMM)
 148     set (GMX_BINARY_SUFFIX "-gpu")
 149     set (GMX_LIBS_SUFFIX "_gpu")
 150   endif(GMX_OPENMM)
 151   mark_as_advanced(FORCE GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 152   message(STATUS "Using default binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 153   message(STATUS "Using default library suffix: \"${GMX_LIBS_SUFFIX}\"")
 154 else(GMX_DEFAULT_SUFFIX)
 155   mark_as_advanced(CLEAR GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 156   message(STATUS "Using manually set binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 157   message(STATUS "Using manually set library suffix: \"${GMX_LIBS_SUFFIX}\"")
 158 endif(GMX_DEFAULT_SUFFIX)
 159
 160 set(PKG_CFLAGS "")
 161 if(GMX_DOUBLE)
 162     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 163 endif(GMX_DOUBLE)
 164 if(GMX_SOFTWARE_INVSQRT)
 165   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 166 endif(GMX_SOFTWARE_INVSQRT)
 167 if(GMX_POWERPC_INVSQRT)
 168   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_POWERPC_INVSQRT")
 169 endif(GMX_POWERPC_INVSQRT)
 170
 171 ########################################################################
 172 #Process MPI settings
 173 ########################################################################
 174 include(CheckCSourceCompiles) # for gmxTestMPI_IN_PLACE
 175 if(GMX_MPI)
 176         MESSAGE(WARNING "
 177             There are known problems with some MPI implementations:
 178                      OpenMPI version < 1.4.1
 179                      MVAPICH2 version <= 1.4.1                               *")
 180     if(GMX_THREADS)
 181         #message(FATAL_ERROR "Thread-based parallelization conflicts with MPI.")
 182         set(GMX_THREADS OFF CACHE BOOL
 183             "Thread-based parallelization conflicts with MPI." FORCE)
 184     endif(GMX_THREADS)
 185     find_package(MPI)
 186     if(MPI_FOUND)
 187         set(GROMACS_C_FLAGS ${GROMACS_FLAGS} ${MPI_COMPILE_FLAGS})
 188         set(GROMACS_LINKER_FLAGS ${GROMACS_LINKER_FLAGS} ${MPI_LINK_FLAGS})
 189
 190         include_directories(${MPI_INCLUDE_PATH})
 191         list(APPEND GMX_EXTRA_LIBRARIES ${MPI_LIBRARIES})
 192         add_definitions( -DMPI ) #for FAHCORE
 193         include(gmxTestMPI_IN_PLACE)
 194         if (GMX_MPI_IN_PLACE)
 195             gmx_test_mpi_in_place(MPI_IN_PLACE_EXISTS)
 196         endif (GMX_MPI_IN_PLACE)
 197     else(MPI_FOUND)
 198         message(FATAL_ERROR "MPI support requested, but no MPI compiler found.")
 199     endif(MPI_FOUND)
 200     include(gmxTestCatamount)
 201     gmx_test_catamount(GMX_CRAY_XT3)
 202     if(GMX_CRAY_XT3)
 203         set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_CRAY_XT3")
 204         set(GMX_NO_SYSTEM 1)
 205         set(GMX_NO_NICE 1)
 206     endif(GMX_CRAY_XT3)
 207     set(GMX_LIB_MPI 1)
 208     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_LIB_MPI")
 209 endif(GMX_MPI)
 210
 211
 212 #######################################################################
 213 # Check for options incompatible with OpenMM build                    #
 214 #######################################################################
 215 if(GMX_OPENMM)
 216     cmake_minimum_required(VERSION 2.6.4)
 217     # we'll use the built-in fft to avoid unnecessary dependencies
 218     string(TOUPPER ${GMX_FFT_LIBRARY} GMX_FFT_LIBRARY)
 219     if(NOT ${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 220         message(STATUS "No external FFT libraries needed for the OpenMM build, switching to fftpack!")
 221         set(GMX_FFT_LIBRARY "fftpack" CACHE STRING
 222                 "No external FFT libraries needed for the OpenMM build, switching to  fftpack!" FORCE)
 223     endif()
 224     if(GMX_MPI)
 225         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
 226     endif(GMX_MPI)
 227     if(GMX_THREADS)
 228         message(STATUS "Threads are  not compatible with OpenMM build, disabled!")
 229         set(GMX_THREADS OFF CACHE BOOL
 230                 "Threads are not compatible with OpenMM build, disabled!" FORCE)
 231     endif(GMX_THREADS)
 232     if(GMX_SOFTWARE_INVSQRT)
 233         set(GMX_SOFTWARE_INVSQRT OFF CACHE STRING
 234                 "The OpenMM build does not need GROMACS software 1/sqrt!" FORCE)
 235     endif(GMX_SOFTWARE_INVSQRT)
 236     string(TOUPPER ${GMX_ACCELERATION} GMX_ACCELERATION)
 237     if(NOT GMX_ACCELERATION STREQUAL "NONE")
 238         message(STATUS "Switching off CPU-based acceleration, the OpenMM build does not support/need any!")
 239         set(GMX_ACCELERATION "none" CACHE STRING
 240                 "Switching off CPU-based acceleration, the OpenMM build does not support/need any!" FORCE)
 241     endif()
 242     if(GMX_FAHCORE)
 243         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
 244     endif(GMX_FAHCORE)
 245     if(GMX_DOUBLE)
 246         message(FATAL_ERROR  "The OpenMM-build does not support double precision calculations!")
 247     endif()
 248     # mark as advanced the unused variables
 249     mark_as_advanced(FORCE GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 250         GMX_QMMM_PROGRAM GMX_THREADS GMX_DOUBLE)
 251 else(GMX_OPENMM)
 252      mark_as_advanced(CLEAR GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 253         GMX_QMMM_PROGRAM GMX_THREADS GMX_DOUBLE)
 254 endif(GMX_OPENMM)
 255
 256
 257 ########################################################################
 258 # Basic system tests (standard libraries, headers, functions, types)   #
 259 ########################################################################
 260 include(CheckIncludeFiles)
 261 check_include_files(string.h     HAVE_STRING_H)
 262 check_include_files(math.h       HAVE_MATH_H)
 263 check_include_files(limits.h     HAVE_LIMITS_H)
 264 check_include_files(memory.h     HAVE_MEMORY_H)
 265 check_include_files(unistd.h     HAVE_UNISTD_H)
 266 check_include_files(pwd.h        HAVE_PWD_H)
 267 check_include_files(stdint.h     HAVE_STDINT_H)
 268 check_include_files(stdlib.h     HAVE_STDLIB_H)
 269 check_include_files(pthread.h    HAVE_PTHREAD_H)
 270 check_include_files(dirent.h     HAVE_DIRENT_H)
 271 check_include_files(inttypes.h   HAVE_INTTYPES_H)
 272 check_include_files(regex.h      HAVE_REGEX_H)
 273 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 274 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
 275 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 276 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
 277 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
 278 # SSE support
 279 check_include_files(xmmintrin.h  HAVE_XMMINTRIN_H)
 280 check_include_files(emmintrin.h  HAVE_EMMINTRIN_H)
 281 check_include_files(pmmintrin.h  HAVE_PMMINTRIN_H)
 282 check_include_files(smmintrin.h  HAVE_SMMINTRIN_H)
 283 check_include_files(io.h                 HAVE_IO_H)
 284
 285
 286 include(CheckFunctionExists)
 287 check_function_exists(strcasecmp        HAVE_STRCASECMP)
 288 check_function_exists(strdup            HAVE_STRDUP)
 289 check_function_exists(vprintf           HAVE_VPRINTF)
 290 check_function_exists(memcmp            HAVE_MEMCMP)
 291 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 292 check_function_exists(memalign          HAVE_MEMALIGN)
 293 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 294 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 295 check_function_exists(isnan             HAVE_ISNAN)
 296 check_function_exists(_isnan            HAVE__ISNAN)
 297 check_function_exists(isfinite          HAVE_ISFINITE)
 298 check_function_exists(_isfinite         HAVE__ISFINITE)
 299 check_function_exists(fsync             HAVE_FSYNC)
 300 check_function_exists(_fileno           HAVE__FILENO)
 301 check_function_exists(fileno            HAVE_FILENO)
 302 check_function_exists(_commit           HAVE__COMMIT)
 303
 304 include(CheckLibraryExists)
 305 check_library_exists(m sqrt "" HAVE_LIBM)
 306 check_library_exists(m cbrt "" HAVE_CBRT)
 307
 308
 309 include(CheckTypeSize)
 310
 311 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 312 check_type_size("int"           SIZEOF_INT)
 313 check_type_size("long int"      SIZEOF_LONG_INT)
 314 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 315 check_type_size("off_t"         SIZEOF_OFF_T)
 316 check_type_size("void *"        SIZEOF_VOIDP)
 317
 318 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 319     set(GMX_64_BIT TRUE)
 320 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 321     set(GMX_64_BIT FALSE)
 322 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 323
 324 # Check for some basic types that we *need*, so set these to int if they are not present
 325 check_type_size(uid_t uid_t)
 326 if(NOT uid_t)
 327   set(uid_t int)
 328 else(NOT uid_t)
 329   set(uid_t 0)
 330 endif(NOT uid_t)
 331
 332 check_type_size(gid_t gid_t)
 333 if(NOT gid_t)
 334   set(gid_t 1)
 335 else(NOT gid_t)
 336   set(gid_t 0)
 337 endif(NOT gid_t)
 338
 339 check_type_size(size_t size_t)
 340 if(NOT size_t)
 341   set(size_t int)
 342 else(NOT size_t)
 343   set(size_t 0)
 344 endif(NOT size_t)
 345
 346 check_type_size(off_t off_t)
 347 if(NOT off_t)
 348   set(off_t int)
 349 else(NOT off_t)
 350   set(off_t 0)
 351 endif(NOT off_t)
 352
 353 include(TestBigEndian)
 354 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 355
 356
 357
 358
 359 ########################################################################
 360 # Find external packages                                               #
 361 ########################################################################
 362 if(UNIX AND NOT APPLE)
 363     if(GMX_PREFER_STATIC_LIBS)
 364         SET(CMAKE_FIND_LIBRARY_SUFFIXES .a ${CMAKE_FIND_LIBRARY_SUFFIXES})
 365         if(BUILD_SHARED_LIBS)
 366             message(WARNING "Static libraries requested, the GROMACS libraries will also be build static (BUILD_SHARED_LIBS=OFF)")
 367             set(BUILD_SHARED_LIBS OFF CACHE BOOL "Enable shared libraries (can be problematic with MPI, Windows)" FORCE)
 368         endif()
 369     endif()
 370 endif()
 371
 372 option(GMX_XML "Use libxml2 to parse xml files" ON)
 373 if (GMX_XML)
 374   find_package(LibXml2)
 375   set(PKG_XML "")
 376   if(LIBXML2_FOUND)
 377     include_directories(${LIBXML2_INCLUDE_DIR})
 378     set(PKG_XML libxml-2.0)
 379     set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 380     set(HAVE_LIBXML2 1)
 381   endif(LIBXML2_FOUND)
 382 endif(GMX_XML)
 383
 384 option(GMX_GSL "Add support for gsl" OFF)
 385 if (GMX_GSL)
 386   find_package(gsl)
 387   set(PKG_GSL "")
 388   if(GSL_FOUND)
 389     include_directories(${GSL_INCLUDE_DIR})
 390     set(PKG_GSL gsl)
 391     set(HAVE_LIBGSL 1)
 392   endif(GSL_FOUND)
 393 endif (GMX_GSL)
 394
 395 option(GMX_X11 "Use X window system" OFF)
 396 if (GMX_X11)
 397         find_package(X11)
 398         # X11 includes/libraries are only set in the ngmx subdirectory!
 399         if(X11_FOUND)
 400         set(HAVE_X11 1)
 401         endif(X11_FOUND)
 402 endif(GMX_X11)
 403
 404 if(GMX_THREADS)
 405     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREADS")
 406     include(ThreadMPI)
 407     set(THREAD_MPI_LIB thread_mpi)
 408     set(GMX_MPI 1)
 409     string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 410     if(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 411         message(FATAL_ERROR "FFTW2 can't be used with threads. Try fftw3 or mkl.")
 412     endif()
 413 endif(GMX_THREADS)
 414
 415 if(GMX_OPENMM)
 416     set(CUDA_BUILD_EMULATION OFF)
 417     find_package(CUDA 3.1 REQUIRED)
 418     add_definitions(-DGMX_OPENMM)
 419     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 420         set(CUDA_VERBOSE_BUILD ON)
 421     endif()
 422     find_package(OpenMM)
 423 endif(GMX_OPENMM)
 424
 425 if(APPLE)
 426    find_library(ACCELERATE_FRAMEWORK Accelerate)
 427    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 428 endif(APPLE)
 429
 430 # only bother with finding git and using version.h if the source is a git repo
 431 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 432     if(USE_VERSION_H)
 433         # We need at least git v1.5.1 be able to parse git's date output. If not
 434         # fund or the version is too small, we can't generate version information.
 435         find_package(Git 1.5.1)
 436         # this should at some point become VERSION_LESS
 437         if(NOT Git_FOUND OR Git_VERSION STRLESS "1.5.1")
 438             message("No compatible git version found, won't be able to generate proper development version information.")
 439             set(USE_VERSION_H OFF)
 440         endif()
 441     endif()
 442 else()
 443     set(USE_VERSION_H OFF)
 444 endif()
 445
 446 if (GMX_DLOPEN)
 447     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS})
 448 endif (GMX_DLOPEN)
 449
 450 ########################################################################
 451 # Generate development version info for cache
 452 ########################################################################
 453 # set(GEN_VERSION_INFO_INTERNAL "ON")
 454 # include(gmxGenerateVersionString)
 455
 456 ########################################################################
 457 # Our own GROMACS tests
 458 ########################################################################
 459
 460 add_definitions( -DHAVE_CONFIG_H )
 461 include_directories(${CMAKE_BINARY_DIR}/src)
 462 include_directories(${CMAKE_SOURCE_DIR}/include)
 463
 464 include(gmxCheckBuildUserTime)
 465 gmx_check_build_user_time(BUILD_TIME BUILD_USER BUILD_MACHINE)
 466
 467 include(gmxTestFloatFormat)
 468 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 469                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 470                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 471
 472 include(gmxTestLargeFiles)
 473 gmx_test_large_files(GMX_LARGEFILES)
 474 check_function_exists(fseeko     HAVE_FSEEKO)
 475
 476 include(gmxTestSignal)
 477 gmx_test_retsigtype(RETSIGTYPE)
 478 gmx_test_sigusr1(HAVE_SIGUSR1)
 479
 480 include(gmxTestInline)
 481 gmx_test_inline(INLINE_KEYWORD)
 482
 483 include(gmxTestRestrict)
 484 gmx_test_inline(RESTRICT_KEYWORD)
 485
 486 include(gmxTestPipes)
 487 gmx_test_pipes(HAVE_PIPES)
 488
 489 include(gmxTestInlineASM)
 490 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 491 gmx_test_inline_asm_msvc_x86(GMX_X86_MSVC_INLINE_ASM)
 492
 493 # turn on SSE if supported with reasonable defaults.
 494 if (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 495   if(CMAKE_SYSTEM_PROCESSOR MATCHES "^(i.86|x86|x64|x86_64|AMD64|amd64)")
 496
 497     set(GMX_ACCELERATION "SSE" CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran" FORCE)
 498
 499     if (GMX_64_BIT)
 500       set(GMX_X86_64_ASM ON CACHE BOOL "Add SSE assembly files for x86_64" FORCE)
 501     else (GMX_64_BIT)
 502       set(GMX_IA32_ASM ON CACHE BOOL "Add SSE assembly files for i386" FORCE)
 503     endif (GMX_64_BIT)
 504
 505     # Determine the assembler/compiler to use
 506   else()
 507     set(GMX_ACCELERATION "none" CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran" FORCE)
 508   endif()
 509 endif (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 510
 511 include(gmxTestXDR)
 512 gmx_test_xdr(GMX_SYSTEM_XDR)
 513 if(NOT GMX_SYSTEM_XDR)
 514     set(GMX_INTERNAL_XDR 1)
 515     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 516 endif(NOT GMX_SYSTEM_XDR)
 517
 518 # Process nonbonded accelerated kernels settings
 519 string(TOUPPER ${GMX_ACCELERATION} ${GMX_ACCELERATION})
 520 if(${GMX_ACCELERATION} STREQUAL "NONE")
 521   # nothing to do
 522 elseif(${GMX_ACCELERATION} STREQUAL "SSE")
 523
 524     if(CMAKE_GENERATOR MATCHES "Visual Studio")
 525       option(GMX_ASM_USEASM-NASM "Use Nasm for assembly instead of compiler (necessary on windows)" ON)
 526     else()
 527       option(GMX_ASM_USEASM-NASM "Use Nasm for assembly instead of compiler (necessary on windows)" OFF)
 528     endif()
 529         mark_as_advanced(GMX_ASM_USEASM-NASM)
 530
 531     if (NOT GMX_64_BIT)
 532         # for 32-bit compiles, we might need to turn on sse
 533         CHECK_C_COMPILER_FLAG("-msse2" XFLAGS_SSE)
 534         if (XFLAGS_SSE)
 535             set(GROMACS_C_FLAGS "-msse2 ${GROMACS_C_FLAGS}")
 536         endif (XFLAGS_SSE)
 537         CHECK_CXX_COMPILER_FLAG("-msse2" XXFLAGS_SSE)
 538         if (XXFLAGS_SSE)
 539             set(GROMACS_CXX_FLAGS "-msse2 ${GROMACS_CXX_FLAGS}")
 540         endif (XXFLAGS_SSE)
 541     endif (NOT GMX_64_BIT)
 542
 543     if(GMX_IA32_ASM)
 544       if(GMX_DOUBLE)
 545         set(GMX_IA32_SSE2 1)
 546       else()
 547        set(GMX_IA32_SSE 1)
 548       endif()
 549     elseif(GMX_X86_64_ASM)
 550       if(GMX_DOUBLE)
 551        set(GMX_X86_64_SSE2 1)
 552       else()
 553         set(GMX_X86_64_SSE 1)
 554       endif()
 555     endif()
 556
 557 #    if(HAVE_PMMINTRIN_H)
 558 #        set(GMX_SSE3 1)
 559 #    endif(HAVE_PMMINTRIN_H)
 560 #    if(HAVE_SMMINTRIN_H)
 561 #        set(GMX_SSE4_1 1)
 562 #    endif(HAVE_SMMINTRIN_H)
 563
 564 elseif(${GMX_ACCELERATION} STREQUAL "FORTRAN")
 565     set(GMX_FORTRAN 1)
 566     #these are switch on by default sometimes
 567     set(GMX_IA32_ASM 0)
 568     set(GMX_GMX_X86_64_ASM 0)
 569 elseif(${GMX_ACCELERATION} STREQUAL "BLUEGENE")
 570 # GMX_ACCELERATION=BlueGene should be set in the Toolchain-BlueGene?-???.cmake file
 571     message(STATUS "Configuring for BlueGene")
 572     set(GMX_BLUEGENE 1)
 573     if (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 574         set(SHARED_LIBS_DEFAULT OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 575         set(BUILD_SHARED_LIBS OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 576     endif (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 577     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on BlueGene" FORCE)
 578     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on BlueGene" FORCE)
 579     set(GMX_X11 OFF CACHE BOOL "X11 not compatible with BlueGene, disabled!" FORCE)
 580     set(GMX_THREADS OFF CACHE BOOL "Threads not compatible with BlueGene, disabled!" FORCE)
 581     set(GMX_MPI ON CACHE BOOL "Use MPI on BlueGene" FORCE)
 582     set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use MASSV for BLAS on BlueGene" FORCE)
 583     set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use MASSV for LAPACK on BlueGene" FORCE)
 584     list(APPEND GMX_EXTRA_LIBRARIES massv)
 585 elseif(${GMX_ACCELERATION} STREQUAL "POWER6")
 586     set(GMX_POWER6 1)
 587     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on Power6" FORCE)
 588     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on Power6" FORCE)
 589 elseif(${GMX_ACCELERATION} STREQUAL "IA64")
 590     set(GMX_IA64_ASM 1)
 591     set(DISABLE_WATERWATER_NLIST 1)
 592     set(DISABLE_WATER_NLIST 1)
 593 elseif(${GMX_ACCELERATION} STREQUAL "ALTIVEC")
 594     check_include_files(altivec.h HAVE_ALTIVEC_H)
 595     if(HAVE_ALTIVEC_H)
 596         set(GMX_PPC_ALTIVEC 1)
 597     endif(HAVE_ALTIVEC_H)
 598 else(${GMX_ACCELERATION} STREQUAL "NONE")
 599     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_ACCELERATION}. Pick one of auto, none, SSE, Fortran, BlueGene, Power6, ia64, altivec")
 600 endif(${GMX_ACCELERATION} STREQUAL "NONE")
 601
 602 if(GMX_FORTRAN OR GMX_POWER6)
 603     if (GMX_THREADS)
 604         message(FATAL_ERROR "FORTRAN/POWER6 is incompatible with threads and only provides a speed-up on certain IBM compilers. Disable FORTRAN (or threads if you really want to use FORTRAN kernels).")
 605     endif(GMX_THREADS)
 606     enable_language(Fortran)
 607     include(FortranCInterface)
 608     discover_fortran_mangling(prefix isupper suffix extra_under_score found)
 609     if(extra_under_score)
 610         set(extrasuffix "_")
 611     endif(extra_under_score)
 612     if(prefix)
 613       set(prefix "${prefix} ##")
 614     endif(prefix)
 615
 616     if(isupper)
 617         set(F77_FUNCDEF   "${prefix} NAME ## ${suffix}")
 618         set(F77_FUNCDEF_  "${prefix} NAME ## ${suffix}${extrasuffix}")
 619     else(isupper)
 620         set(F77_FUNCDEF   "${prefix} name ## ${suffix}")
 621         set(F77_FUNCDEF_  "${prefix} name ## ${suffix}${extrasuffix}")
 622     endif(isupper)
 623 else(GMX_FORTRAN OR GMX_POWER6)
 624         set(F77_FUNCDEF   "name ## _")
 625         set(F77_FUNCDEF_  "name ## _")
 626 endif(GMX_FORTRAN OR GMX_POWER6)
 627
 628 # Process QM/MM Settings
 629 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 630 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 631     set(GMX_QMMM_GAUSSIAN 1)
 632 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 633     set(GMX_QMMM_MOPAC 1)
 634 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 635     set(GMX_QMMM_GAMESS 1)
 636 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 637     set(GMX_QMMM_ORCA 1)
 638 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 639     # nothing to do
 640 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 641     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 642 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 643
 644 # Process FFT library settings - if not OpenMM build
 645 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 646 set(PKG_FFT "")
 647 set(PKG_FFT_LIBS "")
 648 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 649 #    MESSAGE(STATUS "Using external FFT library - fftw3")
 650     if(GMX_DOUBLE)
 651         find_package(FFTW3 REQUIRED)
 652                 include_directories(${FFTW3_INCLUDE_DIR})
 653         set(FFT_LIBRARIES ${FFTW3_LIBRARIES})
 654         set(PKG_FFT "fftw3")
 655     else(GMX_DOUBLE)
 656         find_package(FFTW3F REQUIRED)
 657         include_directories(${FFTW3F_INCLUDE_DIR})
 658         set(FFT_LIBRARIES ${FFTW3F_LIBRARIES})
 659         set(PKG_FFT "fftw3f")
 660     endif(GMX_DOUBLE)
 661
 662     if(NOT FFTW3_FOUND AND NOT FFTW3F_FOUND)
 663         MESSAGE(FATAL_ERROR "Cannot find fftw3 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 664     endif(NOT FFTW3_FOUND AND NOT FFTW3F_FOUND)
 665
 666     set(GMX_FFT_FFTW3 1)
 667
 668 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 669 #    MESSAGE(STATUS "Using external FFT library - fftw2")
 670     if(GMX_DOUBLE)
 671         find_package(FFTW2 REQUIRED)
 672     else(GMX_DOUBLE)
 673         find_package(FFTW2F REQUIRED)
 674     endif(GMX_DOUBLE)
 675
 676     if(NOT FFTW2_FOUND)
 677            MESSAGE(FATAL_ERROR "Cannot find fftw2 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 678     endif(NOT FFTW2_FOUND)
 679     include_directories(${FFTW2_INCLUDE_DIR})
 680     set(FFT_LIBRARIES ${FFTW2_LIBRARIES})
 681     set(PKG_FFT_LIBS ${FFTW2_LIBRARIES})
 682
 683     if("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 684         set(FFTW2_NAME_DFFTW 1)
 685     elseif("${FFTW2_LIBRARIES}" MATCHES "sfftw")
 686         set(FFTW2_NAME_SFFTW 1)
 687     else("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 688         set(FFTW2_NAME_FFTW 1)
 689     endif("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 690
 691     set(GMX_FFT_FFTW2 1)
 692 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 693 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 694     find_package(MKL REQUIRED)
 695     include_directories(${MKL_INCLUDE_DIR})
 696     set(FFT_LIBRARIES ${MKL_LIBRARIES})
 697     set(PKG_FFT_LIBS ${MKL_LIBRARIES})
 698
 699     set(GMX_FFT_MKL 1)
 700     set(HAVE_MKL 1)
 701
 702 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 703 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 704 #    set(GMX_FFT_ACML 1)
 705 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 706     MESSAGE(STATUS "Using internal FFT library - fftpack")
 707     set(GMX_FFT_FFTPACK 1)
 708 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 709     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, fftw2, mkl, acml, fftpack")
 710 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 711
 712 # MKL has BLAS/LAPACK routines
 713 if(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 714   set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 715   set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 716 else(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 717   set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 718   set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 719   if(GMX_EXTERNAL_BLAS)
 720     #FindBLAS needs Fortran
 721     enable_language(Fortran)
 722     find_package(BLAS REQUIRED)
 723     list(APPEND GMX_EXTRA_LIBRARIES ${BLAS_LIBRARIES})
 724   endif(GMX_EXTERNAL_BLAS)
 725   if(GMX_EXTERNAL_LAPACK)
 726     #FindLAPACK needs Fortran
 727     enable_language(Fortran)
 728     find_package(LAPACK REQUIRED)
 729     list(APPEND GMX_EXTRA_LIBRARIES ${LAPACK_LIBRARIES})
 730   endif(GMX_EXTERNAL_LAPACK)
 731 endif(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 732 mark_as_advanced(GMX_EXTERNAL_LAPACK)
 733 mark_as_advanced(GMX_EXTERNAL_BLAS)
 734
 735 # Math and thread libraries must often come after all others when linking...
 736 if(HAVE_LIBM)
 737     list(APPEND GMX_EXTRA_LIBRARIES m)
 738 endif(HAVE_LIBM)
 739
 740 if(GMX_FAHCORE)
 741   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 742       "Path to swindirect.h")
 743   include_directories(${COREWRAP_INCLUDE_DIR})
 744 endif(GMX_FAHCORE)
 745
 746 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 747 # these are set after everything else
 748 if (NOT DEFINED GROMACS_C_FLAGS_SET)
 749     set(GROMACS_C_FLAGS_SET true CACHE INTERNAL "Whether to reset the C flags"
 750         FORCE)
 751     set(CMAKE_C_FLAGS "${GROMACS_C_FLAGS} ${CMAKE_C_FLAGS}" CACHE STRING
 752         "Flags used by the compiler during all build types" FORCE)
 753     set(CMAKE_CXX_FLAGS "${GROMACS_CXX_FLAGS} ${CMAKE_CXX_FLAGS}" CACHE STRING
 754         "Flags used by the compiler during all build types" FORCE)
 755     set(CMAKE_EXE_LINKER_FLAGS
 756         "${GROMACS_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}"
 757         CACHE STRING "Linker flags" FORCE)
 758 endif (NOT DEFINED GROMACS_C_FLAGS_SET)
 759
 760 ########################################################################
 761 # Specify install locations and which subdirectories to process        #
 762 ########################################################################
 763 if ( DEFINED LIB )
 764     set(LIB_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/${LIB}")
 765 else()
 766     set(LIB_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/lib)
 767 endif()
 768 set(BIN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/bin)
 769 set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/gromacs)
 770 set(MAN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/share/man)
 771 set(INCL_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/include)
 772
 773 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
 774
 775 ##################################################################
 776 # Shared library settings - Darwin uses INSTALL_NAME_DIR instead!
 777 ##################################################################
 778 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 779     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
 780     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
 781     set(CMAKE_INSTALL_RPATH "${LIB_INSTALL_DIR}")
 782     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 783 endif()
 784
 785 add_subdirectory(share)
 786 add_subdirectory(include)
 787 add_subdirectory(man)
 788 add_subdirectory(src)
 789 add_subdirectory(scripts)
 790
 791 #######################
 792 ## uninstall target
 793 #######################
 794     CONFIGURE_FILE(
 795                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 796                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 797                    IMMEDIATE @ONLY)
 798 ###########################
 799 ADD_CUSTOM_TARGET(uninstall
 800                   "${CMAKE_COMMAND}" -P
 801                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 802 ###########################
 803
 804
 805 ########################################################################
 806 # Tests                                                                #
 807 ########################################################################
 808
 809 include(CTest)
 810 mark_as_advanced(BUILD_TESTING)
 811 IF(BUILD_TESTING)
 812         enable_testing()
 813         add_test(TestBuildAll make)
 814         add_subdirectory(tests)
 815 ENDIF()
 816