CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2012, by the GROMACS development team, led by
   5 # David van der Spoel, Berk Hess, Erik Lindahl, and including many
   6 # others, as listed in the AUTHORS file in the top-level source
   7 # directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34 #
  35 cmake_minimum_required(VERSION 2.8)
  36 # Keep CMake suitably quiet on Cygwin
  37 set(CMAKE_LEGACY_CYGWIN_WIN32 0) # Remove when CMake >= 2.8.4 is required
  38
  39 # Allows CPack to act differently for normal tools and mdrun (e.g. because of MPI)
  40 set(CPACK_COMPONENT_GROUP_TOOLS_DESCRIPTION "All GROMACS executable tools")
  41 set(CPACK_COMPONENT_GROUP_MDRUN_DESCRIPTION "GROMACS executable for running simulations")
  42
  43 # CMake modules/macros are in a subdirectory to keep this file cleaner
  44 # This needs to be set before project() in order to pick up toolchain files
  45 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  46
  47 project(Gromacs C)
  48 include(Dart)
  49 mark_as_advanced(DART_ROOT)
  50
  51 # PROJECT_VERSION should have the following structure:
  52 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  53 #
  54 # The "-dev" suffix is important to keep because it makes possible to distinguish
  55 # between a build from official release and a build from git release branch on a
  56 # machine with no git.
  57 #
  58 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  59 set(PROJECT_VERSION "4.6-beta3-dev")
  60 set(CUSTOM_VERSION_STRING ""
  61     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  62 mark_as_advanced(CUSTOM_VERSION_STRING)
  63 if (CUSTOM_VERSION_STRING)
  64     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  65 endif (CUSTOM_VERSION_STRING)
  66 set(SOVERSION 6)
  67 # It is a bit irritating, but this has to be set separately for now!
  68 SET(CPACK_PACKAGE_VERSION_MAJOR "4")
  69 SET(CPACK_PACKAGE_VERSION_MINOR "6")
  70 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  71
  72 # The numerical gromacs version. It is 40600 for 4.6.0.
  73 # The #define GMX_VERSION in gmx_header_config_h is set to this value.
  74 math(EXPR NUM_VERSION
  75     "${CPACK_PACKAGE_VERSION_MAJOR}*10000 + ${CPACK_PACKAGE_VERSION_MINOR}*100")
  76 if(CPACK_PACKAGE_VERSION_PATCH)
  77     math(EXPR NUM_VERSION
  78          "${NUM_VERSION} + ${CPACK_PACKAGE_VERSION_PATCH}")
  79 endif()
  80
  81 # The API version tracks the numerical Gromacs version (for now).
  82 # It is potentially different from the Gromacs version in the future, if
  83 # the programs/libraries diverge from the presumably more stable API.
  84 # The #define GMX_API_VERSION in version.h is set to this value to
  85 # provide backward compatibility of software written against the Gromacs API.
  86 set(API_VERSION ${NUM_VERSION})
  87
  88 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  89 set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  90 endif()
  91
  92 include(gmxBuildTypeReference)
  93
  94 if(NOT CMAKE_BUILD_TYPE)
  95     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference." FORCE)
  96 endif(NOT CMAKE_BUILD_TYPE)
  97
  98 enable_language(C)
  99
 100 set(GMX_USE_RELATIVE_INSTALL_PATH OFF CACHE STRING "Use relative paths not absolute paths for cmake install. Has only an effect on cpack.")
 101 mark_as_advanced(GMX_USE_RELATIVE_INSTALL_PATH)
 102
 103 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
 104 set(CPACK_PACKAGE_VENDOR "gromacs.org")
 105 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
 106 if (NOT GMX_USE_RELATIVE_INSTALL_PATH)
 107     set(CPACK_SET_DESTDIR "ON")
 108 endif()
 109 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
 110 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
 111 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/COPYING")
 112 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
 113 set(CPACK_SOURCE_IGNORE_FILES "\\\\.isreposource$;\\\\.git/;\\\\.gitignore$")
 114 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
 115 SET(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/man;man")
 116 set(CPACK_PACKAGE_CONTACT "gmx-users@gromacs.org")
 117
 118 #must come after all cpack settings!
 119 include(CPack)
 120
 121 ########################################################################
 122 # Check and warn if cache generated on a different host is being reused
 123 ########################################################################
 124 if(CMAKE_HOST_UNIX)
 125     execute_process(COMMAND hostname
 126                     OUTPUT_VARIABLE TMP_HOSTNAME
 127                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 128     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 129         message(WARNING "
 130             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 131             is being reused! This could lead to inconsitencies; therefore, it is
 132             recommended to regenerate the cache!")
 133     endif()
 134     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 135             "Hostname of the machine where the cache was generated.")
 136 endif()
 137
 138 ########################################################################
 139 # User input options - enable C++ - before any CXX flags are changed   #
 140 ########################################################################
 141
 142 # decide on GPU settings based on user-settings and GPU/CUDA detection
 143 include(gmxManageGPU)
 144
 145 # TODO: move OpenMM to contrib
 146 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library (not fully supported)" OFF)
 147 mark_as_advanced(GMX_OPENMM)
 148
 149 option(GMX_FORCE_CXX "Enable C++ compilation even if not necessary" OFF)
 150 mark_as_advanced(GMX_FORCE_CXX)
 151
 152 option(GMX_NO_QUOTES "Disable Gromacs cool quotes" OFF)
 153
 154 if(GMX_GPU OR GMX_OPENMM OR GMX_FORCE_CXX)
 155     enable_language(CXX)
 156 endif()
 157 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 158
 159 ########################################################################
 160 # Fix stupid flags on Windows
 161 ########################################################################
 162 SET(SHARED_LIBS_DEFAULT ON)
 163 IF( WIN32 AND NOT CYGWIN)
 164   if (NOT BUILD_SHARED_LIBS)
 165     option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static system libraries (MT instead of MD)!" ON)
 166     mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 167     SET(SHARED_LIBS_DEFAULT OFF)
 168   else()
 169     add_definitions(-DUSE_VISIBILITY -DTMPI_USE_VISIBILITY)
 170     set(PKG_CFLAGS "$PKG_CFLAGS -DUSE_VISIBILITY -DTMPI_USE_VISIBILITY")
 171   endif()
 172
 173   IF (GMX_PREFER_STATIC_LIBS)
 174     #Only setting Debug and Release flags. Others configurations current not used.
 175     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
 176     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
 177     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
 178     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
 179     if(CMAKE_CXX_COMPILER_LOADED)
 180         STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE})
 181         SET(CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE} CACHE STRING "" FORCE)
 182         STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 183         SET(CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG} CACHE STRING "" FORCE)
 184     endif()
 185   ENDIF()
 186
 187   #Workaround for cmake bug 13174. Replace deprecated options.
 188   IF( CMAKE_C_COMPILER_ID MATCHES "Intel" )
 189     if(BUILD_SHARED_LIBS)
 190         STRING(REPLACE "/INCREMENTAL:YES" "" CMAKE_SHARED_LINKER_FLAGS ${CMAKE_SHARED_LINKER_FLAGS})
 191         SET(CMAKE_SHARED_LINKER_FLAGS ${CMAKE_SHARED_LINKER_FLAGS} CACHE STRING "" FORCE)
 192     endif()
 193     STRING(REPLACE /GZ /RTC1 CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
 194     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
 195   ENDIF()
 196   IF( CMAKE_CXX_COMPILER_ID MATCHES "Intel" AND CMAKE_CXX_COMPILER_LOADED)
 197     STRING(REPLACE /GZ /RTC1 CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 198     STRING(REPLACE /GX /EHsc CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 199     SET(CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG} CACHE STRING "" FORCE)
 200
 201     STRING(REPLACE /GX /EHsc CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE})
 202     SET(CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE} CACHE STRING "" FORCE)
 203   ENDIF()
 204 ENDIF()
 205
 206
 207 ########################################################################
 208 # User input options                                                   #
 209 ########################################################################
 210 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 211 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 212 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 213 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 214 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 215 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 216 mark_as_advanced(GMX_FAHCORE)
 217
 218 include(gmxDetectAcceleration)
 219 if(NOT DEFINED GMX_CPU_ACCELERATION)
 220     if(CMAKE_CROSSCOMPILING)
 221         set(GMX_SUGGESTED_CPU_ACCELERATION "None")
 222     else(CMAKE_CROSSCOMPILING)
 223         gmx_detect_acceleration(GMX_SUGGESTED_CPU_ACCELERATION)
 224     endif(CMAKE_CROSSCOMPILING)
 225 endif(NOT DEFINED GMX_CPU_ACCELERATION)
 226
 227 set(GMX_CPU_ACCELERATION "@GMX_SUGGESTED_CPU_ACCELERATION@"
 228     CACHE STRING "Accelerated CPU kernels. Pick one of: None, SSE2, SSE4.1, AVX_128_FMA, AVX_256, BlueGene")
 229
 230 set(GMX_FFT_LIBRARY "fftw3"
 231     CACHE STRING "FFT library choices: fftw3,mkl,fftpack[built-in]")
 232 option(GMX_BUILD_OWN_FFTW "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack." OFF)
 233 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 234 option(GMX_DISABLE_FFTW_MEASURE
 235        "Do not optimize FFTW setups (not needed with SSE)" OFF)
 236 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 237 set(GMX_QMMM_PROGRAM "none"
 238     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
 239 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 240 mark_as_advanced(GMX_BROKEN_CALLOC)
 241 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
 242 mark_as_advanced(GMX_MPI_IN_PLACE)
 243 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 244 mark_as_advanced(GMX_LOAD_PLUGINS)
 245
 246 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 247
 248 option(USE_VERSION_H "Generate development version string/information" ON)
 249 mark_as_advanced(USE_VERSION_H)
 250
 251 option(GMX_DEFAULT_SUFFIX "Use default suffixes for GROMACS binaries and libs (_d for double, _mpi for MPI; rerun cmake after changing to see relevant options)" ON)
 252
 253 if(UNIX)
 254     option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static archives (not available on non-*nix platforms and it will only work if static versions of external dependencies are available and found)!" OFF)
 255     mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 256 endif()
 257
 258 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 259 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 260
 261 ######################################################################
 262 # Compiler tests
 263 # These need to be done early (before further tests).
 264 #####################################################################
 265
 266 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 267 # are used with permission from CMake v2.8.9 so that GROMACS can detect
 268 # invalid options with the Intel Compilers.
 269 # These files should be removed from the source tree when a CMake version that
 270 # includes the features in question becomes required for building GROMACS.
 271 include(CheckCCompilerFlag)
 272 if(CMAKE_CXX_COMPILER_LOADED)
 273     include(CheckCXXCompilerFlag)
 274 endif()
 275
 276 # OpenMP check must come before other CFLAGS!
 277 if(GMX_OPENMP)
 278     find_package(OpenMP)
 279     if(OPENMP_FOUND)
 280         # CMake on Windows doesn't support linker flags passed to target_link_libraries
 281         # (i.e. it treats /openmp as \openmp library file). Also, no OpenMP linker flags are needed.
 282         if(NOT (WIN32 AND NOT CYGWIN))
 283             if(CMAKE_COMPILER_IS_GNUCC AND GMX_PREFER_STATIC_OPENMP)
 284                 set(OpenMP_LINKER_FLAGS "-Wl,-static -lgomp -lrt -Wl,-Bdynamic -lpthread")
 285                 set(OpenMP_SHARED_LINKER_FLAGS "")
 286             else()
 287                 # Only set a linker flag if the user didn't set them manually
 288                 if(NOT DEFINED OpenMP_LINKER_FLAGS)
 289                     set(OpenMP_LINKER_FLAGS "${OpenMP_C_FLAGS}")
 290                 endif()
 291                 if(NOT DEFINED OpenMP_SHARED_LINKER_FLAGS)
 292                     set(OpenMP_SHARED_LINKER_FLAGS "${OpenMP_C_FLAGS}")
 293                 endif()
 294             endif()
 295         endif()
 296     else(OPENMP_FOUND)
 297         message(WARNING
 298                 "The compiler you are using does not support OpenMP parallelism. This might hurt your performance a lot, in particular with GPUs. Try using a more recent version, or a different compiler. For now, we are proceeding by turning off OpenMP.")
 299         set(GMX_OPENMP OFF CACHE STRING "Whether GROMACS will use OpenMP parallelism." FORCE)
 300     endif(OPENMP_FOUND)
 301 endif()
 302
 303
 304 include(gmxCFlags)
 305 gmx_c_flags()
 306
 307 include(gmxGetCompilerInfo)
 308 get_compiler_version()
 309
 310 # gcc 4.4.x is buggy and crashes when compiling some files with O3 and OpenMP on.
 311 # Detect here whether applying a workaround is needed and will apply it later
 312 # on the affected files.
 313 include(gmxGCC44O3BugWorkaround)
 314 gmx_check_gcc44_bug_workaround_needed(GMX_USE_GCC44_BUG_WORKAROUND)
 315
 316 # clang 3.0 is buggy for some unknown reason detected during adding
 317 # the SSE2 group kernels for GROMACS 4.6. If we ever work out what
 318 # that is, we should replace these tests with a compiler feature test,
 319 # update GROMACS Redmine task #1039 and perhaps report a clang bug.
 320 #
 321 # In the meantime, until we require CMake 2.8.10 we cannot rely on it to detect
 322 # the compiler version for us. So we need a manual check for clang 3.0.
 323 include(gmxDetectClang30)
 324 gmx_detect_clang_3_0(COMPILER_IS_CLANG_3_0)
 325 if(COMPILER_IS_CLANG_3_0)
 326     message(FATAL_ERROR "Your compiler is clang version 3.0, which is known to be buggy for GROMACS. Use a different compiler.")
 327 endif()
 328
 329 if (CMAKE_C_COMPILER_ID STREQUAL "PGI")
 330     message(WARNING "All tested PGI compiler versions (up to 12.9.0) generate binaries which produce incorrect results, or even fail to compile Gromacs. Highly recommended to use a different compiler. If you choose to use PGI, make sure to run the regressiontests.")
 331 endif()
 332
 333 ########################################################################
 334 # Set up binary and library suffixing
 335 ########################################################################
 336 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 337 set(GMX_LIBS_SUFFIX ""
 338   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 339 if (GMX_DEFAULT_SUFFIX)
 340   set(GMX_BINARY_SUFFIX "")
 341   set(GMX_LIBS_SUFFIX "")
 342   if (GMX_MPI)
 343     set(GMX_BINARY_SUFFIX "_mpi")
 344     set(GMX_LIBS_SUFFIX "_mpi")
 345   endif(GMX_MPI)
 346   if (GMX_DOUBLE)
 347     set (GMX_BINARY_SUFFIX "${GMX_BINARY_SUFFIX}_d")
 348     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
 349   endif(GMX_DOUBLE)
 350   if (GMX_OPENMM)
 351     set (GMX_BINARY_SUFFIX "-openmm")
 352     set (GMX_LIBS_SUFFIX "_openmm")
 353   endif(GMX_OPENMM)
 354   mark_as_advanced(FORCE GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 355   if (NOT SUFFIX_QUIETLY)
 356     message(STATUS "Using default binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 357     message(STATUS "Using default library suffix: \"${GMX_LIBS_SUFFIX}\"")
 358   endif (NOT SUFFIX_QUIETLY)
 359 else(GMX_DEFAULT_SUFFIX)
 360   mark_as_advanced(CLEAR GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 361   if (NOT SUFFIX_QUIETLY)
 362     message(STATUS "Using manually set binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 363     message(STATUS "Using manually set library suffix: \"${GMX_LIBS_SUFFIX}\"")
 364   endif (NOT SUFFIX_QUIETLY)
 365 endif(GMX_DEFAULT_SUFFIX)
 366 set(SUFFIX_QUIETLY TRUE CACHE INTERNAL "")
 367
 368 set(PKG_CFLAGS "")
 369 if(GMX_DOUBLE)
 370     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 371 endif(GMX_DOUBLE)
 372 if(GMX_SOFTWARE_INVSQRT)
 373   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 374 endif(GMX_SOFTWARE_INVSQRT)
 375
 376 ########################################################################
 377 #Process MPI settings
 378 ########################################################################
 379 include(gmxManageMPI)
 380
 381 #######################################################################
 382 # Check for options incompatible with OpenMM build                    #
 383 #######################################################################
 384 if(GMX_OPENMM)
 385     # we'll use the built-in fft to avoid unnecessary dependencies
 386     string(TOUPPER ${GMX_FFT_LIBRARY} GMX_FFT_LIBRARY)
 387     if(NOT ${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 388         message(STATUS "No external FFT libraries needed for the OpenMM build, switching to fftpack!")
 389         set(GMX_FFT_LIBRARY "fftpack" CACHE STRING
 390                 "No external FFT libraries needed for the OpenMM build, switching to  fftpack!" FORCE)
 391     endif()
 392     if(GMX_MPI)
 393         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
 394     endif(GMX_MPI)
 395     if(GMX_THREAD_MPI)
 396         message(STATUS "Thread-MPI not compatible with OpenMM, disabled!")
 397         set(GMX_THREAD_MPI OFF CACHE BOOL
 398                 "Thread-MPI not compatible with OpenMM build, disabled!" FORCE)
 399     endif(GMX_THREAD_MPI)
 400     if(GMX_OPENMP)
 401         message(STATUS "OpenMP multithreading not compatible with OpenMM, disabled")
 402         set(GMX_OPENMP OFF CACHE BOOL
 403             "OpenMP multithreading not compatible with OpenMM, disabled!" FORCE)
 404     endif()
 405     if(GMX_SOFTWARE_INVSQRT)
 406         set(GMX_SOFTWARE_INVSQRT OFF CACHE STRING
 407                 "The OpenMM build does not need GROMACS software 1/sqrt!" FORCE)
 408     endif(GMX_SOFTWARE_INVSQRT)
 409     string(TOUPPER ${GMX_CPU_ACCELERATION} GMX_CPU_ACCELERATION)
 410     if(NOT GMX_CPU_ACCELERATION STREQUAL "NONE")
 411         message(STATUS "Switching off CPU-based acceleration, the OpenMM build does not support/need any!")
 412         set(GMX_CPU_ACCELERATION "None" CACHE STRING
 413             "Switching off CPU-based acceleration, the OpenMM build does not support/need any!" FORCE)
 414     endif()
 415     if(GMX_FAHCORE)
 416         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
 417     endif(GMX_FAHCORE)
 418     if(GMX_DOUBLE)
 419         message(FATAL_ERROR  "The OpenMM-build does not support double precision calculations!")
 420     endif()
 421     # mark as advanced the unused variables
 422     mark_as_advanced(FORCE GMX_CPU_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 423         GMX_QMMM_PROGRAM GMX_THREAD_MPI GMX_DOUBLE)
 424 else(GMX_OPENMM)
 425      mark_as_advanced(CLEAR GMX_CPU_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 426         GMX_QMMM_PROGRAM GMX_THREAD_MPI GMX_DOUBLE)
 427 endif(GMX_OPENMM)
 428
 429
 430 ########################################################################
 431 # Basic system tests (standard libraries, headers, functions, types)   #
 432 ########################################################################
 433 include(CheckIncludeFiles)
 434 check_include_files(string.h     HAVE_STRING_H)
 435 check_include_files(math.h       HAVE_MATH_H)
 436 check_include_files(limits.h     HAVE_LIMITS_H)
 437 check_include_files(memory.h     HAVE_MEMORY_H)
 438 check_include_files(unistd.h     HAVE_UNISTD_H)
 439 check_include_files(direct.h     HAVE_DIRECT_H)
 440 check_include_files(pwd.h        HAVE_PWD_H)
 441 check_include_files(stdint.h     HAVE_STDINT_H)
 442 check_include_files(stdlib.h     HAVE_STDLIB_H)
 443 check_include_files(pthread.h    HAVE_PTHREAD_H)
 444 check_include_files(dirent.h     HAVE_DIRENT_H)
 445 check_include_files(inttypes.h   HAVE_INTTYPES_H)
 446 check_include_files(regex.h      HAVE_REGEX_H)
 447 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 448 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
 449 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 450 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
 451 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
 452 check_include_files(io.h                 HAVE_IO_H)
 453 check_include_files(sched.h      HAVE_SCHED_H)
 454
 455 include(CheckFunctionExists)
 456 check_function_exists(strcasecmp        HAVE_STRCASECMP)
 457 check_function_exists(strdup            HAVE_STRDUP)
 458 check_function_exists(vprintf           HAVE_VPRINTF)
 459 check_function_exists(memcmp            HAVE_MEMCMP)
 460 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 461 check_function_exists(memalign          HAVE_MEMALIGN)
 462 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 463 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 464 check_function_exists(isnan             HAVE_ISNAN)
 465 check_function_exists(_isnan            HAVE__ISNAN)
 466 check_function_exists(fsync             HAVE_FSYNC)
 467 check_function_exists(_fileno           HAVE__FILENO)
 468 check_function_exists(fileno            HAVE_FILENO)
 469 check_function_exists(_commit           HAVE__COMMIT)
 470 check_function_exists(sigaction         HAVE_SIGACTION)
 471 check_function_exists(sysconf           HAVE_SYSCONF)
 472 check_function_exists(sched_setaffinity HAVE_SCHED_SETAFFINITY)
 473 check_function_exists(sched_getaffinity HAVE_SCHED_GETAFFINITY)
 474 check_function_exists(rsqrt             HAVE_RSQRT)
 475 check_function_exists(rsqrtf            HAVE_RSQRTF)
 476 check_function_exists(sqrtf             HAVE_SQRTF)
 477
 478 include(CheckLibraryExists)
 479 check_library_exists(m sqrt "" HAVE_LIBM)
 480 check_library_exists(m cbrt "" HAVE_CBRT)
 481
 482
 483 include(CheckTypeSize)
 484
 485 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 486 check_type_size("int"           SIZEOF_INT)
 487 check_type_size("long int"      SIZEOF_LONG_INT)
 488 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 489 check_type_size("off_t"         SIZEOF_OFF_T)
 490 check_type_size("void *"        SIZEOF_VOIDP)
 491
 492 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 493     set(GMX_64_BIT TRUE)
 494 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 495     set(GMX_64_BIT FALSE)
 496 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 497
 498 # Check for some basic types that we *need*, so set these to int if they are not present
 499 check_type_size(uid_t uid_t)
 500 if(NOT uid_t)
 501   set(uid_t int)
 502 else(NOT uid_t)
 503   set(uid_t 0)
 504 endif(NOT uid_t)
 505
 506 check_type_size(gid_t gid_t)
 507 if(NOT gid_t)
 508   set(gid_t 1)
 509 else(NOT gid_t)
 510   set(gid_t 0)
 511 endif(NOT gid_t)
 512
 513 check_type_size(size_t size_t)
 514 if(NOT size_t)
 515   set(size_t int)
 516 else(NOT size_t)
 517   set(size_t 0)
 518 endif(NOT size_t)
 519
 520 check_type_size(off_t off_t)
 521 if(NOT off_t)
 522   set(off_t int)
 523 else(NOT off_t)
 524   set(off_t 0)
 525 endif(NOT off_t)
 526
 527 include(TestBigEndian)
 528 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 529
 530
 531
 532
 533 ########################################################################
 534 # Find external packages                                               #
 535 ########################################################################
 536 if(UNIX)
 537     if(GMX_PREFER_STATIC_LIBS)
 538         # On Linux .a is the static library suffix, on Mac OS X .lib can also
 539         # be used, so we'll add both to the preference list.
 540         SET(CMAKE_FIND_LIBRARY_SUFFIXES ".lib;.a" ${CMAKE_FIND_LIBRARY_SUFFIXES})
 541         if(SHARED_LIBS_DEFAULT)
 542             if(BUILD_SHARED_LIBS) #Warn the user about the combination. But don't overwrite the request.
 543                 message(WARNING "Static libraries requested, and shared Gromacs libraries requested.")
 544             elseif(NOT DEFINED BUILD_SHARED_LIBS) #Change default to OFF. Don't warn if it's already off.
 545                 message(WARNING "Static libraries requested, the GROMACS libraries will also be build static (BUILD_SHARED_LIBS=OFF)")
 546                 set(SHARED_LIBS_DEFAULT OFF)
 547             endif()
 548         endif()
 549     endif()
 550 endif()
 551 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI, Windows)" ${SHARED_LIBS_DEFAULT})
 552
 553 option(GMX_GSL "Add support for gsl" OFF)
 554 if (GMX_GSL)
 555   find_package(gsl)
 556   set(PKG_GSL "")
 557   if(GSL_FOUND)
 558     include_directories(${GSL_INCLUDE_DIR})
 559     set(PKG_GSL gsl)
 560     set(HAVE_LIBGSL 1)
 561   endif(GSL_FOUND)
 562 endif (GMX_GSL)
 563
 564 option(GMX_X11 "Use X window system" OFF)
 565 if (GMX_X11)
 566         find_package(X11)
 567         # X11 includes/libraries are only set in the ngmx subdirectory!
 568         if(X11_FOUND)
 569         set(HAVE_X11 1)
 570         endif(X11_FOUND)
 571 endif(GMX_X11)
 572
 573 include(ThreadMPI)
 574 set(THREAD_MPI_LIB thread_mpi)
 575 if(GMX_THREAD_MPI)
 576     tmpi_get_source_list(THREAD_MPI_SRC)
 577     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREAD_MPI")
 578     set(GMX_MPI 1)
 579 else(GMX_THREAD_MPI)
 580     tmpi_get_source_list(THREAD_MPI_SRC NOMPI)
 581 endif(GMX_THREAD_MPI)
 582
 583 if(GMX_OPENMM)
 584     set(CUDA_BUILD_EMULATION OFF)
 585     find_package(CUDA 3.1 REQUIRED)
 586     add_definitions(-DGMX_OPENMM)
 587     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 588         set(CUDA_VERBOSE_BUILD ON)
 589     endif()
 590     find_package(OpenMM)
 591 endif(GMX_OPENMM)
 592
 593 if(GMX_GPU)
 594     # now that we have detected the dependencies, do the second configure pass
 595     gmx_gpu_setup()
 596 endif(GMX_GPU)
 597
 598 if(APPLE)
 599    find_library(ACCELERATE_FRAMEWORK Accelerate)
 600    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 601 endif(APPLE)
 602
 603 if(CYGWIN)
 604     set(GMX_CYGWIN 1)
 605 endif(CYGWIN)
 606
 607 if(WIN32 AND NOT CYGWIN)
 608     set(GMX_NATIVE_WINDOWS 1)
 609 endif()
 610
 611 # only bother with finding git and using version.h if the source is a git repo
 612 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 613     if(USE_VERSION_H)
 614         # We need at least git v1.5.3 be able to parse git's date output. If not
 615         # found or the version is too small, we can't generate version information.
 616         find_package(Git)
 617
 618         # Find out the git version
 619         if(GIT_FOUND AND NOT GIT_VERSION)
 620           execute_process(COMMAND ${GIT_EXECUTABLE} "--version"
 621             OUTPUT_VARIABLE _exec_out
 622             OUTPUT_STRIP_TRAILING_WHITESPACE)
 623           string(REGEX REPLACE "git version (.*)" "\\1" GIT_VERSION ${_exec_out})
 624           set(GIT_VERSION ${GIT_VERSION} CACHE STRING "Git version")
 625           mark_as_advanced(GIT_VERSION)
 626         endif()
 627
 628         if(NOT GIT_FOUND OR GIT_VERSION VERSION_LESS "1.5.3")
 629           message("No compatible git version found, won't be able to generate proper development version information.")
 630           set(USE_VERSION_H OFF)
 631         endif()
 632     endif()
 633 else()
 634     set(USE_VERSION_H OFF)
 635 endif()
 636
 637 ########################################################################
 638 # Generate development version info for cache
 639 ########################################################################
 640 # set(GEN_VERSION_INFO_INTERNAL "ON")
 641 # include(gmxGenerateVersionString)
 642
 643 ########################################################################
 644 # Our own GROMACS tests
 645 ########################################################################
 646
 647 add_definitions( -DHAVE_CONFIG_H )
 648 include_directories(${CMAKE_BINARY_DIR}/src)
 649 include_directories(${CMAKE_BINARY_DIR}/include)
 650 include_directories(${CMAKE_SOURCE_DIR}/include)
 651
 652 include(gmxTestInlineASM)
 653 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 654
 655 include(gmxSetBuildInformation)
 656 gmx_set_build_information()
 657 if(BUILD_CPU_FEATURES MATCHES "rdtscp" AND NOT GMX_DISTRIBUTABLE_BUILD)
 658     # The timestep counter headers do not include config.h
 659     add_definitions(-DHAVE_RDTSCP)
 660 endif(BUILD_CPU_FEATURES MATCHES "rdtscp" AND NOT GMX_DISTRIBUTABLE_BUILD)
 661
 662 include(gmxTestFloatFormat)
 663 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 664                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 665                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 666
 667 include(gmxTestLargeFiles)
 668 gmx_test_large_files(GMX_LARGEFILES)
 669
 670 include(gmxTestSignal)
 671 gmx_test_sigusr1(HAVE_SIGUSR1)
 672
 673 include(gmxTestInline)
 674 gmx_test_inline(INLINE_KEYWORD)
 675
 676 include(gmxTestRestrict)
 677 gmx_test_restrict(RESTRICT_KEYWORD)
 678
 679 include(gmxTestPipes)
 680 gmx_test_pipes(HAVE_PIPES)
 681
 682 include(gmxTestIsfinite)
 683 gmx_test_isfinite(HAVE_ISFINITE)
 684 gmx_test__isfinite(HAVE__ISFINITE)
 685 gmx_test__finite(HAVE__FINITE)
 686
 687 include(gmxTestXDR)
 688 gmx_test_xdr(GMX_SYSTEM_XDR)
 689 if(NOT GMX_SYSTEM_XDR)
 690     set(GMX_INTERNAL_XDR 1)
 691     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 692 endif(NOT GMX_SYSTEM_XDR)
 693
 694 # Process nonbonded accelerated kernels settings
 695 string(TOUPPER ${GMX_CPU_ACCELERATION} ${GMX_CPU_ACCELERATION})
 696 if(${GMX_CPU_ACCELERATION} STREQUAL "NONE")
 697     # nothing to do
 698 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SSE2")
 699
 700     GMX_TEST_CFLAG(GNU_SSE2_CFLAG "-msse2" GROMACS_C_FLAGS)
 701     if(NOT GNU_SSE2_CFLAG AND GMX_NATIVE_WINDOWS)
 702         GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" GROMACS_C_FLAGS)
 703     endif(NOT GNU_SSE2_CFLAG AND GMX_NATIVE_WINDOWS)
 704
 705     if (CMAKE_CXX_COMPILER_LOADED)
 706         GMX_TEST_CXXFLAG(GNU_SSE2_CXXFLAG "-msse2" GROMACS_CXX_FLAGS)
 707         if(NOT GNU_SSE2_CXXFLAG AND GMX_NATIVE_WINDOWS)
 708             GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" GROMACS_CXX_FLAGS)
 709         endif(NOT GNU_SSE2_CXXFLAG AND GMX_NATIVE_WINDOWS)
 710     endif()
 711
 712     # We dont warn for lacking SSE2 flag support, since that is probably standard today.
 713
 714     # Only test the include after we have tried to add the correct flag for SSE2 support
 715     check_include_file(emmintrin.h  HAVE_EMMINTRIN_H ${GROMACS_C_FLAGS})
 716
 717     if(NOT HAVE_EMMINTRIN_H)
 718         message(FATAL_ERROR "Cannot find emmintrin.h, which is required for SSE2 intrinsics support.")
 719     endif(NOT HAVE_EMMINTRIN_H)
 720
 721     set(GMX_CPU_ACCELERATION_X86_SSE2 1)
 722     # The user should not be able to set this orthogonally to the acceleration
 723     set(GMX_X86_SSE2 1)
 724     if (NOT ACCELERATION_QUIETLY)
 725       message(STATUS "Enabling SSE2 Gromacs acceleration, and it will help compiler optimization.")
 726     endif()
 727
 728 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SSE4.1")
 729
 730     GMX_TEST_CFLAG(GNU_SSE4_CFLAG "-msse4.1" GROMACS_C_FLAGS)
 731     if (NOT GNU_SSE4_CFLAG AND GMX_NATIVE_WINDOWS)
 732         GMX_TEST_CFLAG(MSVC_SSE4_CFLAG "/arch:SSE4.1" GROMACS_C_FLAGS)
 733     endif(NOT GNU_SSE4_CFLAG AND GMX_NATIVE_WINDOWS)
 734     if (NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 735         message(WARNING "No C SSE4.1 flag found. Consider a newer compiler, or use SSE2 for slightly lower performance.")
 736         # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 737         # intrinsics when SSE2 support is enabled, so we try that instead.
 738         if (GMX_NATIVE_WINDOWS)
 739             GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" GROMACS_C_FLAGS)
 740         endif()
 741     endif(NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 742
 743     if (CMAKE_CXX_COMPILER_LOADED)
 744         GMX_TEST_CXXFLAG(GNU_SSE4_CXXFLAG "-msse4.1" GROMACS_CXX_FLAG)
 745         if (NOT GNU_SSE4_CXXFLAG AND GMX_NATIVE_WINDOWS)
 746             GMX_TEST_CXXFLAG(MSVC_SSE4_CXXFLAG "/arch:SSE4.1" GROMACS_CXX_FLAGS)
 747         endif(NOT GNU_SSE4_CXXFLAG AND GMX_NATIVE_WINDOWS)
 748         if (NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 749             message(WARNING "No C++ SSE4.1 flag found. Consider a newer compiler, or use SSE2 for slightly lower performance.")
 750             # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 751             # intrinsics when SSE2 support is enabled, so we try that instead.
 752             if (GMX_NATIVE_WINDOWS)
 753                 GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" GROMACS_CXX_FLAGS)
 754             endif()
 755         endif(NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 756     endif()
 757
 758     # This must come after we have added the -msse4.1 flag on some platforms.
 759     check_include_file(smmintrin.h  HAVE_SMMINTRIN_H ${GROMACS_C_FLAGS})
 760
 761     if(NOT HAVE_SMMINTRIN_H)
 762         message(FATAL_ERROR "Cannot find smmintrin.h, which is required for SSE4.1 intrinsics support.")
 763     endif(NOT HAVE_SMMINTRIN_H)
 764
 765     set(GMX_CPU_ACCELERATION_X86_SSE4_1 1)
 766     # The user should not be able to set this orthogonally to the acceleration
 767     set(GMX_X86_SSE4_1 1)
 768     set(GMX_X86_SSE2   1)
 769     if (NOT ACCELERATION_QUIETLY)
 770       message(STATUS "Enabling SSE4.1 Gromacs acceleration, and it will help compiler optimization.")
 771     endif()
 772
 773 elseif(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA" OR ${GMX_CPU_ACCELERATION} STREQUAL "AVX_256")
 774
 775     # Set the AVX compiler flag for both these choices!
 776
 777     GMX_TEST_CFLAG(GNU_AVX_CFLAG "-mavx" GROMACS_C_FLAGS)
 778     if (NOT GNU_AVX_CFLAG AND GMX_NATIVE_WINDOWS)
 779         GMX_TEST_CFLAG(MSVC_AVX_CFLAG "/arch:AVX" GROMACS_C_FLAGS)
 780     endif (NOT GNU_AVX_CFLAG AND GMX_NATIVE_WINDOWS)
 781     if (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 782         message(WARNING "No C AVX flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 783     endif (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 784
 785     if (CMAKE_CXX_COMPILER_LOADED)
 786         GMX_TEST_CXXFLAG(GNU_AVX_CXXFLAG "-mavx" GROMACS_CXX_FLAGS)
 787         if (NOT GNU_AVX_CXXFLAG AND GMX_NATIVE_WINDOWS)
 788             GMX_TEST_CXXFLAG(MSVC_AVX_CXXFLAG "/arch:AVX" GROMACS_CXX_FLAGS)
 789         endif (NOT GNU_AVX_CXXFLAG AND GMX_NATIVE_WINDOWS)
 790         if (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 791             message(WARNING "No C++ AVX flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 792         endif (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 793     endif()
 794
 795     # Set the FMA4 flags (MSVC doesn't require any)
 796     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA" AND NOT MSVC)
 797         GMX_TEST_CFLAG(GNU_FMA_CFLAG "-mfma4" GROMACS_C_FLAGS)
 798         if (NOT GNU_FMA_CFLAG)
 799             message(WARNING "No C FMA4 flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 800         endif(NOT GNU_FMA_CFLAG)
 801         GMX_TEST_CFLAG(GNU_XOP_CFLAG "-mxop" GROMACS_C_FLAGS)
 802         # No big deal if we do not have xop, so no point yelling warnings about it.
 803         if (CMAKE_CXX_COMPILER_LOADED)
 804             GMX_TEST_CXXFLAG(GNU_FMA_CXXFLAG "-mfma4" GROMACS_CXX_FLAGS)
 805             if (NOT GNU_FMA_CXXFLAG)
 806                 message(WARNING "No C++ FMA flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 807             endif (NOT GNU_FMA_CXXFLAG)
 808             GMX_TEST_CXXFLAG(GNU_XOP_CXXFLAG "-mxop" GROMACS_CXX_FLAGS)
 809             # No big deal if we do not have xop, so no point yelling warnings about it.
 810         endif()
 811     endif()
 812
 813     # Only test the header after we have tried to add the flag for AVX support
 814     check_include_file(immintrin.h  HAVE_IMMINTRIN_H ${GROMACS_C_FLAGS})
 815
 816     if(NOT HAVE_IMMINTRIN_H)
 817         message(FATAL_ERROR "Cannot find immintrin.h, which is required for AVX intrinsics support. Consider switching compiler.")
 818     endif(NOT HAVE_IMMINTRIN_H)
 819
 820     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_256")
 821         try_compile(TEST_AVX ${CMAKE_BINARY_DIR}
 822             "${CMAKE_SOURCE_DIR}/cmake/TestAVX.c"
 823             COMPILE_DEFINITIONS "${GROMACS_C_FLAGS}")
 824         if(NOT TEST_AVX)
 825             message(FATAL_ERROR "Cannot compile AVX intrinsics. Consider switching compiler.")
 826         endif()
 827     endif()
 828
 829     # GCC requires x86intrin.h for FMA support. MSVC 2010 requires intrin.h for FMA support.
 830     check_include_file(x86intrin.h HAVE_X86INTRIN_H ${GROMACS_C_FLAGS})
 831     check_include_file(intrin.h HAVE_INTRIN_H ${GROMACS_C_FLAGS})
 832
 833     # The user should not be able to set this orthogonally to the acceleration
 834     set(GMX_X86_SSE4_1 1)
 835     set(GMX_X86_SSE2   1)
 836
 837     # But just enable one of the choices internally...
 838     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA")
 839         set(GMX_CPU_ACCELERATION_X86_AVX_128_FMA 1)
 840         set(GMX_X86_AVX_128_FMA 1)
 841         if (NOT ACCELERATION_QUIETLY)
 842           message(STATUS "Enabling 128-bit AVX Gromacs acceleration (with fused-multiply add), and it will help compiler optimization.")
 843         endif()
 844     else()
 845         # If we are not doing AVX_128, it must be AVX_256...
 846         set(GMX_CPU_ACCELERATION_X86_AVX_256 1)
 847         set(GMX_X86_AVX_256 1)
 848         if (NOT ACCELERATION_QUIETLY)
 849           message(STATUS "Enabling 256-bit AVX Gromacs acceleration, and it will help compiler optimization.")
 850         endif()
 851     endif()
 852
 853 elseif(${GMX_CPU_ACCELERATION} STREQUAL "BLUEGENE")
 854 # GMX_CPU_ACCELERATION=BlueGene should be set in the Toolchain-BlueGene?-???.cmake file
 855     if (NOT ACCELERATION_QUIETLY)
 856       message(STATUS "Configuring for BlueGene")
 857     endif()
 858     set(GMX_BLUEGENE 1)
 859     if (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 860         set(SHARED_LIBS_DEFAULT OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 861         set(BUILD_SHARED_LIBS OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 862     endif (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 863     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on BlueGene" FORCE)
 864     set(GMX_X11 OFF CACHE BOOL "X11 not compatible with BlueGene, disabled!" FORCE)
 865     set(GMX_THREAD_MPI OFF CACHE BOOL "Thread-MPI not compatible with BlueGene, disabled!" FORCE)
 866     set(GMX_MPI ON CACHE BOOL "Use MPI on BlueGene" FORCE)
 867 # Access to /etc/passwd is not available on the back end of BlueGene,
 868 # despite being detected by CMake. This can cause linker warnings
 869 # about harmless things in src/gmxlib/string2.h.
 870     set(HAVE_PWD_H OFF)
 871 # The automatic testing for endianness does not work for the BlueGene cross-compiler
 872     set(GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER 1 CACHE INTERNAL "BlueGene has big endian FP byte order (by default)" FORCE)
 873     set(GMX_IEEE754_BIG_ENDIAN_WORD_ORDER 1 CACHE INTERNAL "BlueGene has big endian FP word order (by default)" FORCE)
 874 else(${GMX_CPU_ACCELERATION} STREQUAL "NONE")
 875     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_CPU_ACCELERATION}. Pick one of None, SSE2, SSE4.1, AVX_128_FMA, AVX_256, BlueGene")
 876 endif(${GMX_CPU_ACCELERATION} STREQUAL "NONE")
 877 set(ACCELERATION_QUIETLY TRUE CACHE INTERNAL "")
 878
 879 # Process QM/MM Settings
 880 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 881 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 882     set(GMX_QMMM_GAUSSIAN 1)
 883 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 884     set(GMX_QMMM_MOPAC 1)
 885 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 886     set(GMX_QMMM_GAMESS 1)
 887 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 888     set(GMX_QMMM_ORCA 1)
 889 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 890     # nothing to do
 891 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 892     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 893 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 894
 895 # Process FFT library settings - if not OpenMM build
 896 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 897 set(PKG_FFT "")
 898 set(PKG_FFT_LIBS "")
 899 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 900     if(GMX_DOUBLE)
 901         set(FFTW fftw)
 902     else()
 903         set(FFTW fftwf)
 904     endif()
 905
 906     if(GMX_BUILD_OWN_FFTW)
 907       add_subdirectory(src/contrib/fftw)
 908     else()
 909       find_package(FFTW COMPONENTS ${FFTW})
 910     endif()
 911
 912     string(TOUPPER "${FFTW}" FFTW)
 913     set(PKG_FFT "${${FFTW}_PKG}")
 914     include_directories(${${FFTW}_INCLUDE_DIRS})
 915     set(FFT_LIBRARIES ${${FFTW}_LIBRARIES})
 916     if(NOT ${FFTW}_FOUND)
 917       MESSAGE(FATAL_ERROR "Cannot find FFTW 3 (with correct precision - libfftw3f for single-precision GROMACS or libfftw3 for double-precision GROMACS). Either choose the right precision, choose another FFT(W) library, enable the advanced option to let GROMACS build FFTW 3 for you, or use the really slow GROMACS built-in fftpack library.")
 918     endif()
 919
 920     set(GMX_FFT_FFTW3 1)
 921
 922     if (NOT ${GMX_CPU_ACCELERATION} STREQUAL "NONE" AND NOT ${FFTW}_HAVE_SIMD)
 923       message(WARNING "The fftw library found is compiled without SIMD support, which makes it slow. Consider recompiling it or contact your admin")
 924     endif()
 925
 926     if(NOT ${GMX_CPU_ACCELERATION} STREQUAL "NONE" AND ${FFTW}_HAVE_AVX)
 927         # If we're not doing CPU acceleration, we don't care about FFTW performance on x86 either
 928         message(WARNING "The FFTW library was compiled with --enable-avx to enable AVX SIMD instructions. That might sound like a good idea for your processor, but for FFTW versions up to 3.3.3, these are slower than the SSE/SSE2 SIMD instructions for the way GROMACS uses FFTs. Limitations in the way FFTW allows GROMACS to measure performance make it awkward for either GROMACS or FFTW to make the decision for you based on runtime performance. You should compile a different FFTW library with --enable-sse or --enable-sse2. If you have a more recent FFTW, you may like to compare the performance of GROMACS with FFTW libraries compiled with and without --enable-avx. However, the GROMACS developers do not really expect the FFTW AVX optimization to help, because the performance is limited by memory access, not computation.")
 929     endif()
 930
 931 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 932 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 933     find_package(MKL REQUIRED)
 934     include_directories(${MKL_INCLUDE_DIR})
 935     set(FFT_LIBRARIES ${MKL_LIBRARIES})
 936     set(PKG_FFT_LIBS ${MKL_LIBRARIES})
 937
 938     set(GMX_FFT_MKL 1)
 939     set(HAVE_MKL 1)
 940
 941 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 942 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 943 #    set(GMX_FFT_ACML 1)
 944 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 945     MESSAGE(STATUS "Using internal FFT library - fftpack")
 946     set(GMX_FFT_FFTPACK 1)
 947 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 948     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, mkl, fftpack")
 949 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 950
 951 # enable threaded fftw3 if we've found it
 952 if(FFTW3_THREADS OR FFTW3F_THREADS)
 953     add_definitions(-DFFT5D_FFTW_THREADS)
 954 endif()
 955
 956 set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 957 set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 958 # MKL has BLAS/LAPACK routines
 959 if(NOT HAVE_MKL AND NOT ACCELERATE_FRAMEWORK)
 960   if(GMX_EXTERNAL_BLAS)
 961     if (GMX_BLAS_USER)
 962         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_BLAS_USER})
 963     else(GMX_BLAS_USER)
 964         set(BLAS_FIND_QUIETLY ON)
 965         find_package(BLAS)
 966         if (BLAS_FOUND)
 967           list(APPEND GMX_EXTRA_LIBRARIES ${BLAS_LIBRARIES})
 968         else()
 969           MESSAGE(STATUS "Using internal BLAS library")
 970           set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external BLAS instead of built-in" FORCE)
 971         endif()
 972     endif(GMX_BLAS_USER)
 973   endif(GMX_EXTERNAL_BLAS)
 974   if(GMX_EXTERNAL_LAPACK)
 975     if (GMX_LAPACK_USER)
 976         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_LAPACK_USER})
 977     else(GMX_LAPACK_USER)
 978         set(LAPACK_FIND_QUIETLY ON)
 979         find_package(LAPACK)
 980         if (LAPACK_FOUND)
 981           list(APPEND GMX_EXTRA_LIBRARIES ${LAPACK_LIBRARIES})
 982         else()
 983           MESSAGE(STATUS "Using internal LAPACK library")
 984           set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in" FORCE)
 985         endif()
 986     endif(GMX_LAPACK_USER)
 987   endif(GMX_EXTERNAL_LAPACK)
 988 endif()
 989 mark_as_advanced(GMX_EXTERNAL_LAPACK)
 990 mark_as_advanced(GMX_EXTERNAL_BLAS)
 991
 992 set(GMX_USE_PLUGINS OFF CACHE INTERNAL "Whether GROMACS will really try to compile support for VMD plugins")
 993
 994 if(GMX_LOAD_PLUGINS)
 995   if(CYGWIN OR NOT WIN32)
 996     # Native Windows does not have, nor need dlopen
 997     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 998     include(gmxTestdlopen)
 999     gmx_test_dlopen(HAVE_DLOPEN)
1000   endif()
1001
1002   # so, should we use plug-ins?
1003   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
1004     if(NOT VMD_QUIETLY)
1005       MESSAGE(STATUS
1006           "Found the ability to use plug-ins when building shared libaries, "
1007           "so will compile to use plug-ins (e.g. to read VMD-supported file "
1008           "formats).")
1009     endif()
1010     if(NOT GMX_VMD_PLUGIN_PATH)
1011       find_package(VMD)
1012     endif()
1013     set(GMX_USE_PLUGINS ON)
1014     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
1015     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
1016   else()
1017     set(PKG_DL_LIBS)
1018   endif()
1019 endif(GMX_LOAD_PLUGINS)
1020 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
1021
1022 if(EXISTS "${CMAKE_SOURCE_DIR}/admin/.isreposource")
1023     if(NOT CMAKE_CROSSCOMPILING)
1024         option(GMX_BUILD_MANPAGES "Build man pages" ON)
1025     else()
1026         message(STATUS "Building the man pages is not available when "
1027             "cross-compiling the developer version from git")
1028     endif()
1029 else()
1030     #make sure source package contains all man pages
1031     if(NOT EXISTS "${CMAKE_SOURCE_DIR}/man/man1/ngmx.1")
1032         message(FATAL_ERROR "Man pages are missing from source package.")
1033     endif()
1034 endif()
1035 mark_as_advanced(GMX_BUILD_MANPAGES)
1036
1037 # Math and thread libraries must often come after all others when linking...
1038 if(HAVE_LIBM)
1039     list(APPEND GMX_EXTRA_LIBRARIES m)
1040 endif(HAVE_LIBM)
1041
1042 if(GMX_FAHCORE)
1043   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
1044       "Path to swindirect.h")
1045   include_directories(${COREWRAP_INCLUDE_DIR})
1046 endif(GMX_FAHCORE)
1047
1048 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
1049 # these are set after everything else
1050 if (NOT DEFINED GROMACS_C_FLAGS_SET)
1051     set(GROMACS_C_FLAGS_SET true CACHE INTERNAL "Whether to reset the C flags"
1052         FORCE)
1053     set(CMAKE_C_FLAGS "${GROMACS_C_FLAGS} ${CMAKE_C_FLAGS}" CACHE STRING
1054         "Flags used by the compiler during all build types" FORCE)
1055     if (CMAKE_CXX_COMPILER_LOADED)
1056         set(CMAKE_CXX_FLAGS "${GROMACS_CXX_FLAGS} ${CMAKE_CXX_FLAGS}" CACHE STRING
1057             "Flags used by the compiler during all build types" FORCE)
1058     endif()
1059     set(CMAKE_EXE_LINKER_FLAGS
1060         "${GROMACS_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}"
1061         CACHE STRING "Linker flags for creating executables" FORCE)
1062     set(CMAKE_SHARED_LINKER_FLAGS
1063         "${GROMACS_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}"
1064         CACHE STRING "Linker flags for creating shared libraries" FORCE)
1065 endif (NOT DEFINED GROMACS_C_FLAGS_SET)
1066
1067 if(NOT GMX_OPENMP)
1068     #Unset all OpenMP flags in case OpenMP was disabled either by the user
1069     #or because it was only partially detected (e.g. only for C but not C++ compiler)
1070     unset(OpenMP_C_FLAGS CACHE)
1071     unset(OpenMP_CXX_FLAGS CACHE)
1072     unset(OpenMP_LINKER_FLAGS CACHE)
1073     unset(OpenMP_SHARED_LINKER_FLAGS)
1074 endif()
1075 set(PKG_CFLAGS "${PKG_CFLAGS} ${OpenMP_C_FLAGS}")
1076
1077 ######################################
1078 # Output compiler and CFLAGS used
1079 ######################################
1080 get_compiler_info(C BUILD_C_COMPILER BUILD_CFLAGS)
1081 if (CMAKE_CXX_COMPILER_LOADED)
1082     get_compiler_info(CXX BUILD_CXX_COMPILER BUILD_CXXFLAGS)
1083 endif ()
1084
1085 ########################################################################
1086 # Specify install locations and which subdirectories to process        #
1087 ########################################################################
1088 if (GMX_USE_RELATIVE_INSTALL_PATH)
1089     set(GMX_INSTALL_PREFIX "" CACHE STRING "Prefix gets appended to CMAKE_INSTALL_PREFIX. For cpack it sets the root folder of the archive.")
1090     mark_as_advanced(GMX_INSTALL_PREFIX)
1091 else()
1092     set(GMX_INSTALL_PREFIX "${CMAKE_INSTALL_PREFIX}/")
1093 endif()
1094
1095 if ( NOT DEFINED GMXLIB )
1096     set(GMXLIB lib)
1097 endif()
1098 set(LIB_INSTALL_DIR "${GMX_INSTALL_PREFIX}${GMXLIB}")
1099 set(BIN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}bin)
1100 set(DATA_INSTALL_DIR ${GMX_INSTALL_PREFIX}share/gromacs)
1101 set(MAN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}share/man)
1102 set(INCL_INSTALL_DIR ${GMX_INSTALL_PREFIX}include)
1103
1104 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
1105
1106 ##################################################################
1107 # Shared library settings - Darwin uses INSTALL_NAME_DIR instead!
1108 ##################################################################
1109 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
1110     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
1111     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
1112     set(CMAKE_INSTALL_RPATH "\\\$ORIGIN/../${GMXLIB}")
1113     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
1114 endif()
1115
1116 #COPYING file: Only necessary for binary distributions.
1117 #Simpler to always install.
1118 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
1119
1120 add_subdirectory(share)
1121 add_subdirectory(include)
1122 add_subdirectory(src)
1123 add_subdirectory(scripts)
1124
1125 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
1126 # Don't bother the user after the first configure pass.
1127 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
1128     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
1129     unset(CUDA_NOTFOUND_AUTO)
1130     unset(CUDA_NOTFOUND_MESSAGE)
1131 endif()
1132 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
1133
1134 #######################
1135 ## uninstall target
1136 #######################
1137     CONFIGURE_FILE(
1138                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
1139                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
1140                    IMMEDIATE @ONLY)
1141 ###########################
1142 ADD_CUSTOM_TARGET(uninstall
1143                   "${CMAKE_COMMAND}" -P
1144                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
1145 ###########################
1146
1147 ########################################################################
1148 # Tests                                                                #
1149 ########################################################################
1150
1151 include(CTest)
1152 mark_as_advanced(BUILD_TESTING)
1153 IF(BUILD_TESTING)
1154         enable_testing()
1155         add_subdirectory(tests)
1156 ENDIF()
1157